home *** CD-ROM | disk | FTP | other *** search
/ World of Shareware - Software Farm 2 / wosw_2.zip / wosw_2 / CPROG / CEXPRESS.ZIP / SCREEN.ASM / DISPMEM.ASM < prev    next >
Assembly Source File  |  1989-05-03  |  2KB  |  71 lines
  1. ;void  display_mem(segment,offset,num_chars,col,row,color);
  2. ;  unsigned short  segment,offset,num_chars;
  3. ;  unsigned char  col,row,color;
  4.  
  5.     EXTRN  _memory_model:byte
  6.     EXTRN  _video_buffer:word
  7.     EXTRN  _snow_protect:byte
  8.  
  9. _TEXT    SEGMENT BYTE PUBLIC 'CODE'
  10.     ASSUME CS:_TEXT
  11.     PUBLIC _display_mem
  12. _display_mem proc near
  13.     push bp            ;
  14.     mov  bp,sp        ;set stack frame
  15.     push di            ;
  16.     push si            ;
  17.     cmp  _memory_model,0    ;near or far?
  18.     jle  begin        ;jump if near
  19.     inc  bp            ;else add 2 to BP
  20.     inc  bp            ;
  21. begin:    mov  cl,_snow_protect    ;get _snow_protect
  22.     push ds            ;save Turbo's DS
  23.     mov  ax,_video_buffer    ;fetch Videobuffer
  24.     mov  es,ax        ;ES pts to buffer
  25.     sub  bx,bx        ;
  26.     mov  bl,[bp+12]        ;Row
  27.     dec  bx            ;count from zero
  28.     mov  [bp+12],cl        ;save _snow_protect
  29.     sub  cx,cx        ;
  30.     mov  cl,[bp+10]        ;Col
  31.     dec  cx            ;count from zero
  32.     mov  ax,160        ;bytes per row
  33.     mul  bl            ;row offset
  34.     shl  cx,1        ;dble cols for attributes
  35.     add  ax,cx        ;offset to start position
  36.     mov  di,ax        ;ES:DI pts to start
  37.     mov  ax,[bp+4]        ;get segment
  38.     mov  ds,ax        ;
  39.     mov  si,[bp+6]        ;offset
  40.     mov  cx,[bp+8]        ;number chars to display
  41.     jcxz L5            ;quit if null
  42.     cld            ;forward direction
  43.     mov  ah,[bp+14]        ;get screen attribute
  44. L1:    lodsb            ;get a char from memory
  45.     cmp  byte ptr[bp+12],0    ;protect against snow?
  46.     je   L4            ;jump if not
  47.     push ax            ;save char-attri
  48.     mov  dx,3dah        ;status byte address
  49. L2:    in   al,dx        ;get status byte
  50.     test al,1        ;test bit
  51.     jnz  L2            ;loop till 0
  52.     cli            ;disable interrupts
  53. L3:    in   al,dx        ;get status byte
  54.     test al,1        ;test bit
  55.     jz   L3            ;loop till 1, then write
  56.     pop  ax            ;restore char-attri
  57. L4:    stosw            ;write the char and color
  58.     loop L1            ;loop till finished
  59. L5:    sti            ;reenable interrupts
  60.     pop  ds            ;
  61.     pop  si            ;
  62.     pop  di            ;
  63.     pop  bp            ;
  64.     cmp  _memory_model,0    ;quit
  65.     jle  quit        ;
  66.     db   0CBh        ;RET far
  67. quit:    ret            ;RET near
  68. _display_mem endp
  69. _TEXT    ENDS
  70.     END
  71.