ANews 1/AnewsCD01.iso/ANews

Text File | 1999-08-15 | 31KB | 960 lines

/**********************************************************\
**
**      Interface du CD ANews
**      ©1999 Frédéric RIGNAULT
**
\**********************************************************/
VERSION = "$VER:v0.81 (13.08.1999)"
VERSION = SUBSTR(VERSION,6)

ROOT="ANewsCD:"

DEBUG=0
REDIR=">NIL:"

/* Déclarations Globale */

FALSE=0
TRUE=1
NOSELECT=4.2949673E+9
TXTCOL="\0339" /* \0339 */
TXTCOL2="\0339"
LASTCAT=0
LASTREP=0
LASTLIST=0
typl.0=11       ;icone.0=ROOT||"Icônes/Auto"     ;aide.0="Boutton Action par défaut:\nNE DOIT PAS ETRE LA!"
typl.1="+run"   ;icone.1=ROOT||"Icônes/Run"      ;aide.1="Lancer le programme."
typl.2="+manuel";icone.2=ROOT||"Icônes/Run"      ;aide.2="Execute une action."
typl.3="+voir"  ;icone.3=ROOT||"Icônes/View"     ;aide.3="Visualiser l'image."
typl.4="+son"   ;icone.4=ROOT||"Icônes/Musique"  ;aide.4="Ecouter le son."
typl.5="+ecoute";icone.5=ROOT||"Icônes/Musique"  ;aide.5="Ecouter le son."
typl.6="+jouer" ;icone.6=ROOT||"Icônes/Musique"  ;aide.6="Jouer le module."
typl.7="+html"  ;icone.7=ROOT||"Icônes/HTML"     ;aide.7="Afficher la page Html."
typl.8="+anim"  ;icone.8=ROOT||"Icônes/Video"    ;aide.8="Voir l'animation"
typl.9="+copie" ;icone.9=ROOT||"Icônes/Disk"     ;aide.9="Copier le(s) fichier."
typl.10="+extract";icone.10=ROOT||"Icônes/Archive" ;aide.10="Extraire l'archive et lance l'installation si disponible."
typl.11="+install";icone.11=ROOT||"Icônes/Disk"    ;aide.11="Lancement de l'installation."
PrefsLoad=FALSE
IconShow=1
IconGuide=1

/* Open libs needed */
options results
IF EXISTS("libs:rexxsupport.library") THEN DO
 IF ~SHOW("L","rexxsupport.library") THEN
  IF ~ADDLIB("rexxsupport.library",0,-30,0) THEN EXIT
 END
ELSE EXIT
IF EXISTS("libs:rexxreqtools.library") THEN DO
 IF ~SHOW("L","rexxreqtools.library") THEN
  IF ~ADDLIB("rexxreqtools.library",0,-30) THEN EXIT
 END
ELSE EXIT
if DEBUG=1 then Say "Libs:OK"

if (show('p','ANEWS')) & (show('p','ASERV')) then do
  address ANEWS SHOW
  exit
end

/* Open message Port Of Script */
address rexx
OPENPORT("ASERV")

/* Open Muirexx */

call StartMUI
call LoadPrefs
call OpenGUI
call InitAll
call GestEvent
address ANEWS QUIT
exit

GestEvent:
Do forever
 address ANEWS
 window ID ANEWS ATTRS MUIA_Window_Sleep FALSE
 address REXX
 gotit=0
 do until gotit
  call waitpkt(ASERV);packet=getpkt(ASERV)
  gotit=(packet ~= null())
 end
 address ANEWS
 window ID ANEWS ATTRS MUIA_Window_Sleep TRUE
 address REXX;class=getarg(packet);reply(packet,0)
 if debug=1 then say class","LASTCAT","LASTREP","LASTLIST
 address ANEWS
 select
   when class='ABOUT' then do
     request ID ANEWS Title '"A propos du Navigateur ANews"' GADGETS "D'accord" STRING replacepat("Navigateur de CD ANews\nVersion %s\n©1999 Frédéric Rignault", "%s", VERSION )
   end
   when class='QUIT' then break
   when class='PREFS' then call OpenPrefs
   when class='CANCELPREFS' then do
     window ID APREF ATTRS MUIA_Window_Open FALSE
   end
   when class='USEPREFS' then do
     call readprefs
     window ID APREF ATTRS MUIA_Window_Open FALSE
     call saveprefs("USE")
   end
   when class='SAVEPREFS' then do
     call readprefs
     window ID APREF ATTRS MUIA_Window_Open FALSE
     call saveprefs("SAVE")
   end
   when class='CATUPD' then call UpdateReps
   when class='REPUPD' then call UpdateList
   when class='LSTUPD' then call UpdateInfos
   when class='AUTO' then call StartAuto
   when class='GUIDE' then call ShowGuide
   when class='HELP' then call ShowHelp
   otherwise do
     if debug=1 then say class||"?"
   end
 end
end
return

