ATComputers Catalog/AutoCont+ATcomp.bin/Data/GameLib.dcr/00006_Inventur.ls

Text File | 2001-08-24 | 5.0 KB | 186 lines

on HdleLeistenSteuerung me
  global _anhang, _LeisteOffen, _LeistenPos, _Lautstaerke
  tell the stage
    if rollover(me.spriteNum) then
      sprite(me.spriteNum - 1).blend = 0
      sprite(me.spriteNum).blend = 100
      sprite(me.spriteNum + 14).blend = 100
      if not _LeisteOffen then
        if the mouseDown and _anhang then
          tell sprite(1)
            HdleLeisteOeffnen(1)
          end tell
        else
          Cursorwechsel("Hand")
        end if
      end if
    else
      if sprite(me.spriteNum).blend = 100 then
        if _LeisteOffen then
          set the volume of sound 5 to _Lautstaerke - 80
          puppetSound(5, "LeisteSchliessen")
        end if
        sprite(me.spriteNum - 1).blend = 100
        sprite(me.spriteNum).blend = 0
        sprite(me.spriteNum + 14).blend = 0
        if not (the mouseDown and _anhang) then
          Cursorwechsel("back")
        end if
        repeat with i = 5 to 17
          sprite(i).visible = 0
          sprite(i).puppet = 0
        end repeat
        sprite(me.spriteNum).puppet = 0
        _LeisteOffen = 0
        _LeistenPos = EMPTY
      end if
    end if
  end tell
end

on HdleLeisteOeffnen zus
  global _Objektliste, _ObjFolge, _LeistenPos, _LeisteOffen, _leerFeldpos, _Lautstaerke
  X = 0
  _leerFeldpos = X
  tell the stage
    repeat with i = 1 to _Objektliste.count
      if _Objektliste[i] = 1 then
        X = X + 1
        if X < 14 then
          nam = _ObjFolge[i]
          sprite(X + 4).member = nam
        end if
      end if
    end repeat
    if (zus = 1) and (X < 13) then
      X = X + zus
      sprite(X + 4).blend = 0
      _leerFeldpos = X
    end if
    if X > 13 then
      X = 13
    end if
    if X > 0 then
      set the volume of sound 5 to _Lautstaerke - 80
      puppetSound(5, "LeisteOeffnen")
      repeat with i = 1 to X
        sprite(i + 4).visible = 1
      end repeat
      _LeistenPos = sprite(4).locH - integer(X * 49) - 2
      _LeisteOffen = 1
    end if
  end tell
end

on HdleZielDown me
  global _anhang, _Kanal, _ObjFolge, _Objektliste, _FlagObj
  _Kanal = me.spriteNum
  tell the stage
    nam = sprite(_Kanal).member.name
    pos = getOne(_ObjFolge, nam)
    if (_Kanal > 0) and (pos > 0) then
      _anhang = 20
      Cursorwechsel("HandZu")
      sprite(20).member = sprite(_Kanal).member
      sprite(_Kanal).blend = 0
      sprite(_Kanal).member = "Zielfelder"
      sprite(20).visible = 1
      sprite(20).loc = point(the mouseH, the mouseV)
      sprite(_anhang).locZ = 98
      _FlagObj = _Objektliste[pos]
      _Objektliste[pos] = -1
    end if
  end tell
end

on HdleZielUp me
  global _Objektliste, _ObjFolge, _AktSeite, _anhang, _Kanal, _FlagObj, _LeisteOffen, _leerFeldpos
  tell the stage
    nam = sprite(20).member.name
    pos = getOne(_ObjFolge, nam)
    if pos > 0 then
      _Objektliste[pos] = _FlagObj
      _FlagObj = 0
      member("Status").text = _AktSeite
      sprite(_anhang).locZ = _anhang
      sprite(20).visible = 0
      sprite(20).puppet = 0
      Cursorwechsel("back")
      if rollover(_Kanal) or _LeisteOffen then
        if _leerFeldpos = 0 then
          sprite(_Kanal).member = sprite(20).member
          sprite(_Kanal).blend = 100
        else
          sprite(_leerFeldpos + 4).member = sprite(20).member
          sprite(_leerFeldpos + 4).blend = 100
          _leerFeldpos = 0
        end if
      else
        repeat with i = 50 to 60
          if rollover(i) and (sprite(i).member.name contains nam) then
            ObjimZiel(nam)
            exit repeat
          end if
        end repeat
      end if
      _anhang = 0
      _Kanal = 0
    end if
  end tell
end

on HdleObjMouseDown me, pKanal, PObjName
  global _anhang, _Kanal
  if _Kanal > 0 then
    _anhang = 20
    tell the stage
      Cursorwechsel("HandZu")
      sprite(_Kanal).visible = 0
      sprite(pKanal).visible = 0
      sprite(20).member = PObjName
      sprite(20).visible = 1
      sprite(20).loc = point(the mouseH, the mouseV)
      sprite(_anhang).locZ = 98
    end tell
  end if
end

on HdleObjMouseUp me, pKanal, PObjName, pZusatz
  global _Objektliste, _ObjFolge, _AktSeite, _anhang, _Kanal, _leerFeldpos
  if _anhang > 0 then
    tell the stage
      member("Status").text = _AktSeite
      sprite(_anhang).locZ = _anhang
      sprite(20).visible = 0
      sprite(20).puppet = 0
      Cursorwechsel("back")
      abgesetzt = 0
      repeat with i = 5 to 17
        if not sprite(i).visible then
          exit repeat
        end if
        if rollover(i) and (_leerFeldpos > 0) then
          abgesetzt = 1
          pos = getOne(_ObjFolge, PObjName)
          _Objektliste[pos] = 1
          sprite(_leerFeldpos + 4).member = PObjName
          sprite(_leerFeldpos + 4).blend = 100
          _leerFeldpos = 0
          if pZusatz then
            ObjinLeiste(PObjName)
          end if
          exit repeat
        end if
      end repeat
      if not abgesetzt then
        sprite(_Kanal).visible = 1
        sprite(pKanal).visible = 1
      end if
      sprite(20).visible = 0
      sprite(20).puppet = 0
      _anhang = 0
      _Kanal = 0
    end tell
  end if
end