home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 2 / crawlyvol2.bin / apps / dtp / pgsmodst / atariprt / dicnx150.s < prev    next >
Text File  |  1991-05-23  |  6KB  |  316 lines
  1.  include "prtequ.h"
  2.  
  3. *
  4. * Old Epson driver
  5. *
  6. CR    equ    $d
  7. LF    equ    $a
  8. FF    equ    $c
  9. ESC    equ    $1b
  10.  
  11.  SECTION printer,CODE,PUBLIC
  12. ***************************************************************
  13. ***************************************************************
  14. ***************************************************************
  15. dumbentry:
  16.     clr.l    d0
  17.     rts
  18.  
  19.     dc.l    "PRNT"
  20.     dc.w    200
  21.  
  22. *
  23. * distribute the calls to the appropriate routines
  24. *
  25. diconix150:
  26.     move.l    a0,table
  27.     lsl.w    #2,d0
  28.     lea    prntbl,a1
  29.     move.l    0(a1,d0.w),a1
  30.     jmp    (a1)
  31.  
  32. *
  33. * identify who I am, and set up who I like to speak to.
  34. *
  35. p_ident:
  36.     move.l    #driver,pdrvrnm(a0)    ;pointer to string for driver name
  37.     move.w    #PARALLEL+ASCENDING,device(a0)
  38. prtok:    moveq    #1,d0
  39.     rts
  40.  
  41. *
  42. * initialize the table of printer specific routines
  43. *
  44. p_init:    clr.b    pdl(a0)            ;no page description language
  45.     clr.b    pmult(a0)        ;automatically print mulitiple copies?
  46.     clr.b    pman(a0)        ;handle manual feed?
  47.     move.b    #PRT_BW,ptype(a0)    ;printer type?
  48.     move.l    sendout(a0),send+2    ;self-modifing code, tisk, tisk!
  49.  
  50. *
  51. * pminlft and pmaxw must be evenly divisible by 16
  52. * this is the part that should be worked out
  53. *
  54.  
  55.     move.w    pdensity(a0),d0
  56.     cmp.w    #7,d0
  57.     bcs    pint1
  58.     moveq    #6,d0
  59. pint1:    lsl.w    #1,d0
  60.  
  61.     lea    xdpi_tbl,a1
  62.     move.w    0(a1,d0.w),pxdpi(a0)    ;x resolution
  63.     lea    ydpi_tbl,a1
  64.     move.w    0(a1,d0.w),pydpi(a0)    ;y resolution
  65.     lea    minl_tbl,a1
  66.     move.w    0(a1,d0.w),pminlft(a0)    ;pixels from the left
  67.     lea    minr_tbl,a1
  68.     move.w    0(a1,d0.w),pminrht(a0)    ;pixels from the right
  69.     lea    mint_tbl,a1
  70.     move.w    0(a1,d0.w),pmintop(a0)    ;pixels down from top
  71.     lea    minb_tbl,a1
  72.     move.w    0(a1,d0.w),pminbot(a0)    ;pixels up from bottom
  73.     lea    xover_tbl,a1
  74.     move.w    0(a1,d0.w),pxover(a0)    ;percentage of x overlap of dots
  75.     lea    yover_tbl,a1
  76.     move.w    0(a1,d0.w),pyover(a0)    ;percentage of y overlap of dots
  77.     lea    rowht_tbl,a1
  78.     move.w    0(a1,d0.w),prowht(a0)    ;rows height modula
  79.  
  80.     move.w    0(a1,d0.w),rowht
  81.     lea    rows_tbl,a1
  82.     move.w    0(a1,d0.w),rows
  83.     lea    grmode_tbl,a1
  84.     move.w    0(a1,d0.w),grmode
  85.  
  86.     lsl.w    #1,d0
  87.     lea    maxw_tbl,a1
  88.     move.l    0(a1,d0.w),pmaxw(a0)    ;maximum # pixels across
  89.     lea    maxh_tbl,a1
  90.     move.l    0(a1,d0.w),pmaxh(a0)    ;maximum # pixels down
  91.     bra    prtok
  92.  
  93. *
  94. * going to begin printing a document
  95. *
  96. p_bgndoc:
  97.     bra    prtok
  98.  
  99. *
  100. * about to start printing of a page
  101. *
  102. p_bgnpage:
  103.     bra    prtok
  104.  
  105. *
  106. * about to print a new tile for the page
  107. *
  108. p_bgntile:
  109.     bra    prtok
  110.  
  111. *
  112. * print a block to the printer
  113. *
  114. p_block:
  115.     move.l    table,a0
  116.      move.l    pblockw(a0),d0
  117.     move.w    d0,width
  118.     move.l    pblockptr(a0),a1
  119.     move.l    (a1),a1
  120.     add.l    pblockoff(a0),a1
  121.     move.l    a1,v_base
  122. *
  123. *
  124.     move.w    rows,count
  125. pblck2:    move.l    v_base,lineptr
  126.     bsr    putline
  127.     moveq    #0,d0
  128.     move.w    width,d0
  129.     add.l    d0,v_base
  130.     subq.w    #1,count
  131.     bne    pblck2
  132. *
  133.     move.b    #ESC,d0            ;already moved 1/216" down
  134.     bsr    send
  135.     move.b    #"J",d0
  136.     bsr    send
  137.     move.w    #24,d0
  138.     sub.w    rows,d0
  139.     bra    send
  140.  
  141. **************************************
  142.  
  143. putline:
  144.     move.l    lineptr,a0
  145.     move.w    #0,twidth
  146.     move.w    #7,d1
  147. print0:    move.w    width,d0
  148. print1:    tst.b    -1(a0,d0.w)
  149.     bne    print2
  150.     subq.w    #1,d0
  151.     bne    print1
  152. print2:    cmp.w    twidth,d0
  153.     blt    print3
  154.     move.w    d0,twidth
  155. print3:    move.w    rows,d3
  156. pri1:    add.w    width,a0
  157.     sub.w    #1,d3
  158.     bgt    pri1
  159.     dbf    d1,print0
  160. *
  161.     tst.w    twidth
  162.     beq    endline
  163.  
  164.     move.b    #ESC,d0
  165.     bsr    send
  166.     move.w    grmode,d0
  167.     bsr    send
  168.  
  169.     move.w    twidth,d0        ;send number of graphic bytes to follow
  170.     lsl.w    #3,d0
  171.     bsr    send
  172.     move.w    twidth,d0    
  173.     lsr.w    #5,d0
  174.     bsr    send
  175.  
  176.     move.w    twidth,d2                 ;length of the data in byte
  177. print4:    move.w    d2,-(sp)
  178.     moveq    #7,d4
  179. print6:    move.w    d4,pixel
  180.     moveq    #7,d1
  181.     moveq    #0,d0
  182.     move.l    lineptr,a0
  183. s1:    btst    d4,(a0)
  184.     beq     s2
  185.     bset    d1,d0
  186. s2:
  187.     move.w    rows,d3
  188. pri2:
  189.     add.w    width,a0
  190.     sub.w    #1,d3
  191.     bgt    pri2
  192.  
  193.     dbf    d1,s1
  194.  
  195.     bsr    send
  196. *
  197.     move.w    pixel,d4
  198.     dbf    d4,print6
  199.  
  200.     add.l    #1,lineptr
  201.     move.w    (sp)+,d2
  202.     subq.w    #1,d2
  203.     bgt    print4
  204.  
  205. endline:
  206.     move.b    #ESC,d0            ;one-time paper feed of 1/216"
  207.     bsr    send
  208.     move.b    #"J",d0
  209.     bsr    send
  210.     move.b    #1,d0
  211.     bsr    send
  212.  
  213.     move.w    #CR,d0
  214.     bra    send
  215.  
  216. ************************************
  217. *
  218. * just finished describing current tile
  219. *
  220. p_endtile:
  221.     move.l    table,a0
  222.     move.l    pblockh(a0),d0
  223.     mulu    #216,d0
  224.     divu    pydpi(a0),d0
  225.     move.w    d0,scroll
  226. pend1:    tst.b    scroll
  227.     beq    pend2
  228.     move.b    #ESC,d0
  229.     bsr    send
  230.     move.b    #"J",d0
  231.     bsr    send
  232.     move.b    #255,d0
  233.     bsr    send
  234.     sub.w    #255,scroll
  235.     bra    pend1
  236. pend2:    tst.w    scroll
  237.     beq    prtok
  238.     move.b    #ESC,d0
  239.     bsr    send
  240.     move.b    #"J",d0
  241.     bsr    send
  242.     move.w    scroll,d0
  243.     bra    send
  244.  
  245.  
  246. *
  247. * just finished describing all tiles for this page
  248. *
  249. p_endpage:
  250.     bra    prtok
  251.  
  252. *
  253. * finished printing the document
  254. *
  255. p_enddoc:
  256.     bra    prtok
  257.  
  258. ***************************************************
  259. ***    these are the send routines for the    ***
  260. ***    dot matrix driver.            ***
  261. ***************************************************
  262. sendline:
  263.     move.b    (a0)+,d0
  264.     beq    prtok
  265.     move.l    a0,-(sp)
  266.     bsr    send
  267.     move.l    (sp)+,a0
  268.     bra    sendline
  269. *
  270. *
  271. send:    jmp    $ffffff
  272. *
  273. *
  274. ***********************************
  275. ***                ***
  276. ***********************************
  277.  SECTION printer,DATA,PUBLIC
  278.  
  279. prntbl:    dc.l    prtok,prtok,prtok,prtok,p_init
  280.     dc.l    p_bgndoc,p_bgnpage,p_bgntile
  281.     dc.l    p_block
  282.     dc.l    p_endtile,p_endpage,p_enddoc
  283.     dc.l    prtok,p_ident
  284.  
  285.  
  286. xdpi_tbl:    dc.w    80,160,80,160,80,160,160
  287. ydpi_tbl:    dc.w    96,96,192,192,288,288,288
  288. minl_tbl:    dc.w    15,30,15,30,15,30,30
  289. minr_tbl:    dc.w    15,30,15,30,15,30,30
  290. mint_tbl:    dc.w    0,0,0,0,0,0,0
  291. minb_tbl:    dc.w    0,0,0,0,0,0,0
  292. maxw_tbl:    dc.l    566,1133,566,1133,566,1133,1133
  293. maxh_tbl:    dc.l    0,0,0,0,0,0,0
  294. xover_tbl:    dc.w    0,50,0,50,0,50,50
  295. yover_tbl:    dc.w    0,0,50,50,66,66,66
  296. rowht_tbl:    dc.w    8,8,16,16,24,24,24
  297. rows_tbl:    dc.w    1,1,2,2,3,3,3
  298. grmode_tbl:    dc.w    "K","L","K","L","K","L","L"
  299.  
  300. driver:        dc.b    "Diconix 150 v2.0.0",0
  301.  
  302.  SECTION printer,BSS,PUBLIC
  303. table:        ds.l    1
  304. twidth:        ds.w    1
  305. pixel:        ds.w    1
  306. v_base:        ds.l    1
  307. lineptr:    ds.l    1
  308. width:        ds.w    1
  309. count:        ds.w    1
  310. grmode:        ds.w    1
  311. rows:        ds.w    1
  312. rowht:        ds.w    1
  313. scroll:        ds.w    1
  314.  
  315. ; v2.0.0 - created 5/17/91 from epsonxo driver.
  316.