Amiga Plus Extra 1997 #5/AmigaPlus_Extra-CD_5-97.iso/online-tools/mail/netmail/drivers/ced.editor

Text File | 1995-09-30 | 2KB | 74 lines

/*
** $VER: CED.editor 1.3 (30.9.95)
** Written by Rocco Coluccelli
** Modified by Riccardo Solmi
**
*/

OPTIONS RESULTS
OPTIONS FAILAT 21

cmd = 'CED'
IF ~EXISTS(cmd) THEN DO
   cmd = GetVar('NetMail/CEDCmd')
   IF cmd = 0 | ~EXISTS(cmd) THEN DO
      ADDRESS COMMAND 'SetEnv NetMail/CEDCmd `Which "CED"`'
      cmd = GetVar('NetMail/CEDCmd')
      IF cmd = 0 THEN DO
         ADDRESS COMMAND 'SetEnv NetMail/CEDCmd `RequestFile Title "Select CED command" Noicons`'
         cmd = GetVar('NetMail/CEDCmd')
         IF cmd = 0 | ~EXISTS(cmd) THEN RETURN 2
         ADDRESS COMMAND 'Copy QUIET ENV:NetMail/CEDCmd ENVARC:NetMail/CEDCmd'
      END
   END
END

cedport = 'rexx_ced'

SELECT
   WHEN UPPER(ARG(1)) = 'EDIT' THEN DO
      PARSE ARG , file, port

      IF ~SHOW('P', port) | ~ABBREV(port, cedport) THEN DO
         IF ~SHOW('P', cedport) THEN DO
            ADDRESS COMMAND
            '"'cmd'" >NIL:'
            'WaitForPort' cedport
            IF RC ~= 0 THEN RETURN 0
         END
         ELSE DO
            ADDRESS VALUE cedport
            'Clear'
         END
         port = cedport
      END

      ADDRESS VALUE port
      'OW' file
      'Status editable'; IF ~result THEN 'Menu' 2 11
   END

   WHEN UPPER(ARG(1)) = 'SAVE' THEN DO
      PARSE ARG , file , port

      IF SHOW('P', port) & ABBREV(port, cedport) THEN DO
         ADDRESS VALUE port
         'Status safesaves'; IF result ~= 1 THEN 'Menu' 1 9 1
         'Status iconcreation'; IF result THEN 'Menu' 1 10
         'Save As' file
            DeleteFile(file'.autos.info')
      END
   END

   WHEN UPPER(ARG(1)) = 'CLOSE' THEN DO
      PARSE ARG , port

      IF SHOW('P', port) & ABBREV(port, cedport) THEN DO
         ADDRESS VALUE port
        'Quit'
      END
   END
   OTHERWISE
END
RETURN port