home *** CD-ROM | disk | FTP | other *** search
/ Crazy Collection 12 / CC-12_1.iso / update / doompack / data.a00 / DMS015.ZIP / DMS015.ASM next >
Encoding:
Assembly Source File  |  1995-06-19  |  10.4 KB  |  406 lines
  1. ;---------------------------------------------------------------------------
  2. ;
  3. ; DMS   v0.12ß          Instant 180-degree turns in Doom!
  4. ; 
  5. ;   Copyright (c) Tom Klok and Dave 'Zoid' Kirsch         August, 1994
  6. ;
  7. ; DMS   v0.13      Support for keyboard added.
  8. ; DMS   v0.15ß     Toggle key to disable/enable mouse Y movement added.
  9. ;       Modifications by Lincoln Yeoh. 
  10. ;
  11. ;   Freely distributable as long as copyright and attributions
  12. ;   are maintained.
  13. ;
  14. ;   a344@mindlink.bc.ca, tom@auggy.mlnet.com
  15. ;   zoid@mindlink.bc.ca, zoid@grog.mlnet.com
  16. ;
  17. ;---------------------------------------------------------------------------
  18.  
  19.         .286
  20.  
  21. bk              equ     8
  22. ht              equ     9
  23. lf              equ     10
  24. ff              equ     12
  25. cr              equ     13
  26. eof             equ     26
  27. eos             equ     '$'
  28.  
  29. mouse_vector    equ     033h
  30. _buttons        equ     00003h
  31. _mickeys        equ     0000Bh
  32. _query          equ     0DEADh
  33. chk_response    equ     0D00Dh
  34. chk_version     equ     0012Ah
  35.  
  36. dos_vector      equ     021h
  37. _outstr         equ     00900h
  38. _getvec         equ     03500h + mouse_vector
  39. _setvec         equ     02500h + mouse_vector
  40. _tsr            equ     03100h
  41. _free           equ     04900h
  42. _exit           equ     04C00h
  43. _exit1          equ     _exit + 1
  44.  
  45. env_offset      equ     0002ch
  46. tail_buff       equ     00081h
  47.  
  48. turn_90         equ     1463
  49. turn_180        equ     turn_90 * 2
  50. turn_270        equ     -turn_90
  51. button_left     equ     1
  52. button_right    equ     2
  53. button_mid      equ     4
  54. button_none     equ     8               ; Any four button mice for PCs? 
  55.  
  56. msdos           macro   name, val
  57.         ifdef   &name
  58.         mov     ax, &name
  59.         ifdef   &val
  60.         mov     dx, offset &val
  61.         endif
  62.         endif
  63.         int     dos_vector
  64.         endm
  65.  
  66. ;---------------------------------------------------------------------------
  67.  
  68. code_seg        segment public
  69.         assume  cs:code_seg, ds:nothing, es:nothing
  70.         org     00100h
  71.  
  72. dms:            jmp     install
  73.  
  74. ;---------------------------------------------------------------------------
  75.  
  76.         align   4
  77. old_vector:     db      'oldv'
  78.         ; +x is right, +y is backwards
  79. newmickeysx     dw      0               ; if non-zero, we're going to pass
  80. newmickeysy     dw      0               ; if non-zero, we're going to pass
  81. mickeyset       db      0
  82.  
  83. ;DON'T CHANGE ORDER OF FOLLOWING LINES OR INSERT ANYTHING IN BETWEEN
  84.  
  85. button          db      0               ; 1 = left, 2 = right, 4 = middle
  86. flipkeydwn      db      52              ;Default set to .
  87. flipkeyup       db      52+128
  88. mvtogkeydwn     db      45              ;Toggle key to disable mouse f/b.
  89. mvtogkeyup      db      45+128          ;Key set to X
  90. ; that's it.                                         
  91.  
  92. keypressed      db      0
  93. mvlock          db      0               ;Disable mouse forward/backward?
  94. togpressed      db      0
  95. oldal           db      0
  96. ;---------------------------------------------------------------------------
  97.  
  98. dms_proc:       cmp     ax, _buttons            ; get button info?
  99.         je      getbutton
  100.  
  101.         cmp     ax, _mickeys            ; get mickeys?
  102.         jne     nopemick
  103.         jmp      getmickeys
  104. nopemick:
  105.         cmp     ax, _query              ; installation check?
  106.         jne     old_handler
  107.  
  108.         mov     ax, chk_response        ; yes, we're here!
  109.         mov     bx, chk_version
  110.         mov     di, offset button
  111.         iret
  112.  
  113. old_handler:
  114.         jmp     dword ptr cs:[old_vector]
  115.  
  116. getbutton:      ; call the mouse handler (we're going to change it)
  117.         ; But first check the keyboard!
  118.         pushf
  119.         mov     cs:[oldal], al
  120.         in      al,060h
  121.         cmp     al,flipkeydwn
  122.         jne     notit
  123.         cmp     cs:[keypressed], 0
  124.         jnz     getnkey                  ; If key hasn't been lifted since 
  125.                     ; the last flip, don't keep flipping!
  126.         mov     cs:[newmickeysx], turn_180
  127.         inc     cs:[keypressed]          ; Okay it's  down now
  128.         jmp     getnkey
  129.         
  130. notit:
  131.         cmp     al,flipkeyup
  132.         jne     getnkey
  133.  
  134. ; flipkey has been released
  135.  
  136.         mov     cs:[keypressed], 0       ; So flip on next flipkeydwn
  137. getnkey:         
  138.         cmp     al,mvtogkeydwn
  139.         jne     notit2
  140.         cmp     cs:[togpressed],0
  141.         jnz     chkbkey
  142.         xor     cs:[mvlock],1
  143.         inc     cs:[togpressed]
  144.         jmp     chkbkey
  145. notit2:
  146.         cmp     al,mvtogkeyup
  147.         jne     chkbkey
  148.         mov     cs:[togpressed],0
  149. chkbkey:
  150.         nop
  151. getbut:
  152.         mov     al, cs:[oldal]
  153.         call    dword ptr cs:[old_vector]
  154.  
  155.         mov     al, cs:[button]
  156.         xor     bl, al
  157.         test    bl, al                  ; test for button set
  158.         jnz     nomickey
  159.  
  160.         ; button(s) were pressed... are we debouncing?
  161.  
  162.         cmp     cs:[mickeyset], 0
  163.         jnz     doiret                  ; debouncing, so ignore it
  164.  
  165.         ; set up our fake mickeys
  166.  
  167.         mov     cs:[newmickeysx], turn_180
  168.         inc     cs:[mickeyset]          ; debouce next time
  169.         iret
  170.  
  171. nomickey:
  172.         xor     bl, al
  173.         mov     cs:[mickeyset], 0       ; not debouncing next time
  174.         iret
  175.  
  176. getmickeys:     ; call the mouse handler (we're going to change it)
  177.  
  178.         pushf
  179.         call    dword ptr cs:[old_vector]
  180.  
  181.         add     cx, cs:[newmickeysx]    ; zoot!  do the turn
  182.         mov     cs:[newmickeysx], 0
  183.         cmp     cs:[mvlock],0
  184.         jz      doiret                 ; No lock- mouse ymove enabled
  185.         mov     dx,0
  186.                 
  187. doiret:         iret
  188.  
  189. end_of_tsr:
  190.  
  191. ;---------------------------------------------------------------------------
  192.  
  193. ttl:            db      "DMS v0.12ß (c) "
  194.         db      " Tom Klok/Dave 'Zoid' Kirsch",cr,lf
  195.         db      "DMS v0.13 "
  196.         db      ??date
  197.         db      " keyboard support added by Lincoln Yeoh.",cr,eos
  198. keypls:         db      cr,lf,"Please press your 180-flip key or press Esc for the default '.' "
  199.         db      cr,lf,eos
  200. keypls2:        db      cr,lf,"Please press your y-toggle key or press Esc for the default 'X' "
  201.         db      cr,lf,eos
  202. keynotok:       db      "Sorry, extended keys not supported!",cr,lf,eos
  203. keyset:         db      "Alright! Let's get going!",cr,lf,eos
  204. welcome:        db      ': installed!',cr,lf,eos
  205. update_str:     db      ': buttons updated.',cr,lf,eos
  206. usage_str:      db      cr,lf,lf,"Usage: DMS -[l][m][r][n] where LMR represent "
  207.         db      "Left, Mid, Right mouse buttons.",cr,lf
  208.         db      "And N for none of the above...",cr,lf
  209.         db      "The default button selection is '-r' for Right."
  210.         db      cr,lf,lf,"Freely distributable.  "
  211.         db      "Queries or comments to a344@mindlink.bc.ca."
  212. crlfeos         db      cr,lf,eos
  213. buttons_str     db      "Mouse buttons to activate: ",eos
  214. left_str        db      "left+",eos
  215. middle_str      db      "middle+",eos
  216. right_str       db      "right+",eos
  217. none_str        db      "NONE ",eos
  218. backup_str      db      bk,"."
  219.         db      cr,lf,eos
  220.  
  221. ;---------------------------------------------------------------------------
  222.  
  223. install:
  224.         msdos   _outstr, ttl
  225.  
  226.         ; chk command line for mouse button preferences
  227.  
  228.         mov     si, tail_buff+1
  229. chk_cmd:
  230.         lodsb
  231.  
  232.         cmp     al, cr          ; is it the terminator?
  233.         je      cmd_done
  234.         cmp     al, 0
  235.         je      cmd_done
  236.  
  237.         cmp     al, ' '
  238.         je      chk_cmd
  239.         cmp     al, '-'
  240.         je      chk_cmd
  241.         cmp     al, '/'
  242.         je      chk_cmd
  243.  
  244.         and     al, 0dfh        ; to uppercase
  245.  
  246.         cmp     al, 'L'
  247.         jne     next2
  248.         or      cs:[button], button_left
  249.         jmp     chk_cmd
  250. next2:
  251.         cmp     al, 'R'
  252.         jne     next3
  253.         or      cs:[button], button_right
  254.         jmp     chk_cmd
  255. next3:
  256.         cmp     al, 'M'
  257.         jne     next4
  258.         or      cs:[button], button_mid
  259.         jmp     chk_cmd
  260. next4:                                  ; For those who don't want to use mouse
  261.         cmp     al, 'N'
  262.         jne     show_usage
  263.         or      cs:[button], button_none
  264.         jmp     chk_cmd
  265. show_usage:
  266.         msdos   _outstr, usage_str
  267.         msdos   _exit1
  268. cmd_done:
  269.         cmp     cs:[button], 0
  270.         jne     moreinstall
  271.         or      cs:[button], button_right
  272. moreinstall:
  273.         msdos   _outstr, keypls
  274. waitup:
  275.         in      al,060h
  276.         cmp     al,128
  277.         jb     waitup
  278.         cmp     al,224
  279.         je      waitk
  280. waitdwn:
  281.         in      al,060h
  282.         cmp     al,224
  283.         je      waitk
  284.         cmp     al,128
  285.         jnb     waitdwn
  286.         jmp     keyok
  287. waitk:
  288.         in      al,060h
  289.         cmp     al,224
  290.         je     waitk
  291.         msdos   _outstr, keynotok
  292.         jmp     moreinstall
  293. keyok:
  294.         cmp     al,1
  295.         je      waitup2
  296.         mov     cs:[flipkeydwn],al
  297.         add     al,128
  298.         mov     cs:[flipkeyup],al
  299. waitup2:
  300.         in      al,060h
  301.         cmp     al,128
  302.         jb     waitup2
  303.         msdos   _outstr, keyset
  304. moreinstallB:
  305.         msdos   _outstr, keypls2
  306. waitupB:
  307.         in      al,060h
  308.         cmp     al,128
  309.         jb     waitupB
  310.         cmp     al,224
  311.         je      waitkB
  312. waitdwnB:
  313.         in      al,060h
  314.         cmp     al,224
  315.         je      waitkB
  316.         cmp     al,128
  317.         jnb     waitdwnB
  318.         jmp     keyokB
  319. waitkB:
  320.         in      al,060h
  321.         cmp     al,224
  322.         je     waitkB
  323.         msdos   _outstr, keynotok
  324.         jmp     moreinstallB
  325. keyokB:
  326.         cmp     al,1
  327.         je      waitup2B
  328.         mov     cs:[mvtogkeydwn],al
  329.         add     al,128
  330.         mov     cs:[mvtogkeyup],al
  331. waitup2B:
  332.         in      al,060h
  333.         cmp     al,128
  334.         jb     waitup2B
  335.         msdos   _outstr, keyset
  336.  
  337.         mov     ax, _query
  338.         int     mouse_vector
  339.         cmp     ax, chk_response
  340.         je      change_button
  341.  
  342.         msdos   _outstr, welcome
  343.  
  344.         msdos   _getvec                 ; es:bx <- int 33h pointer
  345.         mov     word ptr [old_vector], bx
  346.         mov     word ptr [old_vector + 2], es
  347.         msdos   _setvec, dms_proc       ; int 33h pointer <- ds:dx
  348.  
  349.         call    display_buttons
  350.  
  351.         mov     ax, ds:[env_offset]     ; get envt segment
  352.         mov     es, ax
  353.         msdos   _free
  354.  
  355.         mov     dx, offset end_of_tsr
  356.         add     dx, 15
  357.         shr     dx, 4
  358.         msdos   _tsr
  359.  
  360. change_button:
  361.         push    di
  362.         msdos   _getvec                 ; es:bx <- int 33h pointer
  363.         mov     al, cs:[button]
  364.         pop     di
  365.         mov     es:[di], al
  366.         mov     al, cs:[flipkeydwn]
  367.         mov     es:[di+1], al
  368.         mov     al, cs:[flipkeyup]
  369.         mov     es:[di+2], al
  370.         mov     al, cs:[mvtogkeydwn]
  371.         mov     es:[di+3], al
  372.         mov     al, cs:[mvtogkeyup]
  373.         mov     es:[di+4], al
  374.         msdos   _outstr, update_str
  375.         call    display_buttons
  376.         msdos   _exit1
  377.  
  378. display_buttons:
  379.         msdos   _outstr, buttons_str
  380.         test    cs:[button], button_none
  381.         je      gotbuttons
  382.         msdos   _outstr, none_str       
  383.         jmp     db3
  384. gotbuttons:
  385.         test    cs:[button], button_left
  386.         je      db1
  387.         msdos   _outstr, left_str
  388. db1:
  389.         test    cs:[button], button_mid
  390.         je      db2
  391.         msdos   _outstr, middle_str
  392. db2:
  393.         test    cs:[button], button_right
  394.         je      db3
  395.         msdos   _outstr, right_str
  396. db3:
  397.         msdos   _outstr, backup_str
  398.         ret
  399.  
  400.  
  401. ;---------------------------------------------------------------------------
  402.  
  403. code_seg        ends
  404.         end     dms
  405.  
  406.