home *** CD-ROM | disk | FTP | other *** search
/ PC Professionell 2004 December / PCpro_2004_12.ISO / files / webserver / xampp / xampp-cocoon-addon-1.4.9-installer.exe / qdox2html.xsl < prev    next >
Encoding:
Extensible Markup Language  |  2004-07-12  |  34.2 KB  |  1,015 lines
  1. <?xml version="1.0"?>
  2. <!--
  3.   Copyright 1999-2004 The Apache Software Foundation
  4.  
  5.   Licensed under the Apache License, Version 2.0 (the "License");
  6.   you may not use this file except in compliance with the License.
  7.   You may obtain a copy of the License at
  8.  
  9.       http://www.apache.org/licenses/LICENSE-2.0
  10.  
  11.   Unless required by applicable law or agreed to in writing, software
  12.   distributed under the License is distributed on an "AS IS" BASIS,
  13.   WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14.   See the License for the specific language governing permissions and
  15.   limitations under the License.
  16. -->
  17.  
  18. <!-- $Id: qdox2html.xsl,v 1.2 2004/03/06 02:26:14 antonio Exp $ -->
  19.  
  20. <!DOCTYPE xsl:stylesheet [
  21.   <!ENTITY nbsp " ">
  22.   <!ENTITY lt   "<">
  23.   <!ENTITY gt   ">">
  24.   ]>
  25.  
  26. <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
  27.                 xmlns:jd="http://apache.org/cocoon/javadoc/1.0">
  28.   
  29.   
  30.   <xsl:output method="html" />
  31.   
  32.   
  33.   <xsl:template match="/">
  34.     <html>
  35.       <head>
  36.         <title>API specs of <xsl:value-of select="@qname" /></title>
  37.       </head>
  38.       <body bcolor="white">
  39.         <font size="-1" color="grey">This Javadoc has been produced by Cocoon using the QDoxSource component</font>
  40.         <xsl:comment> ======== START OF CLASS DATA ======== </xsl:comment>
  41.         <h2>
  42.           <font size="-1"><xsl:value-of select="*/@package" /></font>
  43.           <br />
  44.           <xsl:choose>
  45.             <xsl:when test="jd:class">
  46.               <xsl:text>Class </xsl:text>
  47.             </xsl:when>
  48.             <xsl:otherwise>
  49.               <xsl:text>Interface </xsl:text>
  50.             </xsl:otherwise>
  51.           </xsl:choose>
  52.           <xsl:if test="*/jd:nested-in">
  53.             <xsl:value-of select="concat(*/jd:nested-in/*/@name, '.')" />
  54.           </xsl:if>
  55.           <xsl:value-of select="*/@name" />
  56.         </h2>
  57.         <xsl:apply-templates select="*" />
  58.       </body>
  59.     </html>
  60.   </xsl:template>
  61.   
  62.   
  63.   <xsl:template match="/jd:class">
  64.     <pre>
  65.       <xsl:apply-templates select="jd:inherit" mode="tree" />
  66.     </pre>
  67.     <xsl:if test="jd:implements/descendant::jd:interface">
  68.       <dl>
  69.         <dt>
  70.           <b>All Implemented Interfaces:</b>
  71.         </dt>
  72.         <dd>
  73.           <xsl:apply-templates select="jd:implements" mode="implemented_interfaces" />
  74.         </dd>
  75.       </dl>
  76.     </xsl:if>
  77.     <xsl:apply-templates select="jd:nested-in" />
  78.     <hr />
  79.     
  80.     <dl>
  81.       <dt>
  82.         <xsl:for-each select="jd:modifiers/*">
  83.           <xsl:value-of select="concat(local-name(), ' ')" />
  84.         </xsl:for-each>
  85.         <xsl:text>class </xsl:text>
  86.         <b><xsl:value-of select="@name" /></b>
  87.       </dt>
  88.       <dt>
  89.         <xsl:text>extends </xsl:text>
  90.         <a href="{jd:inherit/@qname}">
  91.           <xsl:value-of select="jd:inherit/@name" />
  92.         </a>
  93.       </dt>
  94.       <xsl:if test="jd:implements/*">
  95.         <dt>
  96.           <xsl:text>implements </xsl:text>
  97.           <xsl:for-each select="jd:implements/jd:interface">
  98.             <a href="{@qname}">
  99.               <xsl:value-of select="@name" />
  100.             </a>
  101.             <xsl:if test="position() != last()">
  102.               <xsl:text>, </xsl:text>
  103.             </xsl:if>
  104.           </xsl:for-each>
  105.         </dt>
  106.       </xsl:if>
  107.     </dl>
  108.     <p>
  109.       <xsl:apply-templates select="jd:comment" mode="detail" />
  110.     </p>
  111.     <p>
  112.       <xsl:apply-templates select="jd:tags" />
  113.     </p>
  114.     <hr />
  115.     
  116.     <xsl:apply-templates select="jd:innerclasses" mode="summary" />
  117.     <xsl:apply-templates select="jd:fields"       mode="summary" />
  118.     <xsl:apply-templates select="jd:constructors" mode="summary" />
  119.     <xsl:apply-templates select="jd:methods"      mode="summary" />
  120.     
  121.     <p />
  122.     
  123.     <xsl:apply-templates select="jd:fields[jd:field]"             mode="detail" />
  124.     <xsl:apply-templates select="jd:constructors[jd:constructor]" mode="detail" />
  125.     <xsl:apply-templates select="jd:methods[jd:method]"           mode="detail" />
  126.   </xsl:template>
  127.   
  128.   
  129.   <xsl:template match="/jd:interface">
  130.     <pre>
  131.       <xsl:apply-templates select="jd:inherit" mode="tree" />
  132.     </pre>
  133.     <xsl:if test="jd:implements">
  134.       <dl>
  135.         <dt>
  136.           <b>All Superinterfaces:</b>
  137.         </dt>
  138.         <dd>
  139.           <xsl:for-each select="jd:implements//jd:interface">
  140.             <a href="{@qname}">
  141.               <xsl:value-of select="@name" />
  142.             </a>
  143.             <xsl:if test="position() != last()">
  144.               <xsl:text>, </xsl:text>
  145.             </xsl:if>
  146.           </xsl:for-each>
  147.         </dd>
  148.       </dl>
  149.     </xsl:if>
  150.     <xsl:apply-templates select="jd:nested-in" />
  151.     <hr />
  152.     
  153.     <dl>
  154.       <dt>
  155.         <xsl:for-each select="jd:modifiers/*">
  156.           <xsl:value-of select="concat(local-name(), ' ')" />
  157.         </xsl:for-each>
  158.         <xsl:text>interface </xsl:text>
  159.         <b>
  160.           <xsl:if test="jd:nested-in">
  161.             <xsl:value-of select="concat(jd:nested-in/*/@name, '.')" />
  162.           </xsl:if>
  163.           <xsl:value-of select="@name" />
  164.         </b>
  165.       </dt>
  166.       <xsl:if test="jd:implements/*">
  167.         <dt>
  168.           <xsl:text>extends </xsl:text>
  169.           <xsl:for-each select="jd:implements/jd:interface">
  170.             <a href="{@qname}">
  171.               <xsl:value-of select="@name" />
  172.             </a>
  173.             <xsl:if test="position() != last()">
  174.               <xsl:text>, </xsl:text>
  175.             </xsl:if>
  176.           </xsl:for-each>
  177.         </dt>
  178.       </xsl:if>
  179.     </dl>
  180.     <p>
  181.       <xsl:apply-templates select="jd:comment" mode="detail" />
  182.     </p>
  183.     <p>
  184.       <xsl:apply-templates select="jd:tags" />
  185.     </p>
  186.     <hr />
  187.     
  188.     <xsl:apply-templates select="jd:innerclasses" mode="summary" />
  189.     <xsl:apply-templates select="jd:fields"       mode="summary" />
  190.     <xsl:apply-templates select="jd:methods"      mode="summary" />
  191.     
  192.     <p />
  193.     
  194.     <xsl:apply-templates select="jd:fields[jd:field]"   mode="detail" />
  195.     <xsl:apply-templates select="jd:methods[jd:method]" mode="detail" />
  196.   </xsl:template>
  197.   
  198.   
  199.   <xsl:template match="jd:inherit" mode="tree">
  200.     <xsl:for-each select="descendant-or-self::jd:inherit">
  201.       <xsl:sort select="position()" data-type="number" order="descending" />
  202.       
  203.       <xsl:variable name="spaces">
  204.         <xsl:call-template name="repeat">
  205.           <xsl:with-param name="cnt" select="count(descendant::jd:inherit) * 6 - 2" />
  206.           <xsl:with-param name="text" select="' '" />
  207.         </xsl:call-template>
  208.       </xsl:variable>
  209.       
  210.       <xsl:if test="position() != 1">
  211.         <xsl:value-of select="concat($spaces, '| ', $spaces, '+-')" />
  212.       </xsl:if>
  213.       <a href="{@qname}"><xsl:value-of select="@qname" /></a>
  214.       <xsl:text> </xsl:text>
  215.     </xsl:for-each>
  216.     
  217.     <xsl:variable name="spaces">
  218.       <xsl:call-template name="repeat">
  219.         <xsl:with-param name="cnt" select="count(descendant::jd:inherit) * 6 + 4" />
  220.         <xsl:with-param name="text" select="' '" />
  221.       </xsl:call-template>
  222.     </xsl:variable>
  223.     
  224.     <xsl:value-of select="concat($spaces, '| ', $spaces, '+-')" />
  225.     <b><xsl:value-of select="/jd:class/@qname" /></b>
  226.   </xsl:template>
  227.   
  228.   
  229.   <xsl:template match="jd:implements" mode="implemented_interfaces">
  230.     <xsl:for-each select="//jd:interface">
  231.       <xsl:sort select="@name" data-type="text" />
  232.       <xsl:if test="1=1"> <!-- TODO: refine condition ;-) -->
  233.         <xsl:if test="position() != 1">
  234.           <xsl:text>, </xsl:text>
  235.         </xsl:if>
  236.         <a href="{@qname}">
  237.           <xsl:value-of select="@name" />
  238.         </a>
  239.       </xsl:if>
  240.     </xsl:for-each>
  241.   </xsl:template>
  242.   
  243.   
  244.   <xsl:template match="jd:tags">
  245.     <dl>
  246.       <xsl:if test="jd:since">
  247.         <dt>
  248.           <b>Since:</b>
  249.         </dt>
  250.         <dd><xsl:value-of select="jd:since" /></dd>
  251.       </xsl:if>
  252.       <xsl:if test="jd:version">
  253.         <dt>
  254.           <b>Version:</b>
  255.         </dt>
  256.         <dd><xsl:value-of select="jd:version" disable-output-escaping="yes" /></dd>
  257.       </xsl:if>
  258.       <xsl:if test="jd:author">
  259.         <dt>
  260.           <b>Author:</b>
  261.         </dt>
  262.         <dd>
  263.           <xsl:for-each select="jd:author">
  264.             <xsl:value-of select="text()" disable-output-escaping="yes" />
  265.             <xsl:if test="position() != last()">
  266.               <xsl:text>, </xsl:text>
  267.             </xsl:if>
  268.           </xsl:for-each>
  269.         </dd>
  270.       </xsl:if>
  271.       <xsl:if test="jd:see">
  272.         <dt>
  273.           <b>See Also:</b>
  274.         </dt>
  275.         <dd>
  276.           <xsl:for-each select="jd:see">
  277.             <xsl:apply-templates select="jd:link" mode="comment" />
  278.             <xsl:if test="position() != last()">
  279.               <xsl:text>, </xsl:text>
  280.             </xsl:if>
  281.           </xsl:for-each>
  282.         </dd>
  283.       </xsl:if>
  284.     </dl>
  285.   </xsl:template>
  286.   
  287.   
  288.   <xsl:template match="jd:innerclasses" mode="summary">
  289.     <xsl:comment> =========== NESTED CLASS SUMMARY =========== </xsl:comment>
  290.     <a name="nested_class_summary" />
  291.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  292.       <tr bgcolor="#CCCCFF" class="TableHeadingColor">
  293.         <td colspan="2">
  294.           <font size="+2">
  295.             <b>Nested Class Summary</b>
  296.           </font>
  297.         </td>
  298.       </tr>
  299.       <xsl:for-each select="jd:class | jd:interface">
  300.         <xsl:sort select="@name" />
  301.         <tr bgcolor="white" class="TableRowColor">
  302.           <td align="right" valign="top" width="1%">
  303.             <font size="-1">
  304.               <code>
  305.                 <xsl:text> </xsl:text>
  306.                 <xsl:for-each select="jd:modifiers/*">
  307.                   <xsl:value-of select="local-name()" />
  308.                   <xsl:text> </xsl:text>
  309.                 </xsl:for-each>
  310.                 <xsl:value-of select="local-name()" />
  311.               </code>
  312.             </font>
  313.           </td>
  314.           <td>
  315.             <code>
  316.               <b>
  317.                 <a href="{concat(/*/@qname, '.', @name)}">
  318.                   <xsl:value-of select="concat(/*/@name, '.', @name)" />
  319.                 </a>
  320.               </b>
  321.             </code>
  322.             <br />
  323.             <xsl:apply-templates select="jd:comment" mode="summary" />
  324.           </td>
  325.         </tr>
  326.       </xsl:for-each>
  327.     </table>
  328.     <xsl:text> </xsl:text>
  329.     <xsl:apply-templates select="descendant::jd:inherit" mode="innerclass-summary" />
  330.   </xsl:template>
  331.   
  332.   
  333.   <xsl:template match="jd:inherit" mode="innerclass-summary">
  334.     <a name="{concat('nested_classes_inherited_from_class_', @qname)}" />
  335.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  336.       <tr bgcolor="#EEEEFF" class="TableSubHeadingColor">
  337.         <td>
  338.           <b>
  339.             <xsl:value-of select="concat('Nested classes inherited from ', local-name(/*), ' ', @package, '.')" />
  340.             <a href="{@qname}"><xsl:value-of select="@name" /></a>
  341.           </b>
  342.         </td>
  343.       </tr>
  344.       <tr bgcolor="white" class="TableRowColor">
  345.         <td>
  346.           <code>
  347.             <xsl:for-each select="*">
  348.               <xsl:sort select="@name" data-type="text" />
  349.               <a href="{concat(parent::*/@qname, '.', @name)}">
  350.                 <xsl:value-of select="concat(parent::*/@name, '.', @name)" />
  351.               </a>
  352.               <xsl:if test="position() != last()">
  353.                 <xsl:text>, </xsl:text>
  354.               </xsl:if>
  355.             </xsl:for-each>
  356.           </code>
  357.         </td>
  358.       </tr>
  359.     </table>
  360.     <xsl:text> </xsl:text>
  361.   </xsl:template>
  362.   
  363.   
  364.   <xsl:template match="jd:fields" mode="summary">
  365.     <xsl:comment> =========== FIELD SUMMARY =========== </xsl:comment>
  366.     <a name="field_summary" />
  367.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  368.       <tr bgcolor="#CCCCFF" class="TableHeadingColor">
  369.         <td colspan="2">
  370.           <font size="+2">
  371.             <b>Field Summary</b>
  372.           </font>
  373.         </td>
  374.       </tr>
  375.       <xsl:for-each select="jd:field">
  376.         <xsl:sort select="@name" data-type="text" />
  377.         <tr bgcolor="white" class="TableRowColor">
  378.           <td align="right" valign="top" width="1%">
  379.             <font size="-1">
  380.               <code>
  381.                 <xsl:text> </xsl:text>
  382.                 <xsl:for-each select="jd:modifiers/*">
  383.                   <xsl:value-of select="local-name()" />
  384.                   <xsl:text> </xsl:text>
  385.                 </xsl:for-each>
  386.                 <xsl:call-template name="output-type">
  387.                   <xsl:with-param name="type" select="current()" />
  388.                 </xsl:call-template>
  389.               </code>
  390.             </font>
  391.           </td>
  392.           <td>
  393.             <code>
  394.               <b>
  395.                 <a href="{concat('#', @name)}"><xsl:value-of select="@name" /></a>
  396.               </b>
  397.             </code>
  398.             <br />
  399.             <xsl:apply-templates select="jd:comment" mode="summary" />
  400.           </td>
  401.         </tr>
  402.       </xsl:for-each>
  403.     </table>
  404.     <xsl:text> </xsl:text>
  405.     <xsl:apply-templates select="descendant::jd:inherit" mode="field-summary" />
  406.   </xsl:template>
  407.  
  408.   
  409.   <xsl:template match="jd:inherit" mode="field-summary">
  410.     <a name="{concat('fields_inherited_from_class_', @qname)}" />
  411.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  412.       <tr bgcolor="#EEEEFF" class="TableSubHeadingColor">
  413.         <td>
  414.           <b>
  415.             <xsl:value-of select="concat('Fields inherited from ', local-name(/*), ' ', @package, '.')" />
  416.             <a href="{@qname}"><xsl:value-of select="@name" /></a>
  417.           </b>
  418.         </td>
  419.       </tr>
  420.       <tr bgcolor="white" class="TableRowColor">
  421.         <td>
  422.           <code>
  423.             <xsl:for-each select="jd:field">
  424.               <xsl:sort select="@name" data-type="text" />
  425.               <a href="{concat(parent::*/@qname, '#', @name)}"><xsl:value-of select="@name" /></a>
  426.               <xsl:if test="position() != last()">
  427.                 <xsl:text>, </xsl:text>
  428.               </xsl:if>
  429.             </xsl:for-each>
  430.           </code>
  431.         </td>
  432.       </tr>
  433.     </table>
  434.     <xsl:text> </xsl:text>
  435.   </xsl:template>
  436.   
  437.   
  438.   <xsl:template match="jd:fields" mode="detail">
  439.     <xsl:comment> =========== FIELD DETAIL =========== </xsl:comment>
  440.     <a name="field_detail" />
  441.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  442.       <tr bgcolor="#CCCCFF" class="TableHeadingColor">
  443.         <td>
  444.           <font size="+2">
  445.             <b>Field Detail</b>
  446.           </font>
  447.         </td>
  448.       </tr>
  449.     </table>
  450.     <xsl:for-each select="jd:field">
  451.       <xsl:sort select="@name" data-type="text" />
  452.       <a name="{@name}" />
  453.       <h3><xsl:value-of select="@name" /></h3>
  454.       <pre>
  455.         <xsl:for-each select="jd:modifiers/*">
  456.           <xsl:value-of select="local-name()" />
  457.           <xsl:text> </xsl:text>
  458.         </xsl:for-each>
  459.         <xsl:call-template name="output-type">
  460.           <xsl:with-param name="type" select="current()" />
  461.         </xsl:call-template>
  462.         <xsl:text> </xsl:text>
  463.         <b><xsl:value-of select="@name" /></b>
  464.       </pre>
  465.       <dl>
  466.         <xsl:if test="jd:comment">
  467.           <dd>
  468.             <xsl:apply-templates select="jd:comment" mode="detail" />
  469.           </dd>
  470.         </xsl:if>
  471.       </dl>
  472.       <xsl:if test="position() != last()">
  473.         <hr />
  474.       </xsl:if>
  475.     </xsl:for-each>
  476.   </xsl:template>
  477.   
  478.   
  479.   <xsl:template match="jd:constructors" mode="summary">
  480.     <xsl:comment> =========== CONSTRUCTOR SUMMARY =========== </xsl:comment>
  481.     <a name="constructor_summary" />
  482.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  483.       <tr bgcolor="#CCCCFF" class="TableHeadingColor">
  484.         <td colspan="2">
  485.           <font size="+2">
  486.             <b>Constructor Summary</b>
  487.           </font>
  488.         </td>
  489.       </tr>
  490.       <xsl:for-each select="jd:constructor">
  491.         <xsl:sort select="jd:parameters/jd:parameter[1]/@name" data-type="text" />
  492.         <xsl:sort select="jd:parameters/jd:parameter[2]/@name" data-type="text" />
  493.         <xsl:sort select="jd:parameters/jd:parameter[3]/@name" data-type="text" />
  494.         <xsl:sort select="jd:parameters/jd:parameter[4]/@name" data-type="text" />
  495.         <xsl:sort select="jd:parameters/jd:parameter[5]/@name" data-type="text" />
  496.         <tr bgcolor="white" class="TableRowColor">
  497.           <td align="right" valign="top" width="1%">
  498.             <font size="-1">
  499.               <code>
  500.                 <xsl:text> </xsl:text>
  501.                 <xsl:for-each select="jd:modifiers/*">
  502.                   <xsl:value-of select="local-name()" />
  503.                   <xsl:if test="position() != last()">
  504.                     <xsl:text> </xsl:text>
  505.                   </xsl:if>
  506.                 </xsl:for-each>
  507.               </code>
  508.             </font>
  509.           </td>
  510.           <td>
  511.             <code>
  512.               <b>
  513.                 <a href="{concat('#', @signature)}"><xsl:value-of select="@name" /></a>
  514.               </b>
  515.               <!-- Parameters: -->
  516.               <xsl:text>(</xsl:text>
  517.               <xsl:for-each select="jd:parameters/jd:parameter">
  518.                 <xsl:call-template name="output-type">
  519.                   <xsl:with-param name="type" select="current()" />
  520.                 </xsl:call-template>
  521.                 <xsl:value-of select="concat(' ', @name)" />
  522.                 <xsl:if test="position() != last()">
  523.                   <xsl:text>, </xsl:text>
  524.                 </xsl:if>
  525.               </xsl:for-each>
  526.               <xsl:text>)</xsl:text>
  527.             </code>
  528.             <br />
  529.             <xsl:apply-templates select="jd:comment" mode="summary" />
  530.           </td>
  531.         </tr>
  532.       </xsl:for-each>
  533.     </table>
  534.     <xsl:text> </xsl:text>
  535.   </xsl:template>
  536.   
  537.   
  538.   <xsl:template match="jd:constructors" mode="detail">
  539.     <xsl:comment> =========== CONSTRUCTOR DETAIL =========== </xsl:comment>
  540.     <a name="constructor_detail" />
  541.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  542.       <tr bgcolor="#CCCCFF" class="TableHeadingColor">
  543.         <td>
  544.           <font size="+2">
  545.             <b>Constructor Detail</b>
  546.           </font>
  547.         </td>
  548.       </tr>
  549.     </table>
  550.     <xsl:for-each select="jd:constructor">
  551.       <xsl:sort select="jd:parameters/jd:parameter[1]/@name" data-type="text" />
  552.       <xsl:sort select="jd:parameters/jd:parameter[2]/@name" data-type="text" />
  553.       <xsl:sort select="jd:parameters/jd:parameter[3]/@name" data-type="text" />
  554.       <xsl:sort select="jd:parameters/jd:parameter[4]/@name" data-type="text" />
  555.       <xsl:sort select="jd:parameters/jd:parameter[5]/@name" data-type="text" />
  556.       
  557.       <a name="{@signature}" />
  558.       <h3><xsl:value-of select="@name" /></h3>
  559.       <xsl:variable name="mod">
  560.         <xsl:for-each select="jd:modifiers/*">
  561.           <xsl:value-of select="local-name()" />
  562.           <xsl:text> </xsl:text>
  563.         </xsl:for-each>
  564.       </xsl:variable>
  565.       <xsl:variable name="spaces">
  566.         <xsl:call-template name="repeat">
  567.           <xsl:with-param name="text" select="' '" />
  568.           <xsl:with-param name="cnt" select="string-length($mod) + string-length(@name) + 1" />
  569.         </xsl:call-template>
  570.       </xsl:variable>
  571.       <pre>
  572.         <xsl:value-of select="$mod" />
  573.         <b><xsl:value-of select="@name" /></b>
  574.         <xsl:text>(</xsl:text>
  575.         <xsl:for-each select="jd:parameters/jd:parameter">
  576.           <xsl:call-template name="output-type">
  577.             <xsl:with-param name="type" select="current()" />
  578.           </xsl:call-template>
  579.           <xsl:value-of select="concat(' ', @name)" />
  580.           <xsl:if test="position() != last()">
  581.             <xsl:value-of select="concat(', ', $spaces)" />
  582.           </xsl:if>
  583.         </xsl:for-each>
  584.         <xsl:text>)</xsl:text>
  585.         <xsl:if test="jd:throws/jd:exception">
  586.           <xsl:text> </xsl:text>
  587.           <xsl:call-template name="repeat">
  588.             <xsl:with-param name="text" select="' '" />
  589.             <xsl:with-param name="cnt" select="string-length($mod) + string-length(@name) - 6" />
  590.           </xsl:call-template>
  591.           <xsl:text>throws </xsl:text>
  592.           <xsl:for-each select="jd:throws/jd:exception">
  593.             <a href="{@name}">
  594.               <xsl:call-template name="class-part">
  595.                 <xsl:with-param name="classname" select="@name" />
  596.               </xsl:call-template>
  597.             </a>
  598.             <xsl:if test="position() != last()">
  599.               <xsl:value-of select="concat(', ', $spaces)" />
  600.             </xsl:if>
  601.           </xsl:for-each>
  602.         </xsl:if>
  603.       </pre>
  604.       <dl>
  605.         <xsl:if test="jd:comment">
  606.           <dd>
  607.             <xsl:apply-templates select="jd:comment" mode="detail" />
  608.           </dd>
  609.         </xsl:if>
  610.         <p />
  611.         <xsl:apply-templates select="jd:parameters" mode="list_comment" />
  612.         <xsl:if test="jd:throws/jd:exception">
  613.           <dt>
  614.             <b>Throws:</b>
  615.           </dt>
  616.           <xsl:apply-templates select="jd:throws/jd:exception" mode="list_comment" />
  617.         </xsl:if>
  618.       </dl>
  619.       <xsl:if test="position() != last()">
  620.         <hr />
  621.       </xsl:if>
  622.     </xsl:for-each>
  623.   </xsl:template>
  624.   
  625.   
  626.   <xsl:template match="jd:methods" mode="summary">
  627.     <xsl:comment> =========== METHOD SUMMARY =========== </xsl:comment>
  628.     <a name="method_summary" />
  629.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  630.       <tr bgcolor="#CCCCFF" class="TableHeadingColor">
  631.         <td colspan="2">
  632.           <font size="+2">
  633.             <b>Method Summary</b>
  634.           </font>
  635.         </td>
  636.       </tr>
  637.       <xsl:apply-templates select="jd:method" mode="summary">
  638.         <xsl:sort select="@name" data-type="text" />
  639.         <xsl:sort select="jd:parameters/jd:parameter[1]/@name" data-type="text" />
  640.         <xsl:sort select="jd:parameters/jd:parameter[2]/@name" data-type="text" />
  641.         <xsl:sort select="jd:parameters/jd:parameter[3]/@name" data-type="text" />
  642.         <xsl:sort select="jd:parameters/jd:parameter[4]/@name" data-type="text" />
  643.         <xsl:sort select="jd:parameters/jd:parameter[5]/@name" data-type="text" />
  644.       </xsl:apply-templates>
  645.     </table>
  646.     <xsl:text> </xsl:text>
  647.     <xsl:apply-templates select="descendant::jd:inherit[@type=local-name(/*)]" mode="method-summary" />
  648.   </xsl:template>
  649.   
  650.   
  651.   <xsl:template match="jd:method" mode="summary">
  652.     <tr bgcolor="white" class="TableRowColor">
  653.       <td align="right" valign="top" width="1%">
  654.         <font size="-1">
  655.           <code>
  656.             <xsl:text> </xsl:text>
  657.             <xsl:for-each select="jd:modifiers/*">
  658.               <xsl:value-of select="local-name()" />
  659.               <xsl:text> </xsl:text>
  660.             </xsl:for-each>
  661.             <xsl:call-template name="output-type">
  662.               <xsl:with-param name="type" select="current()" />
  663.             </xsl:call-template>
  664.           </code>
  665.         </font>
  666.       </td>
  667.       <td>
  668.         <code>
  669.           <b>
  670.             <a href="{concat('#', @signature)}"><xsl:value-of select="@name" /></a>
  671.           </b>
  672.           <!-- Parameters: -->
  673.           <xsl:text>(</xsl:text>
  674.           <xsl:for-each select="jd:parameters/jd:parameter">
  675.             <xsl:call-template name="output-type">
  676.               <xsl:with-param name="type" select="current()" />
  677.             </xsl:call-template>
  678.             <xsl:value-of select="concat(' ', @name)" />
  679.             <xsl:if test="position() != last()">
  680.               <xsl:text>, </xsl:text>
  681.             </xsl:if>
  682.           </xsl:for-each>
  683.           <xsl:text>)</xsl:text>
  684.         </code>
  685.         <br />
  686.         <xsl:apply-templates select="jd:comment" mode="summary" />
  687.       </td>
  688.     </tr>
  689.   </xsl:template>
  690.   
  691.   
  692.   <xsl:template match="jd:inherit" mode="method-summary">
  693.     <xsl:variable name="signatures" select="ancestor::*[local-name()='inherit' or local-name()='methods']/jd:method/@signature" />
  694.     <xsl:if test="jd:method[not(@signature = $signatures)]">
  695.       <a name="{concat('methods_inherited_from_class_', @qname)}" />
  696.       <table border="1" cellpadding="3" cellspacing="0" width="100%">
  697.         <tr bgcolor="#EEEEFF" class="TableSubHeadingColor">
  698.           <td>
  699.             <b>
  700.               <xsl:value-of select="concat('Methods inherited from ', local-name(/*), ' ', @package, '.')" />
  701.               <a href="{@qname}"><xsl:value-of select="@name" /></a>
  702.             </b>
  703.           </td>
  704.         </tr>
  705.         <tr bgcolor="white" class="TableRowColor">
  706.           <td>
  707.             <code>
  708.               <xsl:for-each select="jd:method[not(@signature = $signatures)]">
  709.                 <xsl:sort select="@name" data-type="text" />
  710.                 <a href="{concat(parent::*/@qname, '#', @signature)}"><xsl:value-of select="@name" /></a>
  711.                 <xsl:if test="position() != last()">
  712.                   <xsl:text>, </xsl:text>
  713.                 </xsl:if>
  714.               </xsl:for-each>
  715.             </code>
  716.           </td>
  717.         </tr>
  718.       </table>
  719.       <xsl:text> </xsl:text>
  720.     </xsl:if>
  721.   </xsl:template>
  722.   
  723.   
  724.   <xsl:template match="jd:methods" mode="detail">
  725.     <xsl:comment> =========== METHOD DETAIL =========== </xsl:comment>
  726.     <a name="method_detail" />
  727.     <table border="1" cellpadding="3" cellspacing="0" width="100%">
  728.       <tr bgcolor="#CCCCFF" class="TableHeadingColor">
  729.         <td>
  730.           <font size="+2">
  731.             <b>Method Detail</b>
  732.           </font>
  733.         </td>
  734.       </tr>
  735.     </table>
  736.     <xsl:for-each select="jd:method">
  737.       <xsl:sort select="@name" data-type="text" />
  738.       <xsl:sort select="jd:parameters/jd:parameter[1]/@name" data-type="text" />
  739.       <xsl:sort select="jd:parameters/jd:parameter[2]/@name" data-type="text" />
  740.       <xsl:sort select="jd:parameters/jd:parameter[3]/@name" data-type="text" />
  741.       <xsl:sort select="jd:parameters/jd:parameter[4]/@name" data-type="text" />
  742.       <xsl:sort select="jd:parameters/jd:parameter[5]/@name" data-type="text" />
  743.       
  744.       <a name="{@signature}" />
  745.       <h3><xsl:value-of select="@name" /></h3>
  746.       <xsl:variable name="mod-type">
  747.         <xsl:for-each select="jd:modifiers/*">
  748.           <xsl:value-of select="local-name()" />
  749.           <xsl:text> </xsl:text>
  750.         </xsl:for-each>
  751.         <xsl:call-template name="output-type">
  752.           <xsl:with-param name="type" select="current()" />
  753.         </xsl:call-template>
  754.       </xsl:variable>
  755.       <xsl:variable name="spaces">
  756.         <xsl:call-template name="repeat">
  757.           <xsl:with-param name="text" select="' '" />
  758.           <xsl:with-param name="cnt" select="string-length($mod-type) + string-length(@name) + 2" />
  759.         </xsl:call-template>
  760.       </xsl:variable>
  761.       <pre>
  762.         <xsl:value-of select="$mod-type" />
  763.         <xsl:text> </xsl:text>
  764.         <b><xsl:value-of select="@name" /></b>
  765.         <xsl:text>(</xsl:text>
  766.         <xsl:for-each select="jd:parameters/jd:parameter">
  767.           <xsl:call-template name="output-type">
  768.             <xsl:with-param name="type" select="current()" />
  769.           </xsl:call-template>
  770.           <xsl:value-of select="concat(' ', @name)" />
  771.           <xsl:if test="position() != last()">
  772.             <xsl:value-of select="concat(', ', $spaces)" />
  773.           </xsl:if>
  774.         </xsl:for-each>
  775.         <xsl:text>)</xsl:text>
  776.         <xsl:if test="jd:throws/jd:exception">
  777.           <xsl:text> </xsl:text>
  778.           <xsl:call-template name="repeat">
  779.             <xsl:with-param name="text" select="' '" />
  780.             <xsl:with-param name="cnt" select="string-length($mod-type) + string-length(@name) - 5" />
  781.           </xsl:call-template>
  782.           <xsl:text>throws </xsl:text>
  783.           <xsl:for-each select="jd:throws/jd:exception">
  784.             <a href="{@name}">
  785.               <xsl:call-template name="class-part">
  786.                 <xsl:with-param name="classname" select="@name" />
  787.               </xsl:call-template>
  788.             </a>
  789.             <xsl:if test="position() != last()">
  790.               <xsl:value-of select="concat(', ', $spaces)" />
  791.             </xsl:if>
  792.           </xsl:for-each>
  793.         </xsl:if>
  794.       </pre>
  795.       <dl>
  796.         <xsl:if test="jd:comment">
  797.           <dd>
  798.             <xsl:apply-templates select="jd:comment" mode="detail" />
  799.           </dd>
  800.         </xsl:if>
  801.         <p />
  802.         <!-- Circumvention for Xalan bug - Xalan does not understand braces in xpath expressions! -->
  803.         <xsl:variable name="m-specifies" select="ancestor::jd:methods/descendant::jd:inherit[@type='interface']/jd:method[@signature = current()/@signature]" />
  804.         <xsl:variable name="specifies" select="$m-specifies[1]" />
  805.         <xsl:if test="$specifies">
  806.           <dt>
  807.             <b>Specified by:</b>
  808.           </dt>
  809.           <dd>
  810.             <a href="{concat($specifies/../@qname, '#', $specifies/@signature)}">
  811.               <xsl:value-of select="$specifies/@name" />
  812.             </a>
  813.             <xsl:text> in interface </xsl:text>
  814.             <a href="{$specifies/../@qname}">
  815.               <xsl:value-of select="$specifies/../@name" />
  816.             </a>
  817.           </dd>
  818.         </xsl:if>
  819.         <!-- Circumvention for Xalan bug - Xalan does not understand braces in xpath expressions! -->
  820.         <xsl:variable name="m-overrides" select="ancestor::jd:methods/descendant::jd:inherit[@type='class']/jd:method[@signature = current()/@signature]" />
  821.         <xsl:variable name="overrides" select="$m-overrides[last()]" />
  822.         <xsl:if test="$overrides">
  823.           <dt>
  824.             <b>Overrides:</b>
  825.           </dt>
  826.           <dd>
  827.             <a href="{concat($overrides/../@qname, '#', $overrides/@signature)}">
  828.               <xsl:value-of select="$overrides/@name" />
  829.             </a>
  830.             <xsl:value-of select="concat(' in ', local-name(/*), ' ')" />
  831.             <a href="{$overrides/../@qname}">
  832.               <xsl:value-of select="$overrides/../@name" />
  833.             </a>
  834.           </dd>
  835.         </xsl:if>
  836.         <xsl:apply-templates select="jd:parameters" mode="list_comment" />
  837.         <xsl:if test="jd:tags/jd:return">
  838.           <dt>
  839.             <b>Returns:</b>
  840.           </dt>
  841.           <dd>
  842.             <xsl:value-of select="jd:tags/jd:return" disable-output-escaping="yes" />
  843.           </dd>
  844.         </xsl:if>
  845.         <xsl:if test="jd:throws/jd:exception">
  846.           <dt>
  847.             <b>Throws:</b>
  848.           </dt>
  849.           <xsl:apply-templates select="jd:throws/jd:exception" mode="list_comment" />
  850.         </xsl:if>
  851.       </dl>
  852.       <xsl:if test="position() != last()">
  853.         <hr />
  854.       </xsl:if>
  855.     </xsl:for-each>
  856.   </xsl:template>
  857.   
  858.   
  859.   <xsl:template match="jd:nested-in">
  860.     <dl>
  861.       <dt>
  862.         <b><xsl:value-of select="concat('Enclosing ', local-name(*), ':')" /></b>
  863.       </dt>
  864.       <dd>
  865.         <a href="{concat(*/@package, '.', */@name)}">
  866.           <xsl:value-of select="*/@name" />
  867.         </a>
  868.       </dd>
  869.     </dl>
  870.   </xsl:template>
  871.   
  872.   
  873.   <xsl:template match="jd:comment" mode="summary">
  874.     <xsl:text>          </xsl:text>
  875.     <xsl:variable name="before-dotspace">
  876.       <xsl:choose>
  877.         <xsl:when test="contains(text(), '. ')">
  878.           <xsl:value-of select="concat(substring-before(text(), '. '), '.')" disable-output-escaping="yes" />
  879.         </xsl:when>
  880.         <xsl:otherwise>
  881.           <xsl:value-of select="text()" disable-output-escaping="yes" />
  882.         </xsl:otherwise>
  883.       </xsl:choose>
  884.     </xsl:variable>
  885.     <xsl:choose>
  886.       <xsl:when test="contains($before-dotspace, '.<')">
  887.         <xsl:value-of select="concat(substring-before($before-dotspace, '.<'), '.')" disable-output-escaping="yes" />
  888.       </xsl:when>
  889.       <xsl:otherwise>
  890.         <xsl:value-of select="$before-dotspace" disable-output-escaping="yes" />
  891.       </xsl:otherwise>
  892.     </xsl:choose>
  893.   </xsl:template>
  894.   
  895.   
  896.   <xsl:template match="jd:comment" mode="detail">
  897.     <xsl:apply-templates select="text()|jd:link" mode="comment" />
  898.   </xsl:template>
  899.   
  900.   
  901.   <xsl:template match="text()" mode="comment">
  902.     <xsl:value-of select="." disable-output-escaping="yes" />
  903.   </xsl:template>
  904.   
  905.   
  906.   <xsl:template match="jd:link" mode="comment">
  907.     <a>
  908.       <xsl:attribute name="href">
  909.         <xsl:value-of select="@class" />
  910.         <xsl:if test="@member">
  911.           <xsl:value-of select="concat('#', @member)" />
  912.         </xsl:if>
  913.       </xsl:attribute>
  914.       <code>
  915.         <xsl:choose>
  916.           <xsl:when test="text()">
  917.             <xsl:value-of select="text()" />
  918.           </xsl:when>
  919.           <xsl:otherwise>
  920.             <xsl:value-of select="@class" />
  921.             <xsl:if test="@member">
  922.               <xsl:value-of select="concat('.', @member)" />
  923.             </xsl:if>
  924.           </xsl:otherwise>
  925.         </xsl:choose>
  926.       </code>
  927.     </a>
  928.   </xsl:template>
  929.   
  930.   
  931.   <xsl:template match="jd:parameters" mode="list_comment">
  932.     <dt>
  933.       <b>Parameters:</b>
  934.     </dt>
  935.     <xsl:for-each select="jd:parameter">
  936.       <dd>
  937.         <code><xsl:value-of select="@name" /></code>
  938.         <xsl:if test="jd:comment">
  939.           <xsl:text> - </xsl:text>
  940.           <xsl:apply-templates select="jd:comment" mode="detail" />
  941.         </xsl:if>
  942.       </dd>
  943.     </xsl:for-each>
  944.   </xsl:template>
  945.  
  946.  
  947.   <xsl:template match="jd:exception" mode="list_comment">
  948.     <dd>
  949.       <a href="{@name}">
  950.         <code>
  951.           <xsl:call-template name="class-part">
  952.             <xsl:with-param name="classname" select="@name" />
  953.           </xsl:call-template>
  954.         </code>
  955.       </a>
  956.       <xsl:text> - </xsl:text>
  957.       <xsl:apply-templates select="jd:comment" mode="detail" />
  958.     </dd>
  959.   </xsl:template>
  960.  
  961.   
  962.   <xsl:template name="output-type">
  963.     <xsl:param name="type" />
  964.     
  965.     <xsl:choose>
  966.       <xsl:when test="contains($type/@type, '.')">
  967.         <!-- Class type: -->
  968.         <a href="{$type/@type}">
  969.           <xsl:call-template name="class-part">
  970.             <xsl:with-param name="classname" select="$type/@type" />
  971.           </xsl:call-template>
  972.         </a>
  973.       </xsl:when>
  974.       <xsl:otherwise>
  975.         <!-- Primitive type: -->
  976.         <xsl:value-of select="$type/@type" />
  977.       </xsl:otherwise>
  978.     </xsl:choose>
  979.     <xsl:call-template name="repeat">
  980.       <xsl:with-param name="text" select="'[]'" />
  981.       <xsl:with-param name="cnt" select="$type/@dimensions" />
  982.     </xsl:call-template>
  983.   </xsl:template>
  984.   
  985.   
  986.   <xsl:template name="repeat">
  987.     <xsl:param name="cnt" />
  988.     <xsl:param name="text" />
  989.     
  990.     <xsl:if test="$cnt > 0">
  991.       <xsl:value-of select="$text" />
  992.       <xsl:call-template name="repeat">
  993.         <xsl:with-param name="cnt" select="$cnt - 1" />
  994.         <xsl:with-param name="text" select="$text" />
  995.       </xsl:call-template>
  996.     </xsl:if>
  997.   </xsl:template>
  998.   
  999.   
  1000.   <xsl:template name="class-part">
  1001.     <xsl:param name="classname" />
  1002.     
  1003.     <xsl:choose>
  1004.       <xsl:when test="contains($classname, '.')">
  1005.         <xsl:call-template name="class-part">
  1006.           <xsl:with-param name="classname" select="substring-after($classname, '.')" />
  1007.         </xsl:call-template>
  1008.       </xsl:when>
  1009.       <xsl:otherwise>
  1010.         <xsl:value-of select="$classname" />
  1011.       </xsl:otherwise>
  1012.     </xsl:choose>
  1013.   </xsl:template>
  1014.   
  1015. </xsl:stylesheet>