home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
World of Shareware - Software Farm 2
/
wosw_2.zip
/
wosw_2
/
CPROG
/
CEXPRESS.ZIP
/
GRAPHIC.ASM
/
CHRLINEB.ASM
< prev
next >
Wrap
Assembly Source File
|
1989-05-03
|
2KB
|
62 lines
;void char_line_b(ch,dir,col,row,length,color);
; unsigned char ch,dir,col,row,length,color;
EXTRN _memory_model:byte
EXTRN _video_page:byte
_TEXT SEGMENT BYTE PUBLIC 'CODE'
ASSUME CS:_TEXT
PUBLIC _char_line_b
_char_line_b proc near
push bp ;
mov bp,sp ;set up stack frame
push di ;
cmp _memory_model,0 ;near or far?
jle begin ;jump if near
inc bp ;else add 2 to BP
inc bp ;
begin: push ds ;save DS
mov bh,_video_page ;get video page number
mov dl,[bp+8] ;COL in DL
dec dl ;count from 0
mov dh,[bp+10] ;ROW in DH
dec dh ;count from 0
mov ah,2 ;function to set cursor
int 10h ;set cursor to line
sub cx,cx ;
mov cl,[bp+12] ;string length in CX
jcxz L3 ;quit if zero
mov bl,[bp+14] ;attribute in BL
mov al,[bp+4] ;char in AL
mov ah,[bp+6] ;get direction param
cmp ah,'V' ;write vertically?
je L1 ;jump ahead if so
cmp ah,'v' ;test for small 'v'
je L1 ;jump if small 'v'
mov ah,9 ;BIOS function number
int 10h ;write horizontally
jmp short L3 ;go quit routine
L1: mov di,cx ;count length in DI
mov cx,1 ;write 1 char each time
L2: mov ah,9 ;function to write char
int 10h ;write it
dec di ;dec length counter
or di,di ;zero yet?
jz L3 ;quit if zero
push ax ;else save char
mov ah,2 ;function to set cursor
inc dh ;inc row number
int 10h ;reset cursor
pop ax ;restore character
jmp short L2 ;go write next
L3: pop ds ;
pop di ;
pop bp ;
cmp _memory_model,0 ;quit
jle quit ;
db 0CBh ;RET far
quit: ret ;RET near
_char_line_b endp
_TEXT ENDS
END