Software One-Stop 3/BOOTCDROM.iso/install/scsi400/install.bat

DOS Batch File | 1995-10-19 | 1.2 KB | 43 lines

@echo ╔═══════════════════════════╗
@echo ║  EZ-SCSI is initializing. ║
@echo ║  Please wait...           ║
@echo ╚═══════════════════════════╝
@echo off
if NOT exist ezscsi.ex_ goto chgdrive
if NOT exist ezscsi.cw_ goto chgdrive
if NOT exist ezscsi.hl_ goto chgdrive

mkdir c:\ezscsi.tmp > nul

for %%f in (ez*.??_) do expand %%f c:\ezscsi.tmp > nul
for %%f in (c:\ezscsi.tmp\*.ex_) do rename %%f *.exe
for %%f in (c:\ezscsi.tmp\*.cw_) do rename %%f *.cwa
for %%f in (c:\ezscsi.tmp\*.hl_) do rename %%f *.hlp
for %%f in (c:\ezscsi.tmp\*.ez_) do rename %%f *.ez

if NOT exist c:\ezscsi.tmp\ezscsi.exe goto fail
if NOT exist c:\ezscsi.tmp\ezscsi.cwa goto fail
if NOT exist c:\ezscsi.tmp\ezscsi.hlp goto fail
if NOT exist c:\ezscsi.tmp\*.ez goto fail
c:\ezscsi.tmp\ezscsi %1 %2 %3 %4
goto success

:fail
@echo.
@echo Unable to decompress the installation utility to your hard drive.
@echo Please make sure your C: drive has at least 770K of free disk space.
@echo.

:success
for %%f in (c:\ezscsi.tmp\*.*) do del %%f
rmdir c:\ezscsi.tmp
goto end

:chgdrive
@echo.
@echo Please change to the drive and directory where the installation program
@echo resides, then type INSTALL.
@echo.

:end