Black Box 4/BlackBox.cdr/proglang/ladybug1.arj/PUFFER.BUG

Text File | 1991-01-13 | 2KB | 160 lines

;puffer.bug

to "start
PU SETXY -25 0
PD
end

to "halfcircle  :N
REPEAT 7 [FD :N RT 10]
PU REPEAT 5 [FD :N RT 10]
PD REPEAT 6 [FD :N RT 10]
end

to "body
HALFCIRCLE 8
FD 8 RT 90 FD 90 BK 90
end

to "circle  :R
REPEAT 36 [RT 5 FD .174532 * :R RT 5]
end

to "eye
PC 3
PU SETXY 94 90 PD CIRCLE 3
PC 2 SETXY 97 90 FD 1 BK 1 PC 1
end

to "nostrils
PU SETXY 124 95
PD CIRCLE 4
end

to "upper.jaw
FD 15 RT 94 FD 45 RT 86
FD 9 RT 86 FD 45 RT 94
EYE
NOSTRILS
PU SETXY 87.9909 81.7679
PD
end

to "lower.jaw
RT 180 FD 13.9 LT 100 FD 40
LT 160 FD 40 RT 80
end

to "head
UPPER.JAW
RT 10
LOWER.JAW
end

to "tri  :N
REPEAT 3 [FD :N RT 120 ]
end

to "neck
RT 180
REPEAT 15 [FD 5 LT 10]
REPEAT 12 [RT 10 FD 3]
LT 60
HEAD
SETH 0
FD 5 LT 90
REPEAT 15 [TRI 4 FD 4 LT 10]
REPEAT 12 [TRI 4 FD 4 RT 14]
end

to "tail
START
SETH 330
REPEAT 3 [FD 5 RT 10]
REPEAT 13 [TRI 5 FD 5 LT 10]
REPEAT 11 [TRI 5 FD 5 RT 10]
LT 110 BK 5 TRI 10
end

to "legs
START
SETH 90
TRI 15 FD 8 TRI 15
FD 64 TRI 15 FD 8
TRI 15
end

to "points
START
SETH -60
REPEAT 7 [TRI 8 RT 60 FD 8 LT 50]
PU
REPEAT 5 [TRI 8 RT 60 FD 8 LT 50]
PD
REPEAT 6 [TRI 8 RT 60 FD 8 LT 50]
end

to "tip
REPEAT 10 [FD 1 LT 18]
FD 30 BK 20 LT 180
end

to "wings
PU SETXY 40 25 SETH 0 PD
REPEAT 6 [FD 8 LT 5]
FD 40 REPEAT 6 [TIP]
BK 20 LT 180 REPEAT 7 [FD 3 LT 10]
end

to "open
PC 0 LOWER.JAW
RT 21.5 PC 1 LOWER.JAW
end

to "shut
PC 0 LOWER.JAW
LT 21.5 PC 1 LOWER.JAW
end

to "chew
PU
SETXY 87.9909 81.7679
SETH 0 HT
PD RT 10
REPEAT 3 [SHUT OPEN]
end

to "flame
PC 2 FD 50 PC 0 BK 50
end

to "fire
PU SETXY 87.9909 81.7679 PC 2 PD
SETH 95 FLAME
end

to "smoke
PU SETXY 127 95 SETH 30 PD PC 3
FD 12 PC 0 BK 12
end

to "breathe
REPEAT 5 [FIRE RT 5 FIRE LT 5]
REPEAT 3 [SMOKE]
end

to "puff
PALETTE 0 PC 1
START
BODY
NECK
TAIL
LEGS
POINTS
WINGS
REPEAT 3 [CHEW BREATHE]
end

make "description [puffing dragon, type puff]
print :description