home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Black Box 4
/
BlackBox.cdr
/
editors
/
amac41.arj
/
COM002.QM
< prev
next >
Wrap
Text File
|
1991-07-28
|
8KB
|
145 lines
* COM002.QM
* Written By Tom Hogshead
* [ See COMTxx.QM For Use ]
* July 28, 1991
* Key Subfile Description
* ===== ========= =====================================================
* @(5) --Make Macro Title Box
*
* @(6) --Copy Macro Title To Index
*
* @(9) --Remove Macro Title Box
*
* (_) {e:\up\COMT*}--Return To COMTxx.QM
*
*-- eoi
*
* ----------------------------------------------------------------------
* @(5) Make macro title box
* (like this, multi-lines OK)
* ----------------------------------------------------------------------
* Type macro title with *no* star in front. Either mark title as a block,
* or press @5, cursor down to end of title, and hit enter. Title need not
* have blank lines on top or bottom before macro execution. See JMPPOSxx.QM
* for discussion and use of position markers.
@5 MacroBegin *
* ------- Check and finish marking line or block if not marked -------*
gotoblockend * Test if block is closed |
jtrue OK: * If closed, go to OK |
markline * If not closed, close temporarily |
* or start mark |
gotoblockend * Move to end of block if closed or stay |
* where we are if block not yet closed |
jtrue OK: * If block is now closed, we started with |
* an open block |
makectrofscreen * Center for viewing |
Pause * Pause to mark end of block |
markline * Mark end of block |
OK: * |
* -------------------------- shift title --------------------------* |
BegLine * |
ShiftRight ShiftRight * Shift all lines to right twice |
AddLine * Add line under title |
GotoBlockBeg * Move to 1st char of first line |
insertline * Insert line on top of title |
cursordown * Move back to top of title |1.5
MarkColumn * Mark 1st character column |
endpara * Move to end of title |
BegLine * Move to begin of last line |
FillBlock '*' Return * Fill 1st column with '*' |
* ------------------------- make box bottom -------------------------* |
CursorDown * Move one line under title |
BegLine "*" * put * at begin of bottom line |
CursorRight * space right |
UnmarkBlock * Un-mark |
DropAnchor * Start block |
GoToColumn "72" Return * Finish block for dashes |
FillBlock "-" Return * fill block with dashes |
markline * Mark bottom line |
copy * Copy to scrap |
* --------------------------- make box top ---------------------------* |
prevpara * Move to begin of title |
Paste * paste bottom line to top line |
* --------------- Insert Position Marker On Top of Box ---------------* |
InsertLine BegLine * Insert a blank line |
"*" * with Marker on it |
CursorRight * |
#031 #030 * |
cursordown * |
cursordown * Cursor down to first line of title |
endline * Move to end of title for more edit |
scrolldown 4 * Re-position screen where we were |
* END: * |
unmarkblock *
*
* 48 bytes Fri 03-29-1991 15:13:26
* 61 bytes Thu 05-02-1991 12:24:22 OK for multi-line titles
* 67 bytes Tue 05-28-1991 21:06:20 (TH select title, add position marker)
* 68 bytes Mon 06-03-1991 22:48:52 (TH added BegLine after block marked)
* 69 bytes Tue 06-04-1991 08:48:51 (TH)
*
* ----------------------------------------------------------------------
* @(6) Copy macro title to index
* ----------------------------------------------------------------------
* Put cursor anywhere in macro title box not on top or bottom line.
* Press @6 to copy title to last line of index on top. Index must have
* at least one blank line at end. Title must not contain "--".
* If the first word in the title is enclosed in ( ) like (6), press @h,
* cursor down to select desired title, and press <enter> to return to
* title line below.
@6 MacroBegin *
UnmarkBlock * Make sure no blocks marked
Find "--" Return "B" Return * Move cursor to top line
CursorDown * Move down one line
MarkLine * Mark top of title
Find "--" Return Return * Move cursor to bottom line
CursorUp * Move to bottom of title
MarkLine * Finish marking title
Copy * Copy title to scrap
BegFile EndPara * Go to last line of index
CursorDown * Move to end of index
Begline *
Paste * Paste title to bottom of index
CursorRight CursorRight * Move to title in index to edit
UnmarkBlock * Un-mark title
*
* 16 bytes Sun 03-31-1991 21:01:48
* 34 bytes Wed 05-01-1991 02:51:46
*
* ----------------------------------------------------------------------
* @(9) Remove macro title box
* ----------------------------------------------------------------------
*
* Position cursor anywhere in title box. Press @9 to remove title box.
* Title box must have at least one blank line on top but need not have
* a blank line beneath it. Top line of box must be * --- >
@9 MacroBegin *
UnMarkBlock * un-mark all blocks
CursorDown * move down to find begin of box
MarkLine * mark top line
PrevPara * move to begin of box
* MarkLine * mark top line
Find "--" Return "L" Return * check if already boxed
JFalse END: * if not, end
DelLine *ELSE delete box top
Find "--" Return DelLine Return * Find box bottom
JFalse END: * if no box bottom
DelLine *ELSE delete box bottom
PrevPara * move to begin of first title line
END: *
ScrollDown * Re-position screen to where we were
UnMarkBlock * un-mark block
*
* 36 bytes Sun 05-05-1991 22:13:00 (TH @9)