InitAll:
If open('f1',ROOT||"Arbre.ani",'r') then Do
 i=0
 j=0
 Arbre.0=0
 do forever
   a=readln('f1')
   if a="END" then break
   if left(a,1)="+" then do
     j=j+1
     parse var a "+" b "," c
     Arbre.i.0=j
     Arbre.i.j.Titre=b
     Arbre.i.j.Rep=c
   end
   else do
     i=i+1
     Arbre.0=i
     Arbre.i.Titre=a
     j=0
     Arbre.i.0=j
   end
 end
 a=close('f1')
 End

address ANEWS

list ID CATS ATTRS MUIA_List_Quiet TRUE
do i=1 to Arbre.0
  list ID CATS INSERT POS MUIA_List_Insert_Bottom STRING TXTCOL||Arbre.i.Titre
end
list ID CATS ATTRS MUIA_List_Quiet FALSE MUIA_List_Active 0
return

UpdateReps:
list ID CATS ATTRS MUIA_List_Active
i=result+1
if LASTCAT=i then return
LASTCAT=i
list ID REPS STRING
list ID REPS ATTRS MUIA_List_Quiet TRUE
DO j=1 to Arbre.i.0
  LIST ID REPS INSERT POS MUIA_List_Insert_Bottom STRING TXTCOL||Arbre.i.j.Titre
end
list ID REPS ATTRS MUIA_List_Quiet FALSE MUIA_List_Active 0
LASTREP=0
return

UpdateList:
parse arg nouv

if nouv="" then nouv=0

list ID CATS ATTRS MUIA_List_Active
i=result+1
list ID REPS ATTRS MUIA_List_Active
j=result+1

if (LASTREP=j) & (nouv=0) then return
LASTREP=j

list ID LIST STRING
list ID LIST ATTRS MUIA_List_Quiet TRUE

repertoire=ROOT||Arbre.i.j.Rep

i=0
if exists(repertoire||'contenu.ani') then do
  If open('f1',repertoire||"contenu.ani",'r') then Do
    do forever
      a=readln('f1')
      if eof('f1') then break
      parse var a b '=' c
      select
        when b="nom" then do
          i=i+1
          contenu.0=i
          contenu.i.nom=c
          contenu.i.finfo=""
          contenu.i.rep=""
          contenu.i.guide=""
          contenu.i.action.0=0
          contenu.i.infos.0=0
          list ID LIST INSERT POS MUIA_List_Insert_Bottom STRING TXTCOL||c
        end
        when b="+rep" then contenu.i.rep=c
        when b="+guide" then contenu.i.guide=c
        when b="+infos" then do
          k=contenu.i.infos.0+1
          contenu.i.infos.0=k
          contenu.i.infos.k=a
        end
        when b="+finfo" then contenu.i.finfo=c
        otherwise do
          j=contenu.i.action.0+1
          contenu.i.action.0=j
          contenu.i.action.j=a
        end
      end
    end
  a=close('f1')
  end
end
list ID LIST ATTRS MUIA_List_Quiet FALSE
if i>0 then do
  if nouv=0 then nouv=1
  if nouv>=0 then list ID LIST ATTRS MUIA_List_Active nouv-1
end
else do
  call UpdGuide(0)
  call UpdIcon(0)
end
LASTLIST=0
return

UpdateInfos:
list ID CATS ATTRS MUIA_List_Active
i=result+1
list ID REPS ATTRS MUIA_List_Active
j=result+1
list ID LIST ATTRS MUIA_List_Active
k=result+1
if LASTLIST=k then return
LASTLIST=k
repertoire=ROOT||Arbre.i.j.Rep
repbase=repertoire
etat=0
listeaction.0=0
listeinfos.0=0
if k=NOSELECT then return
b="nom="||contenu.k.nom
if contenu.k.infos.0>0 then do
 if open('f2',"T:infos.txt",'w') then do
   do l=1 to contenu.k.infos.0
     parse var contenu.k.infos.l a '=' b
     x=listeinfos.0+1
     listeinfos.0=x
     listeinfos.x=b
     call writeln('f2',b)
   end
   call close('f2')
   VIEW ID INFOS FILE "T:infos.txt"
 end
end
else do
   fichier=repbase||contenu.k.rep||contenu.k.finfo
   if exists(fichier) then do
     VIEW ID INFOS FILE fichier
   end
end
repbase=repertoire
if contenu.k.action.0>0 then do
  parse var contenu.k.action.1 a '=' b
  m=0
  do l=1 to typl.0
    if typl.l=a then do
      m=l
      break
    end
  end
  if debug=1 then say "Image:"||m
  call UpdIcon(m)
  do l=1 to contenu.k.action.0
    parse var contenu.k.action.l a '=' b
    x=listeaction.0+1
    listeaction.0=x
    listeaction.x=b
  end
end
else do
  call UpdIcon(0)
end
if (Contenu.k.guide~=lastfile) & (Contenu.k.guide~="") then do
  a=upper(Contenu.k.guide)
  select
   when right(a,6)=".GUIDE" then call UpdGuide(1)
   when (right(a,5)=".HTML") | (right(a,4)=".HTM") then call UpdGuide(2)
   otherwise call UpdGuide(3)
  end
