home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / gnustuff / tos / updates / update16.zoo / lib / memcpy.s < prev    next >
Encoding:
Text File  |  1992-03-06  |  1.6 KB  |  83 lines
  1. #APP
  2.  
  3. | void *memcpy(void *dest, const void *src, size_t cnt);
  4. |    This function is allowed to play fast and loose...
  5. |
  6. |    Michal Jaegermann ntomczak@vm.ucs.ualberta.ca
  7. |    pared down version of bcopy.s
  8. |
  9. | 
  10.     .text
  11.     .even
  12.     .globl _memcpy
  13. _memcpy:
  14.     movl    sp@(4),a1    | dst -> a1
  15.     movl    sp@(8),a0    | src -> a0
  16.     movl    sp@(12),d0    | cnt -> d0
  17.     jeq    return        | cnt == 0, nothing to do
  18.     cmpl    a0,a1
  19.     jeq    return        |  src dst same
  20.     moveml    d2-d3/a1,sp@-    | save d2,d3,a1(dst)
  21.  
  22.     | check for odd src or dst
  23.     movw    a0,d1
  24.     movw    a1,d2
  25.     eorb    d1,d2
  26.     btst    #0,d2
  27.     jne    oddeven
  28.     btst    #0,d1
  29.     jeq    setup
  30.     movb    a0@+,a1@+    | odd  odd
  31.     subql   #1,d0        | move it
  32.  
  33. setup:
  34.     | if we are here we can unroll a copy loop
  35.     movl    d0,d2
  36.     lsrl    #5,d2        | how many times through a copy loop
  37.     movl    d2,d3        | get upper 16 bits of d2 into 
  38.     swap    d3        | lower word of d3
  39.  
  40.     movw    d0,d1
  41.     andw    #0x1c,d1    | 4 bytes/copy  32 bytes max/iter
  42.     lsrw    #1,d1        | calc index into loop (each movl == 2bytes)
  43.     negw    d1        |  
  44.     addw    #18,d1        | 16 + 2 bytes for jmp ext word - d1 == index
  45.  
  46. eveneven:            | may want long alignment for 020/030 etc
  47.     jmp    pc@(0,d1:w)    |  dive into loop at appro spot
  48. loop1:
  49.     movl    a0@+,a1@+
  50.     movl    a0@+,a1@+
  51.     movl    a0@+,a1@+
  52.     movl    a0@+,a1@+
  53.  
  54.     movl    a0@+,a1@+
  55.     movl    a0@+,a1@+
  56.     movl    a0@+,a1@+
  57.     movl    a0@+,a1@+
  58.  
  59.     dbra    d2,loop1
  60.     dbra    d3,loop1
  61.  
  62.     btst    #1,d0
  63.     jeq    L4
  64.     movw    a0@+,a1@+    | residual word
  65. L4:    btst    #0,d0
  66.     jeq    ret
  67.     movb    a0@,a1@        | residual byte
  68. ret:
  69.     moveml    sp@+,d2-d3/a1
  70.     movl    a1,d0        | return destination
  71. return:    rts
  72.  
  73. oddeven:
  74.     movw    d0,d1
  75.     swap    d1
  76.     jra    upbra
  77. upcopy:                | byte-by-byte forward
  78.     movb    a0@+,a1@+
  79. upbra:
  80.     dbra    d0,upcopy
  81.     dbra    d1,upcopy
  82.     jra    ret
  83.