home *** CD-ROM | disk | FTP | other *** search
/ PC Professionell 2005 February / PCpro_2005_02.ISO / files / tipps / shell / wlantest.cmd
Encoding:
Text File  |  2004-12-11  |  7.0 KB  |  215 lines
  1. ::Geheime Windows-Funktionen PCpro 02/2005 (jg)
  2. ::Dieses Programm fuehrt Netzwerktests mittels
  3. ::ping, ipconfig, nslookup und arp aus
  4. ::Details stehen in wlantest.log
  5. ::Dieser Abschnitt testet, ob ihr lokales Loopback erreichbar ist
  6. @echo off
  7. set /P r= IP-Adresse des Routers? 
  8. echo.
  9. echo **************************
  10. echo  Loopback-Test laeuft ...
  11. echo **************************
  12. (date /t & time /t) >> wlantest.log
  13. ping 127.0.0.1 >> wlantest.log
  14. IF "%ERRORLEVEL%"=="0" GOTO :GOODSTACK
  15. echo.
  16. echo Ihr lokales Loopback ist nicht erreichbar,
  17. echo dafuer kann es mehrere Gruende geben:
  18. echo.
  19. echo 1. Ihr TCP/IP-Stack funktioniert nicht richtig
  20. echo    Loesung: Installieren Sie das TCP/IP-Protokoll neu
  21. echo.
  22. echo 2. Ihre Netzwerkkarte funktioniert nicht richtig
  23. echo    Loesung: Installieren Sie die Treiber neu
  24. echo.
  25. echo Das Script wurde vorzeitig abgebrochen
  26. GOTO :END
  27. :GOODSTACK
  28. echo.
  29. echo TCP/IP-Stack ist ok
  30. echo.
  31. ::Dieser Abschnitt testet, ob Ihr Rechner eine gⁿltige IP-Adresse hat
  32. echo.
  33. echo ************************************************
  34. echo  Test, ob korrekte IP-Adresse vergeben wurde ...
  35. echo ************************************************
  36. ::Der Befehl ipconfig /all schreibt die detaillierte
  37. ::Netzwerkkonfiguration in die Log-Datei wlantest.log
  38. ipconfig /all >> wlantest.log
  39. ::Finde die Zeile mit dem Eintrag IP-Adresse und
  40. ::speichere sie in der Textdatei ipstore.txt
  41. ::Wichtig: Deaktivieren Sie alle anderen Wireless-Netzwerkadapter
  42. ::und entfernen Sie die Kabel von Ethernet-Anschluessen
  43. ::Der Befehl ipconfig sollte nur eine IP-Adresse liefern
  44. (ipconfig | find "IP-Adresse") > ipstore.txt
  45. ::Suche IP-Adresse in der Textzeile und lege
  46. ::Variable IP an
  47. FOR /F "tokens=2 delims=:" %%i in (ipstore.txt) do set IP=%%i
  48. ::IP-Adresse auf Muster xxx.xxx.xxx.xxx (15 Zeichen) kuerzen
  49. set IP=%IP:~1,15%
  50. ::Muster xxx.xxx aus IP-Adresse schneiden und als
  51. ::Variable IPTEST abspeichern
  52. set IPTEST=%IP:~0,7%
  53. ::Hat IPTEST den Wert 169.254?
  54. ::Falls ja, versuche neue IP-Adresse anzufordern
  55. ::Falls nein, gehe zum Test, ob IP-Adresse 0.0.0.0 ist
  56. IF /i %IPTEST% NEQ 169.254 GOTO :IPTEST2
  57. echo.
  58. echo Fehler bei Adresszuteilung per DHCP
  59. echo IP-Adresse %IP% ist nicht gueltig
  60. echo Neue IP-Adresse vom DHCP-Server anfordern ...
  61. ipconfig /renew
  62. ipconfig /all >> wlantest.log
  63. (ipconfig | find "IP-Adresse") > ipstore.txt
  64. FOR /F "tokens=2 delims=:" %%i in (ipstore.txt) do set IP=%%i
  65. set IP=%IP:~1,15%
  66. set IPTEST=%IP:~0,7%
  67. IF /i %IPTEST% NEQ 169.254 GOTO :IPTEST2
  68. echo.
  69. echo Fehler bei Adresszuteilung per DHCP
  70. echo IP-Adresse %IP% ist nicht gueltig
  71. echo Der DHCP-Server ist nicht erreichbar oder liefert keine korrekte IP-Adresse
  72. GOTO :END
  73. :IPTEST2
  74. ::Pruefe ob IP-Adresse gleich 0.0.0.0 ist
  75. ::Falls ja, Fehler bei der Netzwerkverbindung
  76. ::Falls nein, gueltige IP-Adresse ausgeben
  77. IF /i %IPTEST% NEQ 0.0.0.0 GOTO :IPVALID
  78. echo.
  79. echo Fehler bei Netzwerkverbindung oder doppelt vergebene IP-Adresse
  80. echo IP-Adresse %IP% nicht gueltig
  81. echo.
  82. echo Das Script wurde vorzeitig abgebrochen
  83. GOTO :END
  84. :IPVALID
  85. echo.
  86. echo IP-Adresse %IP% ist gueltig
  87. echo.
  88. ::Dieser Abschnitt testet die Erreichbarkeit der eigenen IP-Adresse
  89. echo.
  90. echo ***********************************
  91. echo  Test, ob IP-Adresse erreichbar ...
  92. echo ***********************************
  93. ::Ping-Anfrage an Ihren Rechner, alternativ kann
  94. ::statt COMPUTERNAME auch die IP-Adresse stehen
  95. ping %COMPUTERNAME% >> wlantest.log
  96. IF "%ERRORLEVEL%"=="0" GOTO :GOODIP
  97. echo.
  98. ::TCP/IP funktioniert und die IP-Adresse ist gueltig
  99. ::Ping funktioniert jedoch nicht
  100. ::Ein Fehler in der Routing-Tabelle k÷nnte ausschlaggebend sein
  101. ::Andere Moeglichkeit: Firewall blockt ICMP
  102. echo Ihre IP-Adresse %IP% ist nicht per ICMP erreichbar
  103. echo Moegliche Ursachen:
  104. echo.
  105. echo 1. Eine installierte Desktop-Firewall blockt ICMP-Pakete
  106. echo    Loesung: Erlauben Sie Pings in den Firewall-Einstellungen
  107. echo.
  108. echo 2. Ein Fehler in der Routing-Tabelle
  109. echo Loesung: Pruefen Sie folgende Eintraege
  110. ::Routing-Tabelle ausgeben
  111. route PRINT
  112. ::Schreibe Routing-Tabelle in die Log-Datei
  113. route PRINT >> wlantest.log
  114. echo.
  115. echo Das Script wurde vorzeitig abgebrochen
  116. GOTO :END
  117. :GOODIP
  118. echo.
  119. echo Ihre IP-Adresse %IP% ist erreichbar
  120. echo.
  121. ::Dieser Abschnitt testet ob der Router erreichbar ist
  122. echo.
  123. echo ***********************
  124. echo  Router-Test laeuft ...
  125. echo ***********************
  126. ping %r% >> wlantest.log
  127. IF "%ERRORLEVEL%"=="0" GOTO :GOODROUTER
  128. echo.
  129. echo Router bzw. Standard-Gateway %r% nicht erreichbar:
  130. echo.
  131. echo 1. Pruefen Sie Ihre Eingabe beim Script-Aufruf
  132. echo.
  133. echo 2. Pruefen Sie die Einstellungen fuer Standard-Gateway
  134. echo.
  135. echo 3. Pruefen Sie die Eintraege im ARP-Cache (Befehl arp /?)
  136. echo
  137. echo 4. Starten Sie das Netzwerk neu
  138. echo.
  139. ::Inhalt des ARP-Cache ausgeben
  140. arp -a
  141. ::Schreibt Inhalt des ARP-Cache in Log-Datei
  142. arp -a >> wlantest.log
  143. echo.
  144. echo Das Script wurde vorzeitig abgebrochen
  145. GOTO :END
  146. :GOODROUTER
  147. echo.
  148. echo Router %r% ist erreichbar
  149. echo.
  150. ::Dieser Abschnitt testet die Verbindung zu IP-Adressen im Internet
  151. echo.
  152. echo **************************************
  153. echo  Ping-Befehl auf IP-Adresse laeuft ...
  154. echo **************************************
  155. ::Hier schlaegt ein Test auf das Errorlevel
  156. ::unter UmstΣnden fehl. Der Grund: Ein funktionierender
  157. ::Router wird die Meldung "Zielnetz nicht erreichbar"
  158. ::liefern und Errorlevel auf 0 belassen
  159. ::Loesung: Ausgabe von Ping nach TimeToLive durchsuchen
  160. ping 192.0.34.163 | find "TTL=" && GOTO :GOODPING
  161. echo.
  162. echo 192.0.34.163 nicht erreichbar
  163. echo.
  164. echo Ping-Befehl auf alternative IP-Adresse laeuft ...
  165. ping 66.102.9.104 | find "TTL=" && GOTO :GOODPING
  166. echo.
  167. echo 66.102.9.104 auch nicht erreichbar
  168. echo.
  169. echo Pruefen Sie folgende Einstellungen:
  170. echo.
  171. echo 1. Router-Status im Konfigurationsmenue
  172. echo.
  173. echo 2. Netzwerkeinstellungen fuer Standard-Gateway  
  174. echo.
  175. echo Das Script wurde vorzeitig abgebrochen
  176. GOTO :END 
  177. :GOODPING
  178. echo.
  179. echo Webseiten lassen sich per Ping erreichen
  180. echo.
  181. ::Dieser Abschnitt testet die Erreichbarkeit von Webseiten
  182. echo.
  183. echo ***************************************
  184. echo  Ping-Befehl auf Domain-Namen laeuft...
  185. echo ***************************************
  186. ::Test, ob die Webseite der ICANN erreichbar ist
  187. ping www.icann.org | find "TTL=" && GOTO :GOODPINGDOMAIN
  188. echo.
  189. ::Webseite nicht erreichbar, zweiten Test starten
  190. echo DNS-Problem, teste zweite Webadresse
  191. echo.
  192. echo Ping-Befehl auf zweiten Domain-Namen laeuft...
  193. ping www.google.de | find "TTL=" && GOTO :GOODPINGDOMAIN
  194. echo.
  195. ::Es liegt ein DNS-Problem vor
  196. echo DNS-Problem bestaetigt
  197. echo.
  198. echo Testen Sie die DNS-Einstellungen per nslookup
  199. echo.
  200. echo siehe dazu auch wlantest.log
  201. nslookup >> wlantest.log
  202. echo. 
  203. echo Das Script wurde vorzeitig abgebrochen
  204. GOTO :END
  205. :GOODPINGDOMAIN
  206. echo.
  207. echo Gratulation: Webseiten lassen sich per Ping erreichen
  208. echo und DNS funktioniert, der Netzzugang ist ok.
  209. echo.
  210. echo Pruefen Sie Ihre Browser-Einstellungen
  211. echo falls die Internet-Verbindung auch jetzt
  212. echo nicht klappt - evtl. ist ein falscher Proxy-Server eingestellt.
  213. :END
  214. echo.
  215. echo ... Programm beendet -- Details siehe wlantest.log