end
else do
  call UpdGuide(0)
end
return

UpdIcon:
if IconShow~=0 then do
  image ID 'AUT'||IconShow ATTRS MUIA_ShowMe FALSE
  IconShow=0
end
if arg(1)~=IconShow then do
  IconShow=arg(1)
  image ID 'AUT'||IconShow ATTRS MUIA_ShowMe TRUE
end
return

UpdGuide:
if IconGuide~=0 then do
  image ID 'GUID'||IconGuide ATTRS MUIA_ShowMe FALSE
  IconGuide=0
end
if arg(1)~=IconGuide then do
  IconGuide=arg(1)
  image ID 'GUID'||IconGuide ATTRS MUIA_ShowMe TRUE
end
return

View:
if exists(arg(1)) then do
 if open('f1',arg(1),'r') then do
   if open('f2',"T:info.txt","w") then do
     etat=FALSE
     do forever
       a=readln('f1')
       if eof('f1') then break
       if etat=FALSE then do
         if a=";infos" then etat=TRUE
       end
       else do
         call writeln('f2',a)
       end
     end
     call close('f2')
   end
   call close('f1')
   view ID INFOS FILE "T:info.txt"
 end
end
else do
  etat=FALSE
  view ID INFOS STRING ""
end
return(etat)

ShowGuide:
list ID LIST ATTRS MUIA_List_Active
k=result+1
if k=NOSELECT then return
fichier=repbase||contenu.k.rep||Contenu.k.guide
if exists(fichier) then do
 select
  when (upper(right(fichier,4))=".HTM") | (upper(right(fichier,5))=".HTML") then do
    address command "run "||REDIR||" rx "||ROOT||"script/html.rexx "||prefs.html.type||" "||prefs.html.exe||' "'fichier'"'
  end
  when upper(right(fichier,6))=".GUIDE" then do
    address COMMAND 'run '||REDIR||' '||prefs.guide||' "'||fichier||'"'
  end
  otherwise do
    address COMMAND 'run '||REDIR||' '||prefs.texte||' "'||fichier||'"'
  end
 end
end
return

ShowHelp:
address command "run "||REDIR||" rx "||ROOT||"script/html.rexx "||prefs.html.type||" "||prefs.html.exe||' "'||ROOT||'Aide/aide.html"'
return

