home *** CD-ROM | disk | FTP | other *** search
/ Crawly Crypt Collection 1 / crawlyvol1.bin / apps / misc / zx_sp207 / source / midres.s next >
Text File  |  1993-07-18  |  24KB  |  671 lines
  1.           OPT A+      ; use (PC)-relativ adressing
  2.           OPT O3+     ; use short-word addressing
  3.           OPT O4+     ; use MOVEQ
  4.           OPT O5+     ; use ADDQ / SUBQ
  5.  
  6. ;#####################################################################
  7. ;#  BILDSCHIRM-TREIBER FÜR ZX-SPECTRUM VIDEO-EMULATION
  8. ;#  Nur Mittlere Auflösung 640x400 Pixel x 2 Bitplanes
  9. ;#####################################################################
  10. ;#  Zur Verwendung, das assemblierte Programm in ZXVID.TRB umbenennen
  11. ;#  und in den Ordner von SPECCI.DAT kopieren.
  12. ;#####################################################################
  13. ; 
  14. ;---------------------------------------
  15. ; Makro für S/W-Schirm-Transfer
  16. ;---------------------------------------
  17. transm1   macro \1,\2
  18.           moveq     #0,d0
  19.           IFEQ \1,0
  20.           move.b    (a3)+,d0            ; Byte vom Spectrum-Screen
  21.           ELSEIF
  22.           move.b    \1-1(a3),d0
  23.           ENDC
  24.           add.w     d0,d0
  25.           add.w     d0,d0
  26.           IFEQ \2,0
  27.           move.w    0(a0,d0.l),(a4)+
  28.           move.w    -2(a4),(a4)+
  29.           ELSEIF
  30.           move.w    0(a0,d0.l),\2-4(a4) ; ST-Werte aus Tabelle
  31.           move.w    \2-4(a4),\2-2(a4)
  32.           ENDC
  33.           endm
  34.  
  35. transm2   macro \1,\2
  36.           moveq     #0,d0
  37.           IFEQ \1,0
  38.           move.b    (a3)+,d0            ; Byte vom Spectrum-Screen
  39.           ELSEIF
  40.           move.b    \1-1(a3),d0
  41.           ENDC
  42.           add.w     d0,d0
  43.           add.w     d0,d0
  44.           IFEQ \2,0
  45.           move.w    2(a0,d0.l),(a4)+
  46.           move.w    -2(a4),(a4)+
  47.           ELSEIF
  48.           move.w    2(a0,d0.l),\2-4(a4) ; ST-Werte aus Tabelle
  49.           move.w    \2-4(a4),\2-2(a4)
  50.           ENDC
  51.           endm
  52.  
  53. ;---------------------------------------
  54. ; Makro für S/W-Schirm-Transfer Einzel
  55. ;---------------------------------------
  56. transf1   macro \1,\2
  57.           moveq     #0,d0
  58.           IFEQ \1,0
  59.           move.b    (a2),d0
  60.           ELSEIF
  61.           move.b    \1(a2),d0
  62.           ENDC
  63.           add.w     d0,d0
  64.           add.w     d0,d0
  65.           IFEQ \2,0
  66.           move.w    0(a0,d0.l),(a1)
  67.           move.w    (a1),2(a1)
  68.           ELSEIF
  69.           move.w    0(a0,d0.l),\2(a1)   ; ST-Werte aus Tabelle
  70.           move.w    \2(a1),\2+2(a1)
  71.           ENDC
  72.           endm
  73.  
  74. transf2   macro \1,\2
  75.           moveq     #0,d0
  76.           IFEQ \1,0
  77.           move.b    (a2),d0
  78.           ELSEIF
  79.           move.b    \1(a2),d0
  80.           ENDC
  81.           add.w     d0,d0
  82.           add.w     d0,d0
  83.           IFEQ \2,0
  84.           move.w    2(a0,d0.l),(a1)
  85.           move.w    (a1),2(a1)
  86.           ELSEIF
  87.           move.w    2(a0,d0.l),\2(a1)   ; ST-Werte aus Tabelle
  88.           move.w    \2(a1),\2+2(a1)
  89.           ENDC
  90.           endm
  91.  
  92. xbios     equ       14
  93.  
  94. clen      equ       256*128*4             ; Länge Color-Translate-Table
  95. llen      equ       24*4                  ; Länge Linearisierungs-Tabelle
  96. svmlen    equ       3*4*24                ; Länge Worktabelle
  97. flen      equ       256                   ; Länge Flash-Revers-Tabelle
  98.  
  99.  
  100. vdrv_hdr  equ       *
  101.           bra.w     v_install             ; Installierung           +0
  102.           ds.l      1                     ; De-Installierung        +4
  103.           ds.l      1                     ; Einzelbyte Attr.        +8
  104.           ds.l      1                     ; Einzelbyte Noattr.      +12
  105.           ds.l      1                     ; BORDER-Darstellung      +16
  106.           ds.l      1                     ; ganzen Schirm aufbauen  +20
  107.           ds.l      1                     ; VBL-Task                +24
  108.  
  109. v_install:lea       screen,a2
  110.           move.l    a1,(a2)
  111.           lea       flags,a2
  112.           lea       -4(a4),a4             ; 0(a4)=attr_sw, 1(a4)=flash_sw
  113.           move.l    a4,(a2)               ; 2(a4)=fmode
  114.           lea       ctab,a2
  115.           move.l    a0,(a2)+              ; ctab
  116.           adda.l    #clen,a0
  117.           move.l    a0,(a2)+              ; svmtab
  118.           adda.l    #svmlen,a0
  119.           move.l    a0,(a2)+              ; lintab
  120.           adda.l    #llen,a0
  121.           move.l    a0,(a2)               ; ftab
  122.           move.w    #4,-(sp)
  123.           trap      #xbios                ; getrez()
  124.           addq.l    #2,sp
  125.           cmpi.w    #1,d0                 ; Nur mittlere
  126.           beq.s     valres                ; ST-Auflösung!
  127.           moveq     #1,d0                 ; 'Auflösung nicht unterstützt'
  128.           rts
  129.  
  130. valres:   lea       v_deinst,a0
  131.           move.l    a0,4(a5)
  132.           lea       video_m1,a0
  133.           move.l    a0,8(a5)
  134.           lea       video_m2,a0
  135.           move.l    a0,12(a5)
  136.           lea       dborder,a0
  137.           move.l    a0,16(a5)
  138.           lea       buildpage,a0
  139.           move.l    a0,20(a5)
  140.           lea       vbltsk,a0
  141.           move.l    a0,24(a5)
  142.  
  143.           move.l    lintab,a0             ; Linearisierungs-Tabelle
  144.           clr.w     d0                    ; für ZX-SCREEN
  145.           move.w    #2,d6
  146. iloo4:    move.w    d0,-(sp)
  147.           move.w    #7,d5
  148. iloo3:    move.w    d0,-(sp)
  149.           move.l    screen,a1
  150.           add.w     d0,a1
  151.           move.l    a1,(a0)+
  152.           move.w    (sp)+,d0
  153.           add.w     #32,d0
  154.           dbf       d5,iloo3
  155.           move.w    (sp)+,d0
  156.           add.w     #2048,d0
  157.           dbf       d6,iloo4
  158.  
  159.           move.l    ctab,a0
  160.           lea       grey_tab,a1
  161.           clr.b     d0                    ; Attribut 0 - 127
  162.  
  163. iloo11:   clr.b     d6                    ; Pixelwert 0 - 255
  164.           move.b    d0,d5                 ; Attribut in Grauwert umrechnen
  165.           lsr.b     #3,d5
  166.           andi.w    #15,d5                ; d5 = Paper-Color 0..15
  167.           move.b    d0,d4
  168.           andi.w    #7,d4
  169.           btst      #3,d5
  170.           beq.s     ini_15
  171.           bset      #3,d4                 ; d4 = Ink-Color 0..15
  172. ini_15:   lsl.b     #3,d4
  173.           lsl.b     #3,d5
  174.           move.w    0(a1,d4.w),d2         ; d2 = Ink-Grauwert 1.Wort
  175.           move.w    4(a1,d4.w),d3         ; d3 = Ink-Grauwert 2.Wort
  176.           move.w    0(a1,d5.w),d4         ; d4 = Paper-Grauwert 1.Wort
  177.           move.w    4(a1,d5.w),d5         ; d5 = Paper-Grauwert 2.Wort
  178.  
  179.           swap      d0
  180. iloo10:   movem.l   d2-d6,-(sp)           ; Pixel-Wert über Graumaske
  181.           moveq     #7,d7                 ; von Byte auf Wort strecken
  182.           clr.w     d0
  183.           moveq     #0,d1
  184. iloo8:    roxr.b    #1,d6
  185.           bcc.s     ini_60                ; Paper-Pixel
  186.           roxr.w    #1,d2                 ; Ink-Pixel
  187.           roxr.w    d0
  188.           roxr.w    #1,d2
  189.           roxr.w    d0
  190.           roxr.w    #1,d3
  191.           roxr.w    d1
  192.           roxr.w    #1,d3
  193.           roxr.w    d1
  194.           dbf       d7,iloo8
  195.           bra.s     ini_65
  196. ini_60:   roxr.w    #1,d4
  197.           roxr.w    d0
  198.           roxr.w    #1,d4
  199.           roxr.w    d0
  200.           roxr.w    #1,d5
  201.           roxr.w    d1
  202.           roxr.w    #1,d5
  203.           roxr.w    d1
  204.           dbf       d7,iloo8
  205. ini_65:   move.w    d0,(a0)+
  206.           move.w    d1,(a0)+
  207.           movem.l   (sp)+,d2-d6
  208.           addq.b    #1,d6                 ; nächster Pixelwert
  209.           bne.s     iloo10
  210.  
  211.           swap      d0
  212.           addq.b    #1,d0                 ; nächstes Attribut
  213.           bpl.s     iloo11
  214.  
  215. ini_50:   move.w    #2,-(sp)
  216.           trap      #xbios
  217.           addq.l    #2,sp
  218.           lea       stscrn,a0
  219.           move.l    d0,(a0)+
  220.           addi.l    #4*160+16,d0
  221.           move.l    d0,(a0)+
  222.  
  223.           move.l    svmtab,a0
  224.           move.l    stscrn1,a1
  225.           move.l    screen,a2
  226.           lea       6144(a2),a2
  227.           move.l    lintab,a3
  228.           move.w    #23,d0
  229. iloo20:   move.l    a1,(a0)+
  230.           move.l    a2,(a0)+
  231.           move.l    (a3)+,(a0)+
  232.           lea       160*8(a1),a1
  233.           lea       32(a2),a2
  234.           dbf       d0,iloo20
  235.  
  236.           move.l    ftab,a0               ; Flash-Tabelle
  237.           clr.b     d0
  238.           move.w    #127,d1
  239. iloo29:   move.b    d0,(a0)+
  240.           addq.b    #1,d0
  241.           dbf       d1,iloo29
  242.           clr.b     d0                    ; Attribut 0 bis 127
  243. iloo30:   move.b    d0,d1
  244.           move.b    d0,d2
  245.           andi.b    #7,d1                 ; d1 = Ink
  246.           lsl.b     #3,d1                 ; in die Paper-Bits schieben
  247.           lsr.b     #3,d2                 ; Paper in
  248.           andi.b    #7,d2                 ; die Ink-Bits schieben
  249.           move.b    d0,d3
  250.           and.b     #64,d3                ; Bright erhalten
  251.           or.b      d1,d3                 ; vertauschtes Paper/Ink
  252.           or.b      d2,d3                 ; zu Attribut formen
  253.           move.b    d3,(a0)+              ; in die Tabelle damit
  254.           addq.b    #1,d0                 ; bis Attribut = 128
  255.           bpl.s     iloo30
  256.  
  257.           lea       px2st,a0
  258.           clr.w     d0
  259.           move.w    #2,d4
  260. iloo31:   move.w    #7,d3
  261.           move.w    d0,-(sp)
  262. iloo32:   move.w    #7,d2
  263.           move.w    d0,-(sp)
  264. iloo33:   move.w    d0,-(sp)
  265.           moveq     #31,d1
  266. iloo34:   move.w    d0,(a0)+
  267.           addq.w    #4,d0
  268.           dbf       d1,iloo34
  269. iloo35:   move.w    (sp)+,d0
  270.           add.w     #160*8,d0
  271.           dbf       d2,iloo33
  272.           move.w    (sp)+,d0
  273.           add.w     #160,d0
  274.           dbf       d3,iloo32
  275.           move.w    (sp)+,d0
  276.           add.w     #160*8*8,d0
  277.           dbf       d4,iloo31
  278.  
  279.           lea       px2at,a0
  280.           move.w    #22528,d0
  281.           move.w    #2,d4
  282. iloo41:   move.w    #7,d3
  283. iloo42:   move.w    #7,d2
  284. iloo43:   move.w    #31,d1
  285. iloo44:   move.w    d0,(a0)+
  286.           addq.w    #1,d0
  287.           dbf       d1,iloo44
  288.           dbf       d2,iloo43
  289.           sub.w     #256,d0
  290.           dbf       d3,iloo42
  291.           add.w     #256,d0
  292.           dbf       d4,iloo41
  293.  
  294.           lea       at2px,a0
  295.           move.w    #16384,d0
  296.           move.w    #2,d2
  297. iloo51:   move.w    #255,d1
  298. iloo52:   move.w    d0,(a0)+
  299.           addq.w    #1,d0
  300.           dbf       d1,iloo52
  301.           add.w     #2048-256,d0
  302.           dbf       d2,iloo51
  303.           moveq     #0,d0
  304.           rts
  305.  
  306. v_deinst: rts
  307.  
  308. ;---------------------------------------------------------------------
  309. ;         Vertical Blank-Task
  310. ;
  311. ;  Zur Darstellung des Bildschirms während einer LOAD-Operation
  312. ;---------------------------------------------------------------------
  313.  
  314. vbltsk:   move.l   a0,-(sp)
  315.           lea      vbsem,a0
  316.           subq.w   #1,(a0)
  317.           bmi.s    vb_99
  318.           bsr      vid_line
  319.           add.w    #12,2(a0)
  320.           bsr      vid_line
  321.           add.w    #12,2(a0)
  322.           cmpi.w   #288,2(a0)
  323.           blt.s    vb_99
  324.           clr.w    2(a0)
  325. vb_99:    addq.w   #1,(a0)
  326.           move.l   (sp)+,a0
  327.           rte
  328.  
  329. ;---------------------------------------------------------------------
  330. ;         Screenroutinen Medium Res
  331. ;
  332. ;  Zur Darstellung von Bytes im ZX-Screen am ST-Screen
  333. ;
  334. ;  d0.b   Pixel/Attribut-Wert
  335. ;  d1.l   Offset im ZX-Adressraum
  336. ;  a5     Start ZX-Adressraum im ST
  337. ;---------------------------------------------------------------------
  338. ;
  339. video_m2: cmpi.w   #22528,d1              ; Pixel oder Attribut ?
  340.           bcc.s    vm2_90                 ; -> Attribut ignorieren
  341.           movem.l  d0-d2/a0-a1,-(sp)
  342.           subi.w   #16384,d1              ; Pixeloffset 0 - 6143
  343.           bmi.s    vid_98                 ; ADRESSE IM ROM !
  344.           move.w   d1,d2
  345.           add.w    d1,d1                  ; * 2
  346.           lea      px2st,a0               ; ST-Screenadresse
  347.           move.w   0(a0,d1.l),d1          ; aus Pixel-Offset
  348.           move.l   stscrn1,a0             ; ermitteln
  349.           lea      0(a0,d1.l),a1
  350.           move.l   ctab,a0
  351.           adda.l   #120*1024,a0
  352.           andi.w   #$00ff,d0
  353.           add.w    d0,d0
  354.           add.w    d0,d0
  355.           btst     #8,d2
  356.           beq.s    vm2_40
  357.           move.w   2(a0,d0.w),(a1)
  358.           move.w   (a1)+,(a1)
  359.           movem.l  (sp)+,d0-d2/a0-a1
  360.           rte
  361. vm2_40:   move.w   0(a0,d0.w),(a1)
  362.           move.w   (a1)+,(a1)
  363.           movem.l  (sp)+,d0-d2/a0-a1
  364.           rte
  365.  
  366. vm2_90:   tst.b    -3(a4)                 ; Spezialfall: attrsw=0, flashsw=1
  367.           bcs      vidm_flsh              ; muß seperat behandelt werden
  368.           rte
  369.  
  370. vid_98:   movem.l  (sp)+,d0-d2/a0-a1
  371.           move.b   0(a5,d1.l),d0
  372.           rte
  373.  
  374. vid_99:   movem.l  (sp)+,d0-d4/a0-a2
  375.           move.b   0(a5,d1.l),d0
  376.           rte
  377.  
  378. video_m1: movem.l  d0-d4/a0-a2,-(sp)
  379.           cmpi.w   #22528,d1              ; Pixel oder Attribut ?
  380.           bcc.s    vidm_att               ; -> Attribut
  381.           subi.w   #16384,d1              ; Pixeloffset 0 - 6143
  382.           bmi.s    vid_99                 ; ADRESSE IM ROM !
  383. ;
  384.           move.w   d1,d4
  385.           add.w    d1,d1                  ; * 2
  386.           lea      px2st,a0               ; ST-Screenadresse
  387.           move.w   0(a0,d1.l),d2          ; aus Pixel-Offset
  388.           move.l   stscrn1,a0             ; ermitteln
  389.           lea      0(a0,d2.w),a1
  390. ;
  391.           lea      px2at,a0               ; Attribut dieses Pixels
  392.           move.w   0(a0,d1.l),d2
  393.           moveq    #0,d1
  394.           move.b   0(a5,d2.w),d1
  395. ;
  396.           bpl.s    vm1_12                 ; Normales Attribut
  397.           tst.b    -2(a4)                 ; Flash-Zyklus?
  398.           beq.s    vm1_10                 ; nein
  399.           move.l   ftab,a0
  400.           move.b   0(a0,d1.l),d1          ; Flash -> Invers
  401. vm1_10:   andi.b   #$7f,d1
  402. vm1_12:   moveq    #10,d3
  403.           lsl.l    d3,d1
  404.           move.l   ctab,a0
  405.           lea      0(a0,d1.l),a0
  406.           move.b   d0,d3
  407.           add.w    d3,d3
  408.           add.w    d3,d3
  409.           btst     #8,d4
  410.           beq.s    vm1_40
  411.           move.w   2(a0,d3.w),(a1)
  412.           move.w   (a1)+,(a1)
  413.           movem.l  (sp)+,d0-d4/a0-a2
  414.           rte
  415. vm1_40:   move.w   0(a0,d3.w),(a1)
  416.           move.w   (a1)+,(a1)
  417.           movem.l  (sp)+,d0-d4/a0-a2
  418.           rte
  419.  
  420. vidm_att: sub.w    #22528,d1
  421.           add.w    d1,d1                  ; *2
  422.           lea      at2px,a0               ; Attribut -> Pixel
  423.           move.w   0(a0,d1.l),d2          ; ZX-Pixel-Adresse
  424.           lea      0(a5,d2.w),a2          ; Position im ST-Ram
  425. ;
  426.           lea      px2st,a0
  427.           subi.w   #16384,d2              ; 0
  428.           add.w    d2,d2
  429.           move.w   0(a0,d2.w),d1
  430.           move.l   stscrn1,a0
  431.           lea      0(a0,d1.w),a1          ; ST-Screenadresse
  432. ;
  433.           moveq    #0,d1
  434.           move.b   d0,d1
  435.           bpl.s    vma_12                 ; normales Attribut
  436.           tst.b    -2(a4)                 ; Flash-Zyklus?
  437.           beq.s    vma_10                 ; nein
  438.           move.l   ftab,a0
  439.           move.b   0(a0,d1.l),d1          ; Attribut (Flash -> Invers)
  440. vma_10:   andi.b   #$7f,d1
  441. vma_12:   moveq    #10,d3
  442.           lsl.l    d3,d1
  443.           move.l   ctab,a0
  444.           lea      0(a0,d1.l),a0
  445.           transf1 0,0
  446.           transf2 256,80*2
  447.           transf1 256*2,80*4
  448.           transf2 256*3,80*6
  449.           transf1 256*4,80*8
  450.           transf2 256*5,80*10
  451.           transf1 256*6,80*12
  452.           transf2 256*7,80*14
  453.           movem.l  (sp)+,d0-d4/a0-a2
  454.           rte
  455.  
  456. vidm_flsh:movem.l  d0-d3/a0-a2,-(sp)
  457.           sub.w    #16384,d1
  458.           add.w    d1,d1                  ; *2
  459.           lea      at2px,a0               ; Attribut -> Pixel Tabelle
  460.           move.w   0(a0,d1.l),d2          ; ZX-Pixel-Adresse
  461.           lea      0(a5,d2.w),a2          ; Position im ST-Ram
  462. ;
  463.           lea      px2st,a0
  464.           subi.w   #16384,d2              ; 0
  465.           add.w    d2,d2
  466.           move.w   0(a0,d2.w),d1
  467.           move.l   stscrn1,a0
  468.           lea      0(a0,d1.w),a1          ; ST-Screenadresse
  469. ;
  470.           move.l   ctab,a0
  471.           adda.l   #%01111000*1024,a0     ; PAPER 0, INK 7, BRIGHT 1
  472.           tst.b    d0                     ; Flash-Attribut?
  473.           bpl.s    vmf_10                 ; normales Attribut
  474.           tst.b    -2(a4)                 ; Flash-Zyklus?
  475.           beq.s    vmf_10                 ; nein
  476.           suba.l   #(%01111000-%01000111)*1024,a0 ; PAPER 7, INK 0, BRIGHT 1
  477. vmf_10:   equ      *
  478.           transf1 0,0
  479.           transf2 256,80*2
  480.           transf1 256*2,80*4
  481.           transf2 256*3,80*6
  482.           transf1 256*4,80*8
  483.           transf2 256*5,80*10
  484.           transf1 256*6,80*12
  485.           transf2 256*7,80*14
  486.           movem.l  (sp)+,d0-d3/a0-a2
  487.           rte
  488.  
  489. dborder:  movem.l   a0/d0-d2,-(sp)
  490.           lea       grey_tab,a0           ; Graumuster berechnen
  491.           lsl.w     #3,d0                 ; Eintrag Grauwert für Farbe d0
  492.           move.l    0(a0,d0.w),d1         ; Grauwert Scan 1
  493.           move.l    4(a0,d0.w),d2         ; Grauwert Scan 2
  494.           move.l    stscrn,a0
  495.           moveq     #3,d0                 ; Obere 4 Doppelzeilen
  496. mc1:      move.l    d1,(a0)+              ; mit Border-Farbe füllen
  497.           move.l    d1,(a0)+              ; 1
  498.           move.l    d1,(a0)+
  499.           move.l    d1,(a0)+              ; 2
  500.           move.l    d1,(a0)+
  501.           move.l    d1,(a0)+              ; 3
  502.           move.l    d1,(a0)+
  503.           move.l    d1,(a0)+              ; 4
  504.           move.l    d1,(a0)+
  505.           move.l    d1,(a0)+              ; 5
  506.           move.l    d1,(a0)+
  507.           move.l    d1,(a0)+              ; 6
  508.           move.l    d1,(a0)+
  509.           move.l    d1,(a0)+              ; 7
  510.           move.l    d1,(a0)+
  511.           move.l    d1,(a0)+              ; 8
  512.           move.l    d1,(a0)+
  513.           move.l    d1,(a0)+              ; 9
  514.           move.l    d1,(a0)+
  515.           move.l    d1,(a0)+              ; 10
  516.           move.l    d1,(a0)+
  517.           move.l    d1,(a0)+              ; 11
  518.           move.l    d1,(a0)+
  519.           move.l    d1,(a0)+              ; 12
  520.           move.l    d1,(a0)+
  521.           move.l    d1,(a0)+              ; 13
  522.           move.l    d1,(a0)+
  523.           move.l    d1,(a0)+              ; 14
  524.           move.l    d1,(a0)+
  525.           move.l    d1,(a0)+              ; 15
  526.           move.l    d1,(a0)+
  527.           move.l    d1,(a0)+              ; 16
  528.           move.l    d1,(a0)+
  529.           move.l    d1,(a0)+              ; 17
  530.           move.l    d1,(a0)+
  531.           move.l    d1,(a0)+              ; 18
  532.           move.l    d1,(a0)+
  533.           move.l    d1,(a0)+              ; 19
  534.           move.l    d1,(a0)+
  535.           move.l    d1,(a0)+              ; 20
  536.           exg       d1,d2
  537.           dbf       d0,mc1
  538.           move.w    #191,d0               ; Linken und rechten Rand
  539. mc3:      move.l    d1,(a0)               ; mit Borderfarbe füllen
  540.           move.l    d1,4(a0)
  541.           move.l    d1,8(a0)
  542.           move.l    d1,12(a0)
  543.           move.l    d1,160-16(a0)
  544.           move.l    d1,160-12(a0)
  545.           move.l    d1,160-8(a0)
  546.           move.l    d1,160-4(a0)
  547.           exg       d1,d2
  548.           lea       160(a0),a0
  549.           dbf       d0,mc3
  550.           moveq     #3,d0                 ; Untere 4 Doppelzeilen
  551. mc4:      move.l    d1,(a0)+              ; mit Border-Farbe füllen
  552.           move.l    d1,(a0)+              ; 1
  553.           move.l    d1,(a0)+
  554.           move.l    d1,(a0)+              ; 2
  555.           move.l    d1,(a0)+
  556.           move.l    d1,(a0)+              ; 3
  557.           move.l    d1,(a0)+
  558.           move.l    d1,(a0)+              ; 4
  559.           move.l    d1,(a0)+
  560.           move.l    d1,(a0)+              ; 5
  561.           move.l    d1,(a0)+
  562.           move.l    d1,(a0)+              ; 6
  563.           move.l    d1,(a0)+
  564.           move.l    d1,(a0)+              ; 7
  565.           move.l    d1,(a0)+
  566.           move.l    d1,(a0)+              ; 8
  567.           move.l    d1,(a0)+
  568.           move.l    d1,(a0)+              ; 9
  569.           move.l    d1,(a0)+
  570.           move.l    d1,(a0)+              ; 10
  571.           move.l    d1,(a0)+
  572.           move.l    d1,(a0)+              ; 11
  573.           move.l    d1,(a0)+
  574.           move.l    d1,(a0)+              ; 12
  575.           move.l    d1,(a0)+
  576.           move.l    d1,(a0)+              ; 13
  577.           move.l    d1,(a0)+
  578.           move.l    d1,(a0)+              ; 14
  579.           move.l    d1,(a0)+
  580.           move.l    d1,(a0)+              ; 15
  581.           move.l    d1,(a0)+
  582.           move.l    d1,(a0)+              ; 16
  583.           move.l    d1,(a0)+
  584.           move.l    d1,(a0)+              ; 17
  585.           move.l    d1,(a0)+
  586.           move.l    d1,(a0)+              ; 18
  587.           move.l    d1,(a0)+
  588.           move.l    d1,(a0)+              ; 19
  589.           move.l    d1,(a0)+
  590.           move.l    d1,(a0)+              ; 20
  591.           exg       d1,d2
  592.           dbf       d0,mc4
  593.           movem.l   (sp)+,a0/d0-d2
  594.           rts
  595.  
  596. buildpage:move.l    a0,-(sp)
  597.           lea       pass,a0
  598.           clr.w     (a0)                  ; Index = 0
  599. bp_10:    bsr       vid_line              ; Zeile darstellen
  600.           add.w     #12,(a0)
  601.           cmpi.w    #288,(a0)
  602.           bne.s     bp_10
  603.           move.l    (sp)+,a0
  604.           rts
  605.  
  606. vid_line: movem.l   d0-d7/a0-a6,-(sp)
  607.           move.l    flags,a5
  608.           move.l    svmtab,a0
  609.           move.w    pass,d0
  610.           move.l    0(a0,d0.w),a4         ; ST-Screen
  611.           move.l    4(a0,d0.w),a6         ; Attributfile
  612.           move.l    8(a0,d0.w),a3         ; Spectrum Pixelzeile
  613.           move.l    ctab,a2
  614.           move.l    ftab,a1
  615.           moveq     #10,d6                ; für *1024
  616.  
  617.           moveq     #31,d4                ; 32 Chars (a 8 Scans)
  618.           move.l    ctab,a0
  619.           adda.l    #120*1024,a0
  620. vl_loo:   tst.b     (a5)                  ; attr_sw
  621.           beq.s     vl_noatt
  622.           moveq     #0,d1
  623.           move.b    (a6)+,d1              ; Attribut
  624.           move.b    0(a1,d1.l),d1         ; Flash -> Invers
  625.           lsl.l     d6,d1                 ; * 1024
  626.           lea       0(a2,d1.l),a0         ; Tabelle für dieses Attribut
  627. vl_noatt: transm1 0,0
  628.           transm2 256,80*2
  629.           transm1 256*2,80*4
  630.           transm2 256*3,80*6
  631.           transm1 256*4,80*8
  632.           transm2 256*5,80*10
  633.           transm1 256*6,80*12
  634.           transm2 256*7,80*14
  635.           dbf       d4,vl_loo
  636.           movem.l   (sp)+,d0-d7/a0-a6
  637.           rts
  638.  
  639. grey_tab: dc.l      $ffffffff,$ffffffff                ; BLACK   - BRIGHT 0
  640.           dc.l      $aaaaaaaa,$ffffffff                ; BLUE    - BRIGHT 0
  641.           dc.l      $ffffffff,$55555555                ; RED     - BRIGHT 0
  642.           dc.l      $aaaaaaaa,$55555555                ; MAGENTA - BRIGHT 0
  643.           dc.l      $55555555,$aaaaaaaa                ; GREEEN  - BRIGHT 0
  644.           dc.l      $55555555,$ffffffff                ; CYAN    - BRIGHT 0
  645.           dc.l      $ffffffff,$00000000                ; YELLOW  - BRIGHT 0
  646.           dc.l      $11111111,$88888888                ; WHITE   - BRIGHT 0
  647.           dc.l      $ffffffff,$ffffffff                ; BLACK   - BRIGHT 1
  648.           dc.l      $ffffffff,$aaaaaaaa                ; BLUE    - BRIGHT 1
  649.           dc.l      $55555555,$55555555                ; RED     - BRIGHT 1
  650.           dc.l      $55555555,$00000000                ; MAGENTA - BRIGHT 1
  651.           dc.l      $00000000,$55555555                ; GREEN   - BRIGHT 1
  652.           dc.l      $aaaaaaaa,$aaaaaaaa                ; CYAN    - BRIGHT 1
  653.           dc.l      $aaaaaaaa,$00000000                ; YELLOW  - BRIGHT 1
  654.           dc.l      $00000000,$00000000                ; WHITE   - BRIGHT 1
  655.  
  656. vbsem:    dc.w      0
  657. pass:     dc.w      0
  658.  
  659. ctab      ds.l      1
  660. svmtab    ds.l      1
  661. lintab    ds.l      1
  662. ftab:     ds.l      1
  663. stscrn:   ds.l      1
  664. stscrn1:  ds.l      1
  665. screen:   ds.l      1
  666. flags:    ds.l      1
  667.  
  668. at2px:    ds.w      32*24
  669. px2st:    ds.w      6144
  670. px2at:    ds.w      6144
  671.