home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Best of German Only 2
/
romside_best_of_german_only_2.iso
/
dos
/
utility
/
dirinfo
/
dircopy.bat
< prev
next >
Wrap
DOS Batch File
|
1993-07-04
|
2KB
|
69 lines
@ECHO OFF
ECHO OFF
REM DIRCOPY.BAT kopiert ganze Verzeichnisbäume, wenn auf
REM dem Ziellaufwerk genügend Speicherplatz vorhanden ist.
IF "%1"=="/?" GOTO hilfe
IF "%1"=="/h" GOTO hilfe
IF "%1"=="/H" GOTO hilfe
DIRINFO %1 %2
IF ERRORLEVEL 4 GOTO fehler_4
IF ERRORLEVEL 3 GOTO fehler_3
IF ERRORLEVEL 2 GOTO fehler_2
IF ERRORLEVEL 1 GOTO fehler_1
IF ERRORLEVEL 0 GOTO ok_0
:fehler_4
REM Verzeichnis vorhanden, Zugriff auf Ziellaufwerk nicht möglich
ECHO Kopiervorgang nicht möglich.
GOTO ende
:fehler_3
REM Verzeichnis vorhanden, zu wenig Speicherplatz auf Ziellaufwerk
ECHO Kopiervorgang nicht möglich.
GOTO ende
:fehler_2
REM Verzeichnis nicht gefunden
ECHO Kopiervorgang nicht möglich.
GOTO ende
:fehler_1
REM Verzeichnis vorhanden, kein Ziellaufwerk eingegeben
ECHO Kopiervorgang nicht möglich.
ECHO Es muß ein Ziellaufwerk eingegeben werden.
GOTO ende
:ok_0
REM Verzeichnis vorhanden, genügend Speicherplatz auf Ziellaufwerk
ECHO Kopiervorgang läuft, bitte warten ...
ECHO.
XCOPY %1 %2 /S /E /V
IF ERRORLEVEL 2 GOTO x_fehler
IF ERRORLEVEL 0 GOTO x_ok
:x_fehler
ECHO.
ECHO Kopiervorgang fehlerhaft, Befehlssyntax überprüfen.
GOTO ende
:x_ok
ECHO.
ECHO Kopiervorgang fehlerfrei beendet.
GOTO ende
:hilfe
ECHO.
ECHO DIRCOPY.BAT Stapelverarbeitungsdatei zum kopieren von ganzen
ECHO Verzeichnisbäume, überprüft das Ziellaufwerk auf genügend
ECHO Speicherplatz. Benutzt das "Freeware" Programm DIRINFO und den
ECHO MS-DOS Befehl XCOPY.
ECHO.
ECHO DIRCOPY Pfadname_1 Laufwerk:[Pfadname_2] [/?]
ECHO.
ECHO Pfadname_1 Laufwerk, Pfad und Verzeichnisname das kopiert werden soll.
ECHO Laufwerk: Ziellaufwerk, auf das der Verzeichnisbaum (der unter
ECHO Pfadname eingegeben wurde) kopiert wird.
ECHO Pfadname_2 Pfad und Verzeichnisname in dem kopiert werden soll.
ECHO Wird dieser nicht eingegeben, so wird in das aktuelle
ECHO Verzeichnis des Ziellaufwerkes kopiert.
ECHO /? Zeigt diese Hilfsbildschirmseite an.
ECHO.
ECHO Die Dateien DIRCOPY.BAT, DI.BAT, DIRINFO.EXE und XCOPY.EXE sollten
ECHO alle im gleichen Verzeichnis sein, am besten in einem Verzeichnis wo
ECHO die Umgebungsvariable PATH darauf zeigt, z.B. im \DOS Verzeichnis.
:ende
ECHO.