home *** CD-ROM | disk | FTP | other *** search
/ BCI NET 2 / BCI NET 2.iso / archives / programming / source / a2.0bemacs-src.lha / Emacs-19.25 / lisp / font-lock.el < prev    next >
Encoding:
Text File  |  1994-05-30  |  27.3 KB  |  724 lines
  1. ;; Electric Font Lock Mode
  2. ;; Copyright (C) 1992, 1993, 1994 Free Software Foundation, Inc.
  3.  
  4. ;; Author: jwz, then rms
  5. ;; Maintainer: FSF
  6. ;; Keywords: languages, faces
  7.  
  8. ;; This file is part of GNU Emacs.
  9.  
  10. ;; GNU Emacs is free software; you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation; either version 2, or (at your option)
  13. ;; any later version.
  14.  
  15. ;; GNU Emacs is distributed in the hope that it will be useful,
  16. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18. ;; GNU General Public License for more details.
  19.  
  20. ;; You should have received a copy of the GNU General Public License
  21. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23.  
  24.  
  25. ;;; Commentary:
  26.  
  27. ;; Font-lock-mode is a minor mode that causes your comments to be 
  28. ;; displayed in one face, strings in another, reserved words in another,
  29. ;; documentation strings in another, and so on.
  30. ;;
  31. ;; Comments will be displayed in `font-lock-comment-face'.
  32. ;; Strings will be displayed in `font-lock-string-face'.
  33. ;; Doc strings will be displayed in `font-lock-doc-string-face'.
  34. ;; Function and variable names (in their defining forms) will be
  35. ;;  displayed in `font-lock-function-name-face'.
  36. ;; Reserved words will be displayed in `font-lock-keyword-face'.
  37. ;;
  38. ;; To make the text you type be fontified, use M-x font-lock-mode.
  39. ;; When this minor mode is on, the fonts of the current line are
  40. ;; updated with every insertion or deletion.
  41. ;;
  42. ;; To define new reserved words or other patterns to highlight, use
  43. ;; the `font-lock-keywords' variable.  This should be mode-local.
  44. ;;
  45. ;; To turn this on automatically, add this to your .emacs file:
  46. ;;
  47. ;;    (setq emacs-lisp-mode-hook '(lambda () (font-lock-mode 1)))
  48. ;;
  49. ;; On a Sparc2, the initial fontification takes about 12 seconds for a 120k
  50. ;; file of C code, using the default configuration.  You can speed this up
  51. ;; substantially by removing some of the patterns that are highlighted by
  52. ;; default.  Fontifying Lisp code is significantly faster, because Lisp has a
  53. ;; more regular syntax than C, so the expressions don't have to be as hairy.
  54.  
  55. ;;; Code:
  56.  
  57. (or window-system
  58.     (error "Can't fontify on an ASCII terminal"))
  59.  
  60. (or (internal-find-face 'underline)
  61.     (copy-face 'default 'underline))
  62. (set-face-underline-p 'underline t)
  63.  
  64. (defvar font-lock-comment-face
  65.   'italic
  66.   "Face to use for comments.")
  67.  
  68. (defvar font-lock-doc-string-face
  69.   'italic
  70.   "Face to use for documentation strings.")
  71.  
  72. (defvar font-lock-string-face
  73.   'underline
  74.   "Face to use for string constants.")
  75.  
  76. (defvar font-lock-function-name-face
  77.   'bold-italic
  78.   "Face to use for function names.")
  79.  
  80. (defvar font-lock-keyword-face
  81.   'bold
  82.   "Face to use for keywords.")
  83.  
  84. (defvar font-lock-type-face
  85.   'italic
  86.   "Face to use for data types.")
  87.  
  88. (defvar font-lock-no-comments nil
  89.   "Non-nil means Font-Lock shouldn't check for comments or strings.")
  90.  
  91. (make-variable-buffer-local 'font-lock-keywords)
  92. (defvar font-lock-keywords nil
  93.   "*The keywords to highlight.
  94. If this is a list, then elements may be of the forms:
  95.  
  96.   \"string\"              ; A regexp to highlight in the 
  97.                   ;  `font-lock-keyword-face'.
  98.   (\"string\" . N)                ; Highlight subexpression N of the regexp.
  99.   (\"string\" . face-name)      ; Use the named face
  100.   (\"string\" N face-name)        ; Both of the above
  101.   (\"string\" N face-name t)      ; This allows highlighting to override
  102.                   ;  already-highlighted regions.
  103.   (\"string\" N face-name keep)   ; This allows highlighting to occur
  104.                   ; even if some parts of what STRING matches
  105.                   ; are already highlighted--but does not alter
  106.                   ; the existing highlighting of those parts.
  107.  
  108. These regular expressions should not match text which spans lines.
  109. While \\[font-lock-fontify-buffer] handles multi-line patterns correctly,
  110. updating when you edit the buffer does not,
  111. since it considers text one line at a time.
  112.  
  113. Be careful composing regexps for this list; the wrong pattern can dramatically
  114. slow things down!")
  115.  
  116. (defvar font-lock-keywords-case-fold-search nil
  117.   "*Non-nil means the patterns in `font-lock-keywords' are case-insensitive.")
  118.  
  119. (defvar font-lock-verbose t
  120.   "*Non-nil means `font-lock-fontify-buffer' should print status messages.")
  121.  
  122. ;;;###autoload
  123. (defvar font-lock-mode-hook nil
  124.   "Function or functions to run on entry to Font Lock mode.")
  125.  
  126. ;;; These variables record, for each buffer,
  127. ;;; the parse state at a particular position, always the start of a line.
  128. ;;; This is used to make font-lock-fontify-region faster.
  129. (defvar font-lock-cache-position nil)
  130. (defvar font-lock-cache-state nil)
  131. (make-variable-buffer-local 'font-lock-cache-position)
  132. (make-variable-buffer-local 'font-lock-cache-state)
  133.  
  134. (defun font-lock-fontify-region (start end)
  135.   "Put proper face on each string and comment between START and END."
  136.   (save-excursion
  137.     (goto-char start)
  138.     (beginning-of-line)
  139.     (setq end (min end (point-max)))
  140.     (let ((buffer-read-only nil)
  141.       state startline prev prevstate
  142.       (modified (buffer-modified-p)))
  143.       ;; Find the state at the line-beginning before START.
  144.       (setq startline (point))
  145.       (if (eq (point) font-lock-cache-position)
  146.       (setq state font-lock-cache-state)
  147.     ;; Find outermost containing sexp.
  148.     (beginning-of-defun)
  149.     ;; Find the state at STARTLINE.
  150.     (while (< (point) startline)
  151.       (setq state (parse-partial-sexp (point) startline 0)))
  152.     (setq font-lock-cache-state state
  153.           font-lock-cache-position (point)))
  154.       ;; Now find the state precisely at START.
  155.       (setq state (parse-partial-sexp (point) start nil nil state))
  156.       ;; If the region starts inside a string, show the extent of it.
  157.       (if (nth 3 state)
  158.       (let ((beg (point)))
  159.         (while (and (re-search-forward "\\s\"" end 'move)
  160.             (nth 3 (parse-partial-sexp beg (point)
  161.                            nil nil state))))
  162.         (put-text-property beg (point) 'face font-lock-string-face)
  163.         (setq state (parse-partial-sexp beg (point) nil nil state))))
  164.       ;; Likewise for a comment.
  165.       (if (or (nth 4 state) (nth 7 state))
  166.       (let ((beg (point)))
  167.         (while (and (re-search-forward (if comment-end
  168.                            (concat "\\s>\\|"
  169.                                (regexp-quote comment-end))
  170.                          "\\s>")
  171.                        end 'move)
  172.             (nth 3 (parse-partial-sexp beg (point)
  173.                            nil nil state))))
  174.         (put-text-property beg (point) 'face font-lock-comment-face)
  175.         (setq state (parse-partial-sexp beg (point) nil nil state))))
  176.       ;; Find each interesting place between here and END.
  177.       (while (and (< (point) end)
  178.           (setq prev (point) prevstate state)
  179.           (re-search-forward (if comment-start-skip
  180.                      (concat "\\s\"\\|" comment-start-skip)
  181.                        "\\s\"")
  182.                      end t)
  183.           ;; Clear out the fonts of what we skip over.
  184.           (progn (remove-text-properties prev (point) '(face nil)) t)
  185.           ;; Verify the state at that place
  186.           ;; so we don't get fooled by \" or \;.
  187.           (setq state (parse-partial-sexp prev (point)
  188.                           nil nil state)))
  189.     (let ((here (point)))
  190.       (if (or (nth 4 state) (nth 7 state))
  191.           ;; We found a real comment start.
  192.           (let ((beg (match-beginning 0)))
  193.         (goto-char beg)
  194.         (save-restriction
  195.           (narrow-to-region (point-min) end)
  196.           (condition-case nil
  197.               (progn
  198.             (forward-comment 1)
  199.             ;; forward-comment skips all whitespace,
  200.             ;; so go back to the real end of the comment.
  201.             (skip-chars-backward " \t"))
  202.             (error (goto-char end))))
  203.         (put-text-property beg (point) 'face font-lock-comment-face)
  204.         (setq state (parse-partial-sexp here (point) nil nil state)))
  205.         (if (nth 3 state)
  206.         (let ((beg (match-beginning 0)))
  207.           (while (and (re-search-forward "\\s\"" end 'move)
  208.                   (nth 3 (parse-partial-sexp here (point)
  209.                              nil nil state))))
  210.           (put-text-property beg (point) 'face font-lock-string-face)
  211.           (setq state (parse-partial-sexp here (point) nil nil state))))
  212.           ))
  213.     ;; Make sure PREV is non-nil after the loop
  214.     ;; only if it was set on the very last iteration.
  215.     (setq prev nil))
  216.       (and prev
  217.        (remove-text-properties prev end '(face nil)))
  218.       (set-buffer-modified-p modified))))
  219.  
  220. ;; This code used to be used to show a string on reaching the end of it.
  221. ;; It is probably not needed due to later changes to handle strings
  222. ;; starting before the region in question.
  223. ;;        (if (and (null (nth 3 state))
  224. ;;             (eq (char-syntax (preceding-char)) ?\")
  225. ;;             (save-excursion
  226. ;;               (nth 3 (parse-partial-sexp prev (1- (point))
  227. ;;                          nil nil prevstate))))
  228. ;;        ;; We found the end of a string.
  229. ;;        (save-excursion
  230. ;;          (setq foo2 (point))
  231. ;;          (let ((ept (point)))
  232. ;;            (forward-sexp -1)
  233. ;;            ;; Highlight the string when we see the end.
  234. ;;            ;; Doing it at the start leads to trouble:
  235. ;;            ;; either it fails to handle multiline strings
  236. ;;            ;; or it can run away when an unmatched " is inserted.
  237. ;;            (put-text-property (point) ept 'face
  238. ;;                       (if (= (car state) 1)
  239. ;;                       font-lock-doc-string-face
  240. ;;                     font-lock-string-face)))))
  241.  
  242. (defun font-lock-unfontify-region (beg end)
  243.   (let ((modified (buffer-modified-p))
  244.     (buffer-read-only nil))
  245.     (remove-text-properties beg end '(face nil))
  246.     (set-buffer-modified-p modified)))
  247.  
  248. ;; Called when any modification is made to buffer text.
  249. (defun font-lock-after-change-function (beg end old-len)
  250.   (save-excursion
  251.     (save-match-data
  252.       (goto-char beg)
  253.       ;; Discard the cache info if text before it has changed.
  254.       (and font-lock-cache-position
  255.        (> font-lock-cache-position beg)
  256.        (setq font-lock-cache-position nil))
  257.       ;; Rescan till end of line.  yes!
  258.       (goto-char end)
  259.       (end-of-line)
  260.       (setq end (point))
  261.       (goto-char beg)
  262.       (beginning-of-line)
  263.       (setq beg (point))
  264.       ;; First scan for strings and comments.
  265.       ;; Must scan from line start in case of
  266.       ;; inserting space into `intfoo () {}'.
  267.       (if font-lock-no-comments
  268.       (remove-text-properties beg (min (1+ end) (point-max)) '(face nil))
  269.     (font-lock-fontify-region beg (min (1+ end) (point-max))))
  270.       ;; Now scan for keywords.
  271.       (font-lock-hack-keywords beg end))))
  272.  
  273. ;;; Fontifying arbitrary patterns
  274.  
  275. (defsubst font-lock-any-properties-p (start end)
  276.   (or (get-text-property start 'face)
  277.       (let ((next (next-single-property-change start 'face)))
  278.     (and next (< next end)))))
  279.  
  280. (defun font-lock-hack-keywords (start end &optional loudly)
  281.   (goto-char start)
  282.   (let ((case-fold-search font-lock-keywords-case-fold-search)
  283.     (rest font-lock-keywords)
  284.     (count 0)
  285.     (buffer-read-only nil)
  286.     (modified (buffer-modified-p))
  287.     first str match face s e allow-overlap-p)
  288.     (while rest
  289.       (setq first (car rest) rest (cdr rest))
  290.       (goto-char start)
  291.       (cond ((consp first)
  292.          (setq str (car first))
  293.          (cond ((consp (cdr first))
  294.             (setq match (nth 1 first)
  295.               face (eval (nth 2 first))
  296.               allow-overlap-p (nth 3 first)))
  297.            ((symbolp (cdr first))
  298.             (setq match 0 allow-overlap-p nil
  299.               face (eval (cdr first))))
  300.            (t
  301.             (setq match (cdr first)
  302.               allow-overlap-p nil
  303.               face font-lock-keyword-face))))
  304.         (t
  305.          (setq str first match 0 allow-overlap-p nil
  306.            face font-lock-keyword-face)))
  307.       ;(message "regexp: %s" str)
  308.       (while (re-search-forward str end t)
  309.     (setq s (match-beginning match)
  310.           e (match-end match))
  311.     (or s (error "expression did not match subexpression %d" match))
  312.     ;; don't fontify this keyword if we're already in some other context.
  313.     (or (if allow-overlap-p nil (font-lock-any-properties-p s e))
  314.         (if (not (memq allow-overlap-p '(t nil)))
  315.         (save-excursion
  316.           (goto-char s)
  317.           (save-restriction
  318.             (narrow-to-region s e)
  319.             (while (not (eobp))
  320.               (let ((next (next-single-property-change (point) 'face)))
  321.             (if (or (null next) (> next (point-max)))
  322.                 (setq next (point-max)))
  323.             (if (not (get-text-property (point) 'face))
  324.                 (put-text-property (point) next 'face face))
  325.             (goto-char next)))))
  326.           (put-text-property s e 'face face))))
  327.       (if loudly (message "Fontifying %s... (regexps...%s)"
  328.               (buffer-name)
  329.               (make-string (setq count (1+ count)) ?.))))
  330.     (set-buffer-modified-p modified)))
  331.  
  332. ;; The user level functions
  333.  
  334. (defvar font-lock-mode nil) ; for modeline
  335. (or (assq 'font-lock-mode minor-mode-alist)
  336.     (setq minor-mode-alist
  337.       (append minor-mode-alist
  338.           '((font-lock-mode " Font")))))
  339.  
  340. (defvar font-lock-fontified nil) ; whether we have hacked this buffer
  341. (put 'font-lock-fontified 'permanent-local t)
  342.  
  343. ;;;###autoload
  344. (defun font-lock-mode (&optional arg)
  345.   "Toggle Font Lock mode.
  346. With arg, turn Font Lock mode on if and only if arg is positive.
  347.  
  348. When Font Lock mode is enabled, text is fontified as you type it:
  349.  
  350.  - comments are displayed in `font-lock-comment-face';
  351.      (That is a variable whose value should be a face name.)
  352.  - strings are displayed in `font-lock-string-face';
  353.  - documentation strings are displayed in `font-lock-doc-string-face';
  354.  - function and variable names in their defining forms are displayed
  355.    in `font-lock-function-name-face';
  356.  - and certain other expressions are displayed in other faces
  357.    according to the value of the variable `font-lock-keywords'.
  358.  
  359. When you turn Font Lock mode on/off, the buffer is fontified/defontified.
  360. To fontify a buffer without having newly typed text become fontified, you
  361. can use \\[font-lock-fontify-buffer]."
  362.   (interactive "P")
  363.   (let ((on-p (if (null arg)
  364.           (not font-lock-mode)
  365.         (> (prefix-numeric-value arg) 0))))
  366.     (if (equal (buffer-name) " *Compiler Input*") ; hack for bytecomp...
  367.     (setq on-p nil))
  368.     (make-local-variable 'after-change-functions)
  369.     (if on-p
  370.     (or (memq 'font-lock-after-change-function after-change-functions)
  371.         (setq after-change-functions (cons 'font-lock-after-change-function
  372.                            after-change-functions)))
  373.       (setq after-change-functions
  374.         (delq 'font-lock-after-change-function
  375.           (copy-sequence after-change-functions))))
  376.     (set (make-local-variable 'font-lock-mode) on-p)
  377.     (make-local-variable 'font-lock-no-comments)
  378.     (cond (on-p
  379.        (font-lock-set-defaults)
  380.        (make-local-variable 'before-revert-hook)
  381.        (make-local-variable 'after-revert-hook)
  382.        ;; If buffer is reverted, must clean up the state.
  383.        (add-hook 'before-revert-hook 'font-lock-revert-setup)
  384.        (add-hook 'after-revert-hook 'font-lock-revert-cleanup)
  385.        (run-hooks 'font-lock-mode-hook)
  386.        (or font-lock-fontified (font-lock-fontify-buffer)))
  387.       (font-lock-fontified
  388.        (setq font-lock-fontified nil)
  389.        (remove-hook 'before-revert-hook 'font-lock-revert-setup)
  390.        (remove-hook 'after-revert-hook 'font-lock-revert-cleanup)
  391.        (font-lock-unfontify-region (point-min) (point-max))))
  392.     (force-mode-line-update)))
  393.  
  394. ;; If the buffer is about to be reverted, it won't be fontified.
  395. (defun font-lock-revert-setup ()
  396.   (setq font-lock-fontified nil))
  397.  
  398. ;; If the buffer has just been reverted, we might not even be in font-lock
  399. ;; mode anymore, and if we are, the buffer may or may not have already been
  400. ;; refontified.  Refontify here if it looks like we need to.
  401. (defun font-lock-revert-cleanup ()
  402.   (and font-lock-mode
  403.        (not font-lock-fontified)
  404.        (font-lock-mode 1)))
  405.  
  406. (defun font-lock-fontify-buffer ()
  407.   "Fontify the current buffer the way `font-lock-mode' would:
  408.  
  409.  - comments are displayed in `font-lock-comment-face';
  410.  - strings are displayed in `font-lock-string-face';
  411.  - documentation strings are displayed in `font-lock-doc-string-face';
  412.  - function and variable names in their defining forms are displayed
  413.    in `font-lock-function-name-face';
  414.  - and certain other expressions are displayed in other faces
  415.    according to the value of the variable `font-lock-keywords'.
  416.  
  417. This can take a while for large buffers."
  418.   (interactive)
  419.   (let ((was-on font-lock-mode)
  420.     (font-lock-verbose (or font-lock-verbose (interactive-p))))
  421.     (if font-lock-verbose (message "Fontifying %s..." (buffer-name)))
  422.     ;; Turn it on to run hooks and get the right font-lock-keywords.
  423.     (or was-on (font-lock-set-defaults))
  424.     (font-lock-unfontify-region (point-min) (point-max))
  425.     (if (and font-lock-verbose (not font-lock-no-comments))
  426.     (message "Fontifying %s... (syntactically...)" (buffer-name)))
  427.     (save-excursion
  428.       (or font-lock-no-comments
  429.       (font-lock-fontify-region (point-min) (point-max)))
  430.       (if font-lock-verbose (message "Fontifying %s... (regexps...)"
  431.                      (buffer-name)))
  432.       (font-lock-hack-keywords (point-min) (point-max) font-lock-verbose))
  433.     (set (make-local-variable 'font-lock-fontified) t)
  434.     (if font-lock-verbose (message "Fontifying %s... done." (buffer-name)))
  435.     ))
  436.  
  437.  
  438. ;;; Various mode-specific information.
  439.  
  440. (defconst lisp-font-lock-keywords-1
  441.  '(;;
  442.    ;; highlight defining forms.  This doesn't work too nicely for
  443.    ;; (defun (setf foo) ...) but it does work for (defvar foo) which
  444.    ;; is more important.
  445.    ("^(def[-a-z]+\\s +\\([^ \t\n\)]+\\)" 1 font-lock-function-name-face)
  446.    ;;
  447.    ;; highlight CL keywords
  448.    ("\\s :\\(\\(\\sw\\|\\s_\\)+\\)\\>" . 1)
  449.    ;;
  450.    ;; this is highlights things like (def* (setf foo) (bar baz)), but may
  451.    ;; be slower (I haven't really thought about it)
  452. ;   ("^(def[-a-z]+\\s +\\(\\s(\\S)*\\s)\\|\\S(\\S *\\)"
  453. ;    1 font-lock-function-name-face)
  454.    )
  455.  "For consideration as a value of `lisp-font-lock-keywords'.
  456. This does fairly subdued highlighting.")
  457.  
  458. (defconst lisp-font-lock-keywords-2
  459.   (append
  460.    lisp-font-lock-keywords-1
  461.    '(;;
  462.      ;; Highlight control structures
  463.      ("(\\(cond\\|if\\|when\\|unless\\|[ec]?\\(type\\)?case\\)[ \t\n]" . 1)
  464.      ("(\\(while\\|do\\|let\\*?\\|flet\\|labels\\|prog[nv12*]?\\)[ \t\n]" . 1)
  465.      ("(\\(catch\\|\\throw\\|block\\|return\\|return-from\\)[ \t\n]" . 1)
  466.      ("(\\(save-restriction\\|save-window-restriction\\)[ \t\n]" . 1)
  467.      ("(\\(save-excursion\\|unwind-protect\\|condition-case\\)[ \t\n]" . 1)
  468.      ;;
  469.      ;; highlight function names in emacs-lisp docstrings (in the syntax
  470.      ;; that substitute-command-keys understands.)
  471.      ("\\\\\\\\\\[\\([^]\\\n]+\\)]" 1 font-lock-keyword-face t)
  472.      ;;
  473.      ;; highlight words inside `' which tend to be function names
  474.      ("`\\([-a-zA-Z0-9_][-a-zA-Z0-9_][-a-zA-Z0-9_.]+\\)'"
  475.       1 font-lock-keyword-face t)
  476.      ))
  477.  "For consideration as a value of `lisp-font-lock-keywords'.
  478. This does a lot more highlighting.")
  479.  
  480. ;; default to the gaudier variety?
  481. ;(defvar lisp-font-lock-keywords lisp-font-lock-keywords-2
  482. ;  "Additional expressions to highlight in Lisp modes.")
  483. (defvar lisp-font-lock-keywords lisp-font-lock-keywords-1
  484.   "Additional expressions to highlight in Lisp modes.")
  485.  
  486.  
  487. (defconst c-font-lock-keywords-1 nil
  488.  "For consideration as a value of `c-font-lock-keywords'.
  489. This does fairly subdued highlighting.")
  490.  
  491. (defconst c-font-lock-keywords-2 nil
  492.  "For consideration as a value of `c-font-lock-keywords'.
  493. This does a lot more highlighting.")
  494.  
  495. (defconst c++-font-lock-keywords-1 nil
  496.  "For consideration as a value of `c++-font-lock-keywords'.
  497. This does fairly subdued highlighting.")
  498.  
  499. (defconst c++-font-lock-keywords-2 nil
  500.  "For consideration as a value of `c++-font-lock-keywords'.
  501. This does a lot more highlighting.")
  502.  
  503. (let* ((storage "auto\\|extern\\|register\\|static\\|typedef")
  504.        (struct "struct\\|union\\|enum")
  505.        (prefixes "signed\\|unsigned\\|short\\|long")
  506.        (types (concat prefixes "\\|int\\|char\\|float\\|double\\|void"))
  507.        (ctoken "[a-zA-Z0-9_:~*]+")
  508.        (c++-things (concat
  509.             "const\\|class\\|protected:\\|private:\\|public:\\|inline\\|"
  510.             "new\\|delete")))
  511.  (setq c-font-lock-keywords-1
  512.   (list
  513.    ;; fontify preprocessor directives as comments.
  514.    '("^#[ \t]*[a-z]+" . font-lock-comment-face)
  515.    ;;
  516.    ;; fontify names being defined.
  517.    '("^#[ \t]*\\(define\\|undef\\)[ \t]+\\(\\(\\sw\\|\\s_\\)+\\)" 2
  518.      font-lock-function-name-face)
  519.    ;;
  520.    ;; fontify other preprocessor lines.
  521.    '("^#[ \t]*\\(if\\|elif\\|else\\|endif\\)[ \t]+\\([^\n]+\\)"
  522.      2 font-lock-function-name-face keep)
  523.    '("^#[ \t]*\\(ifn?def\\)[ \t]+\\([^ \t\n]+\\)"
  524.      2 font-lock-function-name-face t)
  525.    ;;
  526.    ;; fontify the filename in #include <...>
  527.    ;; don't need to do this for #include "..." because those were
  528.    ;; already fontified as strings by the syntactic pass.
  529.    '("^#[ \t]*include[ \t]+\\(<[^>\"\n]+>\\)" 1 font-lock-string-face)
  530.    ;;
  531.    ;; fontify the names of functions being defined.
  532.    (list (concat
  533.       "^\\(" ctoken "[ \t]+\\)?"    ; type specs; there can be no
  534.       "\\(" ctoken "[ \t]+\\)?"    ; more than 3 tokens, right?
  535.       "\\(" ctoken "[ \t]+\\)?"
  536.       "\\([*&]+[ \t]*\\)?"        ; pointer
  537.       "\\(" ctoken "\\)[ \t]*(")        ; name
  538.     5 'font-lock-function-name-face)
  539.    ;;
  540.    ;;
  541.    ;; Fontify structure names (in structure definition form).
  542.    (list (concat "^\\(" storage "\\)?[ \t]*\\<\\(" struct "\\)"
  543.       "[ \t]+\\(" ctoken "\\)[ \t]*\\(\{\\|$\\)")
  544.     3 'font-lock-function-name-face)
  545.    ;;
  546.    ;; Fontify declarations of simple identifiers (including typedefs).
  547.    ;; (Should this be in c-font-lock-keywords-2 instead?)
  548.    (list (concat "^[ \t]*\\(\\(" storage "\\)[ \t]+\\)?\\(\\(\\(" prefixes
  549.       "\\)\\>[ \t]*\\)*\\(" types "\\)\\)[ \t]+\\(" ctoken
  550.       "\\)[ \t]*[=;]")
  551.     7 'font-lock-function-name-face 'keep)
  552.    ;;
  553.    ;; And likewise for structs
  554.    (list (concat "^[ \t]*\\(\\(" storage "\\)[ \t]+\\)?\\(" struct
  555.       "\\)[ \t]+" ctoken "[ \t]+\\(" ctoken "\\);")
  556.     4 'font-lock-function-name-face 'keep)
  557.    ;;
  558.    ;; Fontify case clauses.  This is fast because its anchored on the left.
  559.    '("case[ \t]+\\(\\(\\sw\\|\\s_\\)+\\):". 1)
  560.    '("\\<\\(default\\):". 1)
  561.    ))
  562.  
  563.  (setq c-font-lock-keywords-2
  564.   (append c-font-lock-keywords-1
  565.    (list
  566.     ;;
  567.     ;; fontify all storage classes and type specifiers
  568.     (cons (concat "\\<\\(" storage "\\)\\>") 'font-lock-type-face)
  569.     (cons (concat "\\<\\(" types "\\)\\>") 'font-lock-type-face)
  570.     (cons (concat "\\<\\(\\(\\(" prefixes "\\)\\>[ \t]*\\)*\\(" types
  571.        "\\)\\)\\>")
  572.      'font-lock-type-face)
  573.     (list (concat "\\<\\(" struct "\\)[ \t]+" ctoken)
  574.      0 'font-lock-type-face 'keep)
  575.     ;;
  576.     ;; fontify all builtin tokens
  577.     (cons (concat
  578.        "[ \t]\\("
  579.        (mapconcat 'identity
  580.         '("for" "while" "do" "return" "goto" "case" "break" "switch"
  581.           "if" "else" "default" "continue" "default")
  582.         "\\|")
  583.        "\\)[ \t\n(){};,]")
  584.      1)
  585.     ;;
  586.     ;; fontify case targets and goto-tags.  This is slow because the
  587.     ;; expression is anchored on the right.
  588.     "\\(\\(\\sw\\|\\s_\\)+\\):"
  589.     ;;
  590.     ;; Fontify variables declared with structures, or typedef names.
  591.     '("}[ \t*]*\\(\\(\\sw\\|\\s_\\)+\\)[ \t]*[,;]"
  592.       1 font-lock-function-name-face)
  593.     ;;
  594.     ;; Fontify global variables without a type.
  595. ;    '("^\\([_a-zA-Z0-9:~*]+\\)[ \t]*[[;={]" 1 font-lock-function-name-face)
  596.     )))
  597.  
  598.  (setq c++-font-lock-keywords-1
  599.        (cons 
  600.     (concat "\\(" c++-things "\\)[ \t\n]")
  601.     c-font-lock-keywords-1))
  602.  (setq c++-font-lock-keywords-2
  603.        (cons 
  604.     (cons (concat "\\<\\(" c++-things "\\)\\>") 'font-lock-type-face)
  605.     c-font-lock-keywords-2))
  606.  )
  607.  
  608. ; default to the gaudier variety?
  609. (defvar c-font-lock-keywords c-font-lock-keywords-1
  610.   "Additional expressions to highlight in C mode.")
  611.  
  612. (defvar c++-font-lock-keywords c++-font-lock-keywords-1
  613.   "Additional expressions to highlight in C++ mode.")
  614.  
  615.  
  616. (defvar perl-font-lock-keywords
  617.   (list
  618.    (cons (concat "[ \n\t{]*\\("
  619.          (mapconcat 'identity
  620.                 '("if" "until" "while" "elsif" "else" "unless" "for"
  621.                   "foreach" "continue" "exit" "die" "last" "goto" "next"
  622.                   "redo" "return" "local" "exec")
  623.                 "\\|")
  624.          "\\)[ \n\t;(]") 1)
  625.    (mapconcat 'identity
  626.           '("#endif" "#else" "#ifdef" "#ifndef" "#if" "#include"
  627.         "#define" "#undef")
  628.           "\\|")
  629.    '("^[ \n\t]*sub[ \t]+\\([^ \t{]+\\)[ \t]*[{]" 1 font-lock-function-name-face)
  630.    '("[ \n\t{]*\\(eval\\)[ \n\t(;]" 1 font-lock-function-name-face)
  631.    '("\\(--- .* ---\\|=== .* ===\\)" . font-lock-doc-string-face)
  632.    )
  633.   "Additional expressions to highlight in Perl mode.")
  634.  
  635. (defvar tex-font-lock-keywords
  636.   (list
  637.    '("\\(\\\\\\w+\\)" 1 font-lock-keyword-face t)
  638.    '("{\\\\em\\([^}]+\\)}" 1 font-lock-comment-face t)
  639.    '("{\\\\bf\\([^}]+\\)}" 1 font-lock-keyword-face t)
  640.    '("^[ \t\n]*\\\\def[\\\\@]\\(\\w+\\)" 1 font-lock-function-name-face t)
  641.    '("\\\\\\(begin\\|end\\){\\([a-zA-Z0-9\\*]+\\)}"
  642.      2 font-lock-function-name-face t)
  643.    '("[^\\\\]\\$\\([^$]*\\)\\$" 1 font-lock-string-face t)
  644. ;   '("\\$\\([^$]*\\)\\$" 1 font-lock-string-face t)
  645.    )
  646.   "Additional expressions to highlight in TeX mode.")
  647.  
  648. (defvar texi-font-lock-keywords
  649.   (list
  650.    "@\\(@\\|[^}\t \n{]+\\)"                    ;commands
  651.    '("^\\(@c\\|@comment\\)[ \t].*$" . font-lock-comment-face)    ;comments
  652.    '("^\\(*.*\\)[\t ]*$" 1 font-lock-function-name-face t)    ;menu items
  653.    '("@\\(emph\\|strong\\|b\\|i\\){\\([^}]+\\)" 2 font-lock-comment-face t)
  654.    '("@\\(file\\|kbd\\|key\\){\\([^}]+\\)" 2 font-lock-string-face t)
  655.    '("@\\(samp\\|code\\|var\\){\\([^}]+\\)" 2 font-lock-function-name-face t)
  656.    '("@\\(xref\\|pxref\\){\\([^}]+\\)" 2 font-lock-keyword-face t)
  657.    '("@end *\\([a-zA-Z0-9]+\\)[ \t]*$" 1 font-lock-function-name-face t)
  658.    '("@item \\(.*\\)$" 1 font-lock-function-name-face t)
  659.    '("\\$\\([^$]*\\)\\$" 1 font-lock-string-face t)
  660.    )
  661.   "Additional expressions to highlight in TeXinfo mode.")
  662.  
  663. (defvar shell-font-lock-keywords
  664.   (list (cons shell-prompt-pattern 'font-lock-keyword-face)
  665.     '("[ \t]\\([+-][^ \t\n]+\\)" 1 font-lock-comment-face)
  666.     '("^[^ \t]+:.*$" . font-lock-string-face)
  667.     '("^\\[[1-9][0-9]*\\]" . font-lock-string-face))
  668.   "Additional expressions to highlight in Shell mode.")
  669.  
  670. (defvar dired-font-lock-keywords
  671.   '(;; Put directory headers in italics.
  672.     ("^  \\(/.+\\)$" 1 font-lock-type-face)
  673.     ;; Put symlinks in bold italics.
  674.     ("\\([^ ]+\\) -> [^ ]+$" . font-lock-function-name-face)
  675.     ;; Put marks in bold.
  676.     ("^\\([^ ]\\).*$" 1 font-lock-keyword-face t)
  677.     ;; Put files that are subdirectories in bold.
  678.     ("^..d.* \\([^ ]+\\)$" 1 font-lock-keyword-face))
  679.   "Additional expressions to highlight in Dired mode.")
  680.  
  681. (defvar rmail-font-lock-keywords
  682.   '(;; Put From field in bold.
  683.     ("^From: \\(.*\\)$" 1 font-lock-keyword-face)
  684.     ;; Put subject in bold italics
  685.     ("^Subject: \\(.*\\)$" 1 font-lock-function-name-face))
  686.   "Additional expressions to highlight in Rmail mode.")
  687.  
  688. (defvar rmail-summary-font-lock-keywords
  689.   '(("^\\s *[0-9]+D.*$" . font-lock-doc-string-face)
  690.     ("^\\s *[0-9]+-.*$" . font-lock-keyword-face))
  691.   "Additional expressions to highlight in Rmail Summary mode.")
  692.  
  693. (defvar compilation-mode-font-lock-keywords
  694.   '(("^\\([^\n:]*:\\([0-9]+:\\)+\\)\\(.*\\)$" 1 font-lock-function-name-face))
  695. ;;;  ("^\\([^\n:]*:\\([0-9]+:\\)+\\)\\(.*\\)$" 0 font-lock-keyword-face keep)
  696.   "Additional expressions to highlight in Compilation mode.")
  697.  
  698. (defun font-lock-set-defaults ()
  699.   "Set `font-lock-keywords' to something appropriate for this mode."
  700.   (if (memq major-mode '(rmail-mode dired-mode compilation-mode shell-mode))
  701.       (setq font-lock-no-comments t))
  702.   (if (not font-lock-keywords)        ; if not already set.
  703.       (setq font-lock-keywords
  704.         (cond ((eq major-mode 'lisp-mode)        lisp-font-lock-keywords)
  705.           ((eq major-mode 'emacs-lisp-mode) lisp-font-lock-keywords)
  706.           ((eq major-mode 'c-mode)        c-font-lock-keywords)
  707.           ((eq major-mode 'c++-c-mode)        c-font-lock-keywords)
  708.           ((eq major-mode 'c++-mode)        c++-font-lock-keywords)
  709.           ((eq major-mode 'perl-mode)         perl-font-lock-keywords)
  710.           ((eq major-mode 'tex-mode)        tex-font-lock-keywords)
  711.           ((eq major-mode 'texinfo-mode)    texi-font-lock-keywords)
  712.           ((eq major-mode 'shell-mode)      shell-font-lock-keywords)
  713.           ((eq major-mode 'dired-mode)      dired-font-lock-keywords)
  714.           ((eq major-mode 'rmail-mode)      rmail-font-lock-keywords)
  715.           ((eq major-mode 'rmail-summary-mode)
  716.            rmail-summary-font-lock-keywords)
  717.           ((eq major-mode 'compilation-mode)
  718.            compilation-mode-font-lock-keywords)
  719.           (t nil)))))
  720.  
  721. (provide 'font-lock)
  722.  
  723. ;;; font-lock.el ends here
  724.