home *** CD-ROM | disk | FTP | other *** search
/ PC Professionell 2006 October / PCpro_2006_10.ISO / files / wininside / ubcd / ubcd34-basic.exe / ubcd34-basic.iso / images / fdubcd.img / AUTOEXEC.BAT next >
Encoding:
DOS Batch File  |  2006-02-03  |  8.4 KB  |  228 lines
  1. @set debug=
  2. @if exist \bin\kbfl.com \bin\kbfl
  3. @if errorlevel 1 set debug=y
  4. @if exist \debug.txt set debug=y
  5. @if "%debug%"=="" echo off
  6. if "%1"==":" if not "%2"=="" goto %2
  7. set prompt=$p$g
  8. set ramdrv=
  9. set path=\bin;\
  10. if "%os%"=="" set os=ms
  11. if exist $MMXXXX0 set ldh=loadhigh
  12. if exist EMMXXXX0 set ldh=loadhigh
  13. if exist EMMQXXX0 set ldh=loadhigh
  14. if exist UMBPCIXX set ldh=loadhigh
  15. if "%persz%"=="" set persz=512
  16. if exist %ramdrv%\bin\fix27.com %ldh% %ramdrv%\bin\fix27.com
  17. if not exist %ramdrv%\bin\peruse.com goto _perq1
  18. if not exist XMSXXXX0 if not exist EMMQXXX0 goto _perq1
  19. if "%persz%"=="0" goto _perq1
  20. %ldh% peruse.com /x%persz% >nul
  21. :_perq1
  22. set persz=
  23. :_about
  24. if "%1"=="" if exist %ramdrv%\bin\2peruse.* goto _abdone
  25. ver /r
  26. echo.
  27. echo MODBOOT v2.6, Copyright (C) by Bart Lagerweij
  28. echo Bart's Modular Boot Disk - http://www.nu2.nu/bootdisk/modboot/
  29. echo This program is free software, but WITHOUT ANY WARRANTY!
  30. echo An official license is being made for this software...
  31. echo See http://www.nu2.nu/license/ for more details.
  32. echo.
  33. echo NwDsk 3.35 Copyright (C) 2002-2006 Erwin Veermans
  34. echo   mailto:NwDsk@Veder.com
  35. echo   http://www.veder.com/nwdsk/
  36. echo NetWare Dos Client 16/32-bit (VLM/NLM) IPX + IP
  37. if "%1"==":" if not "%2"=="" if exist %ramdrv%\bin\diskid.txt type %ramdrv%\bin\diskid.txt
  38. if "%1"==":" if not "%2"=="" goto _end
  39. :_abdone
  40. set srcdrv=
  41. if not exist %ramdrv%\bin\bootdrv.com goto _nobdrv
  42. %ramdrv%\bin\bootdrv.com
  43. :_dummy1
  44. if not "%os%"=="dr" set _benny=H
  45. for %%i in (Z Y X W V U T S R Q P O N M L K J I H G F E D C B A) do if not errorlevel %_benny%%%i set srcdrv=%%i:
  46. set _benny=
  47. :_nobdrv
  48. if "%srcdrv%"=="" set srcdrv=A:
  49. set _srcdrv=%srcdrv%
  50. set _memdisk=
  51. set _linux=
  52. if not exist %ramdrv%\bin\getargs.* goto _ngetargs
  53. getargs >nul
  54. if errorlevel 3 if not errorlevel 4 set _memdisk=3
  55. if errorlevel 2 if not errorlevel 3 set _memdisk=2
  56. if errorlevel 1 if not errorlevel 2 set _memdisk=1
  57. :_ngetargs
  58. if "%_memdisk%"=="" goto _nmemdsk
  59. echo AUTOEXEC: MEMDISK(%_memdisk%)
  60. getargs M >nul
  61. if errorlevel 52 if not errorlevel 53 set _linux=4
  62. if errorlevel 51 if not errorlevel 52 set _linux=3
  63. if errorlevel 50 if not errorlevel 51 set _linux=2
  64. if errorlevel 49 if not errorlevel 50 set _linux=1
  65. if not "%_linux%"=="" echo AUTOEXEC: (%_linux%)LINUX
  66. if not "%_linux%"=="1" goto _nmemdsk
  67. if exist %ramdrv%\bin\modboot.* goto _nmemdsk
  68. :_sys1
  69. echo AUTOEXEC: Probing B:
  70. getargs 1
  71. if errorlevel 1 goto _sysb
  72. goto _sys2
  73. :_sysb
  74. for %%i in (ldlinux.sys syslinux.cfg memdisk.) do if not exist B:\%%i goto _sys2
  75. if not exist B:\bin\modboot.* goto _sys2
  76. set srcdrv=B:
  77. if not "%srcdrv%"=="%_srcdrv%" goto _nmemdsk
  78. :_sys2
  79. echo AUTOEXEC: Probing C:
  80. getargs 2
  81. if errorlevel 1 goto _sysc
  82. goto _nmemdsk
  83. :_sysc
  84. for %%i in (ldlinux.sys syslinux.cfg memdisk.) do if not exist C:\%%i goto _nmemdsk
  85. if not exist C:\bin\modboot.* goto _nmemdsk
  86. set srcdrv=C:
  87. if not "%srcdrv%"=="%_srcdrv%" goto _nmemdsk
  88. :_nmemdsk
  89. %srcdrv%
  90. cd \
  91. echo AUTOEXEC: Booted drive is %srcdrv%
  92. :_goram
  93. if not exist %srcdrv%\bin\2peruse.* if exist %srcdrv%\diskid.txt type diskid.txt
  94. path=%srcdrv%\bin;%srcdrv%\
  95. if "%config%"=="CLEAN" goto _end
  96. if "%config%"=="0" goto _end
  97. if exist EMMQXXX0 goto _xmsok
  98. if exist XMSXXXX0 goto _xmsok
  99. echo.
  100. echo AUTOEXEC: No XMS manager installed (himem.sys)
  101. goto _abort
  102. :_xmsok
  103. :_ramsrc
  104. if exist %_srcdrv%\etc\autoset.bat if not exist %srcdrv%\etc\autoset.bat call %_srcdrv%\etc\autoset.bat
  105. if exist %ramdrv%\etc\autoset.bat call %ramdrv%\etc\autoset.bat
  106. set ramdrv=
  107. if "%ramltr%"=="" set ramltr=Q:
  108. if "%ramsz%"=="" set ramsz=8192
  109. set persz=
  110. if "%ramsz%"=="0" set ramdrv=%srcdrv%
  111. if "%ramsz%"=="0" if not "%_srcdrv%"=="%srcdrv%" set path=%_srcdrv%\bin;%_srcdrv%\;%path%
  112. if not "%ramdrv%"=="" goto _ramok
  113. set ramdrv=%ramltr%
  114. if "%ramdrv%"=="" set ramdrv=Q:
  115. for %%i in (unzip lha extract unuharcd) do if exist %srcdrv%\bin\%%i.exe goto _extracok
  116. echo.
  117. echo AUTOEXEC: Missing file "%srcdrv%\bin\extract.exe"
  118. goto _abort
  119. :_extracok
  120. for %%i in (unzip lha extract unuharcd) do if exist %ramdrv%\bin\%%i.exe goto _ramok
  121. if exist %srcdrv%\bin\xmsdsk.exe goto _xdskok
  122. if exist %srcdrv%\bin\shsurdrv.exe goto _xdskok
  123. echo.
  124. echo AUTOEXEC: Missing file "%srcdrv%\bin\extract.exe"
  125. goto _abort
  126. :_xdskok
  127. echo AUTOEXEC: Setting up Ramdisk at drive %ramdrv%
  128. if exist %srcdrv%\bin\xmsdsk.exe goto _xmsdsk
  129. shsurdrv /D:%ramsz%K,%ramdrv% /T /QQ
  130. if errorlevel 1 if not errorlevel 255 goto _ramok
  131. goto _abort
  132. :_xmsdsk
  133. xmsdsk %ramsz% %ramdrv% /y /t
  134. if errorlevel 1 goto _ramok
  135. goto _abort
  136. :_ramok
  137. if not exist %ramdrv%\etc\nul mkdir %ramdrv%\etc
  138. if not exist %ramdrv%\etc\profile\nul mkdir %ramdrv%\etc\profile
  139. set ramltr=
  140. if not exist %ramdrv%\bin\nul md %ramdrv%\bin
  141. if not exist %ramdrv%\tmp\nul md %ramdrv%\tmp
  142. set temp=%ramdrv%\tmp
  143. set tmp=%ramdrv%\tmp
  144. if not "%srcdrv%"=="%ramdrv%" copy %_srcdrv%\command.com %ramdrv%\bin >nul
  145. if not exist %ramdrv%\bin\command.com goto _dumlab1
  146. set comspec=%ramdrv%\bin\command.com
  147. :_dumlab1
  148. for %%i in (unzip lha extract unuharcd) do if exist %ramdrv%\bin\%%i.exe goto _skipcp
  149. echo AUTOEXEC: Copying %srcdrv%\bin and %srcdrv%\etc to %ramdrv%
  150. if exist %srcdrv%\bin\*.* copy %srcdrv%\bin\*.* %ramdrv%\bin\. >nul
  151. if not exist %ramdrv%\bin\emm386.exe if not exist %ramdrv%\bin\himem.exe if exist %_srcdrv%\bin\*.exe copy %_srcdrv%\bin\*.exe %ramdrv%\bin\. >nul
  152. if not exist %ramdrv%\bin\getargs.com if exist %_srcdrv%\bin\*.com copy %_srcdrv%\bin\*.com %ramdrv%\bin\. >nul
  153. if exist %srcdrv%\etc\*.* copy %srcdrv%\etc\*.* %ramdrv%\etc\. >nul
  154. if exist %srcdrv%\etc\profile\*.* copy %srcdrv%\etc\profile\*.* %ramdrv%\etc\profile\. >nul
  155. if not exist %ramdrv%\bin\extract.exe if not exist %ramdrv%\bin\unzip.exe if not exist %ramdrv%\bin\unuharcd.exe if not exist %ramdrv%\bin\lha.exe goto _abort
  156. :_skipcp
  157. if not "%srcdrv%"=="%ramdrv%" set path=%ramdrv%\bin;%ramdrv%\
  158. :_dumlab5
  159. if not "%debug%"=="" set xtrct=verbose
  160. if exist %srcdrv%\diskid.txt if not exist %ramdrv%\bin\diskid.txt copy %srcdrv%\diskid.txt %ramdrv%\bin\. >nul
  161. if exist %_srcdrv%\config.sys if not exist %ramdrv%\bin\config.sys copy %_srcdrv%\config.sys %ramdrv%\bin\. >nul
  162. if not exist %ramdrv%\bin\getargs.com goto _nargs
  163. getargs >%tmp%\_getargs.bat
  164. if exist %tmp%\_getargs.bat call %tmp%\_getargs.bat
  165. :_nargs
  166. set arcext=
  167. if exist %ramdrv%\bin\*.lzh set arcext=lzh
  168. if exist %ramdrv%\bin\*.zip set arcext=zip
  169. if exist %ramdrv%\bin\*.uha set arcext=uha
  170. if exist %ramdrv%\bin\*.cab set arcext=cab
  171. if not "%arcext%"=="zip" if not "%arcext%"=="cab" if not "%arcext%"=="lzh" if not "%arcext%"=="uha" goto _abort
  172. if not exist %ramdrv%\bin\share.* goto _nshare
  173. %ldh% %ramdrv%\bin\share >nul
  174. if errorlevel 2 %ramdrv%\bin\share >nul
  175. :_nshare
  176. if exist %ramdrv%\bin\modboot.bat goto _modboot
  177. if not exist %ramdrv%\bin\modboot.%arcext% goto _abort
  178. if not "%arcext%"=="zip" goto _nmodzip
  179. echo AUTOEXEC: Extractor UNZIP 5.51 (.zip) by Info-ZIP
  180. unzip.exe -o -C -qq %ramdrv%\bin\modboot.%arcext% -d %ramdrv%\
  181. if errorlevel 1 goto _unpackerr
  182. :_nmodzip
  183. if exist %ramdrv%\bin\modboot.bat goto _modboot
  184. if not "%arcext%"=="lzh" goto _nmodlzh
  185. echo AUTOEXEC: Extractor LHA 2.55e (.lzh) by Haruyasu Yoshizaki
  186. lha.exe x -a1 -m1 -n2 %ramdrv%\bin\modboot.%arcext% %ramdrv%\
  187. if errorlevel 1 goto _unpackerr
  188. :_nmodlzh
  189. if exist %ramdrv%\bin\modboot.bat goto _modboot
  190. if not "%arcext%"=="uha" goto _nmoduha
  191. echo AUTOEXEC: Extractor UNUHARCD 0.6b beta (.uha) by Uwe Herklotz
  192. unuharcd.exe x -y+ -o+ -t%ramdrv%\ %ramdrv%\bin\modboot.%arcext% >%tmp%\extract.out
  193. if errorlevel 1 goto _unpackerr
  194. :_nmoduha
  195. if exist %ramdrv%\bin\modboot.bat goto _modboot
  196. echo AUTOEXEC: Extractor EXTRACT 1.00.603.0 (.%arcext%) by Microsoft
  197. if exist %srcdrv%\bin\modboot.%arcext% goto _modbcabok
  198. echo.
  199. echo AUTOEXEC: Missing file "%srcdrv%\bin\modboot.%arcext%"
  200. goto _abort
  201. :_modbcabok
  202. extract /y /l %ramdrv%\ /e %srcdrv%\bin\modboot.%arcext% >%tmp%\extract.out
  203. if errorlevel 1 goto _unpackerr
  204. if exist %tmp%\extract.out del %tmp%\extract.out
  205. if exist %ramdrv%\bin\modboot.bat goto _modboot
  206. echo.
  207. echo AUTOEXEC: Missing file "%ramdrv%\bin\modboot.bat"
  208. goto _abort
  209. :_unpackerr
  210. if exist %tmp%\extract.out type %tmp%\extract.out
  211. if exist %tmp%\extract.out del %tmp%\extract.out
  212. echo.
  213. echo AUTOEXEC: Error while unpacking "%srcdrv%\bin\modboot.%arcext%"
  214. goto _abort
  215. :_modboot
  216. %ramdrv%
  217. cd \
  218. %ramdrv%\bin\modboot.bat
  219. :_abort
  220. :_error
  221. shift
  222. shift
  223. if not ""=="%1" echo AUTOEXEC: %1 %2 %3 %4 %5 %6 %7 %8
  224. echo AUTOEXEC: Aborted...
  225. echo.
  226. @rem pause
  227. :_end
  228.