home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 2 / crawlyvol2.bin / apps / dtp / pgsmodst / atariprt / epsonxw.s < prev    next >
Text File  |  1991-05-23  |  6KB  |  321 lines
  1.  include "prtequ.h"
  2.  
  3. *
  4. * EpsonX wide carriage print driver
  5. *
  6. CR    equ    $d
  7. LF    equ    $a
  8. FF    equ    $c
  9. ESC    equ    $1b
  10.  
  11.  SECTION printer,CODE,PUBLIC
  12. ***************************************************************
  13. ***************************************************************
  14. ***************************************************************
  15. dumbentry:
  16.     clr.l    d0
  17.     rts
  18.  
  19.     dc.l    "PRNT"
  20.     dc.w    200
  21.  
  22. *
  23. * distribute the calls to the appropriate routines
  24. *
  25. fx100:    move.l    a0,table
  26.     lsl.w    #2,d0
  27.     lea    prntbl,a1
  28.     move.l    0(a1,d0.w),a1
  29.     jmp    (a1)
  30.  
  31. *
  32. * identify who I am, and set up who I like to speak to.
  33. *
  34. p_ident:
  35.     move.l    #driver,pdrvrnm(a0)    ;pointer to string for driver name
  36.     move.w    #PARALLEL+ASCENDING,device(a0)
  37. prtok:    moveq    #1,d0
  38.     rts
  39.  
  40. *
  41. * initialize the table of printer specific routines
  42. *
  43. p_init:    clr.b    pdl(a0)            ;no page description language
  44.     clr.b    pmult(a0)        ;automatically print mulitiple copies?
  45.     clr.b    pman(a0)        ;handle manual feed?
  46.     move.b    #PRT_BW,ptype(a0)    ;printer type?
  47.     move.l    sendout(a0),send+2    ;self-modifing code, tisk, tisk!
  48.  
  49. *
  50. * pminlft and pmaxw must be evenly divisible by 16
  51. * this is the part that should be worked out
  52. *
  53.  
  54.     move.w    pdensity(a0),d0
  55.     cmp.w    #7,d0
  56.     bcs    pint1
  57.     moveq    #6,d0
  58. pint1:    lsl.w    #1,d0
  59.  
  60.     lea    xdpi_tbl,a1
  61.     move.w    0(a1,d0.w),pxdpi(a0)    ;x resolution
  62.     lea    ydpi_tbl,a1
  63.     move.w    0(a1,d0.w),pydpi(a0)    ;y resolution
  64.     lea    minl_tbl,a1
  65.     move.w    0(a1,d0.w),pminlft(a0)    ;pixels from the left
  66.     lea    minr_tbl,a1
  67.     move.w    0(a1,d0.w),pminrht(a0)    ;pixels from the right
  68.     lea    mint_tbl,a1
  69.     move.w    0(a1,d0.w),pmintop(a0)    ;pixels down from top
  70.     lea    minb_tbl,a1
  71.     move.w    0(a1,d0.w),pminbot(a0)    ;pixels up from bottom
  72.     lea    xover_tbl,a1
  73.     move.w    0(a1,d0.w),pxover(a0)    ;percentage of x overlap of dots
  74.     lea    yover_tbl,a1
  75.     move.w    0(a1,d0.w),pyover(a0)    ;percentage of y overlap of dots
  76.     lea    rowht_tbl,a1
  77.     move.w    0(a1,d0.w),prowht(a0)    ;rows height modula
  78.  
  79.     move.w    0(a1,d0.w),rowht
  80.     lea    rows_tbl,a1
  81.     move.w    0(a1,d0.w),rows
  82.     lea    grmode_tbl,a1
  83.     move.w    0(a1,d0.w),grmode
  84.  
  85.     lsl.w    #1,d0
  86.     lea    maxw_tbl,a1
  87.     move.l    0(a1,d0.w),pmaxw(a0)    ;maximum # pixels across
  88.     lea    maxh_tbl,a1
  89.     move.l    0(a1,d0.w),pmaxh(a0)    ;maximum # pixels down
  90.     bra    prtok
  91.  
  92. *
  93. * going to begin printing a document
  94. *
  95. p_bgndoc:
  96.     bra    prtok
  97.  
  98. *
  99. * about to start printing of a page
  100. *
  101. p_bgnpage:
  102.     bra    prtok
  103.  
  104. *
  105. * about to print a new tile for the page
  106. *
  107. p_bgntile:
  108.     bra    prtok
  109.  
  110. *
  111. * print a block to the printer
  112. *
  113. p_block:
  114.     move.l    table,a0
  115.      move.l    pblockw(a0),d0
  116.     move.w    d0,width
  117.     move.l    pblockptr(a0),a1
  118.     move.l    (a1),a1
  119.     add.l    pblockoff(a0),a1
  120.     move.l    a1,v_base
  121. *
  122. *
  123.     move.w    rows,count
  124. pblck2:    move.l    v_base,lineptr
  125.     bsr    putline
  126.     moveq    #0,d0
  127.     move.w    width,d0
  128.     add.l    d0,v_base
  129.     subq.w    #1,count
  130.     bne    pblck2
  131. *
  132.     move.b    #ESC,d0            ;already moved 1/216" down
  133.     bsr    send
  134.     move.b    #"J",d0
  135.     bsr    send
  136.     move.w    #24,d0
  137.     sub.w    rows,d0
  138.     bra    send
  139.  
  140. **************************************
  141.  
  142. putline:
  143.     move.l    lineptr,a0
  144.     move.w    #0,twidth
  145.     move.w    #7,d1
  146. print0:    move.w    width,d0
  147. print1:    tst.b    -1(a0,d0.w)
  148.     bne    print2
  149.     subq.w    #1,d0
  150.     bne    print1
  151. print2:    cmp.w    twidth,d0
  152.     blt    print3
  153.     move.w    d0,twidth
  154. print3:    move.w    rows,d3
  155. pri1:    add.w    width,a0
  156.     sub.w    #1,d3
  157.     bgt    pri1
  158.     dbf    d1,print0
  159. *
  160.     tst.w    twidth
  161.     beq    endline
  162.  
  163.     lea    setgrmode,a0
  164.     bsr    sendline
  165.     move.w    grmode,d0
  166.     bsr    send
  167.  
  168.     move.w    twidth,d0        ;send number of graphic bytes to follow
  169.     lsl.w    #3,d0
  170.     bsr    send
  171.     move.w    twidth,d0    
  172.     lsr.w    #5,d0
  173.     bsr    send
  174.  
  175.     move.w    twidth,d2                 ;length of the data in byte
  176. print4:    move.w    d2,-(sp)
  177.     moveq    #7,d4
  178. print6:    move.w    d4,pixel
  179.     moveq    #7,d1
  180.     moveq    #0,d0
  181.     move.l    lineptr,a0
  182. s1:    btst    d4,(a0)
  183.     beq     s2
  184.     bset    d1,d0
  185. s2:
  186.     move.w    rows,d3
  187. pri2:
  188.     add.w    width,a0
  189.     sub.w    #1,d3
  190.     bgt    pri2
  191.  
  192.     dbf    d1,s1
  193.  
  194.     bsr    send
  195. *
  196.     move.w    pixel,d4
  197.     dbf    d4,print6
  198.  
  199.     add.l    #1,lineptr
  200.     move.w    (sp)+,d2
  201.     subq.w    #1,d2
  202.     bgt    print4
  203.  
  204. endline:
  205.     move.b    #ESC,d0            ;one-time paper feed of 1/216"
  206.     bsr    send
  207.     move.b    #"J",d0
  208.     bsr    send
  209.     move.b    #1,d0
  210.     bsr    send
  211.  
  212.     move.w    #CR,d0
  213.     bra    send
  214.  
  215. ************************************
  216. *
  217. * just finished describing current tile
  218. *
  219. p_endtile:
  220.     move.l    table,a0
  221.     move.l    pblockh(a0),d0
  222.     mulu    #216,d0
  223.     divu    pydpi(a0),d0
  224.     move.w    d0,scroll
  225. pend1:    tst.b    scroll
  226.     beq    pend2
  227.     move.b    #ESC,d0
  228.     bsr    send
  229.     move.b    #"J",d0
  230.     bsr    send
  231.     move.b    #255,d0
  232.     bsr    send
  233.     sub.w    #255,scroll
  234.     bra    pend1
  235. pend2:    tst.w    scroll
  236.     beq    prtok
  237.     move.b    #ESC,d0
  238.     bsr    send
  239.     move.b    #"J",d0
  240.     bsr    send
  241.     move.w    scroll,d0
  242.     bra    send
  243.     
  244. *
  245. * just finished describing all tiles for this page
  246. *
  247. p_endpage:
  248.     bra    prtok
  249.  
  250. *
  251. * finished printing the document
  252. *
  253. p_enddoc:
  254.     bra    prtok
  255.  
  256. *
  257. * user requested stop
  258. *
  259. p_break:
  260.     bra    p_endtile
  261.  
  262. ***************************************************
  263. ***    these are the send routines for the    ***
  264. ***    dot matrix driver.            ***
  265. ***************************************************
  266. *
  267. *
  268. sendline:
  269.     move.b    (a0)+,d0
  270.     beq    prtok
  271.     move.l    a0,-(sp)
  272.     bsr    send
  273.     move.l    (sp)+,a0
  274.     bra    sendline
  275. *
  276. *
  277. send:    jmp    $ffffff
  278. *
  279. *
  280. ***********************************
  281. ***                ***
  282. ***********************************
  283.  SECTION printer,DATA,PUBLIC
  284.  
  285. prntbl:    dc.l    prtok,prtok,prtok,prtok,p_init
  286.     dc.l    p_bgndoc,p_bgnpage,p_bgntile
  287.     dc.l    p_block
  288.     dc.l    p_endtile,p_endpage,p_enddoc
  289.     dc.l    p_break,p_ident
  290.  
  291.  
  292. xdpi_tbl:    dc.w    120,120,120,120,240,240,240
  293. ydpi_tbl:    dc.w    72,72,144,216,72,144,216
  294. minl_tbl:    dc.w    30,30,30,30,60,60,60
  295. minr_tbl:    dc.w    30,30,30,30,60,60,60
  296. mint_tbl:    dc.w    0,0,0,0,0,0,0
  297. minb_tbl:    dc.w    0,0,0,0,0,0,0
  298. maxw_tbl:    dc.l    1584,1584,1584,1584,3168,3168,3168
  299. maxh_tbl:    dc.l    0,0,0,0,0,0,0
  300. xover_tbl:    dc.w    0,0,0,0,50,50,50
  301. yover_tbl:    dc.w    0,0,50,66,0,50,66
  302. rowht_tbl:    dc.w    8,8,16,24,8,16,24
  303. rows_tbl:    dc.w    1,1,2,3,1,2,3
  304. grmode_tbl:    dc.w    1,1,1,1,3,3,3
  305.  
  306. driver:        dc.b    "EpsonX 9-Pin Wide v2.0",0
  307. setgrmode:    dc.b    ESC,"*",0
  308.  
  309.  SECTION printer,BSS,PUBLIC
  310. table:        ds.l    1
  311. twidth:        ds.w    1
  312. pixel:        ds.w    1
  313. v_base:        ds.l    1
  314. lineptr:    ds.l    1
  315. width:        ds.w    1
  316. count:        ds.w    1
  317. grmode:        ds.w    1
  318. rows:        ds.w    1
  319. rowht:        ds.w    1
  320. scroll:        ds.w    1
  321.