StartAuto:
repcopy="#"
list ID LIST ATTRS MUIA_List_Active
k=result+1
if k=NOSELECT then return
if contenu.k.action.0>0 then do
 if left(contenu.k.action.1,8)="+manuel=" then do
   if open('f1',"T:script.run","w") then do
     do l=1 to contenu.k.action.0
       parse var contenu.k.action.l b '=' a
       call writeln('f2',a)
     end
     call close('f1')
     address command "run "||REDIR||" execute <>NIL: T:script.run"
   end
 end
 else do
   do l=1 to contenu.k.action.0
    parse var contenu.k.action.l b '=' a
    fichier=repbase||contenu.k.rep||a
    if debug=1 then say fichier
    select
      when b="+run" then do
        if exists(fichier) then do
          address command "cd "||repbase||contenu.k.rep||'0a'x||"run "||REDIR||' "'||a||'"'
        end
      end
      when b="+voir" then do
        if exists(fichier) then do
          address command prefs.visu||" "||REDIR||' "'||fichier||'"'
        end
      end
      when b="+son" then do
        if exists(fichier) then do
          address command prefs.son||" "||REDIR||' "'||fichier||'"'
        end
      end
      when b="+ecoute" then do
        if exists(fichier) then do
          address command "run "||REDIR||" rx "||ROOT||"script/ecoute.rexx "||prefs.mus.type||" "||prefs.mus.exe||' "'||fichier||'"'
        end
      end
      when b="+jouer" then do
        if exists(fichier) then do
          address command "run "||REDIR||" rx "||ROOT||"script/jouer.rexx "||prefs.mod.type||" "||prefs.mod.exe||' "'||fichier||'"'
        end
      end
      when b="+html" then do
        if exists(fichier) then do
          address command "run "||REDIR||" rx "||ROOT||"script/html.rexx "||prefs.html.type||" "||prefs.html.exe||' "'||fichier||'"'
        end
      end
      when b="+anim" then do
        if exists(fichier) then do
          f5=right(upper(fichier),5)
          f4=right(upper(fichier),4)
          f3=right(upper(fichier),3)
          if f5=".ANIM" then do
            address command "run "||REDIR||" "||prefs.anim.iff||' "'||fichier||'"'
          end
          if f4=".AVI" then do
            address command "run "||REDIR||" "||prefs.anim.avi||' "'||fichier||'"'
          end
          if (f4=".FLI") | (f4=".FLC") then do
            address command "run "||REDIR||" "||prefs.anim.fli||' "'||fichier||'"'
          end
          if (f5=".MPEG") | (f4=".MPG") then do
            address command "run "||REDIR||" "||prefs.anim.mpeg||' "'||fichier||'"'
          end
          if (f3=".QT") | (f4=".MOV") then do
            address command "run "||REDIR||" "||prefs.anim.qt||' "'||fichier||'"'
          end
        end
      end
      when b="+copie" then do
        if repcopy="#" then do
          aslrequest ID ANEWS ATTRS ASLFR_DrawersOnly TRUE ASLFR_InitialDrawer '"'prefs.repdef'"' TITLE """Endroit où copier les fichiers..."""
          if debug=1 then say "Request="result
          repcopy=result
          if repcopy~="0" then do
            if ~exists(repcopy) then do
              repcopy=""
              request ID ANEWS TITLE """Erreur""" GADGETS "OK" STRING "Le répertoire que vous avez selectionné\nn'est pas valide.\nRecommancez l'opération en donnant un\nchemain valide."
            end
            if ~exists(repcopy||contenu.k.rep) then do
               address command "makedir "||repcopy||left(contenu.k.rep,length(contenu.k.rep)-1)
            end
          end
        end
        if repcopy~="" then do
          address command "copy NOREQ CLONE "||fichier||" TO "||repcopy||contenu.k.rep
        end
      end
      when b="+extract" then do
        if repcopy="#" then do
          aslrequest ID ANEWS ATTRS ASLFR_DrawersOnly TRUE ASLFR_InitialDrawer '"'prefs.repdef'"' TITLE """Endroit où extraire l'archive..."""
          repcopy=result
          if ~exists(repcopy) then do
            repcopy=""
            request ID ANEWS TITLE """Erreur""" GADGETS "OK" STRING "Le répertoire que vous avez selectionné\nn'est pas valide.\nRecommancez l'opération en donnant un\nchemain valide."
          end
        end
        if (repcopy~="#") & (repcopy~="")  then do
          select
            when right(upper(fichier),4)=".LHA" then do
              address command "lha x -a -e -r -q "||fichier||" "||repcopy
            end
            when right(upper(fichier),4)=".LZX" then do
              address command "lzx x -a -e -r "||fichier||" "||repcopy
            end
            otherwise do
              if exists(repcopy||a) then do
                say pathstr(repcopy||a)
                say exestr(repcopy||a)
                address command "cd "||pathstr(repcopy||a)||'0a'x||"installer "||exestr(repcopy||a)
              end
            end
          end
        end
      end
      when b="+install" then do
        if exists(fichier) then do
          address command "cd "||pathstr(fichier)||'0a'x||"installer "||exestr(fichier)
        end
      end
      otherwise do
        if debug=1 then say "Commande inconnue:"||b||'='||a
      end
    end
   end
 end
end
return

StartMUI:
if (~(exists("ENVARC:mui/ANEWS.prefs"))) & (~(exists("ENV:mui/ANEWS.prefs"))) then do
  if debug=1 then say "Copy Prefs"
  address command "copy "||ROOT||"Configs/1/ANEWS.prefs env:mui/ANEWS.prefs"
end
address command "path "||REDIR||" ADD "||ROOT||"c"
address command "assign "||REDIR||" ADD Libs: "||ROOT||"Libs"
address command "assign "||REDIR||" ADD Fonts: "||ROOT||"Fonts"
address command "assign "||REDIR||" ADD S: "||ROOT||"S"
address command "assign "||REDIR||" ADD Locale: "||ROOT||"Locale"
address command "assign "||REDIR||" ADD Help: "||ROOT||"Help"
address command "assign "||REDIR||" ADD L: "||ROOT||"L"
address command "assign "||REDIR||" ADD Devs: "||ROOT||"Devs"
address command "assign "||REDIR||" ADD vgp_data: "||ROOT||"Jeux/Demos/AF1"
if ~show("P","deficons") then do
  address command "RUN "||REDIR||" "||ROOT||"c/NewIcons"
end
if ~(exists("MUI:")) then do
  address command "assign "||REDIR||" MUI: "||ROOT||"MUI"
  address command "assign "||REDIR||" ADD Libs: "||ROOT||"MUI/Libs"
  address command "assign "||REDIR||" ADD Locale: "||ROOT||"MUI/Locale"
end
address rexx
muirexx= ROOT||'C/MUIRexx'
if ~(Exists(muirexx)) then do; CALL rtezrequest "Ce n'est pas un CD ANews...",, "Navigateur";exit 20;end
foo=open('OUT','T:mmp.runscript','W');foo=writeln('OUT',"FailAt >NIL: 21");foo=writeln('OUT',"Stack >NIL: 40000");foo=writeln('OUT',"run "||REDIR||" "||muirexx||" PORT ANEWS");foo=writeln('OUT',"waitforport >NIL: ANEWS");foo=close('OUT')
address Command 'execute '||REDIR||' T:mmp.runscript'
delete('T:mmp.runscript')
address command 'run '||REDIR||' rx '||ROOT||'script/autoclose.rexx'
return

