Browser - Artopolis 97/browser.iso/mac/artrope/artrope.dir/00070_Script_creditsFrame

Text File | 1997-10-08 | 6KB | 213 lines

global gIsMac

on exitFrame
  if the frontWindow = the stage then

    if the mouseV < 0 then
      installmyMenu
    else
      installMenu 0
    end if

    if rollover(3) then
      startArtropolisCredits
    end if

    if rollover(4) then
      startDNACredits
    end if
  end if

  go to the frame
end

on mouseDown
  puppetSound 3, "buttons.aif"
  puppetSound 2, "solostep.aif"
  deletePrefile
  cursor 200
  if gIsMac then
    go to frame "MacEnd"
  else
    go to frame "PCEnd"
  end if
end

on startArtropolisCredits
  blendMe(5, #in)
  puppetSprite 8,0
  puppetsprite 9,0
  set the visible of sprite(8) to true
  set the visible of sprite(9) to true
  set the visible of sprite(10) to false
  set the visible of sprite(11) to false
  if the puppet of sprite 8 = 0 then puppetSprite 8,1
  if the puppet of sprite 9 = 0 then puppetSprite 9,1
  updateStage
  moverAtropolis(3,[8,9]) --artropolis credits
  set the visible of sprite(8) to false
  set the visible of sprite(9) to false
  blendMe(5, #out)

end

on startDNACredits
  blendMe(6, #in)
  puppetsprite 10,0
  puppetsprite 11,0
  set the visible of sprite(8) to false
  set the visible of sprite(9) to false
  set the visible of sprite(10) to true
  set the visible of sprite(11) to true
  if the puppet of sprite 10 = 0 then puppetSprite 10,1
  if the puppet of sprite 11 = 0 then puppetSprite 11,1
  updateStage
  moverDNA(4,[10,11]) --dna credits
  set the visible of sprite(10) to false
  set the visible of sprite(11) to false
  blendMe(6,#out)
end

--=============================================================
--atropolis credits mover, made two handlers to hard-code it in
--attempts to make it faster.
---------------------------------------------------------------
on moverAtropolis xSprite, theWomb
  --xSprite = either the right quickdraw rect or the left one
  repeat while the mouseV < 237 and the mouseV > 0
    if the mouseH >320 then
      set the cursor of sprite(xSprite) to [93,94]
      repeat while the mouseH > 320 and the mouseV < 237 and the mouseV > 0
        if the mouseDown then exit
        set speed = integer((the mouseH - 320)/100)
        repeat with i in theWomb
          if the mouseDown then exit
          set the locH of sprite(i) to the locH of sprite(i) - speed
          if the locH of sprite(i) <= -4481 then
            set the locH of sprite(i) to the locH of sprite(i) +(8762)
          end if
          if the locH of sprite(i) >= 4381  then
            set the locH of sprite(i) to the locH of sprite(i)  - 8762
          end if
        end repeat
        updateStage
      end repeat
    end if

    if the mouseH <= 320 then
      set the cursor of sprite(xSprite) to [91,92]
      repeat while the mouseH < 320 and the mouseV < 237 and the mouseV > 0
        if the mouseDown then exit
        set speed = -(integer((320 - the mouseH)/100))
        repeat with i in theWomb
          if the mouseDown then exit
          set the locH of sprite(i) to the locH of sprite(i)  - speed
          if the locH of sprite(i) <= -4481 then
            set the locH of sprite(i) to the locH of sprite(i) +(8762)
          end if
          if the locH of sprite(i) >= 4381  then
            set the locH of sprite(i) to the locH of sprite(i)  -8762
          end if
        end repeat
        updateStage
      end repeat
    end if
  end repeat
  set the cursor of sprite(xSprite) = -1
end



--=============================================================
--atropolis credits mover, made two handlers to hard-code it in
--attempts to make it faster.
---------------------------------------------------------------
on moverDNA xSprite, theWomb
  --xSprite = either the right quickdraw rect or the left one
  repeat while the mouseV >255
    if the mouseH > 320 then
      set the cursor of sprite(xSprite) to [93,94]
      repeat while the mouseH > 320 and the mouseV > 255
        if the mouseDown then exit
        set speed = integer((the mouseH - 320)/100)
        repeat with i in theWomb
          if the mouseDown then exit
          set the locH of sprite(i) to the locH of sprite(i) - speed
          if the locH of sprite(i) <= -2758 then
            set the locH of sprite(i) to the locH of sprite(i) +(5316)
          end if
          if the locH of sprite(i) >= 2658  then
            set the locH of sprite(i) to the locH of sprite(i)  - 5316
          end if
        end repeat
        updateStage
      end repeat
    end if

    if the mouseH <= 320 then
      set the cursor of sprite(xSprite) to [91,92]
      repeat while the mouseH < 320 and the mouseV > 255
        if the mouseDown then exit
        set speed = -(integer((320 - the mouseH)/100))
        repeat with i in theWomb
          if the mouseDown then exit
          set the locH of sprite(i) to the locH of sprite(i)  - speed
          if the locH of sprite(i) <= -2758 then
            set the locH of sprite(i) to the locH of sprite(i) +(5316)
          end if
          if the locH of sprite(i) >= 2658  then
            set the locH of sprite(i) to the locH of sprite(i)  -5316
          end if
        end repeat
        updateStage
      end repeat
    end if
  end repeat
  set the cursor of sprite(xSprite) = -1
end


--===================================
--used to blend the titles for the credits
-------------------------------------
on blendMe xSprite, xState
  case (xState) of

    #in:
      set the blend of sprite xSprite = 0
      set the visible of sprite xSprite = 1
      updateStage
      repeat with i = 1 to 20
        set the blend of sprite xSprite = i*5
        updateStage
      end repeat

    #out:
      repeat with i = 20 down to 1
        set the blend of sprite xSprite = i*5
        updateStage
      end repeat
      set the blend of sprite xSprite = 0
      set the visible of sprite xSprite = 0
      updateStage
  end case

end


on keyDown

  if gIsMac then
    if the commandDown and (the keycode = 12 or the keycode = 47) then
      go to frame "MacEnd"
    else

      if  (the commandDown and the keyCode = 12) or (the keycode = 112) or (the keycode = 12) then
        go to frame "PCEnd"
      end if
    end if
  end if

end