home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Crawly Crypt Collection 1
/
crawlyvol1.bin
/
bbs
/
cat25
/
scripts
/
rufus
/
tausch2.ruf
< prev
Wrap
Text File
|
1993-03-25
|
3KB
|
153 lines
print " MausTausch-Batch v1.21 by Dirk Steins"
print " ESC bricht ab!"
print
#
# Wahlwiederholung ausschalten
REPEAT=0
print
print "Maustausch mit Maus Köln 2"
print
# Variablen initialisieren
calls=0
fehler=0
# Maus Köln 2 anwählen
1:
# 2 Sekunden warten
wait 2000
gosub 50
dial "Maus Köln-Porz"
if status=0 then 9
if status=1 then 2
if status=2 then 3
if status=3 then 4
print " Maus Köln 2: unbekannter Fehler, Batch abgebrochen!"
fehler=1
goto 99
2:
print "Maus Köln 2: Busy"
goto 1
3:
print "Maus Köln 2: No Carrier"
goto 1
4:
print "Maus Köln 2: Error"
goto 1
9:
print "Maus Köln 2: Connect"
print
print "Einloggen in Maus"
print
if LOGGING=0 then 10
log "Connect nach ";
log calls;
log "Versuchen"
10:
# Auf erste Frage warten
rwait 30000,"Benutzer","MausNet"
if status<0 then 70
if status=1 then 76
send "j";
# 30 Sekunden auf zweite Eingabe-Aufforderung warten
rwait 30000,"Name"
if status<>0 then 71
# Sende Funktionstaste F1
send f1 ;
# 1 Sekunden warten
wait 1000
# Sende Funktionstaste Shift-F1 (passwort)
send f11 ;
# auf Hauptmenu warten
rwait 20000,"Haupt"
if status<>0 then 72
# Maustausch anwählen
send "T";
# auf Protokoll-Anforderung warten
rwait 20000,"Proto"
if status<>0 then 73
# Z-Modem als Protokoll
send "Z";
# eine halbe Sekunde warten
wait 500
# Infile senden
print "Infile senden"
print
upload "INFILE.TXT"
if status<>0 then 74
# Warten auf Outfile
print "Warten auf Outfile..."
print
# erstmal 2 sekunden warten
wait 2000
# maximal 2 Minuten warten
rwait 120000,"startet"
# Ohne Dateinamen, der kommt per Z-Modem
print "Outfile empfangen"
print
download
if status<>0 then 75
# Fertig mit Tausch, nun Ausloggen
# Da auch Fehlerbehandlung, erstmal ein Z senden
80:
send "Z";
wait 1000
send "S";
wait 1000
send "J";
# Noch auf No Carrier vom Modem warten
rwait 10000,"NO"
# und nun tschööö
99:
if fehler=1 then 98
quit
98:
end
70:
print
print "Fehler in der Maus: Keine Frage nach Benutzer!"
print
fehler=1
goto 99
71:
print
print "Fehler in der Maus: Keine Frage nach Namen!"
print
fehler=1
goto 99
72:
print
print "Fehler in der Maus: Hauptmenu kommt nicht!"
print
fehler=1
goto 80
73:
print
print "Fehler in der Maus: Protokollanforderung kommt nicht!"
print
fehler=1
goto 80
74:
print
print "Fehler bei der Übertragung: Infile nicht gesendet!"
print
fehler=1
goto 80
75:
print
print "Fehler bei der Übertragung: Outfile nicht empfangen!"
print
fehler=1
goto 80
76:
bell 0
print
print "MausNet läuft, Batch wurde abgebrochen"
print
goto 98
50:
# Subroutine für Ausgabe der Anrufanzahl
calls=calls+1
print "Versuch Nr. ";
print calls
return