LoadPrefs:
prefs.texte="Multiview"
prefs.guide="Multiview"
prefs.visu=ROOT||"c/Visage"
prefs.son=ROOT||"c/Play16"
prefs.mus.type="SongPlayer"
prefs.mus.exe=ROOT||"c/Songplayer/SongPlayer"
prefs.mod.type="Hippoplayer"
prefs.mod.exe=ROOT||"c/Hippoplayer/HiP"
prefs.html.type="IBrowse"
prefs.html.exe=ROOT||"Internet/Navigateur/IBrowseDemo/IBrowse"
prefs.repdef="Ram:"
prefs.anim.iff=ROOT||"c/BigAnim"
prefs.anim.fli=ROOT||"c/flick"
prefs.anim.avi=ROOT||"c/MooVId-Demo"
prefs.anim.qt=ROOT||"c/MooVId-Demo"
prefs.anim.mpeg=ROOT||"c/mp"

if open('f1',"env:ANewsCDPrefs",'r') then do
  if debug=1 then say "Lecture Prefs"
  do forever
    a=readln('f1')
    if eof('f1') then break
    parse var a b "=" c
    select
      when b="texte" then do
        parse var c d " " e
        if exists(d) then prefs.texte=c
      end
      when b="guide" then do
        parse var c d " " e
        if exists(d) then prefs.guide=c
      end
      when b="visu" then do
        parse var c d " " e
        if exists(d) then prefs.visu=c
      end
      when b="son" then do
        parse var c d " " e
        if exists(d) then prefs.son=c
      end
      when b="music" then do
        parse var c d "," e
        if exists(e) then do
          prefs.mus.type=d
          prefs.mus.exe=e
        end
      end
      when b="module" then do
        parse var c d "," e
        if exists(e) then do
          prefs.mod.type=d
          prefs.mod.exe=e
        end
      end
      when b="html" then do
        parse var c d "," e
        if exists(e) then do
          prefs.html.type=d
          prefs.html.exe=e
        end
      end
      when b="repdef" then do
        parse var c d " " e
        if exists(d) then prefs.repdef=c
      end
      when b="animiff" then do
        parse var c d " " e
        if exists(d) then prefs.anim.iff=c
      end
      when b="animavi" then do
        parse var c d " " e
        if exists(d) then prefs.anim.avi=c
      end
      when b="animmpeg" then do
        parse var c d " " e
        if exists(d) then prefs.anim.mpeg=c
      end
      when b="animfli" then do
        parse var c d " " e
        if exists(d) then prefs.anim.fli=c
      end
      when b="animqt" then do
        parse var c d " " e
        if exists(d) then prefs.anim.qt=c
      end
      otherwise do
       if debug=1 then say a
      end
    end
  end
  call close('f1')
end
return

SavePrefs:
call SavePrefs2("env:ANewsCDPrefs")
if arg(1)="SAVE" then call SavePrefs2("envarc:ANewsCDPrefs")
return
SavePrefs2:
if open('f1',arg(1),'w') then do
  if debug=1 then say "Ecriture prefs:"||arg(1)
  call writeln('f1',"texte="||prefs.texte)
  call writeln('f1',"guide="||prefs.guide)
  call writeln('f1',"visu="||prefs.visu)
  call writeln('f1',"son="||prefs.son)
  call writeln('f1',"music="||prefs.mus.type||','||prefs.mus.exe)
  call writeln('f1',"module="||prefs.mod.type||','||prefs.mod.exe)
  call writeln('f1',"html="||prefs.html.type||','||prefs.html.exe)
  call writeln('f1',"repdef="||prefs.repdef)
  call writeln('f1',"animiff="||prefs.anim.iff)
  call writeln('f1',"animfli="||prefs.anim.fli)
  call writeln('f1',"animavi="||prefs.anim.avi)
  call writeln('f1',"animmpeg="||prefs.anim.mpeg)
  call writeln('f1',"animqt="||prefs.anim.qt)
  call close('f1')
end
return

