home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
World of Shareware - Software Farm 2
/
wosw_2.zip
/
wosw_2
/
QBAS
/
123QB11.ZIP
/
MAKELIB.BAT
< prev
Wrap
DOS Batch File
|
1989-12-01
|
2KB
|
84 lines
ECHO OFF
IF "%1"=="" GOTO NOPARAMETERS
IF EXIST 123WRITE.LIB GOTO ERASEPROMPT
IF EXIST 123WRITE.QLB GOTO ERASEPROMPT
IF "%1"=="6" GOTO WRITE_I
IF "%1"=="6A" GOTO WRITE_A
IF "%1"=="40" GOTO WRITE_I
IF "%1"=="41" GOTO WRITE_I
IF "%1"=="45" GOTO WRITE_I
GOTO NOPARAMETERS
REM
REM Create a LIB response file:
REM
:WRITE_I
ECHO 123write.lib >~LIBRSP
ECHO y >>~LIBRSP
ECHO +123wrt_i.obj >>~LIBRSP
ECHO NUL >>~LIBRSP
ECHO 123write.lib >>~LIBRSP
REM
REM Create a LINK response file:
REM
ECHO /Q 123wrt_i.obj >~LINKRSP
ECHO 123write.qlb >>~LINKRSP
ECHO /NOE /NOD >>~LINKRSP
REM
REM tailor the LIBRARIES prompt to the compiler.
REM
IF "%1"=="6" GOTO QB41
IF "%1"=="40" GOTO QB40
IF "%1"=="41" GOTO QB41
IF "%1"=="45" GOTO QB45
:QB40
ECHO BQLB40.LIB;>>~LINKRSP
GOTO DOIT
:QB41
ECHO BQLB41.LIB;>>~LINKRSP
GOTO DOIT
:QB45
ECHO BQLB45.LIB;>>~LINKRSP
GOTO DOIT
:WRITE_A
ECHO 123write.lib >~LIBRSP
ECHO y >>~LIBRSP
ECHO +123wrt_a.obj >>~LIBRSP
ECHO NUL >>~LIBRSP
ECHO 123write.lib >>~LIBRSP
ECHO /Q 123wrt_i.obj >~LINKRSP
ECHO 123write.qlb >>~LINKRSP
ECHO /NOE /NOD >>~LINKRSP
ECHO BQLB41.LIB;>>~LINKRSP
:DOIT
LIB @~librsp
LINK @~linkrsp
DEL ~librsp
DEL ~linkrsp
ECHO Done.
GOTO END
:NOPARAMETERS
ECHO To create the libraries, you must use a parameter on the MAKELIB command line.
ECHO .
ECHO The parameter indicates the compiler you are using. Use:
ECHO .
ECHO 6 for the BASIC Compiler version 6.0 (Will use BQLB41.LIB)
ECHO 6A for the BASIC Compiler version 6.0 (Will use BQLB41.LIB)
ECHO (for use with the /FPA BASIC 6.0 compiler switch)
ECHO 40 for QuickBASIC 4.0 with the BQLB40.LIB file.
ECHO 41 for QuickBASIC 4.0 with the BQLB41.LIB file. (QB 4.0a/b)
ECHO 45 for QuickBASIC 4.5 with the BQLB45.LIB file. (QB 4.5)
ECHO .
ECHO For example, with QuickBasic 4.5:
ECHO .
ECHO MAKELIB 45
ECHO .
ECHO Will do the trick.
ECHO .
GOTO END
:ERASEPROMPT
ECHO One or more of the 123WRITE libraries already exists in the current
ECHO directory. Please, as a precaution, rename or move 123WRITE.LIB and
ECHO 123WRITE.QLB.
GOTO END
:END