home *** CD-ROM | disk | FTP | other *** search
/ World of Shareware - Software Farm 2 / wosw_2.zip / wosw_2 / CPROG / CMDSRC.ZIP / HISTORY.ASM < prev    next >
Assembly Source File  |  1990-04-29  |  9KB  |  364 lines
  1. ; HISTORY.ASM
  2. ; (c) 1989, 1990 Ashok P. Nadkarni
  3. ;
  4. ; This module implements the history feature of the cmdedit program.
  5.  
  6.     INCLUDE common.inc
  7.     INCLUDE    buffers.inc
  8.  
  9.     PUBLIC    hist_top
  10.     PUBLIC    hist_init
  11.     PUBLIC    hist_fwd
  12.     PUBLIC    hist_back
  13.     PUBLIC    hist_fwd_match
  14.     PUBLIC    hist_bck_match
  15.     PUBLIC    remember
  16.     PUBLIC    hist_type
  17.     PUBLIC    execute_auto_recall
  18.     PUBLIC    execute_rsthist
  19.     PUBLIC    hist_ptr
  20.     PUBLIC    history
  21.  
  22. CSEG    SEGMENT    PARA PUBLIC 'CODE'
  23.  
  24.  
  25.     EXTRN    linebuf:BYTE        ;line buffer
  26.     EXTRN    lastchar:WORD
  27.     EXTRN    dot:WORD        ;current position in line buffer
  28.  
  29.  
  30. ; The history stack is maintained as a string stack using the functions in
  31. ; the string stack library. The top and bottom of the stack are always
  32. ; zero length strings (the bottom is always a zero length sentinel
  33. ; implemented by the string stack package but the top is explicitly 
  34. ; maintained by the history code.
  35. history    $string_stack 2 DUP (<>)    ;Buffer descriptors
  36. hist_ptr    DW    ?        ;Ptr to current buffer descriptor
  37.  
  38.  
  39. DGROUP    GROUP    CSEG
  40.  
  41.     EXTRN    bell:PROC
  42.     EXTRN    set_disp_marks:PROC
  43.     EXTRN    erase_to_dot:PROC
  44.  
  45.     ASSUME    CS:DGROUP,DS:DGROUP,ES:DGROUP,SS:DGROUP
  46.  
  47.  
  48. ;+
  49. ; FUNCTION : hist_init
  50. ;
  51. ; Initializes the various data structures associated with the
  52. ; command history buffers. CALLER MUST ENSURE PASSED ADDRESSES ARE VALID
  53. ; AND BUFFER IS LARGE ENOUGH.
  54. ;
  55. ; Parameters:
  56. ;    AX     - length of buffer in bytes
  57. ;    BX    - address of buffer
  58. ;    CX    - 0 if DOS buffer, any other value if application buffer
  59. ; 
  60. ; Returns:
  61. ;    Nothing.
  62. ; Registers destroyed : BX,CX
  63. ;-
  64. hist_init proc    near
  65.     push    bx
  66.     mov    bx,offset DGROUP:history ;bx := address of buffer descriptors
  67.     jcxz    @hist_init_1        ;if DOS, bx OK
  68.     add    bx,TYPE $string_stack    ;else point to application descriptor
  69. @hist_init_1:
  70.     xchg    ax,cx            ;CX = buffer size
  71.     pop    ax            ;AX = Buffer address
  72.                     ;BX points to appropriate descriptor
  73.     call    near ptr strstk_init    ;Initialize buffer and descriptor
  74.     xor    al,al            ;Push a zero length string onto stack
  75.     mov    cl,1            ;Force onto stack
  76.     call    near ptr strstk_push    ;Assumes no errors
  77.     ret
  78. hist_init    endp
  79.  
  80.  
  81. ;+
  82. ; FUNCTION : execute_rsthist
  83. execute_rsthist proc    near
  84.     mov    bx,offset DGROUP:history ;bx := address of buffer descriptors
  85.     jcxz    @execute_rsthist_1    ;if DOS, bx OK
  86.     add    bx,TYPE $string_stack    ;else point to application descriptor
  87. @execute_rsthist_1:
  88.     call    near ptr strstk_reset    ;Initialize buffer and descriptor
  89.     xor    al,al            ;Push a zero length string onto stack
  90.     mov    cl,1            ;Force onto stack
  91.     call    near ptr strstk_push    ;Assumes no errors
  92.     ret
  93. execute_rsthist    endp
  94.  
  95.  
  96.  
  97. ;+
  98. ; FUNCTION : hist_type
  99. ;
  100. ;    Sets the hist_ptr global to point at the descriptor for the
  101. ;    current caller (DOS or application).
  102. ;
  103. ; Parameters:
  104. ;    CX =    0 if DOS, anything else for application
  105. ;
  106. ; Returns:
  107. ;    Nothing.
  108. ; Registers destroyed : BX
  109. ;-
  110. hist_type proc near
  111.     mov    bx,offset DGROUP:history ;address of first descriptor
  112.     mov    hist_ptr,bx
  113.     ret
  114. hist_type endp
  115.  
  116.  
  117. ;+
  118. ; FUNCTION : hist_top
  119. ;
  120. ;    Resets the history pointer to the null string at top of history stack.
  121. ;    The line buffer itslef is NOT changed.
  122. ; Parameters:
  123. ;    None.
  124. ;
  125. ; Returns:
  126. ;    Nothing.
  127. ; Registers destroyed:  BX
  128. ;-
  129. hist_top proc near
  130.     mov    bx,hist_ptr        ;Point to current descriptor
  131.     call    near ptr strstk_settop    ;Set to top of history stack.
  132.  
  133.     ret
  134. hist_top endp
  135.  
  136.  
  137. ;+
  138. ; FUNCTION : hist_back
  139. ;
  140. ;    Gets the previous history line (if there is one) and stores it
  141. ;    in the line buffer. Also makes it the current line.
  142. ;
  143. ; Parameters:
  144. ;    None.
  145. ;
  146. ; Returns:
  147. ;    Nothing.
  148. ; Registers destroyed: AX,BX,CX
  149. ;-
  150. hist_back proc near
  151.     mov    dot,offset DGROUP:linebuf
  152.     jmp    hist_bck_match        ;Will return to caller
  153. hist_back endp
  154.  
  155.  
  156.  
  157. ;+
  158. ; FUNCTION : hist_fwd
  159. ;
  160. ;    Gets the next history line (if there is one) and stores it
  161. ;    in the line buffer. Also makes it the current line.
  162. ;
  163. ; Parameters:
  164. ;    None.
  165. ;
  166. ; Returns:
  167. ;    Nothing.
  168. ; Registers destroyed :
  169. ;-
  170. hist_fwd proc near
  171.     mov    dot,offset DGROUP:linebuf
  172.     jmp    hist_fwd_match        ;Will return to caller
  173. hist_fwd endp
  174.  
  175.  
  176.  
  177. ;+
  178. ; 
  179. ; FUNCTION : hist_copy
  180. ;
  181. ;    Copies the current history line into the line buffer. The dot
  182. ;    is set to the beginning of the line.
  183. ;
  184. ; Parameters:
  185. ;    BX =    points to the beginning of a line in the history buffer.
  186. ;
  187. ; Returns:
  188. ;    Nothing.
  189. ;
  190. ; Registers destroyed: 
  191. ;-
  192. hist_copy proc near
  193.     mov    bx,hist_ptr    ;Current descriptor
  194.     mov    ax,offset DGROUP:linebuf ;the history line storage
  195.     push    ax        ;Remember
  196.     mov    dot,ax        ;Cursor will be at the beginning of line
  197.     xchg    ax,dx        ;dx->first char in line (parameter)
  198.     mov    ax,lastchar    ;ax->upper limit (parameter)
  199.     call    near ptr set_disp_marks ;Indicate changed range
  200.                 ;No registers destroyed
  201.     mov    ax,dx        ;Restore beginning of line
  202.     sub    cx,LINEBUF_SIZE    ;cx<-max length of line
  203.     push    cx        ;Save it
  204.     call    near ptr strstk_copy ;Copy history line into linebuf
  205.                 ;AX == length of history string
  206.     pop    cx        ;
  207.     jnc    @hist_copy_90    ;Jump if no error from strstk_copy
  208.     call    near ptr bell    ;History line too long for buffer
  209.     mov    ax,cx        ;Number of bytes = max length of line
  210. @hist_copy_90:
  211.     pop    dx        ;dx->beginning of line
  212.     add    ax,dx        ;ax->end
  213.     mov    lastchar,ax    ;Update end of line
  214.     call    near ptr set_disp_marks ;Indicate changed range
  215.                 ;No registers destroyed
  216.     ret
  217. hist_copy endp
  218.  
  219.  
  220.  
  221. ;+
  222. ; 
  223. ; FUNCTION : remember
  224. ;
  225. ;    Saves the line buffer in the history area. If the line already
  226. ;    exists, it is moved to the top of the stack.
  227. ;
  228. ; Parameters:
  229. ;    None.
  230. ;
  231. ; Returns:
  232. ;    Nothing.
  233. ;
  234. ; Registers destroyed:
  235. ;    AX,BX,CX,DX
  236. ;-
  237. remember proc near
  238.     mov    bx,hist_ptr        ;Descriptor
  239.     call    near ptr strstk_settop    ;Reset stack pointer
  240.     mov    ax,offset DGROUP:linebuf ;AX->line to be stored
  241.     mov    cx,lastchar
  242.     sub    cx,ax            ;CX<-length of line
  243.     call    near ptr strstk_bck_find ;Look for it in history
  244. ;                      buffer. Note that if it is a
  245. ;                      null string, the sentinel at
  246. ;                      top of the stack is not found
  247. ;                      which is at it should be.
  248.     jc    @remember_10        ;Not in stack
  249.     call    near ptr strstk_kill    ;If found delete it from stack
  250. @remember_10:
  251.     call    near ptr strstk_settop    ;Point to sentinel at top of stack
  252.     call    near ptr strstk_kill    ;Delete it
  253.     mov    dx,offset DGROUP:linebuf ;String to be remembered
  254.     mov    ax,lastchar        ;Length of string
  255.     sub    ax,dx            ;AX(AL)<-length of string
  256.     mov    cl,1            ;Force the push
  257.     call    near ptr strstk_push    ;ignore success/fail status
  258.     xor    ax,ax            ;Zero length sentinel
  259.     mov    cl,1
  260.     call    near ptr strstk_push    ;Push it
  261.     ret
  262. remember endp
  263.  
  264.  
  265.  
  266. ;+
  267. ; 
  268. ; FUNCTION : hist_fwd_match, hist_bck_match
  269. ;
  270. ;    Looks fwd/back thru the history buffer starting from the current
  271. ;    history location looking for a line whose first n chracters match
  272. ;    the n characters before the current position in the line buffer.
  273. ;
  274. ; Parameters:
  275. ;    None.
  276. ;
  277. ; Returns:
  278. ;    CF    = 0 if match found
  279. ;          1 if no match
  280. ;
  281. ; Registers destroyed:
  282. ;-
  283. hist_match proc near
  284. hist_fwd_match LABEL near
  285.     mov    dx,offset DGROUP:strstk_fwd_match
  286.     jmp    short @hist_match_10
  287. hist_bck_match label near
  288.     mov    dx,offset DGROUP:strstk_bck_match
  289. @hist_match_10:
  290.     mov    bx,hist_ptr    ;Descriptor address
  291.     mov    ax,offset DGROUP:linebuf ;start of pattern
  292.     mov    cx,dot        ;Current position in linebuffer
  293.     sub    cx,ax        ;Number of chars to match
  294.     push    cx        ;Save
  295.     push    ax
  296.     call    dx        ;Will set CF if no match, else sets
  297.                 ; 'current' to matched string
  298.     pushf            ;Remember flags
  299.     jc    @hist_match_20    ;No match
  300.     call    near ptr hist_copy ;Copy and display the history line
  301.                 ;Now reset it to original position
  302. @hist_match_20:
  303.     popf            ;Restore flags
  304.     pop    ax        ;Line address
  305.     pop    cx        ;Restore count
  306.     pushf            ;Save flags
  307.     add    ax,cx        ;AX->dot
  308.     mov    dot,ax
  309.     popf            ;Restore flags
  310.     jnc    @hist_match_99    ;If match was found, exit
  311.     mov    ax,lastchar    ;AX->end-of-line
  312.     call    erase_to_dot    ;Else delete remaining chars in the
  313. ;                 line (chars between AX and dot)
  314.     stc            ;Indicate no match
  315. @hist_match_99:
  316.     ret
  317. hist_match endp
  318.  
  319.  
  320.  
  321. ;+
  322. ; FUNCTION : execute_auto_recall
  323. ;
  324. ;    This function looks backward through the history buffer for a
  325. ;    line with a prefix that matches the characters to the left of
  326. ;    the dot. The search begins with the CURRENT history line. ie.
  327. ;    if the current history line has a matching prefix, the current
  328. ;    pointer is not changed. If no match is found, the history stack
  329. ;    is reset.
  330. ;
  331. ; Parameters:
  332. ;    None.
  333. ;
  334. ; Returns:
  335. ;    CF    = 0 if match found
  336. ;          1 if no match
  337. ; Register(s) destroyed:
  338. ;    AX,BX,CX,DX
  339. ;-
  340. execute_auto_recall proc near
  341.     mov    bx,hist_ptr        ;BX->current history stack descriptor
  342.     mov    ax,offset DGROUP:linebuf ;AX->pattern
  343.     mov    cx,dot
  344.     sub    cx,ax            ;CX<-length of pattern
  345.     call    near ptr strstk_prefix    ;Current history line matches?
  346.     jne    @execute_auto_recall_50    ;No
  347.     clc                ;Yes, current line matches
  348.     jmp    short @execute_auto_recall_99
  349.  
  350. @execute_auto_recall_50:
  351.     call    near ptr hist_bck_match    ;Search backward
  352.     jnc    @execute_auto_recall_99    ;Found a match
  353. ;    No match, reset history stack pointer
  354.     mov    bx,hist_ptr        ;BX->current history stack descriptor
  355.     call    near ptr hist_top    ;Reset history stack
  356.     stc                ;Indicate no match
  357. @execute_auto_recall_99:
  358.     ret
  359. execute_auto_recall endp
  360.  
  361. CSEG    ENDS
  362.  
  363.     END
  364.