home *** CD-ROM | disk | FTP | other *** search
/ Black Box 4 / BlackBox.cdr / hamradio / nosvw137.arj / NOSFILES.ZIP / DOM2HOST.BAS < prev    next >
BASIC Source File  |  1991-09-18  |  3KB  |  100 lines
  1. 10 REM    "DOM2HOST.BAS"                                   [137]
  2. 20 REM
  3. 30 REM        Translates NOS hosts files in DOMAIN.TXT format to
  4. 40 REM        HOSTS.NET format (for NET) or
  5. 50 REM        MSYSHOST.NET format (for MSYS)
  6. 60 REM
  7. 70 REM    Release 129  (i.e. 199'1', week '29')
  8. 80 REM    19 July 1991
  9. 90 REM
  10. 100 REM   Written by Ian Wade, G3NRW @ GB7BIL
  11. 110 REM
  12. 120 REM   This program is Public Domain and may be freely distributed.
  13. 130 REM
  14. 140 REM   **************************************************************
  15. 150 REM
  16. 160 REM   IMPORTANT:  BEFORE RUNNING THIS PROGRAM FOR THE FIRST TIME, SET
  17. 170 REM               THE VARIABLE T$ IN THE PROGRAM STATEMENT IMMEDIATELY
  18. 180 REM               BELOW TO:
  19. 190 REM                 "H" IF CONVERTING TO HOSTS.NET FORMAT, OR
  20. 200 REM                 "M" IF CONVERTING TO MSYSHOST.NET FORMAT.
  21. 210 REM
  22. 220 REM               THEN SAVE THE PROGRAM.
  23. 230 REM   **************************************************************
  24. 240 REM
  25. 250        T$="H"
  26. 260 REM
  27. 270 REM
  28. 280 REM   FILE FORMATS:
  29. 290 REM   ============
  30. 300 REM
  31. 310 REM   Input File: DOMAIN.TXT format:
  32. 320 REM      callsign.ampr.org.  IN A  44.131.rr.xxx  #comment
  33. 330 REM
  34. 340 REM   Output File: HOSTS.NET format:
  35. 350 REM      44.131.rr.xxx  callsign.ampr.org  callsign  #comment
  36. 360 REM
  37. 370 REM   Output File: MSYSHOST.NET format:
  38. 380 REM      44.131.rr.xxx  [callsign]  callsign  #comment
  39. 390 REM
  40. 400 ON ERROR GOTO 890
  41. 410 D$ = ""
  42. 420 INPUT "Input file name (e.g. DOMAIN.TXT), or RETURN to quit: ",D$
  43. 430 IF D$ = "" THEN 980
  44. 440 OPEN "I", #1, D$
  45. 450 ON ERROR GOTO 0
  46. 460 H$ = ""
  47. 470 INPUT "Output filename (e.g. HOSTS.NET),  or RETURN to quit: ",H$
  48. 480 IF H$ = "" THEN 980
  49. 490 ON ERROR GOTO 930
  50. 500 OPEN "I", #2, H$
  51. 510 CLOSE #2
  52. 520 PRINT
  53. 530 PRINT CHR$(7) + "****************** WARNING:  file " + H$ + " already exists."
  54. 540 PRINT
  55. 550 Y$=""
  56. 560 INPUT "                        Do you wish to overwrite it (y/n)? ", Y$
  57. 570 PRINT
  58. 580 IF Y$ = "y" OR Y$ = "Y" THEN 600
  59. 590 GOTO 460
  60. 600 ON ERROR GOTO 0
  61. 610 ON ERROR GOTO 940
  62. 620 OPEN "O", #2, H$
  63. 630 ON ERROR GOTO 0
  64. 640 PRINT #2, "# Converted from " + D$
  65. 650 PRINT #2, "# on " + DATE$ + " at " + TIME$
  66. 660 PRINT #2, "#"
  67. 670 PRINT "Converting ";
  68. 680 IF EOF(1) THEN 840
  69. 690 PRINT ".";
  70. 700 LINE INPUT #1, L$
  71. 710 X$=MID$(L$,1,1)
  72. 720 IF X$ = "#" OR X$ = " " OR X$ = "   " THEN 820
  73. 730 N=INSTR(L$,".ampr.org.")
  74. 740 C$=MID$(L$,1,N-1)
  75. 750 N=INSTR(L$,"44.131")
  76. 760 M=INSTR(N+1,L$,"#")
  77. 770 I$=MID$(L$,N,M-1-N)
  78. 780 IF T$ = "H" THEN Z$=I$+" " + C$+".ampr.org "+C$ + " " + MID$(L$,M)
  79. 790 IF T$ = "M" THEN Z$=I$+" [" + C$ + "] " + C$ + " " + MID$(L$,M)
  80. 800 PRINT #2, Z$
  81. 810 GOTO 680
  82. 820 PRINT #2, L$
  83. 830 GOTO 680
  84. 840 PRINT
  85. 850 PRINT "Done"
  86. 860 PRINT
  87. 870 CLOSE
  88. 880 GOTO 400
  89. 890 PRINT
  90. 900 PRINT CHR$(7) + "****************** File " D$ " does not exist.  Try again"
  91. 910 PRINT
  92. 920 RESUME 410
  93. 930 RESUME 600
  94. 940 PRINT
  95. 950 PRINT CHR$(7) + "****************** Output filename error.  Try again."
  96. 960 PRINT
  97. 970 RESUME 460
  98. 980 CLOSE
  99. 990 STOP
  100.