home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Loadstar 17
/
017.d81
/
matcher
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-08-26
|
2KB
|
71 lines
100 GOSUB1000
200 IFRND(0)<.5THEN320
210 T0=0:T1=0
220 LA$=RIGHT$(HH$,3)
230 FORI=1TOLEN(HH$)-3
240 IFMID$(HH$,I,3)<>LA$THEN270
250 IFMID$(HH$,I+3,1)="0"THENT0=T0+1
260 IFMID$(HH$,I+3,1)="1"THENT1=T1+1
270 NEXTI
300 IFT0>T1THENPC$="0":GOTO400
310 IFT0<T1THENPC$="1":GOTO400
320 IFRND(0)<.5THENPC$="0":GOTO400
330 PC$="1"
400 INPUT"ENTER YOUR NUMBER [0 OR 1] (2=EXIT)]";PH$
402 IFPH$="2"THEN60000
410 IFPH$<>"0"ANDPH$<>"1"THEN400
500 PRINT"COMPUTER PICKED "PC$;" --- YOU PICKED ";PH$:PRINT
510 IFPC$=PH$THENTC=TC+1:PRINT"THE COMPUTER WON THIS ONE."
520 IFPC$<>PH$THENTH=TH+1:PRINT"YOU WON THIS ROUND."
530 PRINT"COMPUTER'S SCORE IS:"TC: PRINT"YOUR SCORE IS :"TH
540 IF(TC=100ORTH=100)THEN2000
550 HH$=HH$+PH$
560 GOTO200
1000 PRINT"[147]WOULD YOU LIKE INSTRUCTIONS?"
1002 POKE198,0:WAIT198,1:GET KEY$
1004 IFKEY$<>"N"ANDKEY$<>"Y"THEN1002
1006 IFKEY$="N"THEN 1900
1008 :
1010 PRINT"[147]"
1020 PRINT" MATCHER IS AN EXPERIMENT IN THE "
1022 PRINT"GROWING FIELD OF COMPUTER INTELLIGENCE."
1024 PRINT" HERE IS HOW THE EXPERIMENT IS DONE:"
1026 PRINT"THE COMPUTER PICKS EITHER A ONE OR A"
1028 PRINT"ZERO. YOU THEN PICK EITHER A ONE OR A"
1030 PRINT"ZERO. IF YOU BOTH PICK THE SAME THING,"
1032 PRINT"THEN THE COMPUTER GETS A POINT. IF YOU"
1034 PRINT"PICKED DIFFERENT NUMBERS, THEN YOU GET"
1036 PRINT"A POINT. THE FIRST TO GET 100 POINTS"
1038 PRINT"IS THE WINNER!":PRINT
1040 PRINTSPC(8)"PRESS A KEY TO CONTINUE[146]";:POKE198,0:WAIT198,1:GET KEY$
1045 PRINT"[147] THE COMPUTER, IN AN ATTEMPT TO WIN"
1046 PRINT"THE GAME, WILL TRY TO GUESS WHAT "
1048 PRINT"NUMBER YOU WILL PICK. THE COMPUTER'S"
1050 PRINT"DECISION IS BASED UPON YOUR PAST"
1052 PRINT"RECORD OF RESPONSE. TRY DIFFERENT"
1054 PRINT"STYLES OF PLAYING AND SEE HOW YOU DO!"
1056 PRINT:PRINT:PRINT:PRINT:PRINT
1058 PRINTSPC(9)"PRESS A KEY TO PLAY[146]";:POKE198,0:WAIT198,1:GET KEY$
1060 :
1900 PRINT"[147]":RETURN
2000 PRINT"[147]"
2010 IFTC=100THENPRINT"THE COMPUTER WON THIS TIME..."
2020 IFTH=100THENPRINT"YOU WON WON THIS TIME..."
2030 TC=0:TH=0
2040 FORDL=1TO500:NEXTDL
2050 :
2060 PRINT"DO YOU WANT TO PLAY AGAIN?"
2070 POKE198,0:WAIT198,1:GET KEY$
2080 IFKEY$<>"Y"ANDKEY$<>"N"THEN2070
2090 IFKEY$="Y"THENPRINT"[147]":CLR:GOTO200
2100 GOTO63000
2200 :
60000 REM QUIT?
60010 PRINT"[147]DO YOU WANT TO QUIT?"
60020 POKE198,0:WAIT198,1:GET KEY$
60030 IFKEY$<>"Y"ANDKEY$<>"N"THEN60020
60040 IFKEY$="N"THEN PRINT"[147]":GOTO200
60050 :
63000 REM RETURN TO LS
63010 LOAD"PAYLOAD CONNECT",8