home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Plus Extra 1997 #5
/
AmigaPlus_Extra-CD_5-97.iso
/
online-tools
/
mail
/
netmail
/
drivers
/
edge.editor
< prev
next >
Wrap
Text File
|
1995-08-11
|
2KB
|
82 lines
/*
** $VER: Edge.editor 1.1 (11.8.95)
** Copyright (c) 1995 Riccardo Solmi
**
*/
OPTIONS RESULTS
OPTIONS FAILAT 21
cmd = 'Edge'
IF ~EXISTS(cmd) THEN DO
cmd = GetVar('NetMail/EdgeCmd')
IF cmd = 0 | ~EXISTS(cmd) THEN DO
ADDRESS COMMAND 'SetEnv NetMail/EdgeCmd `Which "Edge"`'
cmd = GetVar('NetMail/EdgeCmd')
IF cmd = 0 THEN DO
ADDRESS COMMAND 'SetEnv NetMail/EdgeCmd `RequestFile Title "Select Edge command" Noicons`'
cmd = GetVar('NetMail/EdgeCmd')
IF cmd = 0 | ~EXISTS(cmd) THEN RETURN 2
ADDRESS COMMAND 'Copy QUIET ENV:NetMail/EdgeCmd ENVARC:NetMail/EdgeCmd'
END
END
END
SELECT
WHEN UPPER(ARG(1)) = 'EDIT' THEN DO
PARSE ARG , file, port
winpar = ''
wininfo = GetVar('NetMail/EditorWin')
IF wininfo ~= 0 THEN DO
PARSE VAR wininfo pL pT pW pH .
winpar = 'LEFTEDGE' pL 'TOPEDGE' pT 'WIDTH' pW 'HEIGHT' pH
END
IF ~EXISTS(file) THEN ADDRESS COMMAND 'ECHO >"'file'" ""'
IF SHOW('P', 'EDGE') THEN DO
IF ~SHOW('P', port) | ~ABBREV(port, 'EDGE') THEN DO
ADDRESS 'EDGE'
'New' winpar
port = RESULT
END
ADDRESS VALUE port
'Open "'file'" FORCE'
END
ELSE DO
ADDRESS COMMAND
'"'cmd'" "'file'"'
'WaitForPort EDGE'
IF RC ~= 0 THEN RETURN 5
ADDRESS 'EDGE'
'AddressOf'
port = RESULT
ADDRESS VALUE port
IF winpar ~= '' THEN 'ChangeWindow' winpar
END
END
WHEN UPPER(ARG(1)) = 'SAVE' THEN DO
PARSE ARG , port
IF SHOW('P', port) & ABBREV(port, 'EDGE') THEN DO
ADDRESS VALUE port
'Save NOICON NOBACKUP'
END
END
WHEN UPPER(ARG(1)) = 'CLOSE' THEN DO
PARSE ARG , port
IF SHOW('P', port) & ABBREV(port, 'EDGE') THEN DO
ADDRESS VALUE port
wininfo = GetVar('NetMail/EditorWin')
PARSE VAR wininfo pL pT pW pH cLTWH
'Window'
PARSE VAR RESULT 'X 'pL', Y 'pT', W 'pW', H 'pH','
CALL SetVar('NetMail/EditorWin', pL pT pW pH cLTWH)
'Flag _GE_Flags DormantQuit CLEAR'
'Close FORCE'
END
END
END
RETURN port