home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Classic Fond 1
/
ClassicFond01.iso
/
role-pla
/
legacy.zip
/
MAKEBOOT.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-08-24
|
3KB
|
77 lines
::::::::::::::::::::::::::::::::::::::::::
:::: The Legacy Boot Disk Maker ::::
::::::::::::::::::::::::::::::::::::::::::
@echo off
:::::::::::::::::::::::::::::::::::::::::::
:OkContinue
echo
echo ======================================
echo You are about to format a floppy disk
echo in drive A ! Make sure this is a spare
echo disk and not one of your original
echo Legacy disks.
echo ======================================
:::::::::::::::::::::::::::::::::::::::::::
if not exist c:\dos\format.exe goto FSK
c:\dos\format A: /V:LegacyBoot /s /u
if errorlevel 5 goto FormatError
if errorlevel 4 c:\dos\format A: /V:LegacyBoot /s /u /F:720
if errorlevel 3 goto FormatError
goto OKformat
:::::::::::::::::::::::::::::::::::::::::::
:FSK
format A: /V:LegacyBoot /s /u
if errorlevel 5 goto FormatError
if errorlevel 4 format A: /V:LegacyBoot /s /u /F:720
if errorlevel 3 goto FormatError
:::::::::::::::::::::::::::::::::::::::::::
:OkFormat
echo Creating Startup Files..
echo @echo off > A:\autoexec.bat
echo @echo The Legacy Boot Disk >> A:\autoexec.bat
echo @echo -------------------------- >> A:\autoexec.bat
echo PROMPT=$p$g>> A:\autoexec.bat
PATH >> A:\autoexec.bat
echo DEVICE=C:\DOS\HIMEM.SYS > A:\config.sys
rem 768 is about ok for a 2MB machine, give the rest to SMARTDRV
echo DEVICE=C:\DOS\EMM386.EXE 768 RAM >> A:\config.sys
echo DOS=HIGH,UMB >> A:\config.sys
echo BUFFERS=20 >> A:\config.sys
echo FILES=40 >> A:\config.sys
echo DEVICEHIGH=C:\DOS\SMARTDRV.SYS 256 >> A:\config.sys
:::::::::::::::::::::::::::::::::::::::::::
:Mouse
if not exist c:\dos\find.exe goto Mouse2
type c:\config.sys|c:\dos\find/i "mouse"
type c:\config.sys|c:\dos\find/i "mouse" >> A:\config.sys
type c:\autoexec.bat|c:\dos\find/i "mouse"
type c:\autoexec.bat|c:\dos\find/i "mouse" >> A:\autoexec.bat
goto OkBootMade
:::::::::::::::::::::::::::::::::::::::::::
:Mouse2
type c:\config.sys|find/i "mouse"
type c:\config.sys|find/i "mouse" >> A:\config.sys
type c:\autoexec.bat|find/i "mouse"
type c:\autoexec.bat|find/i "mouse" >> A:\autoexec.bat
:::::::::::::::::::::::::::::::::::::::::::
:OkBootMade
echo Copied from your existing system files
:Now get the directory that bootmake has
:been run from to determine auto-boot info.
cd1
type t.1 >> A:\autoexec.bat
echo @echo Loading The Legacy .. please wait >> A:\autoexec.bat
echo legacy >> A:\autoexec.bat
del t.1
:::::::::::::::::::::::::::::::::::::::::::
echo.
echo The Legacy Boot Disk has been created
echo Press CTRL ALT DEL to reboot machine...
goto exit
:::::::::::::::::::::::::::::::::::::::::::
:FormatError
echo Boot Disk has not been made..
:::::::::::::::::::::::::::::::::::::::::::
:exit