home *** CD-ROM | disk | FTP | other *** search
/ World of Shareware - Software Farm 2 / wosw_2.zip / wosw_2 / QBAS / VBUTIL.ZIP / FILEOPEN.DOC < prev    next >
Text File  |  1992-10-19  |  4KB  |  143 lines
  1.  
  2. Sub cboFiletype_Click ()
  3.     Select Case cboFiletype.ListIndex
  4.         Case 0      ' Text Files (*.txt)
  5.             NewPattern = "*.txt"
  6.         Case 1      ' All Files (*.*)
  7.             NewPattern = "*.*"
  8.     End Select
  9.     
  10.     txtFileName.Text = NewPattern
  11.     filFiles.Pattern = NewPattern
  12.     ' reinitialize the file controls
  13.     filFiles.Refresh
  14. End Sub
  15.  
  16. Sub cmdcancel_Click ()
  17.     
  18.     ' Set the file name text box to null.
  19.     ' By checking the text property of this text box,
  20.     ' other procedures can tell if Cancel has been
  21.     ' selected.
  22.     FileForm.txtFileName.Text = Empty
  23.     
  24.     ' Hide the form
  25.     FileForm.Hide
  26.  
  27. End Sub
  28.  
  29. Sub cmdOK_Click ()
  30. Dim Msg As String
  31. On Error Resume Next
  32.     If txtFileName.Text Like "*[;>]*" Or txtFileName.Text Like "*[ ,+|/]*" Then
  33.         Msg = "Bad filename"
  34.         ' Display error and select the offending text.
  35.         MsgBox Msg, 48, App.EXEName
  36.         txtFileName.SetFocus
  37.         txtFileName.SelStart = 0
  38.         txtFileName.SelLength = Len(txtFileName.Text)
  39.     Else
  40.         Hide
  41.     End If
  42.  
  43. End Sub
  44.  
  45. Sub dirDirs_Change ()
  46.     
  47.     ' propogate directory changes to other controls
  48.     filFiles.Path = dirDirs.Path
  49.     lblCurrentDir.Caption = dirDirs.Path
  50.     ChDir dirDirs.Path
  51.     txtFileName.Text = filFiles.Pattern
  52.  
  53. End Sub
  54.  
  55. Sub drvDrives_Change ()
  56.  
  57.     ' change the dirDirs control path, it will
  58.     ' pass the change on to the filFiles control
  59.     dirDirs.Path = drvDrives.Drive
  60.     ChDrive (drvDrives.Drive)
  61.  
  62. End Sub
  63.  
  64. Sub filFiles_Click ()
  65.     
  66.     ' echo the selected name in the Text box
  67.     txtFileName.Text = filFiles.FileName
  68.  
  69. End Sub
  70.  
  71. Sub filFiles_DblClick ()
  72.  
  73.     ' we have a final selection from the File Save dialog
  74.     'txtFilename.Text = filFiles.FileName
  75.     cmdOK_Click
  76.  
  77. End Sub
  78.  
  79. Sub filFiles_PathChange ()
  80.     dirDirs.Path = filFiles.Path
  81.     drvDrives.Drive = filFiles.Path
  82. End Sub
  83.  
  84. Sub filFiles_PatternChange ()
  85.     'Show the current search pattern in the txtFileName control
  86.     txtFileName.Text = filFiles.Pattern
  87.     dirDirs.Path = filFiles.Path
  88. End Sub
  89.  
  90. Sub Form_Activate ()
  91.     ' If File Open dialog, set Text box to current pattern
  92.     If FileForm.Caption = "Open" Then
  93.         txtFileName.Text = filFiles.Pattern
  94.     End If
  95.     
  96.     ' If a File Save dialog, set the text box
  97.     ' to the current file name
  98.     If FileForm.Caption = "Save As" Then
  99.         ' File is not named
  100.         If frmMDI.ActiveForm.Caption = "Untitled" Then
  101.             FileForm.txtFileName.Text = filFiles.Pattern
  102.         ' File has a name
  103.         Else
  104.             FileForm.txtFileName.Text = frmMDI.ActiveForm.Caption
  105.     End If
  106.     
  107.     End If
  108.     ' initialize file controls
  109.     filFiles.Refresh
  110.     
  111.     ' Clear current selection in Filetype list box
  112.     cboFiletype.ListIndex = -1
  113.     
  114.     ' Set FileType list box to first item (*.txt)
  115.     cboFiletype.ListIndex = 0
  116.     
  117.     ' highlight the current selection
  118.     FileForm.txtFileName.SelStart = 0
  119.     FileForm.txtFileName.SelLength = Len(FileForm.txtFileName.Text)
  120.  
  121. End Sub
  122.  
  123. Sub Form_Load ()
  124.     ' display full path name in a label
  125.     lblCurrentDir.Caption = dirDirs.Path
  126.  
  127.     ' add items to List Files of Type list
  128.     cboFiletype.AddItem "Text Files (*.txt)"
  129.     cboFiletype.AddItem "All Files (*.*)"
  130. End Sub
  131.  
  132. Sub Form_Unload (Cancel As Integer)
  133.     
  134.     Cancel = True   ' Don't unload form, just hide it
  135.     Call cmdcancel_Click
  136. End Sub
  137.  
  138. Sub txtFileName_Change ()
  139.     ' Disable OK button if no filename.
  140.     cmdOK.Enabled = (Len(txtFileName.Text) > 0)
  141. End Sub
  142.  
  143.