home *** CD-ROM | disk | FTP | other *** search
/ World of Shareware - Software Farm 2 / wosw_2.zip / wosw_2 / DATABASE / RACONT.ZIP / BREAKIT.BAS next >
BASIC Source File  |  1991-04-19  |  2KB  |  71 lines
  1. 10 ON ERROR GOTO 480
  2. 20 D$(1)="-":D$(2)="\":D$(3)="|":D$(4)="/"
  3. 30 D=1
  4. 40 CLS
  5. 50 INPUT "Enter name of input file";F$
  6. 60 OPEN "i",#1,F$
  7. 70 IF LOF(1)>250000 THEN GOTO 120
  8. 80 OPEN "o",#2,"index1.bat"
  9. 90 PRINT#2,"INDEX ";F$
  10. 100 CLOSE
  11. 110 SYSTEM
  12. 120 PRINT"            ╔════════════════════════════════════════════════╗"
  13. 130 PRINT"            ║     BREAKING UP INPUT FILE INTO WORKING        ║"
  14. 140 PRINT"            ║          FILES FOR RACONTEX INDEXER            ║"
  15. 150 PRINT"            ╚════════════════════════════════════════════════╝"
  16. 160 O$="P!"
  17. 170 I=I+1
  18. 180 O1$=O$+"."+RIGHT$(STR$(I),LEN(STR$(I))-1)
  19. 190 OPEN"o",#2,O1$
  20. 200 LOCATE 13,1
  21. 210 PRINT "                  ╔═════════════════════════╗"
  22. 220 PRINT "                  ║                         ║"
  23. 230 PRINT "                  ║                         ║"
  24. 240 PRINT "                  ║                         ║"
  25. 250 PRINT "                  ╚═════════════════════════╝"
  26. 260 LOCATE 14,21
  27. 270 PRINT "opening file ";O1$
  28. 280 LOCATE 8,1
  29. 290 PRINT "                             ╔═══╗"
  30. 300 PRINT "                             ║   ╣"
  31. 310 PRINT "                             ╚═══╝"
  32. 320 TAIL$=TAIL$+" "+O1$
  33. 330 LINE INPUT #1,L$
  34. 340 LOCATE 9,32:PRINT D$(D):D=D+1:IF D>4 THEN D=1
  35. 350 IF LEN(L$)>10 THEN IF RIGHT$(L$,10)="          " THEN L$=LEFT$(L$,LEN(L$)-10):GOTO 350
  36. 360 IF RIGHT$(L$,1)=" "THEN L$=LEFT$(L$,LEN(L$)-1):GOTO 360
  37. 370 CH=CH+LEN(L$)+2
  38. 380 LOCATE 16,21:PRINT "File Size = ";CH
  39. 390 PRINT#2,L$
  40. 400 IF EOF(1) THEN 430
  41. 410 IF CH>250000! THEN CLOSE 2 :CH=0:GOTO 170
  42. 420 GOTO 330
  43. 430 CLOSE
  44. 440 OPEN"o",#2,"index1.bat"
  45. 450 PRINT#2,"INDEX "+TAIL$
  46. 460 CLOSE
  47. 470 SYSTEM
  48. 480 REM error routine
  49. 490 IF ERL=60  THEN GOSUB 560:RESUME 60
  50. 500 PRINT"Please report to your system administrator error #";ERR;" at line ";ERL;" of BREAKIT"
  51. 510 PRINT "Press ENTER"
  52. 520 INPUT DUM$
  53. 530 OPEN"o",#2,"index1.bat"
  54. 540 CLOSE
  55. 550 SYSTEM
  56. 560 REM wrong file routine
  57. 570 CLS
  58. 580 PRINT "I can't open the file called ";F$
  59. 590 PRINT "What other file name should I try?"
  60. 600 PRINT "(enter NUL as a file name to abort this run)
  61. 610 INPUT F$
  62. 620 CLS
  63. 630 IF F$="NUL" OR F$="nul" GOTO 530
  64. 640 RETURN
  65. 
  66.  
  67.  
  68.  
  69.  
  70.  
  71.