home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Loadstar 14
/
014.d81
/
plottext
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-08-26
|
4KB
|
151 lines
1 rem plottext
1000 ifl=0thenl=1:load"sysplotter.o",8,1
1010 dr=49167:rem draw
1020 sys49152:rem set graphics
1030 sys49158:rem clear graphics
1040 sys49161,0:rem set background black
1050 sys49164,7:rem set color yellow
1060 x=120:y=3:l$="loadstar staff":gosub1380
1070 x=4:y=20:l$="a. gross profit":gosub1380
1080 x=4:y=40:l$="b. gross loss":gosub1380
1090 x=4:y=60:l$="c. negligible stuff":gosub1380
1100 fory=18to67:sysdr,120,y:next
1110 forx=121to136step2:fory=20to26:sysdr,x,y:next:next
1120 forx=121to188step2:fory=40to46:sysdr,x,y:next:next
1130 forx=121to221step2:fory=60to66::sysdr,x,y:next:next
1140 forxy=0to2*(NULL)step.04:x=160-38*cos(xy):y=160+27*sin(xy):sysdr,x,y:next
1150 fory=160to133step-1:sysdr,160,y:next
1160 xy=0:x=160:fory=160to135step-1:xy=xy+1:ifxy=2thenx=x+1:xy=0
1170 sysdr,x,y:next
1180 xy=0:x=160:fory=160to174step.5:xy=xy+1:ifxy=1thenx=x+1:xy=0
1190 sysdr,x,y:next
1200 x=163:y=136:l$="a":gosub1380
1210 x=135:y=160:l$="c":gosub1380
1220 x=182:y=149:l$="b":gosub1380
1230 x=113:y=191:l$="press space bar":gosub1380
1240 rem
1250 poke198,0
1260 getk$:ifk$=""then1260
1270 sys49155:rem ungraphics
1280 rem print"[147]"
1290 goto63000: rem 'end'
1300 rem ***********************
1310 rem * -p-l-o-t-t-e-x-t- *
1320 rem * set x to the horiz- *
1330 rem * ontal coordinate, y *
1340 rem * to the vertical. *
1350 rem * set l$ to the string*
1360 rem * you want to draw. *
1370 rem * then gosub here. *
1380 rem * variables used: *
1390 rem * x, y, xy, l, l$, k$ *
1400 rem * and dr. *
1410 rem ***********************
1420 iflen(l$)<1thenreturn
1430 forxy=1tolen(l$):k$=mid$(l$,xy,1)
1440 ifk$=" "ork$="[160]"then1460
1450 gosub1490
1460 x=x+6:ifx>312thenx=0:y=y+8
1470 next
1480 return
1490 l=asc(k$)-64
1500 ifl<1thengosub1820:return
1510 onlgosub1550,1560,1570,1580,1590,1600,1610,1620,1630,1640,1650,1660,1670
1520 l=l-13:ifl<1then1540
1530 onlgosub1680,1690,1700,1710,1720,1730,1740,1750,1760,1770,1780,1790,1800
1540 return
1550 gosub2450:gosub2040:gosub2030:return
1560 gosub2020:gosub2070:gosub2080:gosub2220:gosub2090:gosub2100:return
1570 gosub2020:gosub2040:gosub2120:return
1580 gosub2020:gosub2110:gosub2080:gosub2060:return
1590 gosub1600:gosub2120:return
1600 gosub2020:gosub2040:gosub2070:return
1610 gosub1570:gosub2130:gosub2100:return
1620 gosub2450:gosub2070:return
1630 gosub2140:return
1640 gosub2150:gosub2060:gosub2050:return
1650 gosub2020:gosub2160:return
1660 gosub2020:gosub2120:return
1670 gosub2450:gosub2190:return
1680 gosub2450:gosub2200:return
1690 gosub2110:gosub2060:gosub2080:gosub2210:return
1700 gosub1600:gosub2090:return
1710 gosub1690:gosub2230:return
1720 gosub1700:gosub2230:return
1730 gosub2080:gosub2070:gosub2220:gosub2100:gosub2240:return
1740 gosub2140:gosub2040:return
1750 gosub2450:gosub2060:return
1760 gosub2250:return
1770 gosub2450:gosub2270:return
1780 gosub2300:gosub2280:return
1790 gosub2300:gosub2330:return
1800 gosub2040:gosub2120:gosub2320:return
1810 remend of alphabet
1820 ifk$="$"thengosub2410:return
1830 ifk$="%"thengosub2380:return
1840 ifk$=","thengosub2370:return
1850 ifk$="-"thengosub2360:return
1860 ifk$="."thengosub2350:return
1870 l=l+17:ifl<1then1890
1880 onlgosub1900,1910,1920,1940,1950,1960,1970,1980,1990,2010
1890 return
1900 gosub1690:gosub2320:return
1910 gosub2140:sysdr,x+1,y+1:return
1920 gosub2120:gosub2080:gosub2090:gosub2070:sysdr,x,y+1
1930 sysdr,x,y+4:sysdr,x,y+5:return
1940 gosub2080:gosub2070:gosub2060:gosub2090:gosub2100:return
1950 gosub2030:gosub2330:gosub2340:return
1960 gosub2040:gosub2340:gosub2070:gosub2100:gosub2060:return
1970 gosub2210:gosub2080:gosub2070:gosub2060:gosub2100:return
1980 gosub2040:gosub2320:sysdr,x,y+6:return
1990 gosub2080:gosub2070:gosub2060:gosub2090:gosub2100:gosub2240
2000 sysdr,x,y+4:sysdr,x,y+5:return
2010 gosub2110:gosub2080:gosub2070:gosub2060:gosub2240:return
2020 foryy=0to6:sysdr,x,y+yy:next:return
2030 forxx=0to4:sysdr,x+xx,y+3:next:return
2040 forxx=0to4:sysdr,x+xx,y:next:return
2050 foryy=0to6:sysdr,x+4,y+yy:next:return
2060 forxx=1to3:sysdr,x+xx,y+6:next:return
2070 forxx=1to3:sysdr,x+xx,y+3:next:return
2080 forxx=1to3:sysdr,x+xx,y:next:return
2090 sysdr,x+4,y+2:sysdr,x+4,y+1:return
2100 sysdr,x+4,y+5:sysdr,x+4,y+4:return
2110 foryy=1to5:sysdr,x+4,y+yy:next:return
2120 forxx=0to4:sysdr,x+xx,y+6:next:return
2130 forxx=2to4:sysdr,x+xx,y+3:next:return
2140 foryy=0to6:sysdr,x+2,y+yy:next:return
2150 foryy=3to6:sysdr,x,y+yy:next:return
2160 sysdr,x+4,y:sysdr,x+3,y+1:sysdr,x+2,y+2:sysdr,x+1,y+3
2170 gosub2230
2180 return
2190 sysdr,x+1,y+1:sysdr,x+3,y+1:sysdr,x+2,y+2:sysdr,x+2,y+3:return
2200 xx=0:foryy=2to4:xx=xx+1:sysdr,x+xx,y+xx:next
2210 foryy=1to5:sysdr,x,y+yy:next:return
2220 forxx=1to3:sysdr,x+xx,y+6:next:return
2230 sysdr,x+2,y+4:sysdr,x+3,y+5:sysdr,x+4,y+6:return
2240 sysdr,x,y+1:sysdr,x,y+2:return
2250 foryy=0to4:sysdr,x,y+yy:sysdr,x+4,y+yy:next:sysdr,x+1,y+5:sysdr,x+3,y+5
2260 sysdr,x+2,y+6:return
2270 sysdr,x+2,y+3:sysdr,x+2,y+4:sysdr,x+1,y+5:sysdr,x+3,y+5:return
2280 foryy=5to6:sysdr,x,y+yy:sysdr,x+4,y+yy:next:sysdr,x+1,y+4:sysdr,x+3,y+4
2290 return
2300 foryy=0to1:sysdr,x,y+yy:sysdr,x+4,y+yy:next:sysdr,x+1,y+2:sysdr,x+3,y+2
2310 sysdr,x+2,y+3:return
2320 yy=5:forxx=0to4:sysdr,x+xx,y+yy:yy=yy-1:next:return
2330 foryy=4to6:sysdr,x+2,y+yy:next:return
2340 foryy=0to3:sysdr,x,y+yy:next:return
2350 forxx=2to3:sysdr,x+xx,y+5:sysdr,x+xx,y+6:next:return
2360 gosub2070:return
2370 sysdr,x+3,y+4:sysdr,x+3,y+5:sysdr,x+2,y+6:return
2380 gosub2320
2390 forxx=0to1:sysdr,x+xx,y:sysdr,x+xx,y+1:next
2400 forxx=3to4:sysdr,x+xx,y+5:sysdr,x+xx,y+6:next:return
2410 gosub2070:forxx=1to4:sysdr,x+xx,y+1:next
2420 forxx=0to3:sysdr,x+xx,y+5:next
2430 sysdr,x,y+2:sysdr,x,y+5:sysdr,x+4,y+1:sysdr,x+4,y+4
2440 sysdr,x+2,y:sysdr,x+2,y+6:return
2450 gosub2020:gosub2050:return
63000 print"[147][204]oading [211][217][211][208][204][207][212] menu..."
63010 print"[144]load"chr$(34)"plotter boot"chr$(34)",8":print"run"
63020 poke631,13:poke632,13:poke198,2: end