home *** CD-ROM | disk | FTP | other *** search
/ Windows 95 v2.4 Fix / W95-v2.4fix.iso / ACADWIN / SUPPORT / EDGE.LSP < prev    next >
Encoding:
Lisp/Scheme  |  1995-02-08  |  7.6 KB  |  231 lines
  1. ; Next available MSG number is    12 
  2. ; MODULE_ID EDGE_LSP_
  3. ;;;
  4. ;;;    edge.lsp            
  5. ;;;    
  6. ;;;    Copyright (C) 1988, 1990, 1992, 1994 by Autodesk, Inc.
  7. ;;;
  8. ;;;    Permission to use, copy, modify, and distribute this software
  9. ;;;    for any purpose and without fee is hereby granted, provided
  10. ;;;    that the above copyright notice appears in all copies and
  11. ;;;    that both that copyright notice and the limited warranty and
  12. ;;;    restricted rights notice below appear in all supporting
  13. ;;;    documentation.
  14. ;;;
  15. ;;;    AUTODESK PROVIDES THIS PROGRAM "AS IS" AND WITH ALL FAULTS.
  16. ;;;    AUTODESK SPECIFICALLY DISCLAIMS ANY IMPLIED WARRANTY OF
  17. ;;;    MERCHANTABILITY OR FITNESS FOR A PARTICULAR USE.  AUTODESK, INC.
  18. ;;;    DOES NOT WARRANT THAT THE OPERATION OF THE PROGRAM WILL BE
  19. ;;;    UNINTERRUPTED OR ERROR FREE.
  20. ;;;
  21. ;;;    Use, duplication, or disclosure by the U.S. Government is subject to
  22. ;;;    restrictions set forth in FAR 52.227-19 (Commercial Computer
  23. ;;;    Software - Restricted Rights) and DFAR 252.227-7013(c)(1)(ii) 
  24. ;;;    (Rights in Technical Data and Computer Software), as applicable.
  25. ;;;
  26. ;;;.
  27. ;;;
  28. ;;; --------------------------------------------------------------------------;
  29. ;;; DESCRIPTION
  30. ;;;
  31. ;;;   Interactive editor for changing the visibility of 3DFACE edges.           
  32. ;;;   Prompt:         "Display/<Select edge>: "                                 
  33. ;;;
  34. ;;;   Features:                                                                 
  35. ;;;    > "Display" -  Allows selective regeneration of 3DFACE's highlighting    
  36. ;;;                   invisible edges.                                          
  37. ;;;    >  Select   -  Reverses the visibility of each edge found.               
  38. ;;;
  39. ;;;   Note:                                                                     
  40. ;;;    >  EDGE uses Osnap MIDpoint as the center of a small crossing box        
  41. ;;;       when selecting edges.                                                 
  42. ;;;    >  Only edges displayed (or highlighted) can be modified.  (Use          
  43. ;;;       "Display" to display a 3DFACE.)                                       
  44. ;;;    >  Invisible edges will always be displayed if the system variable       
  45. ;;;       SPLFRAME is set to 1.                                                 
  46. ;;;
  47. ;;; --------------------------------------------------------------------------;
  48.  
  49. ;;; ----------------------------- CREATE NEW *ERROR* -------------------------;
  50.  
  51. (defun edge-er (n) 
  52.   (if (/= s "Funci≤n cancelada") 
  53.     (princ (strcat "\nError: " n))
  54.   ) 
  55.   (command) 
  56.   (command "_.UCS" "_P") 
  57.   (setvar "osmode" o1)
  58.   (setvar "gridmode" g1)
  59.   (setvar "aperture" a1)
  60.   (setvar "splframe" v1)
  61.   (setvar "ucsfollow" u1)
  62.   (command "_.UNDO" "_E") 
  63.   (setvar "cmdecho" s1)
  64.   (setq n1 -1)
  65.   (repeat (sslength faclst) 
  66.     (redraw (entupd (ssname faclst (setq n1 (1+ n1)))))
  67.   ) 
  68.   (setq *error* lisp-er)
  69.   (prin1)
  70. ) 
  71. ;;; ---------------------------- COMMONLY USED MACROS ------------------------;
  72.  
  73. (defun getval (n e) 
  74.   (cdr (assoc n e))
  75. ) 
  76.  
  77. (defun fltfac (ss / n1) 
  78.   (setq n1 0)
  79.   (if ss 
  80.     (repeat (sslength ss) 
  81.       (if (/= (getval 0 (entget (setq e1 (ssname ss n1)))) ;|MSG0|;"3DFACE") 
  82.         (ssdel e1 ss) 
  83.         (setq n1 (1+ n1))
  84.       )
  85.     )
  86.   ) 
  87.   ss
  88. ) 
  89.  
  90. ;;; ------------------------- FORCE DISPLAY OF ALL EDGES ---------------------;
  91.  
  92. (defun dsply (/ ss n1 t1) 
  93.   (setvar "osmode" 0)
  94.   (initget "Seleccionar Todo") 
  95.   (setq ss (if (eq (getkword "\nSeleccionar/<Todo>: ") "Seleccionar") 
  96.              (fltfac (ssget)) 
  97.              (ssget ;|MSG0|;"_x" '((0 . ;|MSG0|;"3dface")))
  98.            ) 
  99.         n1 -1)
  100.   (setvar "osmode" 2)
  101.   (cond (ss (princ "\n** Regeneraci≤n objetos 3DCARA...") 
  102.             (repeat (sslength ss) 
  103.               (ssadd (setq t1 (ssname ss (setq n1 (1+ n1)))) faclst) 
  104.               (shohdn (entget (entupd t1)))) 
  105.             (princ "terminada.") T) 
  106.     (T (princ "\nNo se han encontrado objetos 3DCARA.") nil)
  107.   )
  108. ) 
  109. ;;; ----------------------------- SHOW HIDDEN EDGES --------------------------;
  110.  
  111. (defun shohdn (e / b1 p1 p2 p3 p4) 
  112.   (setq b1 (getval 70 e))
  113.   (mapcar '(lambda (j k) (set j (getval k e))) 
  114.           '(p1 p2 p3 p4) 
  115.           '(10 11 12 13)) 
  116.   (if (= (logand b1 1) 1) 
  117.     (grdraw p1 p2 c1 1)
  118.   ) 
  119.   (if (= (logand b1 2) 2) 
  120.     (grdraw p2 p3 c1 1)
  121.   ) 
  122.   (if (= (logand b1 4) 4) 
  123.     (grdraw p3 p4 c1 1)
  124.   ) 
  125.   (if (= (logand b1 8) 8) 
  126.     (grdraw p4 p1 c1 1)
  127.   )
  128. ) 
  129.  
  130. ;;; --------------------------- GET ENTITY TO EDIT ---------------------------;
  131.  
  132. (defun getfce (pt / ll ur n1 ss e1 p1) 
  133.   (setq p1 (trans pt 0 2) 
  134.         ll (trans (polar P1 (/ (* pi 5) 4) h1) 2 0) 
  135.         ur (trans (polar P1 (/ pi 4) h1) 2 0) 
  136.         n1 0)
  137.   (setvar "osmode" 0)
  138.   (if (setq ss (ssget ;|MSG0|;"_c" ll ur))
  139.     (setq ss (fltfac ss))
  140.   ) 
  141.   (setvar "osmode" 2)
  142.   ss
  143. ) 
  144.  
  145. ;;; --------------------- MODIFY 3DFACE EDGE VISIBILITY FLAG -----------------;
  146.  
  147. (defun modfce (ss pt / n1 e1 e0 p0 b1 b2 b3) 
  148.   (setq n1 0)
  149.   (repeat (sslength ss) 
  150.     (setq e1 (entget (ssname ss n1)) 
  151.           e0 (getval -1 e1))
  152.     (ssadd e0 faclst) 
  153.     (mapcar '(lambda (j k) (set j (getval k e1))) 
  154.             '(p1 p2 p3 p4) 
  155.             '(10 11 12 13)) 
  156.     (setq p0 (if (equal (distance p3 p4) 0 1e-8) 
  157.                (mapcar '(lambda (j k l) (/ (+ j k l) 3)) p1 p2 p3) 
  158.                (mapcar '(lambda (j k l m) (/ (+ j k l m) 4)) p1 p2 p3 p4)
  159.              ))
  160.     (setq b1 (getval 70 e1) 
  161.           b2 (cond ((equal pt (inters p0 pt p1 p2) h1) 1) 
  162.                ((equal pt (inters p0 pt p2 p3) h1) 2) 
  163.                ((equal pt (inters p0 pt p3 p4) h1) 4) 
  164.                ((equal pt (inters p0 pt p4 p1) h1) 8) 
  165.                (T 0)
  166.              ) 
  167.           b3 (+ b1 (if (= (logand b1 b2) b2) 
  168.                      (- b2) 
  169.                      b2
  170.                    )
  171.              ) 
  172.           e1 (shohdn (entmod (subst (cons 70 b3) (assoc 70 e1) e1))) 
  173.           n1 (1+ n1))
  174.   ) 
  175.   T
  176. ) 
  177. ;;; ------------------------------ MAIN PROGRAM ------------------------------;
  178.  
  179. (defun c:EDGE (/ lisp-er s1 o1 g1 a1 v1 h1 u1 faclst c1 r1 t1 ss pt n e n1) 
  180.   (setq lisp-er *error* 
  181.         *error* edge-er 
  182.         s1 (getvar "cmdecho") 
  183.         o1 (getvar "osmode") 
  184.         g1 (getvar "gridmode") 
  185.         a1 (getvar "aperture") 
  186.         v1 (getvar "splframe") 
  187.         u1 (getvar "ucsfollow") 
  188.         h1 (/ (getvar "viewsize") 100) 
  189.         faclst (ssadd) 
  190.         c1 7 
  191.         r1 T)
  192.   (setvar "cmdecho" 0)
  193.   (command "_.UNDO" "_GROUP") 
  194.   (setvar "osmode" 2)
  195.   (setvar "gridmode" 0)
  196.   (setvar "aperture" 5)
  197.   (setvar "splframe" 1)
  198.   (setvar "ucsfollow" 0)
  199.   (command "_.UCS" "_W") 
  200.   (while r1 
  201.     (initget "Visualizar") 
  202.     (setq t1 (getpoint "\nVisualizar/<designar arista>: ") 
  203.           r1 (cond ((eq t1 "Visualizar") (dsply)) 
  204.                ((eq (type t1) 'LIST) (setq ss (getfce t1))
  205.                 (cond ((null ss) (princ " No se han encontrado aristas 3DCARA.")) 
  206.                   ((= (sslength ss) 0) (princ " Este no es un objeto 3DCARA.")) 
  207.                   (t (modfce ss t1))
  208.                 )
  209.                ) 
  210.                (T nil)
  211.              ))
  212.   ) 
  213.   (command "_.UCS" "_P") 
  214.   (setvar "osmode" o1)
  215.   (setvar "gridmode" g1)
  216.   (setvar "aperture" a1)
  217.   (setvar "splframe" v1)
  218.   (setvar "ucsfollow" u1)
  219.   (command "_.UNDO" "_E") 
  220.   (setvar "cmdecho" s1)
  221.   (setq n1 -1)
  222.   (repeat (sslength faclst) 
  223.     (redraw (entupd (ssname faclst (setq n1 (1+ n1)))))
  224.   ) 
  225.   (setq *error* lisp-er)
  226.   (prin1)
  227. ) 
  228.  
  229. ;;; --------------------------------------------------------------------------;
  230.  
  231.