home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 2 / crawlyvol2.bin / apps / dtp / pgsmodst / atariprt / oki182.s < prev    next >
Text File  |  1991-05-23  |  6KB  |  336 lines
  1.  include "prtequ.h"
  2.  
  3. *
  4. * Okidate Microline 182 print driver
  5. *
  6. CR    equ    $d
  7. LF    equ    $a
  8. FF    equ    $c
  9. ESC    equ    $1b
  10. FS    equ    $1c
  11.  
  12.  SECTION printer,CODE,PUBLIC
  13. ***************************************************************
  14. ***************************************************************
  15. ***************************************************************
  16. dumbentry:
  17.     clr.l    d0
  18.     rts
  19.  
  20.     dc.l    "PRNT"
  21.     dc.w    200
  22.  
  23. *
  24. * distribute the calls to the appropriate routines
  25. *
  26. oki182:    move.l    a0,table
  27.     lsl.w    #2,d0
  28.     lea    prntbl,a1
  29.     move.l    0(a1,d0.w),a1
  30.     jmp    (a1)
  31.  
  32. *
  33. * identify who I am, and set up who I like to speak to.
  34. *
  35. p_ident:
  36.     move.l    #driver,pdrvrnm(a0)    ;pointer to string for driver name
  37.     move.w    #PARALLEL+ASCENDING,device(a0)
  38. prtok:    moveq    #1,d0
  39.     rts
  40.  
  41. *
  42. * initialize the table of printer specific routines
  43. *
  44. p_init:    clr.b    pdl(a0)            ;no page description language
  45.     clr.b    pmult(a0)        ;automatically print mulitiple copies?
  46.     clr.b    pman(a0)        ;handle manual feed?
  47.     move.b    #PRT_BW,ptype(a0)    ;printer type?
  48.     move.l    sendout(a0),send+2    ;self-modifing code, tisk, tisk!
  49.  
  50. *
  51. * pminlft and pmaxw must be evenly divisible by 16
  52. * this is the part that should be worked out
  53. *
  54.  
  55.     move.w    pdensity(a0),d0
  56.     cmp.w    #7,d0
  57.     bcs    pint1
  58.     moveq    #6,d0
  59. pint1:    lsl.w    #1,d0
  60.  
  61.     lea    xdpi_tbl,a1
  62.     move.w    0(a1,d0.w),pxdpi(a0)    ;x resolution
  63.     lea    ydpi_tbl,a1
  64.     move.w    0(a1,d0.w),pydpi(a0)    ;y resolution
  65.     lea    minl_tbl,a1
  66.     move.w    0(a1,d0.w),pminlft(a0)    ;pixels from the left
  67.     lea    minr_tbl,a1
  68.     move.w    0(a1,d0.w),pminrht(a0)    ;pixels from the right
  69.     lea    mint_tbl,a1
  70.     move.w    0(a1,d0.w),pmintop(a0)    ;pixels down from top
  71.     lea    minb_tbl,a1
  72.     move.w    0(a1,d0.w),pminbot(a0)    ;pixels up from bottom
  73.     lea    xover_tbl,a1
  74.     move.w    0(a1,d0.w),pxover(a0)    ;percentage of x overlap of dots
  75.     lea    yover_tbl,a1
  76.     move.w    0(a1,d0.w),pyover(a0)    ;percentage of y overlap of dots
  77.     lea    rowht_tbl,a1
  78.     move.w    0(a1,d0.w),prowht(a0)    ;rows height modula
  79.  
  80.     move.w    0(a1,d0.w),rowht
  81.     lea    rows_tbl,a1
  82.     move.w    0(a1,d0.w),rows
  83.     lea    grmode_tbl,a1
  84.     move.w    0(a1,d0.w),grmode
  85.  
  86.     lsl.w    #1,d0
  87.     lea    maxw_tbl,a1
  88.     move.l    0(a1,d0.w),pmaxw(a0)    ;maximum # pixels across
  89.     lea    maxh_tbl,a1
  90.     move.l    0(a1,d0.w),pmaxh(a0)    ;maximum # pixels down
  91.  
  92.     bra    prtok
  93.  
  94. *
  95. * going to begin printing a document
  96. *
  97. p_bgndoc:
  98.     move.b    #ESC,d0
  99.     bsr    send
  100.     move.b    #"-",d0
  101.     bsr    send
  102.     move.b    #FS,d0
  103.     bra    send
  104.  
  105. *
  106. * about to start printing of a page
  107. *
  108. p_bgnpage:
  109.     bra    prtok
  110.  
  111. *
  112. * about to print a new tile for the page
  113. *
  114. p_bgntile:
  115.     bra    prtok
  116.  
  117. *
  118. * print a block to the printer
  119. *
  120. p_block:
  121.     move.l    table,a0
  122.     move.l    pblockw(a0),d0
  123.     move.w    d0,width
  124.     move.l    pblockptr(a0),a1
  125.     move.l    (a1),a1
  126.     add.l    pblockoff(a0),a1
  127.     move.l    a1,v_base
  128. *
  129. *
  130.     move.w    rows,count
  131. pblck2:    move.l    v_base,lineptr
  132.     bsr    putline
  133.     moveq    #0,d0
  134.     move.w    width,d0
  135.     add.l    d0,v_base
  136.     subq.w    #1,count
  137.     bne    pblck2
  138. *
  139.     move.b    #ESC,d0
  140.     bsr    send
  141.     move.b    #"%",d0
  142.     bsr    send
  143.     move.b    #"5",d0
  144.     bsr    send
  145.     move.w    #14,d0
  146.     sub.w    rows,d0
  147.     bra    send
  148.  
  149. **************************************
  150.  
  151. putline:
  152.     move.l    lineptr,a0
  153.     move.w    #0,twidth
  154.     move.w    #6,d1
  155. print0:    move.w    width,d0
  156. print1:    tst.b    -1(a0,d0.w)
  157.     bne    print2
  158.     subq.w    #1,d0
  159.     bne    print1
  160. print2:    cmp.w    twidth,d0
  161.     blt    print3
  162.     move.w    d0,twidth
  163. print3:    move.w    rows,d3
  164. pri1:    add.w    width,a0
  165.     sub.w    #1,d3
  166.     bgt    pri1
  167.     dbf    d1,print0
  168. *
  169.     tst.w    twidth
  170.     beq    endline
  171.  
  172.     move.b    #ESC,d0
  173.     bsr    send
  174.     move.w    grmode,d0
  175.     bsr    send
  176.     move.b    #3,d0
  177.     bsr    send
  178.  
  179.     move.w    twidth,d2                 ;length of the data in byte
  180. print4:    move.w    d2,-(sp)
  181.     moveq    #7,d4
  182. print6:    move.w    d4,pixel
  183.     moveq    #0,d1
  184.     moveq    #0,d0
  185.     move.l    lineptr,a0
  186. s1:    btst    d4,(a0)
  187.     beq     s2
  188.     bset    d1,d0
  189. s2:
  190.     move.w    rows,d3
  191. pri2:    add.w    width,a0
  192.     sub.w    #1,d3
  193.     bgt    pri2
  194.  
  195.     addq.w    #1,d1
  196.     cmp.w    #7,d1
  197.     bcs    s1
  198.  
  199.     cmp.b    #3,d0
  200.     bne    .1
  201.     bsr    send
  202.     move.b    #3,d0
  203. .1:    bsr    send
  204. *
  205.     move.w    pixel,d4
  206.     dbf    d4,print6
  207.  
  208.     add.l    #1,lineptr
  209.     move.w    (sp)+,d2
  210.     subq.w    #1,d2
  211.     bgt    print4
  212.  
  213.     move.b    #3,d0
  214.     bsr    send
  215.     move.b    #2,d0
  216.     bsr    send
  217.  
  218. endline:
  219.     move.b    #CR,d0
  220.     bsr    send
  221.     move.b    #ESC,d0
  222.     bsr    send
  223.     move.b    #"%",d0
  224.     bsr    send
  225.     move.b    #"5",d0
  226.     bsr    send
  227.     move.b    #1,d0
  228.     bra    send
  229.  
  230. ************************************
  231. *
  232. * just finished describing current tile
  233. *
  234. p_endtile:
  235.     move.l    table,a0
  236.     move.l    pblockh(a0),d0
  237.     mulu    #144,d0
  238.     divu    pydpi(a0),d0
  239.     move.w    d0,scroll
  240. pend1:    tst.b    scroll
  241.     beq    pend2
  242.     move.b    #ESC,d0
  243.     bsr    send
  244.     move.b    #"%",d0
  245.     bsr    send
  246.     move.b    #"5",d0
  247.     bsr    send
  248.     move.b    #255,d0
  249.     bsr    send
  250.     sub.w    #255,scroll
  251.     bra    pend1
  252. pend2:    tst.w    scroll
  253.     beq    prtok
  254.     move.b    #ESC,d0
  255.     bsr    send
  256.     move.b    #"%",d0
  257.     bsr    send
  258.     move.b    #"5",d0
  259.     bsr    send
  260.     move.w    scroll,d0
  261.     bra    send
  262.     
  263. *
  264. * just finished describing all tiles for this page
  265. *
  266. p_endpage:
  267.     bra    prtok
  268.  
  269. *
  270. * finished printing the document
  271. *
  272. p_enddoc:
  273.     bra    prtok
  274.  
  275. *
  276. * user requested stop
  277. *
  278. p_break:
  279.     bra    p_endtile
  280.  
  281. ***************************************************
  282. ***    these are the send routines for the    ***
  283. ***    dot matrix driver.            ***
  284. ***************************************************
  285.  
  286. sendline:
  287.     move.b    (a0)+,d0
  288.     beq    prtok
  289.     move.l    a0,-(sp)
  290.     bsr    send
  291.     move.l    (sp)+,a0
  292.     bra    sendline
  293.  
  294. send:    jmp    $ffffff
  295.  
  296. ***********************************
  297. ***                ***
  298. ***********************************
  299.  SECTION printer,DATA,PUBLIC
  300.  
  301. prntbl:    dc.l    prtok,prtok,prtok,prtok,p_init
  302.     dc.l    p_bgndoc,p_bgnpage,p_bgntile
  303.     dc.l    p_block
  304.     dc.l    p_endtile,p_endpage,p_enddoc
  305.     dc.l    p_break,p_ident
  306.  
  307.  
  308. xdpi_tbl:    dc.w    72,72,144,144,144,144,144
  309. ydpi_tbl:    dc.w    72,144,72,144,144,144,144
  310. minl_tbl:    dc.w    18,18,36,36,36,36,36
  311. minr_tbl:    dc.w    18,18,36,36,36,36,36
  312. mint_tbl:    dc.w    0,0,0,0,0,0,0
  313. minb_tbl:    dc.w    0,0,0,0,0,0,0
  314. maxw_tbl:    dc.l    576,576,1152,1152,1152,1152,1152
  315. maxh_tbl:    dc.l    0,0,0,0,0,0,0
  316. xover_tbl:    dc.w    0,0,50,50,50,50,50
  317. yover_tbl:    dc.w    0,50,0,50,50,50,50
  318. rowht_tbl:    dc.w    7,14,7,14,14,14,14
  319. rows_tbl:    dc.w    1,2,1,2,2,2,2
  320. grmode_tbl:    dc.w    "Q","Q","R","R","R","R","R"
  321.  
  322. driver:        dc.b    "Okidate ML-182 v2.0 beta",0
  323.  
  324.  SECTION printer,BSS,PUBLIC
  325. table:        ds.l    1
  326. twidth:        ds.w    1
  327. pixel:        ds.w    1
  328. v_base:        ds.l    1
  329. lineptr:    ds.l    1
  330. width:        ds.w    1
  331. count:        ds.w    1
  332. grmode:        ds.w    1
  333. rows:        ds.w    1
  334. rowht:        ds.w    1
  335. scroll:        ds.w    1
  336.