home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Black Box 4
/
BlackBox.cdr
/
autocad
/
qs310.arj
/
QS.MNU
< prev
next >
Wrap
Lisp/Scheme
|
1990-08-28
|
60KB
|
3,234 lines
***BUTTONS
;
$p1=*
^c^c
^B
^O
^G
^D
^E
^T
***AUX1
;
$p1=*
^C^C
^B
^O
^G
^D
^E
^T
***POP1
[Tools]
[OSNAP]^C^C$p1= $p1=* OSNAP \
CENter
ENDpoint
INSert
[INTersection]INT
MIDpoint
NEArest
NODe
[PERpendicular]PER
QUAdrant
[QUICK,]QUICK,^Z$p1=*
TANgent
NONE
[~--]
[FILTERS... ]$p1=filters $p1=*
[Cancel]^C^C
[U]^C^CU
[Redo]^C^CREDO
[List]^C^CLIST
**filters
[Filters]
.X
.Y
.Z
.XY
.XZ
.YZ
[TOOLS...]$p1= $p1=*
***POP2
[Draw]
[Line]*^C^C$S=X $s=line line
[Arc]*^C^C$S=X $s=poparc arc
[Circle]*^C^C$S=X $s=popcircl circle
[Polyline]*^C^C$S=X $s=pline pline
[3D Polyline]*^C^C$S=X $S=3dpoly 3dpoly
[Insert]^C^Csetvar attdia 1 $S=X $s=insert insert
[Dtext]*^C^C$S=X $s=Dtext Dtext
[Hatch...]^C^C$i=hatch1 $i=*
[3D Construction...]$i=3dobjects $i=*
***POP3
[Modify]
[Erase]*^C^C$S=X $s=erase erase si auto
[Move]*^C^C$S=X $s=move move si auto
[Copy]*^C^C$S=X $s=copy copy si auto
[Properties]*^C^C$S=X $S=chprop chprop si auto
[Break]*^C^C$S=X $S=break break
[Fillet]*^C^C$S=X $S=fillet fillet
[Mirror]*^C^C$S=X $S=mirror mirror auto
[Trim]*^C^C$S=X $s=trim trim auto
[Extend]*^C^C$S=X $s=extend extend auto
[Stretch]*^C^C$S=X $s=stretch stretch crossing
[Edit Polylines]^C^C^P+
(defun m:p1(/ m:pa m:pc m:d m:w)(menucmd "S=X")(menucmd "S=PSEL");+
(setq m:d T)(while m:d (setq m:pc (ssget))(setq m:pa (ssname m:pc 0));+
(if(=(cdr(assoc 0 (entget m:pa))) "POLYLINE")(progn(setq m:d nil)+
(m:p2 m:pa m:pc))(progn(prompt "Entity selected is not a polyline")(terpri);+
(if (member (cdr (assoc 0 (entget m:pa))) '("LINE" "ARC"))(progn+
(initget "Yes No")(setq m:w (getkword "Do you want to turn it into one? <Y>"));+
(if (or (= m:w "Yes")(null m:w))(progn(setq m:d nil)(menucmd "S=X");+
(menucmd "S=P0")(command "PEDIT" m:pa "yes" pause)))))))))+
(defun m:p2(m:pa m:pc / m:pb)(menucmd "S=X")+
(if (= (setq m:pb (cdr (assoc 70 (entget m:pa)))) nil)(menucmd "S=P0");+
(progn (setq m:pb (/ m:pb 2))(if (>= m:pb 8)(menucmd "S=P16");+
(if(< m:pb 4)(menucmd "S=P0")(menucmd "S=P8")))))(command "PEDIT" m:pa pause))+
(defun perror (msg)(setq *error* m:err m:err nil)(princ))+
(defun C:PEDITM (/ m:err)(setq m:err *error* *error* perror)(m:p1);+
(setq *error* m:err m:err nil)(princ))(princ) PEDITM ^P
***POP4
[Display]
[Redraw]'redraw
[~--]
[Zoom Window]'zoom w
[Zoom Previous]'zoom p
[Zoom All]^C^Czoom a
[Zoom Dynamic]'zoom d
[~--]
[Pan]'pan
[Dview Options...]^C^C$i=dviewi $i=*
[Vpoint 3D...]^C^C$S=X $S=VPOINT3D $i=3dviews $i=*
[~--]
[Plan View (UCS)]^C^Cplan;;
[Plan View (World)]^C^Cplan wo
[~--]
[Set Viewports...]^C^C$S=X $S=vports $i=vporti $i=*
***POP5
[Settings]
[UCS Dialogue...]^C^C$S=X $s=ucs1 dducs
[UCS Options...]^C^C$S=X $S=ucs1 $i=ucs $i=*
[UCS Previous]^C^CUCS P
[~--]
[Drawing Aids...]'ddrmodes
[Entity Creation...]'ddemodes
[Modify Layer...]'ddlmodes
***POP6
[Options]
[Ashade...]^C^C^P(progn(setq m:err *error*)(princ))+
(defun *error* (msg)(princ msg)(setq *error* m:err m:err nil)(princ))+
(cond ((null C:SCENE)(vmon)(if (/= nil (findfile "ashade.lsp"));+
(progn (terpri)(prompt "Please wait... Loading ashade. ")(load "ashade")+
(menucmd "I=AS")(menucmd "I=*")(setq *error* m:err m:err nil))(progn (terpri);+
(prompt "The file 'Ashade.lsp' was not found in your current search directories.")+
(terpri)(prompt "Check your AutoShade Manual for installation instructions.");+
(setq *error* m:err m:err nil)(princ))))+
(T (setq *error* m:err m:err nil)(menucmd "I=AS")(menucmd "I=*")(princ))) ^P
[Fonts...]^C^C$i=fonts1 $i=*
***POP7
[File ]
[Save ]^C^CSave;
[End ]^C^Cend
[Quit ]^C^C$S=X $s=quit quit
[~-- ]
[Plot ]^C^Cplot
[Print]^C^Cprplot
***POP8
[Help]
[Help]'help
***icon
**poly
[Set Polymesh and Polyline Variables]
[acad(pmq)]'setvar surftype 5
[acad(pmc)]'setvar surftype 6
[acad(pmb)]'setvar surftype 8
[acad(plq)]'setvar splinetype 5
[acad(plc)]'setvar splinetype 6
[ Set SPLINESEGS]'setvar splinesegs \
[ Set SPLFRAME]'setvar splframe \
[ Set DENSITY]'setvar surfu \'setvar surfv \
[ Exit]$p3=pop3
**as
[Select Ashade Command]
[acad(camera)]^C^C$S=X $S=CAMERA camera \\\$i=as $i=*
[acad(camview)]^C^C$S=X $S=ASHADE camview
[acad(point)]^C^C$S=X $S=LIGHTS LIGHT \p \$i=as $i=*
[acad(directed)]^C^C$S=X $S=LIGHTS LIGHT \d \\$i=as $i=*
[acad(scene)]^C^C$S=X $S=ACTION scene
[acad(filmroll)]^C^C$S=X $S=ACTION filmroll
[ Exit]^c^c
**ucs
[User Coordinate System Options]
[ Set to World]^C^Cucs world
[acad(left)]^c^c^P(setvar"lastpoint"(trans(getvar"ucsorg")0 1))(princ) +
ucs 3p \@0,-1,0 @0,0,1 ^P
[ Set to Screen]^C^Cucs view
[acad(top)]^c^c^P(setvar"lastpoint"(trans(getvar"ucsorg")0 1))(princ) +
ucs 3p \@1,0,0 @0,1,0 ^P
[acad(front)]^c^c^P(setvar"lastpoint"(trans(getvar"ucsorg")0 1))(princ) +
ucs 3p \@1,0,0 @0,0,1 ^P
[acad(bottom)]^c^c^P(setvar"lastpoint"(trans(getvar"ucsorg")0 1))(princ) +
ucs 3p \@1,0,0 @0,-1,0 ^P
[acad(back)]^c^c^P(setvar"lastpoint"(trans(getvar"ucsorg")0 1))(princ) +
ucs 3p \@-1,0,0 @0,0,1 ^P
[acad(right)]^c^c^P(setvar"lastpoint"(trans(getvar"ucsorg")0 1))(princ) +
ucs 3p \@0,1,0 @0,0,1 ^P
[ Exit]^c^c
**3DViews
[Select View Direction]
[acad(ul)]^C^CVPOINT R;<<135;
[acad(l)]^C^CVPOINT R;<<180;
[acad(ll)]^C^CVPOINT R;<<225;
[acad(user)]
[acad(u)]^C^CVPOINT R;<<90;
[acad(p)]^C^Cvpoint 0,0,1
[acad(lo)]^C^CVPOINT R;<<270;
[acad(user)]
[acad(ur)]^C^CVPOINT R;<<45;
[acad(r)]^C^CVPOINT R;<<0;
[acad(lr)]^C^CVPOINT R;<<315;
[acad(user)]
[acad(t)]VPOINT;;
[acad(h)]$S=X $S=HIDE
[ Exit]^c^c
**dviewi
[DVIEW Options]
[acad(dvca)]^C^C$S=X $S=DVIEW select;\dview;p;;ca;\\;
[acad(dvzo)]^C^C$S=X $S=DVIEW select;\dview;p;;z;\;
[acad(dvpa)]^C^C$S=X $S=DVIEW select;\dview;p;;pa;\\;
[ Exit]^c^c
**3DObjects
[3D Objects and 3D Surface Commands]
[acad(box3d)]^C^C^P(progn(setq m:err *error*)(prin1))+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:BOX))(C:BOX))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(wedge)]^C^C^P(progn(setq m:err *error*)(princ));+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:WEDGE))(C:WEDGE))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(rev)]^C^C$S=X $S=3D revsurf
[acad(surftab1)]'setvar surftab1 \$I=*
[acad(pyramid)]^C^C^P(progn(setq m:err *error*)(princ))+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:PYRAMID))(C:PYRAMID))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(cone)]^C^C^P(progn(setq m:err *error*)(princ));+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:CONE))(C:CONE))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(rul)]^C^C$S=X $S=3D rulesurf
[acad(surftab2)]'setvar surftab2 \$I=*
[acad(dome)]^C^C^P(progn(setq m:err *error*)(princ));+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:DOME))(C:DOME))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(dish)]^C^C^P(progn(setq m:err *error*)(princ));+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:DISH))(C:DISH))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(edg)]^C^C$S=X $S=3D edgesurf
[acad(mesh)]^C^C^P(progn(setq m:err *error*)(princ));+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:MESH))(C:MESH))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(sphere)]^C^C^P(progn(setq m:err *error*)(princ));+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:SPHERE))(C:SPHERE))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(torus)]^C^C^P(progn(setq m:err *error*)(princ));+
(defun m:l3d ()(cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2"))(progn (terpri)(prompt +
"The file `3d.lsp' was not found in your current search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.")+
(princ))))(T (princ)))(cond ((not (null C:TORUS))(C:TORUS))(T (princ)));+
(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(prin1))(m:l3d)(princ) ^P
[acad(tab)]^C^C$S=X $S=3D tabsurf
[ Exit]^c^c
**fonts1
[Select Text Font]
[acad(romans)]^c^cstyle romans romans
[acad(romanc)]^c^cstyle romanc romanc
[acad(italicc)]^c^cstyle italicc italicc
[acad(romand)]^c^cstyle romand romand
[acad(romant)]^c^cstyle romant romant
[acad(italict)]^c^cstyle italict italict
[acad(monotxt)]^c^cstyle monotxt monotxt
[ Next]$i=fonts2 $i=*
[ Exit]^c^c
**fonts2
[Select Text Font]
[acad(gothice)]^c^cstyle gothice gothice
[acad(greeks)]^c^cstyle greeks greeks
[acad(scripts)]^c^cstyle scripts scripts
[acad(gothicg)]^c^cstyle gothicg gothicg
[acad(greekc)]^c^cstyle greekc greekc
[acad(scriptc)]^c^cstyle scriptc scriptc
[acad(gothici)]^c^cstyle gothici gothici
[ Next]$i=fonts3 $i=*
[ Exit]^c^c
**fonts3
[Select Text Font]
[acad(syastro)]^c^cstyle syastro syastro
[acad(symath)]^c^cstyle symath symath
[acad(symusic)]^c^cstyle symusic symusic
[acad(symap)]^c^cstyle symap symap
[acad(symeteo)]^c^cstyle symeteo symeteo
[acad(txt)]^c^cstyle txt txt
[acad(user)]
[ Beginning]$i=fonts1 $i=*
[ Exit]^c^c
**hatch1
[Select Hatch Pattern]
[ Previous/User]^c^chatch
[acad(ansi31)]^c^chatch ansi31
[acad(ansi32)]^c^chatch ansi32
[acad(ansi34)]^c^chatch ansi34
[acad(ansi35)]^c^chatch ansi35
[acad(ansi33)]^c^chatch ansi33
[acad(ansi36)]^c^chatch ansi36
[acad(ansi37)]^c^chatch ansi37
[acad(ansi38)]^c^chatch ansi38
[acad(box)]^c^chatch box
[acad(brass)]^c^chatch brass
[acad(brick)]^c^chatch brick
[acad(clay)]^c^chatch clay
[acad(cork)]^c^chatch cork
[ Next]$i=hatch2 $i=*
[ Exit]^c^c
**hatch2
[Select Hatch Pattern]
[acad(cross)]^c^chatch cross
[acad(dash)]^c^chatch dash
[acad(dolmit)]^c^chatch dolmit
[acad(dots)]^c^chatch dots
[acad(earth)]^c^chatch earth
[acad(escher)]^c^chatch escher
[acad(flex)]^c^chatch flex
[acad(grass)]^c^chatch grass
[acad(grate)]^c^chatch grate
[acad(hex)]^c^chatch hex
[acad(honey)]^c^chatch honey
[acad(hound)]^c^chatch hound
[acad(insul)]^c^chatch insul
[acad(line)]^c^chatch line
[ Next]$i=hatch3 $i=*
[ Exit]^c^c
**hatch3
[Select Hatch Pattern]
[acad(mudst)]^c^chatch mudst
[acad(net)]^c^chatch net
[acad(net3)]^c^chatch net3
[acad(plast)]^c^chatch plast
[acad(plasti)]^c^chatch plasti
[acad(sacncr)]^c^chatch sacncr
[acad(square)]^c^chatch square
[acad(stars)]^c^chatch stars
[acad(steel)]^c^chatch steel
[acad(swamp)]^c^chatch swamp
[acad(trans)]^c^chatch trans
[acad(triang)]^c^chatch triang
[acad(zigzag)]^c^chatch zigzag
[acad(angle)]^c^chatch angle
[ Beginning]$i=hatch1 $i=*
[ Exit]^c^c
**vporti
[Viewport Settings (Current is dominant)]
[acad(vp1)]^C^CVPORTS;SI
[acad(vp3v)]^C^CVPORTS;SI;;3;v
[acad(vp3h)]^C^CVPORTS;SI;;3;h
[acad(vp4)]^C^CVPORTS;SI;;4
[acad(vp2v)]^C^CVPORTS;SI;;2;v
[acad(vp3r)]^C^CVPORTS;SI;;3;r
[acad(vp3l)]^C^CVPORTS;SI;;3;l
[acad(vp4l)]^C^C^PUNDO;M;(setq m:g (getvar "gridmode"));SETVAR;GRIDMODE;0;+
VPORTS;SI;;2;;(setvar "CVPORT" (car (cadr (vports))))(princ);;2;;;J;;+
(car (cadr (vports)));(setvar "CVPORT" (car (cadr (vports))))(princ)+
;;3;h;(setvar "gridmode" m:g)(princ);ZOOM;A;(setvar "CVPORT"+
(car (cadddr (vports))))(setvar "gridmode" m:g)(princ);ZOOM;A;+
(setvar "CVPORT" (car (cadddr (vports))))(setvar "gridmode" m:g)(princ);+
ZOOM;A;(setvar "CVPORT" (car (cadddr (vports))))(setvar "gridmode" m:g)+
(princ);ZOOM;A;UNDO;E ^P
[acad(vp2h)]^C^CVPORTS;SI;;2;h
[acad(vp3a)]^C^CVPORTS;SI;;3;a;
[acad(vp3b)]^C^CVPORTS;SI;;3;b;
[acad(vp4r)]^C^C^PUNDO;M;(setq m:g (getvar "gridmode"));SETVAR;GRIDMODE;0;+
VPORTS;SI;;2;;;2;;(setvar "CVPORT" (car (caddr (vports))));;j;;+
(car (caddr (vports)));(setvar "CVPORT" (car (cadr (vports))));;3;h;+
(setvar "gridmode" m:g)(princ);ZOOM;A;(setvar "CVPORT" (car (cadddr (vports))))+
(setvar "gridmode" m:g)(princ);ZOOM;A;(setvar "CVPORT" (car (cadddr (vports))))+
(setvar "gridmode" m:g)(princ);ZOOM;A;(setvar "CVPORT" (car (cadddr (vports))))+
(setvar "gridmode" m:g)(princ);ZOOM;A;UNDO;E ^P
[ Join Viewports]^C^CVPORTS;J
[ Restore Saved]^C^CVPORTS;R;
[ List Saved]^C^CVPORTS;?;
[ Exit]^c^c
***SCREEN
**S
[AutoCAD]^C^C$S=X $S=S $P1=POP1 $P3=POP3
[* * * *]$S=OSNAPB
[Setup]^C^C^P(progn(prompt "Loading setup... ")(load "setup")) ^P$S=X $S=UNITS
[BLOCKS]$S=X $S=BL
[DIM:]$S=X $S=DIM ^C^CDIM
[DISPLAY]$S=X $S=DS
[DRAW]$S=X $S=DR
[EDIT]$S=X $S=ED
[INQUIRY]$S=X $S=INQ
[LAYER:]$S=X $S=LAYER ^C^CLAYER
[SETTINGS]$S=X $S=SET
[PLOT]$S=X $S=PLOT
[UCS:]$S=X $S=UCS1 ^C^CUCS
[UTILITY]$S=X $S=UT
[3D]$S=X $S=3D
[ASHADE]^C^C^P(progn(setq m:err *error*)(prin1))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(princ))(cond ((null C:SCENE)(vmon)+
(if (/= nil (findfile "ashade.lsp"))(progn (terpri);+
(prompt "Please wait... Loading ashade. ")(load "ashade")+
(menucmd "S=X")(menucmd "S=ASHADE")(setq *error* m:err m:err nil))(progn (terpri);+
(prompt "The file 'Ashade.lsp' was not found in your current search directories.")+
(terpri)(prompt "Check your AutoShade Manual for installation instructions.");+
(setq *error* m:err m:err nil)(princ))))+
(T (setq *error* m:err m:err nil)(menucmd "S=X")(menucmd "S=ASHADE")(princ))) ^P
[QUICKSRF]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=QS
[SAVE:]^C^CSAVE
**X 3
[__LAST__]$S= $S=
[ DRAW ]^C^C$S=X $S=DR
[ EDIT ]^C^C$S=X $S=ED
**BL 3
[ATTDEF:]$S=X $S=ATTDEF ^C^CATTDEF
[BASE:]^C^CBASE
[BLOCK:]$S=X $S=BLOCK ^C^CBLOCK
[INSERT:]$S=X $S=INSERT ^C^CINSERT
[MINSERT:]$S=X $S=MINSERT ^C^CMINSERT
[WBLOCK:]$S=X $S=WBLOCK ^C^CWBLOCK
**DS 3
[ATTDISP:]$S=X $S=ATTDISP ^C^CATTDISP
[DVIEW:]$S=X $S=DVIEW ^C^CDVIEW
[PAN:]'PAN
[PLAN:]$S=X $S=PLAN ^C^CPLAN
[REDRAW:]'REDRAW
[REDRALL:]'REDRAWALL
[REGEN:]^C^CREGEN
[REGNALL:]^C^CREGENALL
[RGNAUTO:]$S=X $S=RGNAUTO ^C^CREGENAUTO
[VIEW:]$S=X $S=VIEW 'VIEW
[VIEWRES:]$S=X $S=VIEWRES ^C^CVIEWRES
[VPOINT:]$S=X $S=VPOINT ^C^CVPOINT
[ZOOM:]$S=X $S=ZOOM 'ZOOM
**DR 3
[ARC]$S=X $S=ARC
[ATTDEF:]$S=X $S=ATTDEF ^C^CATTDEF
[CIRCLE]$S=X $S=CIRCLE
[DONUT:]^C^CDONUT
[DTEXT:]$S=X $S=DTEXT ^C^CDTEXT
[ELLIPSE:]$S=X $S=ELLIPSE ^C^CELLIPSE
[HATCH:]$S=X $S=HATCH ^C^CHATCH
[INSERT:]$S=X $S=INSERT ^C^CINSERT
[LINE:]$S=X $S=LINE ^C^CLINE
[MINSERT:]$S=X $S=MINSERT ^C^CMINSERT
[OFFSET:]$S=X $S=OFFSET ^C^COFFSET
[PLINE:]$S=X $S=PLINE ^C^CPLINE
[next]$S=X $S=DR2
**DR2 3
[POINT:]$S=X $S=POINT ^C^CPOINT
[POLYGON:]$S=X $S=POLYGON ^C^CPOLYGON
[SHAPE:]$S=X $S=SHAPE ^C^CSHAPE
[SKETCH:]$S=X $S=SKETCH ^C^CSKETCH
[SOLID:]$S=X $S=SOLID ^C^CSOLID
[TEXT:]$S=X $S=TEXT ^C^CTEXT
[TRACE:]$S=X $S=TRACE ^C^CTRACE
[3DFACE:]$S=X $S=3DFACE ^C^C3DFACE
[3D]$S=X $S=3D
[previous]$S=X $S=DR
[__LAST__]$S= $S=
**ED 3
[ARRAY:]$S=X $S=ARRAY ^C^CARRAY
[ATTEDIT:]$S=X $S=ATTEDIT ^C^CATTEDIT
[DDATTE:]^C^CDDATTE
[BREAK:]$S=X $S=BREAK ^C^CBREAK
[CHAMFER:]$S=X $S=CHAMFER ^C^CCHAMFER
[CHANGE:]$S=X $S=CHANGE ^C^CCHANGE
[CHPROP:]$S=X $S=CHPROP ^C^CCHPROP
[COPY:]$S=X $S=COPY ^C^CCOPY
[DIVIDE:]$S=X $S=DIVIDE ^C^CDIVIDE
[ERASE:]$S=X $S=ERASE ^C^CERASE
[EXPLODE:]^C^CEXPLODE
[EXTEND:]$S=X $S=EXTEND ^C^CEXTEND
[next]$S=X $S=ED2
**ED2 3
[FILLET:]$S=X $S=FILLET ^C^CFILLET
[MEASURE:]$S=X $S=MEASURE ^C^CMEASURE
[MIRROR:]$S=X $S=MIRROR ^C^CMIRROR
[MOVE:]$S=X $S=MOVE ^C^CMOVE
[OFFSET:]$S=X $S=OFFSET ^C^COFFSET
[PEDIT:]^C^C^P+
(defun m:p1(/ m:pa m:pc m:d m:w)(menucmd "S=X")(menucmd "S=PSEL");+
(setq m:d T)(while m:d (setq m:pc (ssget))(setq m:pa (ssname m:pc 0));+
(if(=(cdr(assoc 0 (entget m:pa))) "POLYLINE")(progn(setq m:d nil)+
(m:p2 m:pa m:pc))(progn(prompt "Entity selected is not a polyline")(terpri);+
(if (member (cdr (assoc 0 (entget m:pa))) '("LINE" "ARC"))(progn+
(initget "Yes No")(setq m:w (getkword "Do you want to turn it into one? <Y>"));+
(if (or (= m:w "Yes")(null m:w))(progn(setq m:d nil)(menucmd "S=X");+
(menucmd "S=P0")(command "PEDIT" m:pa "yes" pause)))))))))+
(defun m:p2(m:pa m:pc / m:pb)(menucmd "S=X")+
(if (= (setq m:pb (cdr (assoc 70 (entget m:pa)))) nil)(menucmd "S=P0");+
(progn (setq m:pb (/ m:pb 2))(if (>= m:pb 8)(menucmd "S=P16");+
(if(< m:pb 4)(menucmd "S=P0")(menucmd "S=P8")))))(command "PEDIT" m:pa pause))+
(defun perror (msg)(setq *error* m:err m:err nil)(princ))+
(defun C:PEDITM (/ m:err)(setq m:err *error* *error* perror)(m:p1);+
(setq *error* m:err m:err nil)(princ))(princ) PEDITM ^P
[ROTATE:]$S=X $S=ROTATE ^C^CROTATE
[SELECT:]$S=X $S=SELECT ^C^CSELECT
[SCALE:]$S=X $S=SCALE ^C^CSCALE
[STRETCH:]$S=X $S=STRETCH ^C^CSTRETCH C
[TRIM:]$S=X $S=TRIM ^C^CTRIM
[UNDO:]$S=X $S=UNDO ^C^CUNDO
[previous]$S=X $S=ED
**INQ 5
[AREA:]$S=X $S=AREA ^C^CAREA
[DBLIST:]^CDBLIST
[DIST:]^C^CDIST
[HELP:]'HELP
[ID:]$S=X $S=ID ^C^CID
[LIST:]$S=X $S=LIST ^C^CLIST
[STATUS:]^C^CSTATUS
[TIME:]^C^CTIME
**SET 3
[DDEMODES]'DDEMODES
[DDRMODES]'DDRMODES
[--------]
[APERTUR:]$S=X $S=APERTURE ^C^CAPERTURE
[AXIS:]$S=X $S=AXIS ^C^CAXIS
[BLIPS:]$S=X $S=BLIPMODE ^C^CBLIPMODE
[COLOR:]$S=X $S=COLOR ^C^CCOLOR
[DRAGMOD:]$S=X $S=DRAGMODE ^C^CDRAGMODE
[ELEV:]^C^CELEV
[GRID:]$S=X $S=GRID ^C^CGRID
[HANDLES:]$S=X $S=HANDLES ^C^CHANDLES
[LINETYP:]$S=X $S=LINETYPE ^C^CLINETYPE
[LIMITS:]$S=X $S=LIMITS ^C^CLIMITS
[next]$S=X $S=SET2
**SET2 3
[LTSCALE:]^C^CLTSCALE
[OSNAP:]$S=X $S=OSNAPC ^C^COSNAP
[QTEXT:]$S=X $S=QTEXT ^C^CQTEXT
[SETVAR:]$S=X $S=SETVAR 'SETVAR
[SNAP:]$S=X $S=SNAP ^C^CSNAP
[STYLE:]$S=X $S=STYLE ^C^CSTYLE
[TABLET:]$S=X $S=TABLET ^C^CTABLET
[UCS:]$S=X $S=UCS1 ^C^CUCS
[UCSICON:]$S=X $S=UCSICON ^C^CUCSICON
[UNITS:]^CUNITS
[VPORTS:]$S=X $S=VPORTS ^C^CVPORTS
[previous]$S=X $S=SET
**PLOT 3
[ C D]
[ H E]
[ O V]
[ O I]
[ S C]
[ E E]
[PLOTTER]^C^CPLOT
[PRINTER]^C^CPRPLOT
**UT 3
[ATTEXT:]$S=X $S=ATTEXT ^C^CATTEXT
[DXF/DXB]$S=X $S=DXF
[FILES:]^C^CFILES
[IGES]$S=X $S=IGES
[MENU:]$S=X $S=CHTEMP ^C^CMENU
[PURGE:]$S=X $S=PURGE ^C^CPURGE
[RENAME:]$S=X $S=RENAME ^C^CRENAME
[SCRIPT:]$S=X $S=SCRIPT ^C^CSCRIPT
[SLIDES]$S=X $S=SLIDES
[External]$S=X $S=EXCOMDS
[Commands]$S=X $S=EXCOMDS
[END]$S=X $S=END
[QUIT]$S=X $S=QUIT
**OSNAPB 2
[ HELP ]$S= 'help
[CENter]CENTER $S=
[ENDpoint]ENDPOINT $S=
[INSert]INSERT $S=
[INTersec]INTERSEC $S=
[MIDpoint]MIDPOINT $S=
[NEArest]NEAREST $S=
[NODe]NODE $S=
[PERpend]PERPEND $S=
[QUAdrant]QUADRANT $S=
[QUICK,]QUICK,^Z
[TANgent]TANGENT $S=
[NONE]NONE $S=
[CANCEL:]^C^C$S=
[U:]^C^CU $S=
[REDO:]^C^CREDO $S=
[REDRAW:]'REDRAW $S=
[SETVAR:]$S= 'SETVAR
[__LAST__]$S=
**BLOCK 3
[BLOCK:]^C^CBLOCK
?
Window
Last
Previous
Crossing
Remove
Add
Yes
[OOPS]^C^COOPS
**INSERT 3
[INSERT:]^C^CINSERT
?
[*]*\
corner
xyz
drag
Scale
Xscale
Yscale
Zscale
Rotate
**WBLOCK 3
[WBLOCK:]^C^CWBLOCK
=
*
[blank];
Window
Last
Previous
Crossing
Remove
Add
Undo
**MINSERT 3
[MINSERT:]^C^CMINSERT
?
corner
xyz
drag
**DIM 3
[DIM:]^C^CDIM
[DIM1:]^C^CDIM1
[LINEAR]$S=X $S=DIMLINEAR
angular
diameter
radius
center
leader
[Dim Vars]$S=X $S=VAR1
[redraw]'REDRAW
status
undo
style
[EXIT]EXIT;$S=X $S=S
[next]$S=X $S=FORMAT
**DIMLINEAR 3
[DIM:]^C^CDIM
[DIM1:]^C^CDIM1
horiz
vertical
aligned
rotated
[baseline]^C^Cdim BASE
[continue]^C^Cdim CONT
[previous]$S=X $S=DIM
**ATTDEF 3
[ATTDEF:]^C^CATTDEF
Invisibl
Constant
Verify
[Preset]P
Aligned
[Centered]C
Fit
Middle
Right
Style
**LAYER 3
[DDLMODES]'DDLMODES
[LAYER:]^C^CLAYER
[?]? *
Make
Set
New
ON
OFF
[Color]COLOR $S=X $S=LACOLOR \$S=X $S=LAYER
[Chroma]^C^CVSLIDE chroma
[ Restore]'REDRAW
[Ltype]LTYPE $S=X $S=LALT \$S=X $S=LAYER
Freeze
Thaw
**LACOLOR 3
[COLOR]
red
yellow
green
cyan
blue
magenta
white
**LALT 3
[LINETYPE]
[contin.]CONTINUOUS
dashed
hidden
center
phantom
dot
dashdot
border
divide
**ZOOM 3
[ZOOM:]'ZOOM
All
[Center]C
Dynamic
Extents
Left
Previous
Window
Yes
No
**ATTDISP 3
[ATTDISP:]^C^CATTDISP
Normal
ON
OFF
**DVIEW 3
[DVIEW:]^C^CDview
Window
Last
Previous
Crossing
Remove
Add
[By Layer]^P(defun berror (msg)(setq *error* m:err m:err nil)(princ))+
(progn (setq m:err *error* *error* berror);+
(setq l(getstring (strcat "Layer name: <" (getvar "clayer") "> ")))+
(if (= l "")(setq s(ssget "X" (list(cons 8 (getvar "clayer")))))+
(setq s(ssget "X" (list(cons 8 l)))))(setq *error* m:err m:err nil) s) ^P
[--------]
[Dviewblk]^C^CDVIEW;;
[ Dview ]$S=X $S=DVIEW1
[Options]$S=X $S=DVIEW1
**DVIEW1 3
CAmera
TArget
Distance
POints
PAn
Zoom
TWist
[CLip]Clip $S=X $S=DVIEW2
Hide
Off
Undo
[eXit]Exit $S=X $S=S
**DVIEW2 3
[Back]Back $S=X $S=BACK
[Front]Front $S=X $S=FRONT
[Off]Off $S=X $S=DVIEW1
**BACK 3
[ back]
[clipping]
[ON]On $S=X $S=DVIEW1
[OFF]Off $S=X $S=DVIEW1
**FRONT 3
[ front]
[clipping]
[ON]On $S=X $S=DVIEW1
[OFF]Off $S=X $S=DVIEW1
[Eye]Eye $S=X $S=DVIEW1
**RGNAUTO 3
[RGNAUTO:]^C^CREGENAUTO
[ON]On $S=X $S=DS
[OFF]Off $S=X $S=DS
**VIEW 3
[VIEW:]'VIEW
?
[Delete]Delete;
[Restore]Restore;
[Save]Save;
[Window]Window;
**VPORTS 3
[VPORTS:]^C^CVPORTS
Save
Restore
Delete
Join
Single
?
[2]2 $S=X $S=VP2
[3]3 $S=X $S=VP3
4
**VP2 3
[Horizont]H $S=X $S=VPORTS
[Vertical]V $S=X $S=VPORTS
**VP3 3
[Horizont]H $S=X $S=VPORTS
[Vertical]V $S=X $S=VPORTS
[Above]A $S=X $S=VPORTS
[Below]B $S=X $S=VPORTS
[Left]L $S=X $S=VPORTS
[Right]R $S=X $S=VPORTS
**LINE 3
[LINE:]^C^CLINE
[continue]^C^CLINE;;
close
undo
.x
.y
.z
.xy
.xz
.yz
**3D 3
[EDGSURF:]^C^CEDGESURF
[REVSURF:]^C^CREVSURF
[RULSURF:]^C^CRULESURF
[TABSURF:]^C^CTABSURF
[Surftb1:]'SETVAR SURFTAB1
[Surftb2:]'SETVAR SURFTAB2
[3DFACE:]$S=X $S=3DFACE ^C^C3DFACE
[3DMESH:]^C^C3DMESH
[3DPOLY:]$S=X $S=3DPOLY ^C^C3DPOLY
[ 3d ]^C^C^P(progn(setq m:err *error*)(princ))+
(defun m:l3d () (cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn(terpri)(prompt +
"The file `3d.lsp' was not found in your search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.");+
(princ))))((not (null C:BOX)) (menucmd "S=X") (menucmd "S=3D2")(princ))+
(T(princ)))(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg);+
(menucmd "S=X")(menucmd "S=S")(setq *error* m:err m:err nil)(princ))(m:l3d);^P
[objects]^C^C^P(progn(setq m:err *error*)(princ))+
(defun m:l3d () (cond ((null C:BOX)(vmon)(if (/= nil (findfile "3d.lsp"))+
(progn (terpri)(prompt "Please wait... Loading 3D Objects. ");+
(load "3d")(menucmd "S=X")(menucmd "S=3D2")(princ))(progn(terpri)(prompt +
"The file `3d.lsp' was not found in your search path directories. ")(terpri);+
(prompt "Check installation of the Support Files and try again.");+
(princ))))((not (null C:BOX)) (menucmd "S=X") (menucmd "S=3D2")(princ))+
(T(princ)))(setq *error* m:err m:err nil))(defun *error* (msg)(princ msg);+
(menucmd "S=X")(menucmd "S=S")(setq *error* m:err m:err nil)(princ))(m:l3d);^P
**3D2 3
Box
Cone
Dish
Dome
Mesh
Pyramid
Sphere
Torus
Wedge
**ELEVTHK 3
[ELEV:]^C^CELEV
[CHANGE:]^C^CCHANGE
Window
Last
Previous
Crossing
Remove
Add
Undo
[Elev]PROP E
[Thick]PROP T
**HIDE 3
[HIDE ?]
[YES]^C^CHIDE
[NO]$S= $S=
**VPOINT 3
[VPOINT:]^C^CVPOINT
[rotate]rotate;
[axes];
[plan]none 0,0,1
[HIDE:]$S=X $S=HIDE
**VPOINT3D 3
[ Angle ]^C^CVPOINT R;;
[from XY ]^C^CVPOINT R;;
[ Plane ]^C^CVPOINT R;;
[ +80 ]<<80
[ +60 ]<<60
[ +45 ]<<45
[ +30 ]<<30
[ +10 ]<<10
[ 0 ]<<0.0000001
[ -10 ]<<350
[ -30 ]<<330
[ -45 ]<<315
[ -60 ]<<300
[ -80 ]<<280
**PLINE 3
[PLINE:]^C^CPLINE
[Arc]ARC $S=X $S=PARC
Close
Halfwid
Length
Undo
Width
[FILL ON]'SETVAR FILLMODE 1
[FILL OFF]'SETVAR FILLMODE 0
**PARC 3
[POLYARC]
[angle]$S=X $S=PARCANG A
[CEnter]$S=X $S=PARCEN CE
[tanDir]D \DRAG
[Radius]$S=X $S=PARCRAD R
[2nd PT]S \DRAG
[CLose]$S=X $S=PLINE CLOSE
undo
[contline]$S=X $S=PLINE L
[PLINE:]$S=X $S=PLINE ^C^CPLINE
**PARCANG 3
[ANGLE]
[center]$S=X $S=PARC Center drag
[radius]$S=X $S=PARC R \
[drag]$S=X $S=PARC drag
**PARCEN 3
[CENTER]
[angle]$S=X $S=PARC A drag
[length]$S=X $S=PARC L drag
[drag]$S=X $S=PARC drag
**PARCRAD 3
[RADIUS]
[angle]A \drag $S=X $S=PARC A \drag
[drag]$S=X $S=PARC drag
**OFFSET 3
[OFFSET:]^C^COFFSET
Through
[done];
**ARC 3
[ARC]
[3-point:]^C^CARC \\DRAG
[S,C,E:]^C^CARC \C \DRAG
[S,C,A:]^C^CARC \C \A DRAG
[S,C,L:]^C^CARC \C \L DRAG
[S,E,A:]^C^CARC \E \A
[S,E,R:]^C^CARC \E \R
[S,E,D:]^C^CARC \E \D DRAG
[C,S,E:]^C^CARC C \\DRAG
[C,S,A:]^C^CARC C \\A DRAG
[C,S,L:]^C^CARC C \\L DRAG
[CONTIN:]^C^CARC ;DRAG
**popARC 3
[ARC]
[3-point:]*^C^CARC \\DRAG
[S,C,E:]*^C^CARC \C \DRAG
[S,C,A:]*^C^CARC \C \A DRAG
[S,C,L:]*^C^CARC \C \L DRAG
[S,E,A:]*^C^CARC \E \A
[S,E,R:]*^C^CARC \E \R
[S,E,D:]*^C^CARC \E \D DRAG
[C,S,E:]*^C^CARC C \\DRAG
[C,S,A:]*^C^CARC C \\A DRAG
[C,S,L:]*^C^CARC C \\L DRAG
[CONTIN:]^C^CARC ;DRAG
**CIRCLE 3
[CIRCLE]
[CEN,RAD:]^C^CCIRCLE \DRAG
[CEN,DIA:]^C^CCIRCLE \D
[2 POINT:]^C^CCIRCLE 2P \DRAG
[3 POINT:]^C^CCIRCLE 3P \\DRAG
[TTR:]^C^CCIRCLE TTR
**popCIRCL 3
[CIRCLE]
[CEN,RAD:]*^C^CCIRCLE \DRAG
[CEN,DIA:]*^C^CCIRCLE \D
[2 POINT:]*^C^CCIRCLE 2P \DRAG
[3 POINT:]*^C^CCIRCLE 3P \\DRAG
[TTR:]*^C^CCIRCLE TTR
**ASHADE 3
[LIGHTS:]^C^C$S=X $S=LIGHTS LIGHT
[CAMERA:]^C^C$S=X $S=CAMERA CAMERA
[ACTION]^C^C$S=X $S=ACTION
[CAMVIEW:]^C^CCAMVIEW
**LIGHTS 3
[LIGHT:]^C^CLIGHT
[Point]p
Directed
[Filters]
.x
.y
.z
.xy
.xz
.yz
[CAMERA:]^C^C$S=X $S=CAMERA CAMERA
[ACTION]$S=X $S=ACTION
**CAMERA 3
[CAMERA:]^C^CCAMERA
[Filters]
.x
.y
.z
.xy
.xz
.yz
[CAMVIEW:]^C^CCAMVIEW
[LIGHTS:]^C^C$S=X $S=LIGHTS LIGHT
[ACTION]$S=X $S=ACTION
**ACTION 3
[ACTION]
[SCENE:]^C^CSCENE
[FLMROLL:]^C^CFILMROLL
[LIGHTS:]^C^C$S=X $S=LIGHTS LIGHT
[CAMERA:]^C^C$S=X $S=CAMERA CAMERA
**ELLIPSE 3
[ELLIPSE:]^C^CELLIPSE
[Center]C
Rotation
Iso
Diameter
**POLYGON 3
[POLYGON:]^C^CPOLYGON
Edge
[I-scribe]I
[C-scribe]C
**SHAPE 3
[SHAPE:]^C^CSHAPE
?
[LOAD:]^C^CLOAD
?
**SKETCH 3
[SKETCH:]^C^CSKETCH
Connect
Erase
Record
[eXit]x
Quit
[------]
[SKPOLY:]'SETVAR SKPOLY 1
[SKLINE:]'SETVAR SKPOLY 0
[------]
**SOLID 3
[SOLID:]^C^CSOLID
[FILL ON]'SETVAR FILLMODE 1
[FILL OFF]'SETVAR FILLMODE 0
**TRACE 3
[TRACE:]^C^CTRACE
[FILL ON]'SETVAR FILLMODE 1
[FILL OFF]'SETVAR FILLMODE 0
**POINT 3
[POINT:]^C^CPOINT
.x
.y
.z
.xy
.xz
.yz
[Complex]
[Points]
[example:]^C^CVSLIDE points
[remove]^C^CREDRAW
[example:]^C^CREDRAW
[Pdmode:]'SETVAR PDMODE
[Pdsize:]'SETVAR PDSIZE
**HATCH 3
[HATCH:]^C^CHATCH
?
u
u,o
u,i
Yes
Window
Last
Previous
Crossing
Remove
Add
Undo
**3DFACE 3
[3DFACE:]^C^C3DFACE
.x
.y
.z
.xy
.xz
.yz
[Invisibl]I
[ShowEdge]^P(setvar "splframe" 1)(prompt "Invisible edges will be SHOWN after next Regeneration.")(princ) ^P
[HideEdge]^P(setvar "splframe" 0)(prompt "Invisible edges will be HIDDEN after next Regeneration.")(princ) ^P
**3DPOLY 3
[3DPOLY:]^C^C3DPOLY
Close
Undo
.x
.y
.z
.xy
.xz
.yz
**ID 3
[ID:]^C^CID
.x
.y
.z
.xy
.xz
.yz
**LIMITS 3
[LIMITS:]^C^CLIMITS
ON
OFF
**UCS1 3
[UCS:]^C^CUCS
[DDUCS:]^C^CDDUCS
?
Previous
Restore
[Save]S
Delete
World
[RENAME:]^C^CRename UCS
[Follow:]'SETVAR UCSFOLLOW
[next]$S=X $S=UCS2
**UCS2 3
[UCS:]$S=X $S=UCS1 ^C^CUCS
Origin
Zaxis
3point
X
Y
Z
View
Entity
[previous]$S=X $S=UCS1
**UCSICON 3
[UCSICON:]^C^CUCSICON
ON
OFF
All
Origin
Noorigin
**PLAN 3
[PLAN:]^C^CPLAN
Current
UCS
World
[Follow:]'SETVAR UCSFOLLOW
**LIST 3
[LIST:]^C^CLIST
Window
Last
Previous
Crossing
Remove
Add
Undo
**AREA 3
[AREA:]^C^CAREA
Entity
Add
Subtract
**TEXT 3
[TEXT:]^C^CTEXT
[DTEXT:]^C^CDTEXT
aligned
[centered]C
fit
middle
right
style
[STYLE:]$S=X $S=STYLE ^C^CSTYLE
**TEXTSET 5
[DTEXT]$S=X $S=DTEXT ^C^C$T4=DTEXT1 $T4=DTEXT2
[REG.TEXT]$S=X $S=TEXT ^C^C$T4=TEXT1 $T4=TEXT2
[STYLE:]$S=X $S=STYLE ^C^CSTYLE
**STYLE 3
[STYLE:]^C^CSTYLE
?
[Fonts]$S=X $S=F1
Yes
No
[DTEXT:]$S=X $S=DTEXT ^C^CDTEXT
[TEXT:]$S=X $S=TEXT ^C^CTEXT
**F1 3
Cyrillic
Cyriltlc
Greekc
Greeks
Gothice
Gothicg
Gothici
Italicc
Italict
Romanc
Romand
Romans
[next]$S=X $S=F2
[STYLMNU]$S=X $S=STYLE
**F2 3
Romant
Scriptc
Scripts
Syastro
Symap
Symath
Symeteo
Symusic
[previous]$S=X $S=F1
[STYLMNU]$S=X $S=STYLE
**DTEXT 3
[DTEXT:]^C^CDTEXT
[TEXT:]^C^CTEXT
[centered]C
right
aligned
middle
fit
style
[STYLE:]$S=X $S=STYLE ^C^CSTYLE
**AXIS 3
[AXIS:]^C^CAXIS
[axs=snap]SNAP
ON
OFF
Aspect
**BLIPMODE 3
[BLIPS:]^C^CBLIPMODE
ON
OFF
**END 3
END ?
[Yes]^C^CEND
[No]$S=X $S=S
**QUIT 3
[QUIT:]^c^cquit
[Yes]Y
[No]n $S=X $S=S
**VAR1 3
[dimalt]$S=X $S=OF DIMALT \
[dimaltd]DIMALTD \
[dimaltf]DIMALTF \
[dimapost]DIMAPOST \
[dimaso]$S=X $S=OF DIMASO \
[dimasz]DIMASZ \
[--------]
[dimblk]DIMBLK \
[dimblk1]DIMBLK1 \
[dimblk2]DIMBLK2 \
[--------]
[dimcen]DIMCEN \
[dimdle]DIMDLE \
[dimdli]DIMDLI \
[dimexe]DIMEXE \
[next]$S=X $S=VAR2
[DIMMENU]$S=X $S=DIM
**VAR2 3
[dimexo]DIMEXO \
[dimlfac]DIMLFAC \
[dimlim]$S=X $S=OF DIMLIM \
[dimpost]DIMPOST \
[dimrnd]DIMRND \
[dimsah]$S=X $S=OF DIMSAH \
[dimscale]DIMSCALE \
[dimse1]$S=X $S=OF DIMSE1 \
[dimse2]$S=X $S=OF DIMSE2 \
[dimsho]$S=X $S=OF DIMSHO \
[dimsoxd]$S=X $S=OF DIMSOXD \
[dimtad]$S=X $S=OF DIMTAD \
[dimtih]$S=X $S=OF DIMTIH \
[dimtix]$S=X $S=OF DIMTIX \
[previous]$S=X $S=VAR1
[next]$S=X $S=VAR3
[DIMMENU]$S=X $S=DIM
**VAR3 3
[dimtm]DIMTM \
[dimtofl]$S=X $S=OF DIMTOFL \
[dimtoh]$S=X $S=OF DIMTOH \
[dimtol]$S=X $S=OF DIMTOL \
[dimtp]DIMTP \
[dimtsz]DIMTSZ \
[dimtvp]DIMTVP \
[dimtxt]DIMTXT \
[dimzin]$S=X $S=DIMZIN DIMZIN \
[previous]$S=X $S=VAR2
[DIMMENU]$S=X $S=DIM
**OF 3
[ON]$S= $S= ON
[OFF]$S= $S= OFF
**DIMZIN 4
[ New]
[ Dimzin]
[ Value]
[0]$S= $S= 0
[1]$S= $S= 1
[2]$S= $S= 2
[3]$S= $S= 3
**FORMAT 3
[DIM:]^C^CDIM
[DIM1:]^C^CDIM1
[HOMETEXT]$S=X $S=HOMETEXT HOMETEXT
[UPDATE]$S=X $S=UPDATE UPDATE
[NEWTEXT]$S=X $S=NEWTEXT NEWTEXT
[DIMMENU]$S=X $S=DIM
**HOMETEXT 3
[DIM:]^C^CDIM
[DIM1:]^C^CDIM1
HOMETEXT
Window
Last
Previous
Crossing
Remove
Add
Undo
**UPDATE 3
[DIM:]^C^CDIM
[DIM1:]^C^CDIM1
UPDATE
Window
Last
Previous
Crossing
Remove
Add
Undo
**NEWTEXT 3
[DIM:]^C^CDIM
[DIM1:]^C^CDIM1
[NEWTEXT]NEWTEXT
Window
Last
Previous
Crossing
Remove
Add
Undo
**LINETYPE 3
[LINETYP:]^C^CLINETYPE
?
Create
Load
[Set]S $S=X $S=CHLT \$S=X $S=LINETYPE
Yes
No
**LIMITS 3
[LIMITS:]^C^CLIMITS
On
Off
**SNAP 3
[SNAP:]^C^CSNAP
ON
OFF
[Aspect]A;
[Rotate]R;
[Style]S;
[ Iso]Iso;
[ Standrd]Standard;
**TABLET 3
[TABLET:]^C^CTABLET
cal
[config]CFG 4 25 9 11 9 9 13 25 7 Y
[re-cfg]CFG 4 Y 25 9 11 9 9 13 25 7 Y
ON
OFF
Yes
No
**OSNAPC 3
[OSNAP:]^C^COSNAP
[CENter]CENTER\
[ENDpoint]ENDPOINT\
[INSert]INSERT\
[INTersec]INTERSEC\
[MIDpoint]MIDPOINT\
[NEArest]NEAREST\
[NODe]NODE\
[PERpend]PERPEND\
[QUAdrant]QUADRANT\
[TANgent]TANGENT\
[NONE]^C^COSNAP NONE $S= $S=
[Quick,]QUICK,^Z
[,],\
**DRAGMODE 3
[DRAGMODE]^C^CDRAGMODE
[ON]ON $S=X $S=S
[OFF]OFF $S=X $S=S
[Auto]A $S=X $S=S
**GRID 3
[GRID:]^C^CGRID
[grd=snap]SNAP
ON
OFF
Aspect
**HANDLES 3
[HANDLES:]^C^CHANDLES
[ON]ON
[DESTROY]DESTROY
**SETVAR 3
[SETVAR:]^C^CSETVAR
?
['SETVAR]'SETVAR
**QTEXT 3
[QTEXT:]^C^CQTEXT
ON
OFF
[REGEN:]REGEN
**VIEWRES 3
[VIEWRES:]^C^CVIEWRES
No
Yes
100
500
[RGNAUTO:]^C^CREGENAUTO
[ On]On
[ Off]Off
**APERTURE 3
[APERTUR:]'SETVAR APERTURE
[PICKBOX:]'SETVAR PICKBOX
[1]$S= $S= 1
[2]$S= $S= 2
[3]$S= $S= 3
[4]$S= $S= 4
[5]$S= $S= 5
[6]$S= $S= 6
[7]$S= $S= 7
[8]$S= $S= 8
[9]$S= $S= 9
[10]$S= $S= 10
[15]$S= $S= 15
**ARRAY 3
[ARRAY:]^C^CARRAY
Window
Last
Previous
Crossing
Remove
Add
Undo
Rectang
Polar
Yes
No
**ROTATE 3
[ROTATE:]^C^CROTATE
Window
Last
Previous
Crossing
Remove
Add
Undo
Referenc
**SELECT 3
[SELECT:]^C^CSELECT
Window
Last
Previous
Crossing
Remove
Add
Undo
**SCALE 3
[SCALE:]^C^CSCALE
Window
Last
Previous
Crossing
Remove
Add
Undo
Referenc
**BREAK 3
[BREAK:]^C^CBREAK
First
@
**BREAK2P 3
[BREAK:]^C^CBREAK \F
**BREAKSPL 3
[BREAK:]^C^CBREAK \F \@
**MOVE 3
[MOVE:]^C^CMOVE
Window
Last
Previous
Crossing
Remove
Add
Undo
**COPY 3
[COPY:]^C^CCOPY
Window
Last
Previous
Crossing
Remove
Add
Undo
Multiple
**UNDO 3
[UNDO:]^C^CUNDO
[Back 1]^C^CUNDO 1
[Auto]$S=X $S=UNDOA Auto
Back
End
Group
Mark
[Control]$S=X $S=UNDOC Control
Yes
No
[REDO:]REDO
**UNDOC 3
All
None
One
**UNDOA 3
On
Off
**ERASE 3
[ERASE:]^C^CERASE
Window
Last
Previous
Crossing
Remove
Add
Undo
[OOPS:]^C^COOPS
**PSEL 3
Window
Last
Crossing
Yes
No
**P0 3
[PEDIT:]^C^C^P+
(defun m:p1(/ m:pa m:pc m:d m:w)(menucmd "S=X")(menucmd "S=PSEL");+
(setq m:d T)(while m:d (setq m:pc (ssget))(setq m:pa (ssname m:pc 0));+
(if(=(cdr(assoc 0 (entget m:pa))) "POLYLINE")(progn(setq m:d nil)+
(m:p2 m:pa m:pc))(progn(prompt "Entity selected is not a polyline")(terpri);+
(if (member (cdr (assoc 0 (entget m:pa))) '("LINE" "ARC"))(progn+
(initget "Yes No")(setq m:w (getkword "Do you want to turn it into one? <Y>"));+
(if (or (= m:w "Yes")(null m:w))(progn(setq m:d nil)(menucmd "S=X");+
(menucmd "S=P0")(command "PEDIT" m:pa "yes" pause)))))))))+
(defun m:p2(m:pa m:pc / m:pb)(menucmd "S=X")+
(if (= (setq m:pb (cdr (assoc 70 (entget m:pa)))) nil)(menucmd "S=P0");+
(progn (setq m:pb (/ m:pb 2))(if (>= m:pb 8)(menucmd "S=P16");+
(if(< m:pb 4)(menucmd "S=P0")(menucmd "S=P8")))))(command "PEDIT" m:pa pause))+
(defun perror (msg)(setq *error* m:err m:err nil)(princ))+
(defun C:PEDITM (/ m:err)(setq m:err *error* *error* perror)(m:p1);+
(setq *error* m:err m:err nil)(princ))(princ) PEDITM ^P
Close
Open
Join
Width
[Ed Vrtx]E $S=X $S=PVERTED
[Fit Curv]Fit
Spline
Decurve
[Undo]U
[eXit]X $S=X $S=S
[PolyVars]$S=X $S=PVARS $i=poly $i=*
**P8 3
[PEDIT:]^C^C^P+
(defun m:p1(/ m:pa m:pc m:d m:w)(menucmd "S=X")(menucmd "S=PSEL");+
(setq m:d T)(while m:d (setq m:pc (ssget))(setq m:pa (ssname m:pc 0));+
(if(=(cdr(assoc 0 (entget m:pa))) "POLYLINE")(progn(setq m:d nil)+
(m:p2 m:pa m:pc))(progn(prompt "Entity selected is not a polyline")(terpri);+
(if (member (cdr (assoc 0 (entget m:pa))) '("LINE" "ARC"))(progn+
(initget "Yes No")(setq m:w (getkword "Do you want to turn it into one? <Y>"));+
(if (or (= m:w "Yes")(null m:w))(progn(setq m:d nil)(menucmd "S=X");+
(menucmd "S=P0")(command "PEDIT" m:pa "yes" pause)))))))))+
(defun m:p2(m:pa m:pc / m:pb)(menucmd "S=X")+
(if (= (setq m:pb (cdr (assoc 70 (entget m:pa)))) nil)(menucmd "S=P0");+
(progn (setq m:pb (/ m:pb 2))(if (>= m:pb 8)(menucmd "S=P16");+
(if(< m:pb 4)(menucmd "S=P0")(menucmd "S=P8")))))(command "PEDIT" m:pa pause))+
(defun perror (msg)(setq *error* m:err m:err nil)(princ))+
(defun C:PEDITM (/ m:err)(setq m:err *error* *error* perror)(m:p1);+
(setq *error* m:err m:err nil)(princ))(princ) PEDITM ^P
Close
Open
[Ed Vrtx]E $S=X $S=3DPVERTED
Spline
Decurve
[Undo]U
[eXit]X $S=X $S=S
[PolyVars]$S=X $S=PVARS $i=poly $i=*
**P16 3
[PEDIT:]^C^C^P+
(defun m:p1(/ m:pa m:pc m:d m:w)(menucmd "S=X")(menucmd "S=PSEL");+
(setq m:d T)(while m:d (setq m:pc (ssget))(setq m:pa (ssname m:pc 0));+
(if(=(cdr(assoc 0 (entget m:pa))) "POLYLINE")(progn(setq m:d nil)+
(m:p2 m:pa m:pc))(progn(prompt "Entity selected is not a polyline")(terpri);+
(if (member (cdr (assoc 0 (entget m:pa))) '("LINE" "ARC"))(progn+
(initget "Yes No")(setq m:w (getkword "Do you want to turn it into one? <Y>"));+
(if (or (= m:w "Yes")(null m:w))(progn(setq m:d nil)(menucmd "S=X");+
(menucmd "S=P0")(command "PEDIT" m:pa "yes" pause)))))))))+
(defun m:p2(m:pa m:pc / m:pb)(menucmd "S=X")+
(if (= (setq m:pb (cdr (assoc 70 (entget m:pa)))) nil)(menucmd "S=P0");+
(progn (setq m:pb (/ m:pb 2))(if (>= m:pb 8)(menucmd "S=P16");+
(if(< m:pb 4)(menucmd "S=P0")(menucmd "S=P8")))))(command "PEDIT" m:pa pause))+
(defun perror (msg)(setq *error* m:err m:err nil)(princ))+
(defun C:PEDITM (/ m:err)(setq m:err *error* *error* perror)(m:p1);+
(setq *error* m:err m:err nil)(princ))(princ) PEDITM ^P
[Ed Vrtx]E $S=X $S=3DMVERTED
Smooth
Desmooth
[Mclose]M
[Nclose]N
[Mopen]M
[Nopen]N
[Undo]U
[eXit]X $S=X $S=S
[PolyVars]$S=X $S=PVARS $i=poly $i=*
**PVERTED 3
[ED VRTX]
Next
Previous
Break
Insert
Move
Straight
Width
Tangent
Go
Regen
[Undo]X U $S=X $S=P0
[eXit]X $S=X $S=P0
**3DPVERTED 3
[ED VRTX]
Next
Previous
Break
Insert
Move
Regen
Straight
[eXit]X $S=X $S=P8
**3DMVERTED 3
[ED VRTX]
Next
Previous
Left
Right
Up
Down
Move
Regen
[eXit]X $S=X $S=P16
**PVARS 3
[Polyvars]$i=poly $i=*
[SPLframe]'SETVAR SPLFRAME
[ On]1
[ Off]0
[SPLsegs]'SETVAR SPLINESEGS
[SPLtype]'SETVAR SPLINETYPE
[ Quad]5
[ Cubic]6
[SURFtype]'SETVAR SURFTYPE
[ Quad]5
[ Cubic]6
[ Bezier]8
[UDensity]'SETVAR SURFU
[VDensity]'SETVAR SURFV
**TRIM 3
[TRIM:]^C^CTRIM
Window
Last
Previous
Crossing
Remove
Add
Undo
**ATTEXT 3
[ATTEXT:]^C^CATTEXT
CDF
SDF
DXF
[Entities]Ent
Window
Last
Previous
Crossing
Remove
Add
Undo
**SLIDES 3
[MSLIDE:]^C^CMSLIDE
[VSLIDE:]^C^CVSLIDE
**SCRIPT 3
[SCRIPT:]^C^CSCRIPT
[RESUME:]'RESUME
[RSCRIPT:]^C^CRSCRIPT
**PURGE 3
[PURGE:]^C^CPURGE
Blocks
LAyers
LTypes
SHapes
STyles
All
Yes
No
**RENAME 3
[RENAME:]^C^CRENAME
Block
LAyer
LType
Style
Ucs
VIew
VPort
**DXF 3
[DXFIN:]^C^CDXFIN
[DXFOUT:]^C^CDXFOUT
16
Entities
Window
Last
Previous
Crossing
Remove
Add
Undo
[DXBIN:]^C^CDXBIN
**IGES 3
[IGESIN:]^C^CIGESIN
[IGESOUT:]^C^CIGESOUT
**EXTEND 3
[EXTEND:]^C^CEXTEND
Window
Last
Previous
Crossing
Remove
Add
Undo
[SELECT:]^C^CSELECT
[ZOOM W:]'ZOOM W
**STRETCH 3
[STRETCH:]^C^CSTRETCH C
Window
Last
Previous
Crossing
Remove
Add
Undo
**MIRROR 3
[MIRROR:]^C^CMIRROR
Window
Last
Previous
Crossing
Remove
Add
Undo
Yes
No
**FILLET0 3
[FILLET:0]^C^CFILLET R 0;;
[polyline]P
**FILLET 3
[FILLET:]^C^CFILLET
[radius]R \FILLET
[radius 0]R 0 FILLET
polyline
**CHAMFER 3
[CHAMFER:]^C^CCHAMFER
[distance]D \\CHAMFER
[dist = 0]D 0 0 CHAMFER
polyline
**DIVIDE 3
[DIVIDE:]^C^CDIVIDE
Block
Yes
No
**MEASURE 3
[MEASURE:]^C^CMEASURE
Block
Yes
No
**CHANGE 3
[CHANGE:]^C^CCHANGE
Window
Last
Previous
Crossing
Remove
Add
Undo
[Color]PROP COLOR $S=X $S=CHCOLOR \ $S=X $S=CHANGE
[Chroma]^C^CVSLIDE chroma
[ Restore]^C^CREDRAW
[Elev]PROP ELEV
[LAyer]PROP LAYER
[LType]PROP LT $S=X $S=CHLT \$S=X $S=CHANGE
[Thicknes]PROP THICKNESS
**CHPROP 3
[CHPROP:]^C^CCHPROP
Window
Last
Previous
Crossing
Remove
Add
Undo
[Color]PROP COLOR $S=X $S=CHCOLOR \$S=X $S=CHPROP
[Chroma]^C^CVSLIDE chroma
[ Restore]^C^CREDRAW
[LAyer]PROP LAYER
[LType]PROP LT $S=X $S=CHLT \$S=X $S=CHPROP
[Thicknes]PROP THICKNESS
**CHCOLOR 3
[COLOR]
bylayer
byblock
red
yellow
green
cyan
blue
magenta
white
**CHLT 3
[LTYPE]
bylayer
byblock
[contin.]CONTINUOUS
dashed
hidden
center
phantom
dot
dashdot
border
divide
**COLOR 3
[COLOR:]^C^CCOLOR
bylayer
byblock
red
yellow
green
cyan
blue
magenta
white
[Chroma]^C^CVSLIDE chroma
[ Restore]^C^CREDRAW
**ATTEDIT 3
[ATTEDIT:]^C^CATTEDIT
Window
Last
Crossing
Remove
Add
Undo
[Value]Value $S=X $S=ATTEDIT2
Position
Height
Angle
Style
Layer
[Color] $S=X $S=ATTCOLOR C
Next
[__LAST__]$S= $S=
**ATTEDIT2 3
[Change]Change $S=X $S=ATTEDIT
[Replace]Replace $S=X $S=ATTEDIT
**ATTCOLOR 3
[COLOR]
[red]RED $S= $S=
[yellow]YELLOW $S= $S=
[green]GREEN $S= $S=
[cyan]CYAN $S= $S=
[blue]BLUE $S= $S=
[magenta]MAGENTA $S= $S=
[white]WHITE $S= $S=
**UNITS 2
[UNIT ]
[TYPE ]
[scientfc]1;
[decimal ]2;
[enginrng]3;
[archtect]4;
[metric ]5;
**U1 2
[Scientfc]
[Scale ]
[4 TIMES ]4.0;
[2 TIMES ]2.0;
[FULL ]1.0;
[HALF ]0.5;
[QUARTER ]0.25;
[OTHER ]^P0;^P
**U2 2
[Decimal ]
[Scale ]
[4 TIMES ]4.0;
[2 TIMES ]2.0;
[FULL ]1.0;
[HALF ]0.5;
[QUARTER ]0.25;
[OTHER ]^P0;^P
**U3 2
[Enginrng]
[Scale ]
[1"=10' ]120.0;
[1"=20' ]240.0;
[1"=30' ]360.0;
[1"=40' ]480.0;
[1"=50' ]600.0;
[1"=60' ]720.0;
[1"=80' ]960.0;
[1"=100' ]1200.0;
[OTHER ]^P0;^P
**U4 2
[Archtect]
[1/40"=1']480.0;
[1/20"=1']240.0;
[1/16"=1']192.0;
[ 1/8"=1']96.0;
[ 1/4"=1']48.0;
[ 1/2"=1']24.0;
[ 3/4"=1']16.0;
[ 1"=1']12.0;
[ 3"=1']4.0;
[ 6"=1']2.0;
[ FULL ]1.0;
[OTHER...]^P0;^P
**U5 2
[Metric ]
[ 1:5000 ]5000.0;
[ 1:2000 ]2000.0;
[ 1:1000 ]1000.0;
[ 1:500 ]500.0;
[ 1:200 ]200.0;
[ 1:100 ]100.0;
[ 1:75 ]75.0;
[ 1:50 ]50.0;
[ 1:20 ]20.0;
[ 1:10 ]10.0;
[ 1:5 ]5.0;
[ FULL ]1.0;
[OTHER...]^P0;^P
**ENGLISH 2
[Horizntl]
[ Sheet ]
[ Size ]
[A-8.5x11]11.0 8.5;
[B- 11x17]17.0 11.0;
[C- 17x22]22.0 17.0;
[ 18x24]24.0 18.0;
[D- 22X34]34.0 22.0;
[ 24x36]36.0 24.0;
[E- 34x44]44.0 34.0;
[OTHER...]^P0 0;^P
[VERTCAL>]$S=X $S=ENGVERT
**ENGVERT 2
[Vertical]
[ Sheet ]
[ Size ]
[A-8.5x11]8.5 11.0;
[B- 11x17]11.0 17.0;
[C- 17x22]17.0 22.0;
[ 18x24]18.0 24.0;
[D- 22X34]22.0 34.0;
[ 24x36]24.0 36.0;
[E- 34x44]34.0 44.0;
[OTHER...]^P0 0;^P
[HORZNTL>]$S=X $S=ENGLISH
**METRIC 2
[Horizntl]
[ Sheet ]
[ Size ]
[1189x841]1189.0 841.0;
[1000x707]1000.0 707.0;
[ 841x594]841.0 594.0;
[ 594x420]594.0 420.0;
[ 420x297]420.0 297.0;
[ 297x210]297.0 210.0;
[OTHER...]^P0 0;^P
[VERTCAL>]$S=X $S=METRICVERT
**METRICVERT 2
[Vertical]
[ Sheet ]
[ Size ]
[1189x841]841.0 1189.0;
[1000x707]707.0 1000.0;
[ 841x594]594.0 841.0;
[ 594x420]420.0 594.0;
[ 420x297]297.0 420.0;
[ 297x210]210.0 297.0;
[OTHER...]^P0 0;^P
[HORZNTL>]$S=X $S=METRIC
**CHTEMP 3
[Change ]
[Template]
[Arch...]^C^C^P(progn(if v:acam(progn(command "menu" (strcat v:acam "aec-a"))+
(prompt "AEC Architectural loaded."))(prompt "AEC Architectural not available.")+
)(princ)) ^P
[Mech...]^C^C^P(progn(if v:acmm(progn(command "menu" (strcat v:acmm "aec-m"))+
(prompt "AEC Mechanical loaded."))(prompt "AEC Mechanical not available.")+
)(princ)) ^P
**EXCOMDS 3
[CATALOG:]^C^CCATALOG
[DEL:]^C^CDEL
[DIR:]^C^CDIR
[EDIT:]^C^CEDIT
[SH:]^C^CSH
[SHELL:]^C^CSHELL
[TYPE:]^C^CTYPE
***TABLET1
[A-1]
[A-2]
[A-3]
[A-4]
[A-5]
[A-6]
[A-7]
[A-8]
[A-9]
[A-10]
[A-11]
[A-12]
[A-13]
[A-14]
[A-15]
[A-16]
[A-17]
[A-18]
[A-19]
[A-20]
[A-21]
[A-22]
[A-23]
[A-24]
[A-25]
[B-1]
[B-2]
[B-3]
[B-4]
[B-5]
[B-6]
[B-7]
[B-8]
[B-9]
[B-10]
[B-11]
[B-12]
[B-13]
[B-14]
[B-15]
[B-16]
[B-17]
[B-18]
[B-19]
[B-20]
[B-21]
[B-22]
[B-23]
[B-24]
[B-25]
[C-1]
[C-2]
[C-3]
[C-4]
[C-5]
[C-6]
[C-7]
[C-8]
[C-9]
[C-10]
[C-11]
[C-12]
[C-13]
[C-14]
[C-15]
[C-16]
[C-17]
[C-18]
[C-19]
[C-20]
[C-21]
[C-22]
[C-23]
[C-24]
[C-25]
[D-1]
[D-2]
[D-3]
[D-4]
[D-5]
[D-6]
[D-7]
[D-8]
[D-9]
[D-10]
[D-11]
[D-12]
[D-13]
[D-14]
[D-15]
[D-16]
[D-17]
[D-18]
[D-19]
[D-20]
[D-21]
[D-22]
[D-23]
[D-24]
[D-25]
[E-1]
[E-2]
[E-3]
[E-4]
[E-5]
[E-6]
[E-7]
[E-8]
[E-9]
[E-10]
[E-11]
[E-12]
[E-13]
[E-14]
[E-15]
[E-16]
[E-17]
[E-18]
[E-19]
[E-20]
[E-21]
[E-22]
[E-23]
[E-24]
[E-25]
[F-1]
[F-2]
[F-3]
[F-4]
[F-5]
[F-6]
[F-7]
[F-8]
[F-9]
[F-10]
[F-11]
[F-12]
[F-13]
[F-14]
[F-15]
[F-16]
[F-17]
[F-18]
[F-19]
[F-20]
[F-21]
[F-22]
[F-23]
[F-24]
[F-25]
[G-1]
[G-2]
[G-3]
[G-4]
[G-5]
[G-6]
[G-7]
[G-8]
[G-9]
[G-10]
[G-11]
[G-12]
[G-13]
[G-14]
[G-15]
[G-16]
[G-17]
[G-18]
[G-19]
[G-20]
[G-21]
[G-22]
[G-23]
[G-24]
[G-25]
[H-1]
[H-2]
[H-3]
[H-4]
[H-5]
[H-6]
[H-7]
[H-8]
[H-9]
[H-10]
[H-11]
[H-12]
[H-13]
[H-14]
[H-15]
[H-16]
[H-17]
[H-18]
[H-19]
[H-20]
[H-21]
[H-22]
[H-23]
[H-24]
[H-25]
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
***TABLET2
$S=X $S=HIDE
$S=X $S=VPOINT VPOINT;;
$S=X $S=ELEVTHK ^C^CELEV
$S=X $S=UCS1 ^C^CUCS
^C^CUCS;PREV
^C^CUCS;V
;
^O
$S=X $S=ZOOM 'ZOOM W
$S=X $S=LINE ^C^CLINE
'REDRAW
[VPOINT ]^C^CVPOINT R;<<135;$S=X $S=VPOINT3D
[VPT rear]^C^CVPOINT R;<<90;$S=X $S=VPOINT3D
[VPOINT ]^C^CVPOINT R;<<45;$S=X $S=VPOINT3D
$S=X $S=UCS1 ^C^CUCS
^C^CUCS;;
^C^CPLAN;W
;
^O
$S=X $S=ZOOM 'ZOOM W
$S=X $S=PLINE ^C^CPLINE
'REDRAW
[VPT left]^C^CVPOINT R;<<180;$S=X $S=VPOINT3D
[VPT plan]^C^CPLAN;;
[VPT rigt]^C^CVPOINT R;<<0;$S=X $S=VPOINT3D
$S=X $S=DVIEW ^C^CDVIEW
$S=X $S=DVIEW ^C^CSELECT;\DVIEW;P;;CA;\\;
$S=X $S=DVIEW ^C^C$S=X $S=DVIEW1 DVIEW;;
;
^D
$S=X $S=ZOOM 'ZOOM D
$S=X $S=ARC ^C^CARC
'REDRAW
[VPOINT ]^C^CVPOINT R;<<225;$S=X $S=VPOINT3D
[VPT frnt]^C^CVPOINT R;<<270;$S=X $S=VPOINT3D
[VPOINT ]^C^CVPOINT R;<<315;$S=X $S=VPOINT3D
$S=X $S=DVIEW ^C^CDVIEW
$S=X $S=DVIEW ^C^CSELECT;\DVIEW;P;;Z;\;
$S=X $S=DVIEW ^C^CSELECT;\DVIEW;P;;PA;\\;
;
^Q
$S=X $S=ZOOM 'ZOOM A
$S=X $S=CIRCLE ^C^CCIRCLE
'REDRAW
^C^C^P(progn(setq m:err *error*)(prin1))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(princ))(cond ((null C:LIGHT)(vmon)+
(if (/= nil (findfile "ashade.lsp"))(progn (terpri);+
(prompt "Please wait... Loading ashade. ")(load "ashade")+
(menucmd "S=X")(menucmd "S=LIGHTS")(setq *error* m:err m:err nil))(progn (terpri);+
(prompt "The file 'Ashade.lsp' was not found in your current search directories")+
(terpri)(prompt "Check your AutoShade Manual for installation instructions.");+
(setq *error* m:err m:err nil)(princ))))+
(T (setq *error* m:err m:err nil)(menucmd "S=X")(menucmd "S=LIGHTS")(princ)));+
(if (and C:LIGHT as-err)(C:LIGHT)(prompt "LIGHT is not properly loaded."))(princ) ^P
^C^C^P(progn(setq m:err *error*)(prin1))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(princ))(cond ((null C:CAMERA)(vmon)+
(if (/= nil (findfile "ashade.lsp"))(progn (terpri);+
(prompt "Please wait... Loading ashade. ")(load "ashade")+
(menucmd "S=X")(menucmd "S=CAMERA")(setq *error* m:err m:err nil))(progn (terpri);+
(prompt "The file 'Ashade.lsp' was not found in your current search directories")+
(terpri)(prompt "Check your AutoShade Manual for installation instructions.");+
(setq *error* m:err m:err nil)(princ))))+
(T (setq *error* m:err m:err nil)(menucmd "S=X")(menucmd "S=CAMERA")(princ)));+
(if (and C:CAMERA as-err)(C:CAMERA)(prompt "CAMERA is not properly loaded."))(princ) ^P
^C^C^P(progn(setq m:err *error*)(prin1))(defun *error* (msg)(princ msg)+
(setq *error* m:err m:err nil)(princ))(cond ((null C:LIGHT)(vmon)+
(if (/= nil (findfile "ashade.lsp"))(progn (terpri);+
(prompt "Please wait... Loading ashade. ")(load "ashade")+
(menucmd "S=X")(menucmd "S=ACTION")(setq *error* m:err m:err nil))(progn (terpri);+
(prompt "The file 'Ashade.lsp' was not found in your current search directories")+
(terpri)(prompt "Check your AutoShade Manual for installation instructions.");+
(setq *error* m:err m:err nil)(princ))))+
(T (setq *error* m:err m:err nil)(menucmd "S=X")(menucmd "S=ACTION")(princ))) ^P
$S=X $S=3D ^C^CRULESURF
$S=X $S=3D ^C^CREVSURF
$S=X $S=3DFACE ^C^C3DFACE
;
'GRAPHSCR
$S=X $S=ZOOM 'ZOOM P
$S=X $S=ELLIPSE ^C^CELLIPSE
'REDRAW
$S=X $S=VPORTS ^C^CVPORTS
$S=X $S=VPORTS ^C^CVPORTS;JOIN
^C^CVPORTS;SI
$S=X $S=3D ^C^CEDGESURF
$S=X $S=3D ^C^CTABSURF
$S=X $S=3DPOLY ^C^C3DPOLY
;
^E
$S=X $S=ZOOM 'ZOOM E
$S=X $S=POLYGON ^C^CPOLYGON
'REDRAW
;
;
;
;
;
;
;
^G
$S=X $S=ZOOM 'ZOOM
$S=X $S=POINT ^C^CPOINT
'REDRAW
$S=X $S=BLOCK ^C^CBLOCK
$S=X $S=INSERT ^C^CINSERT
$S=X $S=ATTDEF ^C^CATTDEF
;
$S=X $S=LAYER ^C^CLAYER
$S=X $S=LAYER ^C^CLAYER
;
^B
$S=X $S=PAN 'PAN
^C^CDONUT
'REDRAW
$S=X $S=WBLOCK ^C^CWBLOCK
$S=X $S=MINSERT ^C^CMINSERT
$S=X $S=ATTDEF ^C^CATTDEF
;
$S=X $S=LAYER ^C^CLAYER ? *;;
^C^CLAYER S \;
;
^B
$S=X $S=DS
$S=X $S=DR
'REDRAW
***TABLET3
;
;
;
<<135
<<135
<<90
<<90
<<45
<<45
;
;
;
<<180
<<180
<\
<\
<<0
<<0
;
;
;
<<225
<<225
<<270
<<270
<<315
<<315
;
;
;
^H
^H
^H
^H
^H
^H
;
;
;
7/8\
7/8\
/16\
/16\
/32\
/32\
;
;
;
1/2\
1/2\
5/8\
5/8\
3/4\
3/4\
;
;
;
1/8\
1/8\
1/4\
1/4\
3/8\
3/8\
;
;
;
-\
-\
/\
/\
X\
X\
;
;
;
@\
@\
'\
'\
"\
"\
;
;
;
7\
7\
8\
8\
9\
9\
;
;
4\
4\
5\
5\
6\
6\
;
;
;
1\
1\
2\
2\
3\
3\
;
;
0\
0\
.\
.\
,\
,\
***TABLET4
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
^C^CTIME
$S=X $S=ID ^C^CID
^C^CSTATUS
$S=X $S=LIST ^C^CLIST
'HELP
'HELP
;
$S=X $S=DTEXT ^C^CDTEXT
$S=X $S=DTEXT ^C^CDTEXT C
$S=X $S=DTEXT ^C^CDTEXT R
;
^C^COSNAP NONE
CENTER
ENDPOINT
INSERT
INTERSEC
MIDPOINT
NEAREST
NODE
PERPEND
QUADRANT
TANGENT
;
^C^CSAVE
^C^CSAVE
^C^CDBLIST
$S=X $S=AREA ^C^CAREA
^C^CDIST
$S=X $S=LIST ^C^CLIST
'HELP
'HELP
;
$S=X $S=DTEXT ^C^CDTEXT A
$S=X $S=DTEXT ^C^CDTEXT M
$S=X $S=DTEXT ^C^CDTEXT F
;
^C^C
^C^C
^C^CU
^C^CREDO
MULTIPLE
WINDOW
LAST
PREVIOUS
CROSSING
REMOVE
ADD
;
$S=X $S=END ^C^CEND
$S=X $S=QUIT ^C^CQUIT
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
;
^C^CFILES
^C^CFILES
^C^CDIM1 STATUS
$S=X $S=VAR1 ^C^CDIM
UNDO
'REDRAW
EXIT;$S=X $S=S
EXIT;$S=X $S=S
;
$S=X $S=TEXTSET
$S=X $S=SNAP ^C^CSNAP
$S=X $S=GRID ^C^CGRID
;
$S=X $S=SCALE ^C^CSCALE
$S=X $S=ROTATE ^C^CROTATE
$S=X $S=OFFSET ^C^COFFSET
$S=X $S=MOVE ^C^CMOVE
$S=X $S=ERASE ^C^CERASE
$S=X $S=ERASE ^C^CERASE
^C^COOPS
^C^C^P+
(defun m:p1(/ m:pa m:pc m:d m:w)(menucmd "S=X")(menucmd "S=PSEL");+
(setq m:d T)(while m:d (setq m:pc (ssget))(setq m:pa (ssname m:pc 0));+
(if(=(cdr(assoc 0 (entget m:pa))) "POLYLINE")(progn(setq m:d nil)+
(m:p2 m:pa m:pc))(progn(prompt "Entity selected is not a polyline")(terpri);+
(if (member (cdr (assoc 0 (entget m:pa))) '("LINE" "ARC"))(progn+
(initget "Yes No")(setq m:w (getkword "Do you want to turn it into one? <Y>"));+
(if (or (= m:w "Yes")(null m:w))(progn(setq m:d nil)(menucmd "S=X");+
(menucmd "S=P0")(command "PEDIT" m:pa "yes" pause)))))))))+
(defun m:p2(m:pa m:pc / m:pb)(menucmd "S=X")+
(if (= (setq m:pb (cdr (assoc 70 (entget m:pa)))) nil)(menucmd "S=P0");+
(progn (setq m:pb (/ m:pb 2))(if (>= m:pb 8)(menucmd "S=P16");+
(if(< m:pb 4)(menucmd "S=P0")(menucmd "S=P8")))))(command "PEDIT" m:pa pause))+
(defun perror (msg)(setq *error* m:err m:err nil)(princ))+
(defun C:PEDITM (/ m:err)(setq m:err *error* *error* perror)(m:p1);+
(setq *error* m:err m:err nil)(princ))(princ) PEDITM ^P
^C^CEXPLODE
$S=X $S=ARRAY ^C^CARRAY
$S=X $S=DIVIDE ^C^CDIVIDE
;
^C^CPLOT
^C^CPRPLOT
$S=X $S=DIM ^C^CDIM1
$S=X $S=DIM ^C^CDIM LEADER
$S=X $S=DIMLINEAR BASELINE
$S=X $S=DIMLINEAR CONTIN
$S=X $S=DIMLINEAR ^C^CDIM VERT
$S=X $S=DIMLINEAR ^C^CDIM HORIZ
;
$S=X $S=AXIS ^C^CAXIS
$S=X $S=SET
$S=X $S=OSNAPC ^C^COSNAP
;
$S=X $S=MIRROR ^C^CMIRROR
$S=X $S=BREAK2P ^C^CBREAK \F
$S=X $S=BREAKSPL ^C^CBREAK \F \@
$S=X $S=COPY ^C^CCOPY
$S=X $S=EXTEND ^C^CEXTEND
$S=X $S=STRETCH ^C^CSTRETCH C
$S=X $S=TRIM ^C^CTRIM
$S=X $S=FILLET0 ^C^CFILLET R 0;;
$S=X $S=FILLET ^C^CFILLET
$S=X $S=CHAMFER ^C^CCHAMFER
$S=X $S=MEASURE ^C^CMEASURE
;
$S=X $S=UT
$S=X $S=CHTEMP ^C^CMENU
$S=X $S=DIM ^C^CDIM CENTER
$S=X $S=DIM ^C^CDIM RADIUS
$S=X $S=DIM ^C^CDIM DIAMETER
$S=X $S=DIM ^C^CDIM ANGULAR
$S=X $S=DIM ^C^CDIM ROTATED
$S=X $S=DIMLINEAR ^C^CDIM ALIGNED
;
$S=X $S=QTEXT ^C^CQTEXT
$S=X $S=DRAGMODE ^C^CDRAGMODE
$S=X $S=APERTURE
;
$S=X $S=CHANGE ^C^CCHANGE
$S=X $S=CHANGE ^C^CCHANGE
$S=X $S=ATTEDIT ^C^CATTEDIT
;
$S=X $S=EXCOMDS
$S=X $S=EXCOMDS
**DTEXT1 33
$S=X $S=DTEXT ^C^CDTEXT
$S=X $S=DTEXT ^C^CDTEXT C
$S=X $S=DTEXT ^C^CDTEXT R
**DTEXT2 58
$S=X $S=DTEXT ^C^CDTEXT A
$S=X $S=DTEXT ^C^CDTEXT M
$S=X $S=DTEXT ^C^CDTEXT F
**TEXT1 33
$S=X $S=TEXT ^C^CTEXT
$S=X $S=TEXT ^C^CTEXT C
$S=X $S=TEXT ^C^CTEXT R
**TEXT2 58
$S=X $S=TEXT ^C^CTEXT A
$S=X $S=TEXT ^C^CTEXT M
$S=X $S=TEXT ^C^CTEXT F
**QS 3
[GEN:]^C^CGEN
[QSX:]$S=X $S=SELECT ^C^CQSX
[QSOPT:]$S=X $S=QS1 ^C^CQSOPT
[QS:]^C^CQS
[INDEX:]$S=X $S=SELECT ^C^CINDEX
[LABEL:]$S=X $S=MOVE ^C^CLABEL
[SMOO:]$S=X $S=SELECT $S=SMOO ^C^CSMOO
[TICK:]$S=X $S=SELECT $S=TICK ^C^CTICK
[POST:]$S=X $S=SELECT ^C^CPOST
[SURFACE:]^C^CSURFACE
[PROFIL:]^C^CPROFIL
[DRAPE:]$S=X $S=SELECT ^C^CDRAPE
[FLATTEN:]$S=X $S=SELECT ^C^CFLATTEN
[VOLUME:]$S=X $S=SELECT $S=VOLUME ^C^CVOLUME
[--MORE--]$S=QSB
[VPOINT:]^C^Cvpoint;;
**QSB 3
[GEN:]^C^CGEN
[QSX:]$S=X $S=SELECT ^C^CQSX
[QSOPT:]$S=X $S=QS1 ^C^CQSOPT
[QS:]^C^CQS
[INDEX:]$S=X $S=SELECT ^C^CINDEX
[LABEL:]$S=X $S=MOVE ^C^CLABEL
[SMOO:]$S=X $S=SELECT $S=SMOO ^C^CSMOO
[TILT:]$S=X $S=SELECT ^C^CTILT
[UNTILT:]$S=X $S=SELECT ^C^CUNTILT
[UNWRAP:]$S=X $S=SELECT ^C^CUNWRAP
[WRAP:]$S=X $S=SELECT ^C^CWRAP
[MAP:]$S=X $S=SELECT ^C^CMAP
[SLOPE:]$S=SLOPE ^C^CSLOPE
[SURFOP:]$S=SURFOP ^C^CSURFOP
[--LAST--]$S=QS
[VPOINT:]^C^Cvpoint;;
***POP9
**P9A
[QuickSurf I]
[Random points]^P(if c:qs (princ) (load "qs")) ^P^C^CGEN
[Extract points]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT ^C^CQSX
[Set options]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=QS1 ^C^CQSOPT
[Run QuickSurf]^P(if c:qs (princ) (load "qs")) ^P^C^CQS
[Index]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT ^C^CINDEX
[Label contours]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=MOVE ^C^CLABEL
[Smoo]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT $S=SMOO ^C^CSMOO
[~--]
[Hatchure]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT $S=TICK ^C^CTICK
[Label points]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT ^C^CPOST
[Surface]^P(if c:qs (princ) (load "qs")) ^P^C^CSURFACE
[Profil]^P(if c:qs (princ) (load "qs")) ^P^C^CPROFIL
[Drape]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT ^C^CDRAPE
[Flatten]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT ^C^CFLATTEN
[Volume]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT $S=VOLUME ^C^CVOLUME
[QuickSurf II >]^P(if c:qs (princ) (load "qs")) ^P$P9=P9B $P9=*
[~--]
[3D View]^C^CVPOINT;;
**P9B
[QuickSurf II]
[Random points]^P(if c:qs (princ) (load "qs")) ^P^C^CGEN
[Extract points]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT ^C^CQSX
[Set options]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=QS1 ^C^CQSOPT
[Run QuickSurf]^P(if c:qs (princ) (load "qs")) ^P^C^CQS
[Index]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT ^C^CINDEX
[Label contours]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=MOVE ^C^CLABEL
[Smoo]^P(if c:qs (princ) (load "qs")) ^P$S=X $S=SELECT $S=SMOO ^C^CSMOO
[~--]
[Tilt]$S=X $S=SELECT ^C^CTILT
[Untilt]$S=X $S=SELECT ^C^CUNTILT
[Unwrap]$S=X $S=SELECT ^C^CUNWRAP
[Wrap]$S=X $S=SELECT ^C^CWRAP
[Map]$S=X $S=SELECT ^C^CMAP
[Slope]$S=SLOPE ^C^CSLOPE
[Surfop]$S=SURFOP ^C^CSURFOP
[QuickSurf I >]$P9=P9A $P9=*
**QS1 3
[QSOPT:]$S=X $S=QS1 ^C^CQSOPT
[Old]O
[New]N
[Yes]Y
[No]N
[Mono]M
[Color]C
[Layered]Y
[None]N
[QS:]$S=X $S=QS ^C^CQS
[QUICKSRF]$S=X $S=QS
**SURFOP 3
-
[+]+
*
/
[Reciproc]R
[Abs]A
[miN]N
[maX]X
[Sin]S
[Cos]C
[Ln]L
[Exp]E
[Floor]F
**SLOPE 3
[Absolute]A
[dz/dX]X
[dz/dY]Y
[Directn]D
[Curvatur]C
**TICK 13
[Up]U
[Center]C
[Down]D
[TICK:]^C^CTICK
**VOLUME 13
[EXPLODE:]^C^CEXPLODE
[VOLUME:]^C^CVOLUME
**SMOO 13
[SMOO:]^C^CSMOO
[Decurve]^C^C(setq howsmooth "d") SMOO
[Fit]^C^C(setq howsmooth "f") SMOO
[Spline]^C^C(setq howsmooth "s") SMOO
[Segments]^C^C(setq howsmooth "s" splinesegs (getint "Spline segments: "))