home *** CD-ROM | disk | FTP | other *** search
/ PC Professionell 2004 December / PCpro_2004_12.ISO / files / webserver / xampp / xampp-tomcat-addon-1.4.9-installer.exe / catalina.bat < prev    next >
Encoding:
DOS Batch File  |  2004-08-28  |  7.3 KB  |  193 lines
  1. @echo off
  2. if "%OS%" == "Windows_NT" setlocal
  3. rem ---------------------------------------------------------------------------
  4. rem Start/Stop Script for the CATALINA Server
  5. rem
  6. rem Environment Variable Prequisites
  7. rem
  8. rem   CATALINA_HOME   May point at your Catalina "build" directory.
  9. rem
  10. rem   CATALINA_BASE   (Optional) Base directory for resolving dynamic portions
  11. rem                   of a Catalina installation.  If not present, resolves to
  12. rem                   the same directory that CATALINA_HOME points to.
  13. rem
  14. rem   CATALINA_OPTS   (Optional) Java runtime options used when the "start",
  15. rem                   "stop", or "run" command is executed.
  16. rem
  17. rem   CATALINA_TMPDIR (Optional) Directory path location of temporary directory
  18. rem                   the JVM should use (java.io.tmpdir).  Defaults to
  19. rem                   %CATALINA_BASE%\temp.
  20. rem
  21. rem   JAVA_HOME       Must point at your Java Development Kit installation.
  22. rem
  23. rem   JAVA_OPTS       (Optional) Java runtime options used when the "start",
  24. rem                   "stop", or "run" command is executed.
  25. rem
  26. rem   JSSE_HOME       (Optional) May point at your Java Secure Sockets Extension
  27. rem                   (JSSE) installation, whose JAR files will be added to the
  28. rem                   system class path used to start Tomcat.
  29. rem
  30. rem   JPDA_TRANSPORT  (Optional) JPDA transport used when the "jpda start"
  31. rem                   command is executed. The default is "dt_shmem".
  32. rem
  33. rem   JPDA_ADDRESS    (Optional) Java runtime options used when the "jpda start"
  34. rem                   command is executed. The default is "jdbconn".
  35. rem
  36. rem $Id: catalina.bat,v 1.9.2.1 2004/08/21 15:49:47 yoavs Exp $
  37. rem ---------------------------------------------------------------------------
  38.  
  39. rem Guess CATALINA_HOME if not defined
  40. set CURRENT_DIR=%cd%
  41. if not "%CATALINA_HOME%" == "" goto gotHome
  42. set CATALINA_HOME=%CURRENT_DIR%
  43. if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
  44. cd ..
  45. set CATALINA_HOME=%cd%
  46. cd %CURRENT_DIR%
  47. :gotHome
  48. if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
  49. echo The CATALINA_HOME environment variable is not defined correctly
  50. echo This environment variable is needed to run this program
  51. goto end
  52. :okHome
  53.  
  54. rem Get standard environment variables
  55. if exist "%CATALINA_HOME%\bin\setenv.bat" call "%CATALINA_HOME%\bin\setenv.bat"
  56.  
  57. rem Get standard Java environment variables
  58. if exist "%CATALINA_HOME%\bin\setclasspath.bat" goto okSetclasspath
  59. echo Cannot find %CATALINA_HOME%\bin\setclasspath.bat
  60. echo This file is needed to run this program
  61. goto end
  62. :okSetclasspath
  63. set BASEDIR=%CATALINA_HOME%
  64. call "%CATALINA_HOME%\bin\setclasspath.bat"
  65.  
  66. rem Add on extra jar files to CLASSPATH
  67. if "%JSSE_HOME%" == "" goto noJsse
  68. set CLASSPATH=%CLASSPATH%;%JSSE_HOME%\lib\jcert.jar;%JSSE_HOME%\lib\jnet.jar;%JSSE_HOME%\lib\jsse.jar
  69. :noJsse
  70. set CLASSPATH=%CLASSPATH%;%CATALINA_HOME%\bin\bootstrap.jar
  71.  
  72. if not "%CATALINA_BASE%" == "" goto gotBase
  73. set CATALINA_BASE=%CATALINA_HOME%
  74. :gotBase
  75.  
  76. if not "%CATALINA_TMPDIR%" == "" goto gotTmpdir
  77. set CATALINA_TMPDIR=%CATALINA_BASE%\temp
  78. :gotTmpdir
  79.  
  80. rem ----- Execute The Requested Command ---------------------------------------
  81.  
  82. echo Using CATALINA_BASE:   %CATALINA_BASE%
  83. echo Using CATALINA_HOME:   %CATALINA_HOME%
  84. echo Using CATALINA_TMPDIR: %CATALINA_TMPDIR%
  85. echo Using JAVA_HOME:       %JAVA_HOME%
  86.  
  87. set _EXECJAVA=%_RUNJAVA%
  88. set MAINCLASS=org.apache.catalina.startup.Bootstrap
  89. set ACTION=start
  90. set SECURITY_POLICY_FILE=
  91. set DEBUG_OPTS=
  92. set JPDA=
  93.  
  94. if not ""%1"" == ""jpda"" goto noJpda
  95. set JPDA=jpda
  96. if not "%JPDA_TRANSPORT%" == "" goto gotJpdaTransport
  97. set JPDA_TRANSPORT=dt_shmem
  98. :gotJpdaTransport
  99. if not "%JPDA_ADDRESS%" == "" goto gotJpdaAddress
  100. set JPDA_ADDRESS=jdbconn
  101. :gotJpdaAddress
  102. shift
  103. :noJpda
  104.  
  105. if ""%1"" == ""debug"" goto doDebug
  106. if ""%1"" == ""run"" goto doRun
  107. if ""%1"" == ""start"" goto doStart
  108. if ""%1"" == ""stop"" goto doStop
  109. if ""%1"" == ""version"" goto doVersion
  110.  
  111. echo Usage:  catalina ( commands ... )
  112. echo commands:
  113. echo   debug             Start Catalina in a debugger
  114. echo   debug -security   Debug Catalina with a security manager
  115. echo   jpda start        Start Catalina under JPDA debugger
  116. echo   run               Start Catalina in the current window
  117. echo   run -security     Start in the current window with security manager
  118. echo   start             Start Catalina in a separate window
  119. echo   start -security   Start in a separate window with security manager
  120. echo   stop              Stop Catalina
  121. echo   version           What version of tomcat are you running?
  122. goto end
  123.  
  124. :doDebug
  125. shift
  126. set _EXECJAVA=%_RUNJDB%
  127. set DEBUG_OPTS=-sourcepath "%CATALINA_HOME%\..\..\jakarta-tomcat-catalina\catalina\src\share"
  128. if not ""%1"" == ""-security"" goto execCmd
  129. shift
  130. echo Using Security Manager
  131. set SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy
  132. goto execCmd
  133.  
  134. :doRun
  135. shift
  136. if not ""%1"" == ""-security"" goto execCmd
  137. shift
  138. echo Using Security Manager
  139. set SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy
  140. goto execCmd
  141.  
  142. :doStart
  143. shift
  144. if not "%OS%" == "Windows_NT" goto noTitle
  145. set _EXECJAVA=start "Tomcat" %_RUNJAVA%
  146. goto gotTitle
  147. :noTitle
  148. set _EXECJAVA=start %_RUNJAVA%
  149. :gotTitle
  150. if not ""%1"" == ""-security"" goto execCmd
  151. shift
  152. echo Using Security Manager
  153. set SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy
  154. goto execCmd
  155.  
  156. :doStop
  157. shift
  158. set ACTION=stop
  159. goto execCmd
  160.  
  161. :doVersion
  162. %_EXECJAVA% -classpath "%CATALINA_HOME%\server\lib\catalina.jar" org.apache.catalina.util.ServerInfo
  163. goto end
  164.  
  165.  
  166. :execCmd
  167. rem Get remaining unshifted command line arguments and save them in the
  168. set CMD_LINE_ARGS=
  169. :setArgs
  170. if ""%1""=="""" goto doneSetArgs
  171. set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
  172. shift
  173. goto setArgs
  174. :doneSetArgs
  175.  
  176. rem Execute Java with the applicable properties
  177. if not "%JPDA%" == "" goto doJpda
  178. if not "%SECURITY_POLICY_FILE%" == "" goto doSecurity
  179. %_EXECJAVA% %JAVA_OPTS% %CATALINA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  180. goto end
  181. :doSecurity
  182. %_EXECJAVA% %JAVA_OPTS% %CATALINA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Djava.security.manager -Djava.security.policy=="%SECURITY_POLICY_FILE%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  183. goto end
  184. :doJpda
  185. if not "%SECURITY_POLICY_FILE%" == "" goto doSecurityJpda
  186. %_EXECJAVA% %JAVA_OPTS% %CATALINA_OPTS% -Xdebug -Xrunjdwp:transport=%JPDA_TRANSPORT%,address=%JPDA_ADDRESS%,server=y,suspend=n %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  187. goto end
  188. :doSecurityJpda
  189. %_EXECJAVA% %JAVA_OPTS% %CATALINA_OPTS% -Xrunjdwp:transport=%JPDA_TRANSPORT%,address=%JPDA_ADDRESS%,server=y,suspend=n %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Djava.security.manager -Djava.security.policy=="%SECURITY_POLICY_FILE%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  190. goto end
  191.  
  192. :end
  193.