OpenGUI:
address ANEWS
ASLFR_DrawersOnly = 0x8008002F
ASLFR_InitialDrawer = 0x80080009
ASLFR_RejectIcons = 0x8008003C
MUIA_Application_Active=0x804260ab
MUIA_Application_Iconified = 0x8042a07f
MUIA_ApplicationObject=0x8042d3ee
MUIA_CycleChain = 0x80421ce7
MUIA_ControlChar = 0x8042120b
MUIA_Cycle_Active=0x80421788
MUIA_Disabled=0x80423661
MUIA_Font=0x8042be50
MUIA_Gauge_Current=0x8042f0dd
MUIA_Gauge_Divide=0x8042d8df
MUIA_Gauge_Horiz=0x804232dd
MUIA_Gauge_InfoText=0x8042bf15
MUIA_Gauge_Max=0x8042bcdb
MUIA_Group_ActivePage=0x80424199
MUIA_Group_Columns=0x8042f416
MUIA_Group_PageMode=0x80421a5f
MUIA_Group_SameSize=0x80420860
MUIA_HorizWeight = 0x80426db9
MUIA_InnerRight=0x804297ff
MUIA_InnerRight=0x804297ff
MUIA_List_Active=0x8042391c
MUIA_List_Format=0x80423c0a
MUIA_List_MinLineHeight=0x8042d1c3
MUIA_List_Quiet = 0x8042d8c7
MUIA_Listview_DoubleClick=0x80424635
MUIA_Dropable = 0x8042fbce
MUIA_List_DragSortable = 0x80426099
MUIA_List_ShowDropMarks = 0x8042c6f3
MUIA_Listview_DragType = 0x80425cd3
MUIA_Listview_MultiSelect = 0x80427e08
MUIA_Menu_Enabled = 0x8042ed48
MUIA_Menuitem_Checked = 0x8042562a
MUIA_Menuitem_Checkit = 0x80425ace
MUIA_Menuitem_Enabled = 0x8042ae0f
MUIA_Menuitem_Exclude = 0x80420bc6
MUIA_Menuitem_Shortcut = 0x80422030
MUIA_Menuitem_Title=0x804218be
MUIA_Menuitem_Toggle = 0x80424d5c
MUIA_Numeric_Format=0x804263e9
MUIA_Numeric_Value = 0x8042ae3a
MUIA_Pressed=0x80423535
MUIA_Selected=0x8042654b
MUIA_ShowMe=0x80429ba8
MUIA_Slider_Horiz=0x8042fad1
MUIA_Slider_Level=0x8042ae3a
MUIA_Slider_Max=0x8042d78a
MUIA_Slider_Min=0x8042e404
MUIA_Slider_Quiet=0x80420b26
MUIA_String_Accept=0x8042e3e1
MUIA_String_Contents=0x80428ffd
MUIA_String_DisplayPos=0x8042ccbf
MUIA_String_EditHook=0x80424c33
MUIA_String_Format=0x80427484
MUIA_String_Integer=0x80426e8a
MUIA_String_MaxLen=0x80424984
MUIA_String_Reject=0x8042179c
MUIA_Width=0x8042b59c
MUIA_Width=0x8042b59c
MUIA_Window_Activate=0x80428d2f
MUIA_Window_DefaultObject = 0x804294d7
MUIA_Window_Open=0x80428aa0
MUIA_Window_SizeRight = 0x80424780
MUIA_Window_Sleep=0x8042e7db
MUIA_Window_InputEvent = 0x804247d8
MUIA_Window_ID = 0x804201bd
MUIM_Application_AboutMUI = 0x8042d21d
MUIM_Application_OpenConfigWindow = 0x804299ba
MUIV_EveryTime = 0x49893131
MUIV_Font_Tiny=-3
MUIV_Font_Big = -6
MUIV_List_Insert_Bottom=-3
MUIV_Listview_DragType_Immediate = 1
MUIV_String_Format_Center=1
MUIA_Text_HiChar = 0x804218ff
MUIA_InputMode = 0x8042fb04
MUIV_InputMode_RelVerify = 1
MUIA_Text_PreParse = 0x8042566d
MUIA_Listview_SelectChange = 0x8042178f

window ID ANEWS COMMAND """QUIT""" PORT ASERV TITLE """Navigateur du CD Anews"""
  menu LABEL "Projet"
    item COMMAND '"method 'MUIM_Application_AboutMUI' 0"' PORT ANEWS LABEL "A propos de MUI..."
    item COMMAND '"'ABOUT'"' PORT ASERV label "A propos du Navigateur de CD ANews"
    item ATTRS MUIA_Menuitem_Title '-1'
    menu LABEL "Préférences..."
     item COMMAND '"PREFS"' PORT ASERV ATTRS MUIA_Menuitem_Shortcut 'P' LABEL "Navigateur..."
     item COMMAND '"method 'MUIM_Application_OpenConfigWindow'"' PORT ANEWS LABEL "MUI..."
    endmenu
    item ATTRS MUIA_Menuitem_Title '-1'
    item COMMAND '"QUIT"' PORT ASERV ATTRS MUIA_Menuitem_Shortcut 'Q' LABEL "Quitter"
  endmenu
  group HORIZ
    group
      group HORIZ
        group ATTRS MUIA_HorizWeight 80  LABELS 'Catégories'
          list ID CATS HELP """Liste des thèmes abordés\ndans le CD ANews.""" ATTRS MUIA_Font MUIV_Font_Big
        endgroup
        group LABELS 'Répertoires'
          list ID REPS HELP """Liste des répertoires\nde la cétogie choisie.""" ATTRS MUIA_Font MUIV_Font_Big
        endgroup
        group
          image COMMAND 'HELP' PORT ASERV HELP """Boutton d'Aide:\nAffiche le guide d'aide pour\nl'utilisation du CD Anews.""" ICON ROOT||"Icônes/help"
          image ID GUID1 COMMAND 'GUIDE' PORT ASERV HELP """Boutton Documentation:\nAffiche la documentation\ndu contenu choisis.""" ICON ROOT||"Icônes/guide"
          image ID GUID2 COMMAND 'GUIDE' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP """Boutton Documentation:\nAffiche la documentation\ndu contenu choisis.""" ICON ROOT||"Icônes/html"
          image ID GUID3 COMMAND 'GUIDE' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP """Boutton Documentation:\nAffiche la documentation\ndu contenu choisis.""" ICON ROOT||"Icônes/ReadMe"
          space
          image ID AUT1 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe TRUE HELP '"'Aide.1'"' ICON icone.1
          image ID AUT2 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.2'"' ICON icone.2
          image ID AUT3 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.3'"' ICON icone.3
          image ID AUT4 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.4'"' ICON icone.4
          image ID AUT5 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.5'"' ICON icone.5
          image ID AUT6 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.6'"' ICON icone.6
          image ID AUT7 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.7'"' ICON icone.7
          image ID AUT8 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.8'"' ICON icone.8
          image ID AUT9 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.9'"' ICON icone.9
          image ID AUT10 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.10'"' ICON icone.10
          image ID AUT11 COMMAND 'AUTO' PORT ASERV ATTRS MUIA_ShowMe FALSE HELP '"'Aide.11'"' ICON icone.11
        endgroup
      endgroup
      group LABELS 'Informations'
        view ID INFOS HELP """Affiche les informations courtes\nrelatives au contenu selectionné.\nLe Boutton Guide permet d'accéder\nà une documentation plus complète."""
      endgroup
    endgroup
    group ATTRS MUIA_HorizWeight 55 LABELS 'Contenu du répertoire'
     list ID LIST COMMAND 'AUTO' PORT ASERV HELP """Contenu du répertoire déjà configuré""" ATTRS MUIA_Font MUIV_Font_Big
    endgroup
  endgroup
endwindow
callhook ID CATS COMMAND "CATUPD" PORT 'ASERV' ATTRS MUIA_List_Active MUIV_EveryTime
callhook ID REPS COMMAND "REPUPD" PORT 'ASERV' ATTRS MUIA_List_Active MUIV_EveryTime
callhook ID LIST COMMAND "LSTUPD" PORT 'ASERV' ATTRS MUIA_List_Active MUIV_EveryTime
return

OpenPrefs:
if PrefsLoad=FALSE then do
  if debug=1 then Say "Initialisation Prefs"
  PrefsLoad=TRUE
  address ANEWS
  window ID APREF COMMAND """CANCELPREFS""" PORT ASERV TITLE """Préférences"""
  group REGISTER HORIZ LABELS "Général,Animation"
   group HORIZ
    group
     label DOUBLE "Texte"
     label DOUBLE "Guides"
     label DOUBLE "Images"
     label DOUBLE "Sons (Court)"
     label DOUBLE "Musiques"
     label DOUBLE "Modules"
     label DOUBLE "Html"
     label DOUBLE "Copie Auto"
    endgroup
    group
     popasl ID FTXT HELP """Programme utilisé pour visualiser\nles \033btextes\033n.""" ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.texte
     popasl ID FGUID HELP """Programme utilisé pour visualiser\nles \033bGuides\033n et les fichiers texte.""" ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.guide
     popasl ID FIMG HELP """Programme utilisé pour visualiser les \033bImages\033n.""" ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.visu
     popasl ID FSON HELP """Programme utilisé pour écouter les \033bSons\033n.""" ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.son
     group HORIZ
      cycle ID TMUS ATTRS MUIA_HorizWeight 50 MUIA_Cycle_Active list2num(prefs.mus.type,"SongPlayer","AMPlifier"),
            HELP """Type de programme utilisé pour écouter\nles \033bMusiques\033n sous forme de sample.""" LABELS "SongPlayer,AMPlifier"
      popasl ID FMUS ATTRS ASLFR_RejectIcons TRUE HELP """Emplacement de l'executable utilisé pour écouter\nles \033bMusiques\033n sous forme de sample.""" CONTENT prefs.mus.exe
     endgroup
     group HORIZ
      cycle ID TMOD ATTRS MUIA_HorizWeight 50 MUIA_Cycle_Active list2num(prefs.mod.type,"Hippoplayer","EaglePlayer" ),
            HELP """Type de programme utilisé pour écouter\nles \033bModules\033n.""" LABELS "Hippoplayer,EaglePlayer"
      popasl ID FMOD ATTRS ASLFR_RejectIcons TRUE HELP """Emplacement de l'executable utilisé pour écouter\nles \033bModules\033n.""" CONTENT prefs.mod.exe
     endgroup
     group HORIZ
      cycle ID THTML ATTRS MUIA_HorizWeight 50 MUIA_Cycle_Active list2num(prefs.html.type,"IBrowse","AWeb","Voyager"),
            HELP """Type de programme utilisé pour visualiser\nles \033bPages Html\033n.""" LABELS "IBrowse,AWeb,Voyager"
/*      cycle ID THTML ATTRS MUIA_Cycle_Active list2num(prefs.html.type,"IBrowse","AWeb","Voyager")*/
      popasl ID FHTML ATTRS ASLFR_RejectIcons TRUE HELP """Emplacement de l'executable utilisé pour visualiser\nles \033bPages Html\033n.""" CONTENT prefs.html.exe
     endgroup
     popasl ID FCOPY ATTRS ASLFR_RejectIcons TRUE ASLFR_DrawersOnly TRUE HELP """Emplacement par défaut où seront copier les fichiers.""" CONTENT prefs.repdef
    endgroup
   endgroup
   group HORIZ
    group
     label DOUBLE "Anim IFF"
     label DOUBLE "FLI/FLC"
     label DOUBLE "AVI"
     label DOUBLE "MPEG"
     label DOUBLE "QT"
    endgroup
    group
     popasl ID AIFF HELP """Programme utilisé pour visualiser\nles \033bAnimations IFF\033n.""" ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.anim.iff
     popasl ID AFLI HELP """Programme utilisé pour visualiser les \033bAnimations FLI/FLC\033n.""" ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.anim.fli
     popasl ID AAVI HELP """Programme utilisé pour visualiser les \033bAnimations AVI\033n.""" ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.anim.avi
     popasl ID AMPEG HELP """Programme utilisé pour visualiser les \033bAnimations MPEG\033n."""  ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.anim.mpeg
     popasl ID AQT HELP """Programme utilisé pour visualiser les \033bAnimations QuickTime\033n.""" ATTRS ASLFR_RejectIcons TRUE CONTENT prefs.anim.qt
    endgroup
   endgroup
  endgroup
  group HORIZ
   button COMMAND "SAVEPREFS" PORT ASERV LABEL "Sauver"
   button COMMAND "USEPREFS" PORT ASERV LABEL "Utiliser"
   button COMMAND "CANCELPREFS" PORT ASERV LABEL "Annuler"
  endgroup
  endwindow
end
else do
  popasl ID FTXT CONTENT prefs.texte
  popasl ID FGUID CONTENT prefs.guide
  popasl ID FIMG CONTENT prefs.visu
  popasl ID FSON CONTENT prefs.son
  cycle ID TMUS ATTRS MUIA_Cycle_Active list2num(prefs.mus.type,"SongPlayer","AMPlifier")
  popasl ID FMUS CONTENT prefs.mus.exe
  cycle ID TMOD ATTRS MUIA_Cycle_Active list2num(prefs.mod.type,"Hippoplayer","EaglePlayer" )
  popasl ID FMOD CONTENT prefs.mod.exe
  cycle ID THTML ATTRS MUIA_Cycle_Active list2num(prefs.html.type,"IBrowse","AWeb","Voyager")
  popasl ID FHTML CONTENT prefs.html.exe
  popasl ID FCOPY CONTENT prefs.repdef

  popasl ID AIFF CONTENT prefs.anim.iff
  popasl ID AFLI CONTENT prefs.anim.fli
  popasl ID AAVI CONTENT prefs.anim.avi
  popasl ID AMPEG CONTENT prefs.anim.mpeg
  popasl ID AQT CONTENT prefs.anim.gt

  window ID APREF ATTRS MUIA_Window_Open TRUE
end
return

ReadPrefs:
popasl ID FTXT
prefs.texte=result
popasl ID FGUID
prefs.guide=result
popasl ID FIMG
prefs.visu=result
popasl ID FSON
prefs.son=result
cycle ID TMUS
prefs.mus.type=result
popasl ID FMUS
prefs.mus.exe=result
cycle ID TMOD
prefs.mod.type=result
popasl ID FMOD
prefs.mod.exe=result
cycle ID THTML
prefs.html.type=result
popasl ID FHTML
prefs.html.exe=result
popasl ID FCOPY
prefs.repdef=result
popasl ID AIFF
prefs.anim.iff=result
popasl ID AFLI
prefs.anim.fli=result
popasl ID AAVI
prefs.anim.avi=result
popasl ID AMPEG
prefs.anim.mepg=result
popasl ID AQT
prefs.anim.gt=result
return

list2num: PROCEDURE
if arg()>1 then do
  do i=2 to arg()
    if UPPER(arg(1))=UPPER(arg(i)) then return(i-2)
  end
end
return 0

replacepat: PROCEDURE
str=arg(1);pat=arg(2);replc=arg(3)
p=Pos(pat,str)
if p=1 then str=replc||SubStr(str,p+Length(pat))
if p>1 then str=Left(str,p-1)||replc||SubStr(str,p+Length(pat))
RETURN str

pathstr: PROCEDURE
str=arg(1)
do i=length(str) to 1 by -1
  a=substr(str,i,1)
  if (a='/') | (a=':') then do
    return substr(str,1,i)
  end
end
return ""

exestr: PROCEDURE
str=arg(1)
do i=length(str) to 1 by -1
  a=substr(str,i,1)
  if (a='/') | (a=':') then do
    return substr(str,i+1,length(str)-i)
  end
end
return ""