home *** CD-ROM | disk | FTP | other *** search
/ PC Professionell 2004 December / PCpro_2004_12.ISO / files / webserver / tsw / TSW_3.4.0.exe / Apache2 / perl / Plugins.pm < prev    next >
Encoding:
Perl POD Document  |  2004-01-30  |  30.9 KB  |  1,042 lines
  1. #============================================================= -*-Perl-*-
  2. #
  3. # Template::Plugins
  4. #
  5. # DESCRIPTION
  6. #   Plugin provider which handles the loading of plugin modules and 
  7. #   instantiation of plugin objects.
  8. #
  9. # AUTHORS
  10. #   Andy Wardley <abw@kfs.org>
  11. #
  12. # COPYRIGHT
  13. #   Copyright (C) 1996-2000 Andy Wardley.  All Rights Reserved.
  14. #   Copyright (C) 1998-2000 Canon Research Centre Europe Ltd.
  15. #
  16. #   This module is free software; you can redistribute it and/or
  17. #   modify it under the same terms as Perl itself.
  18. #
  19. #----------------------------------------------------------------------------
  20. #
  21. # $Id: Plugins.pm,v 2.70 2004/01/13 16:19:15 abw Exp $
  22. #
  23. #============================================================================
  24.  
  25. package Template::Plugins;
  26.  
  27. require 5.004;
  28.  
  29. use strict;
  30. use base qw( Template::Base );
  31. use vars qw( $VERSION $DEBUG $STD_PLUGINS );
  32. use Template::Constants;
  33.  
  34. $VERSION = sprintf("%d.%02d", q$Revision: 2.70 $ =~ /(\d+)\.(\d+)/);
  35.  
  36. $STD_PLUGINS   = {
  37.     'autoformat' => 'Template::Plugin::Autoformat',
  38.     'cgi'        => 'Template::Plugin::CGI',
  39.     'datafile'   => 'Template::Plugin::Datafile',
  40.     'date'       => 'Template::Plugin::Date',
  41.     'debug'      => 'Template::Plugin::Debug',
  42.     'directory'  => 'Template::Plugin::Directory',
  43.     'dbi'        => 'Template::Plugin::DBI',
  44.     'dumper'     => 'Template::Plugin::Dumper',
  45.     'file'       => 'Template::Plugin::File',
  46.     'format'     => 'Template::Plugin::Format',
  47.     'html'       => 'Template::Plugin::HTML',
  48.     'image'      => 'Template::Plugin::Image',
  49.     'iterator'   => 'Template::Plugin::Iterator',
  50.     'pod'        => 'Template::Plugin::Pod',
  51.     'table'      => 'Template::Plugin::Table',
  52.     'url'        => 'Template::Plugin::URL',
  53.     'view'       => 'Template::Plugin::View',
  54.     'wrap'       => 'Template::Plugin::Wrap',
  55.     'xmlstyle'   => 'Template::Plugin::XML::Style',
  56. };
  57.  
  58.  
  59. #========================================================================
  60. #                         -- PUBLIC METHODS --
  61. #========================================================================
  62.  
  63. #------------------------------------------------------------------------
  64. # fetch($name, \@args, $context)
  65. #
  66. # General purpose method for requesting instantiation of a plugin
  67. # object.  The name of the plugin is passed as the first parameter.
  68. # The internal FACTORY lookup table is consulted to retrieve the
  69. # appropriate factory object or class name.  If undefined, the _load()
  70. # method is called to attempt to load the module and return a factory
  71. # class/object which is then cached for subsequent use.  A reference
  72. # to the calling context should be passed as the third parameter.
  73. # This is passed to the _load() class method.  The new() method is
  74. # then called against the factory class name or prototype object to
  75. # instantiate a new plugin object, passing any arguments specified by
  76. # list reference as the second parameter.  e.g. where $factory is the
  77. # class name 'MyClass', the new() method is called as a class method,
  78. # $factory->new(...), equivalent to MyClass->new(...) .  Where
  79. # $factory is a prototype object, the new() method is called as an
  80. # object method, $myobject->new(...).  This latter approach allows
  81. # plugins to act as Singletons, cache shared data, etc.  
  82. #
  83. # Returns a reference to a plugin, (undef, STATUS_DECLINE) to decline
  84. # the request or ($error, STATUS_ERROR) on error.
  85. #------------------------------------------------------------------------
  86.  
  87. sub fetch {
  88.     my ($self, $name, $args, $context) = @_;
  89.     my ($factory, $plugin, $error);
  90.  
  91.     $self->debug("fetch($name, ", 
  92.                  defined $args ? ('[ ', join(', ', @$args), ' ]') : '<no args>', ', ',
  93.                  defined $context ? $context : '<no context>', 
  94.                  ')') if $self->{ DEBUG };
  95.  
  96.     # NOTE:
  97.     # the $context ref gets passed as the first parameter to all regular
  98.     # plugins, but not to those loaded via LOAD_PERL;  to hack around
  99.     # this until we have a better implementation, we pass the $args
  100.     # reference to _load() and let it unshift the first args in the 
  101.     # LOAD_PERL case
  102.  
  103.     $args ||= [ ];
  104.     unshift @$args, $context;
  105.  
  106.     $factory = $self->{ FACTORY }->{ $name } ||= do {
  107.     ($factory, $error) = $self->_load($name, $context);
  108.     return ($factory, $error) if $error;            ## RETURN
  109.     $factory;
  110.     };
  111.  
  112.     # call the new() method on the factory object or class name
  113.     eval {
  114.     if (ref $factory eq 'CODE') {
  115.         defined( $plugin = &$factory(@$args) )
  116.         || die "$name plugin failed\n";
  117.     }
  118.     else {
  119.         defined( $plugin = $factory->new(@$args) )
  120.         || die "$name plugin failed: ", $factory->error(), "\n";
  121.     }
  122.     };
  123.     if ($error = $@) {
  124. #    chomp $error;
  125.     return $self->{ TOLERANT } 
  126.            ? (undef,  Template::Constants::STATUS_DECLINED)
  127.            : ($error, Template::Constants::STATUS_ERROR);
  128.     }
  129.  
  130.     return $plugin;
  131. }
  132.  
  133.  
  134.  
  135. #========================================================================
  136. #                        -- PRIVATE METHODS --
  137. #========================================================================
  138.  
  139. #------------------------------------------------------------------------
  140. # _init(\%config)
  141. #
  142. # Private initialisation method.
  143. #------------------------------------------------------------------------
  144.  
  145. sub _init {
  146.     my ($self, $params) = @_;
  147.     my ($pbase, $plugins, $factory) = 
  148.     @$params{ qw( PLUGIN_BASE PLUGINS PLUGIN_FACTORY ) };
  149.  
  150.     $plugins ||= { };
  151.     if (ref $pbase ne 'ARRAY') {
  152.     $pbase = $pbase ? [ $pbase ] : [ ];
  153.     }
  154.     push(@$pbase, 'Template::Plugin');
  155.  
  156.     $self->{ PLUGIN_BASE } = $pbase;
  157.     $self->{ PLUGINS     } = { %$STD_PLUGINS, %$plugins };
  158.     $self->{ TOLERANT    } = $params->{ TOLERANT }  || 0;
  159.     $self->{ LOAD_PERL   } = $params->{ LOAD_PERL } || 0;
  160.     $self->{ FACTORY     } = $factory || { };
  161.     $self->{ DEBUG       } = ( $params->{ DEBUG } || 0 )
  162.                              & Template::Constants::DEBUG_PLUGINS;
  163.  
  164.     return $self;
  165. }
  166.  
  167.  
  168.  
  169. #------------------------------------------------------------------------
  170. # _load($name, $context)
  171. #
  172. # Private method which attempts to load a plugin module and determine the 
  173. # correct factory name or object by calling the load() class method in
  174. # the loaded module.
  175. #------------------------------------------------------------------------
  176.  
  177. sub _load {
  178.     my ($self, $name, $context) = @_;
  179.     my ($factory, $module, $base, $pkg, $file, $ok, $error);
  180.  
  181.     if ($module = $self->{ PLUGINS }->{ $name }) {
  182.     # plugin module name is explicitly stated in PLUGIN_NAME
  183.     $pkg = $module;
  184.     ($file = $module) =~ s|::|/|g;
  185.     $file =~ s|::|/|g;
  186.     $self->debug("loading $module.pm (PLUGIN_NAME)")
  187.             if $self->{ DEBUG };
  188.     $ok = eval { require "$file.pm" };
  189.     $error = $@;
  190.     }
  191.     else {
  192.     # try each of the PLUGIN_BASE values to build module name
  193.     ($module = $name) =~ s/\./::/g;
  194.  
  195.     foreach $base (@{ $self->{ PLUGIN_BASE } }) {
  196.         $pkg = $base . '::' . $module;
  197.         ($file = $pkg) =~ s|::|/|g;
  198.  
  199.         $self->debug("loading $file.pm (PLUGIN_BASE)")
  200.                 if $self->{ DEBUG };
  201.  
  202.         $ok = eval { require "$file.pm" };
  203.         last unless $@;
  204.     
  205.         $error .= "$@\n" 
  206.         unless ($@ =~ /^Can\'t locate $file\.pm/);
  207.     }
  208.     }
  209.  
  210.     if ($ok) {
  211.     $self->debug("calling $pkg->load()") if $self->{ DEBUG };
  212.  
  213.     $factory = eval { $pkg->load($context) };
  214.     $error   = '';
  215.     if ($@ || ! $factory) {
  216.         $error = $@ || 'load() returned a false value';
  217.     }
  218.     }
  219.     elsif ($self->{ LOAD_PERL }) {
  220.     # fallback - is it a regular Perl module?
  221.     ($file = $module) =~ s|::|/|g;
  222.     eval { require "$file.pm" };
  223.     if ($@) {
  224.         $error = $@;
  225.     }
  226.     else {
  227.         # this is a regular Perl module so the new() constructor
  228.         # isn't expecting a $context reference as the first argument;
  229.         # so we construct a closure which removes it before calling
  230.         # $module->new(@_);
  231.         $factory = sub {
  232.         shift;
  233.         $module->new(@_);
  234.         };
  235.         $error   = '';
  236.     }
  237.     }
  238.  
  239.     if ($factory) {
  240.     $self->debug("$name => $factory") if $self->{ DEBUG };
  241.     return $factory;
  242.     }
  243.     elsif ($error) {
  244.     return $self->{ TOLERANT } 
  245.         ? (undef,  Template::Constants::STATUS_DECLINED) 
  246.         : ($error, Template::Constants::STATUS_ERROR);
  247.     }
  248.     else {
  249.     return (undef, Template::Constants::STATUS_DECLINED);
  250.     }
  251. }
  252.  
  253.  
  254. #------------------------------------------------------------------------
  255. # _dump()
  256. # 
  257. # Debug method which constructs and returns text representing the current
  258. # state of the object.
  259. #------------------------------------------------------------------------
  260.  
  261. sub _dump {
  262.     my $self = shift;
  263.     my $output = "[Template::Plugins] {\n";
  264.     my $format = "    %-16s => %s\n";
  265.     my $key;
  266.  
  267.     foreach $key (qw( TOLERANT LOAD_PERL )) {
  268.     $output .= sprintf($format, $key, $self->{ $key });
  269.     }
  270.  
  271.     local $" = ', ';
  272.     my $fkeys = join(", ", keys %{$self->{ FACTORY }});
  273.     my $plugins = $self->{ PLUGINS };
  274.     $plugins = join('', map { 
  275.     sprintf("    $format", $_, $plugins->{ $_ });
  276.     } keys %$plugins);
  277.     $plugins = "{\n$plugins    }";
  278.     
  279.     $output .= sprintf($format, 'PLUGIN_BASE', "[ @{ $self->{ PLUGIN_BASE } } ]");
  280.     $output .= sprintf($format, 'PLUGINS', $plugins);
  281.     $output .= sprintf($format, 'FACTORY', $fkeys);
  282.     $output .= '}';
  283.     return $output;
  284. }
  285.  
  286.  
  287. 1;
  288.  
  289. __END__
  290.  
  291.  
  292. #------------------------------------------------------------------------
  293. # IMPORTANT NOTE
  294. #   This documentation is generated automatically from source
  295. #   templates.  Any changes you make here may be lost.
  296. # 
  297. #   The 'docsrc' documentation source bundle is available for download
  298. #   from http://www.template-toolkit.org/docs.html and contains all
  299. #   the source templates, XML files, scripts, etc., from which the
  300. #   documentation for the Template Toolkit is built.
  301. #------------------------------------------------------------------------
  302.  
  303. =head1 NAME
  304.  
  305. Template::Plugins - Plugin provider module
  306.  
  307. =head1 SYNOPSIS
  308.  
  309.     use Template::Plugins;
  310.  
  311.     $plugin_provider = Template::Plugins->new(\%options);
  312.  
  313.     ($plugin, $error) = $plugin_provider->fetch($name, @args);
  314.  
  315. =head1 DESCRIPTION
  316.  
  317. The Template::Plugins module defines a provider class which can be used
  318. to load and instantiate Template Toolkit plugin modules.
  319.  
  320. =head1 METHODS
  321.  
  322. =head2 new(\%params) 
  323.  
  324. Constructor method which instantiates and returns a reference to a
  325. Template::Plugins object.  A reference to a hash array of configuration
  326. items may be passed as a parameter.  These are described below.  
  327.  
  328. Note that the Template.pm front-end module creates a Template::Plugins
  329. provider, passing all configuration items.  Thus, the examples shown
  330. below in the form:
  331.  
  332.     $plugprov = Template::Plugins->new({
  333.     PLUGIN_BASE => 'MyTemplate::Plugin',
  334.         LOAD_PERL   => 1,
  335.     ...
  336.     });
  337.  
  338. can also be used via the Template module as:
  339.  
  340.     $ttengine = Template->new({
  341.     PLUGIN_BASE => 'MyTemplate::Plugin',
  342.         LOAD_PERL   => 1,
  343.     ...
  344.     });
  345.  
  346. as well as the more explicit form of:
  347.  
  348.     $plugprov = Template::Plugins->new({
  349.     PLUGIN_BASE => 'MyTemplate::Plugin',
  350.         LOAD_PERL   => 1,
  351.     ...
  352.     });
  353.  
  354.     $ttengine = Template->new({
  355.     LOAD_PLUGINS => [ $plugprov ],
  356.     });
  357.  
  358. =head2 fetch($name, @args)
  359.  
  360. Called to request that a plugin of a given name be provided.  The relevant 
  361. module is first loaded (if necessary) and the load() class method called 
  362. to return the factory class name (usually the same package name) or a 
  363. factory object (a prototype).  The new() method is then called as a 
  364. class or object method against the factory, passing all remaining
  365. parameters.
  366.  
  367. Returns a reference to a new plugin object or ($error, STATUS_ERROR)
  368. on error.  May also return (undef, STATUS_DECLINED) to decline to
  369. serve the request.  If TOLERANT is set then all errors will be
  370. returned as declines.
  371.  
  372. =head1 CONFIGURATION OPTIONS
  373.  
  374. The following list details the configuration options that can be provided
  375. to the Template::Plugins new() constructor.
  376.  
  377. =over 4
  378.  
  379.  
  380.  
  381.  
  382. =item PLUGINS
  383.  
  384. The PLUGINS options can be used to provide a reference to a hash array
  385. that maps plugin names to Perl module names.  A number of standard
  386. plugins are defined (e.g. 'table', 'cgi', 'dbi', etc.) which map to
  387. their corresponding Template::Plugin::* counterparts.  These can be
  388. redefined by values in the PLUGINS hash.
  389.  
  390.     my $plugins = Template::Plugins->new({
  391.     PLUGINS => {
  392.         cgi => 'MyOrg::Template::Plugin::CGI',
  393.             foo => 'MyOrg::Template::Plugin::Foo',
  394.         bar => 'MyOrg::Template::Plugin::Bar',
  395.     },
  396.     });
  397.  
  398. The USE directive is used to create plugin objects and does so by
  399. calling the plugin() method on the current Template::Context object.
  400. If the plugin name is defined in the PLUGINS hash then the
  401. corresponding Perl module is loaded via require().  The context then
  402. calls the load() class method which should return the class name 
  403. (default and general case) or a prototype object against which the 
  404. new() method can be called to instantiate individual plugin objects.
  405.  
  406. If the plugin name is not defined in the PLUGINS hash then the PLUGIN_BASE
  407. and/or LOAD_PERL options come into effect.
  408.  
  409.  
  410.  
  411.  
  412.  
  413. =item PLUGIN_BASE
  414.  
  415. If a plugin is not defined in the PLUGINS hash then the PLUGIN_BASE is used
  416. to attempt to construct a correct Perl module name which can be successfully 
  417. loaded.  
  418.  
  419. The PLUGIN_BASE can be specified as a single value or as a reference
  420. to an array of multiple values.  The default PLUGIN_BASE value,
  421. 'Template::Plugin', is always added the the end of the PLUGIN_BASE
  422. list (a single value is first converted to a list).  Each value should
  423. contain a Perl package name to which the requested plugin name is
  424. appended.
  425.  
  426. example 1:
  427.  
  428.     my $plugins = Template::Plugins->new({
  429.     PLUGIN_BASE => 'MyOrg::Template::Plugin',
  430.     });
  431.  
  432.     [% USE Foo %]    # => MyOrg::Template::Plugin::Foo
  433.                        or        Template::Plugin::Foo 
  434.  
  435. example 2:
  436.  
  437.     my $plugins = Template::Plugins->new({
  438.     PLUGIN_BASE => [   'MyOrg::Template::Plugin',
  439.              'YourOrg::Template::Plugin'  ],
  440.     });
  441.  
  442.     [% USE Foo %]    # =>   MyOrg::Template::Plugin::Foo
  443.                        or YourOrg::Template::Plugin::Foo 
  444.                        or          Template::Plugin::Foo 
  445.  
  446.  
  447.  
  448.  
  449.  
  450.  
  451. =item LOAD_PERL
  452.  
  453. If a plugin cannot be loaded using the PLUGINS or PLUGIN_BASE
  454. approaches then the provider can make a final attempt to load the
  455. module without prepending any prefix to the module path.  This allows
  456. regular Perl modules (i.e. those that don't reside in the
  457. Template::Plugin or some other such namespace) to be loaded and used
  458. as plugins.
  459.  
  460. By default, the LOAD_PERL option is set to 0 and no attempt will be made
  461. to load any Perl modules that aren't named explicitly in the PLUGINS
  462. hash or reside in a package as named by one of the PLUGIN_BASE
  463. components.  
  464.  
  465. Plugins loaded using the PLUGINS or PLUGIN_BASE receive a reference to
  466. the current context object as the first argument to the new()
  467. constructor.  Modules loaded using LOAD_PERL are assumed to not
  468. conform to the plugin interface.  They must provide a new() class
  469. method for instantiating objects but it will not receive a reference
  470. to the context as the first argument.  Plugin modules should provide a
  471. load() class method (or inherit the default one from the
  472. Template::Plugin base class) which is called the first time the plugin
  473. is loaded.  Regular Perl modules need not.  In all other respects,
  474. regular Perl objects and Template Toolkit plugins are identical.
  475.  
  476. If a particular Perl module does not conform to the common, but not
  477. unilateral, new() constructor convention then a simple plugin wrapper
  478. can be written to interface to it.
  479.  
  480.  
  481.  
  482.  
  483. =item TOLERANT
  484.  
  485. The TOLERANT flag is used by the various Template Toolkit provider
  486. modules (Template::Provider, Template::Plugins, Template::Filters) to
  487. control their behaviour when errors are encountered.  By default, any
  488. errors are reported as such, with the request for the particular
  489. resource (template, plugin, filter) being denied and an exception
  490. raised.  When the TOLERANT flag is set to any true values, errors will
  491. be silently ignored and the provider will instead return
  492. STATUS_DECLINED.  This allows a subsequent provider to take
  493. responsibility for providing the resource, rather than failing the
  494. request outright.  If all providers decline to service the request,
  495. either through tolerated failure or a genuine disinclination to
  496. comply, then a 'E<lt>resourceE<gt> not found' exception is raised.
  497.  
  498.  
  499.  
  500.  
  501. =item DEBUG
  502.  
  503. The DEBUG option can be used to enable debugging messages from the
  504. Template::Plugins module by setting it to include the DEBUG_PLUGINS
  505. value.
  506.  
  507.     use Template::Constants qw( :debug );
  508.  
  509.     my $template = Template->new({
  510.     DEBUG => DEBUG_FILTERS | DEBUG_PLUGINS,
  511.     });
  512.  
  513.  
  514.  
  515.  
  516. =back
  517.  
  518.  
  519.  
  520. =head1 TEMPLATE TOOLKIT PLUGINS
  521.  
  522. The following plugin modules are distributed with the Template
  523. Toolkit.  Some of the plugins interface to external modules (detailed
  524. below) which should be downloaded from any CPAN site and installed
  525. before using the plugin.
  526.  
  527. =head2 Autoformat
  528.  
  529. The Autoformat plugin is an interface to Damian Conway's Text::Autoformat 
  530. Perl module which provides advanced text wrapping and formatting.  See
  531. L<Template::Plugin::Autoformat> and L<Text::Autoformat> for further 
  532. details.
  533.  
  534.     [% USE autoformat(left=10, right=20) %]
  535.     [% autoformat(mytext) %]        # call autoformat sub
  536.     [% mytext FILTER autoformat %]  # or use autoformat filter
  537.  
  538. The Text::Autoformat module is available from CPAN:
  539.  
  540.     http://www.cpan.org/modules/by-module/Text/
  541.  
  542. =head2 CGI
  543.  
  544. The CGI plugin is a wrapper around Lincoln Stein's 
  545. E<lt>lstein@genome.wi.mit.eduE<gt> CGI.pm module.  The plugin is 
  546. distributed with the Template Toolkit (see L<Template::Plugin::CGI>)
  547. and the CGI module itself is distributed with recent versions Perl,
  548. or is available from CPAN.
  549.  
  550.     [% USE CGI %]
  551.     [% CGI.param('param_name') %]
  552.     [% CGI.start_form %]
  553.     [% CGI.popup_menu( Name   => 'color', 
  554.                        Values => [ 'Green', 'Brown' ] ) %]
  555.     [% CGI.end_form %]
  556.  
  557. =head2 Datafile
  558.  
  559. Provides an interface to data stored in a plain text file in a simple
  560. delimited format.  The first line in the file specifies field names
  561. which should be delimiter by any non-word character sequence.
  562. Subsequent lines define data using the same delimiter as int he first
  563. line.  Blank lines and comments (lines starting '#') are ignored.  See
  564. L<Template::Plugin::Datafile> for further details.
  565.  
  566. /tmp/mydata:
  567.  
  568.     # define names for each field
  569.     id : email : name : tel
  570.     # here's the data
  571.     fred : fred@here.com : Fred Smith : 555-1234
  572.     bill : bill@here.com : Bill White : 555-5678
  573.  
  574. example:
  575.  
  576.     [% USE userlist = datafile('/tmp/mydata') %]
  577.  
  578.     [% FOREACH user = userlist %]
  579.        [% user.name %] ([% user.id %])
  580.     [% END %]
  581.  
  582. =head2 Date
  583.  
  584. The Date plugin provides an easy way to generate formatted time and date
  585. strings by delegating to the POSIX strftime() routine.   See
  586. L<Template::Plugin::Date> and L<POSIX> for further details.
  587.  
  588.     [% USE date %]
  589.     [% date.format %]        # current time/date
  590.  
  591.     File last modified: [% date.format(template.modtime) %]
  592.  
  593. =head2 Directory
  594.  
  595. The Directory plugin provides a simple interface to a directory and
  596. the files within it.  See L<Template::Plugin::Directory> for further
  597. details.
  598.  
  599.     [% USE dir = Directory('/tmp') %]
  600.     [% FOREACH file = dir.files %]
  601.         # all the plain files in the directory
  602.     [% END %]
  603.     [% FOREACH file = dir.dirs %]
  604.         # all the sub-directories
  605.     [% END %]
  606.  
  607. =head2 DBI
  608.  
  609. The DBI plugin, developed by Simon Matthews
  610. E<lt>sam@knowledgepool.comE<gt>, brings the full power of Tim Bunce's
  611. E<lt>Tim.Bunce@ig.co.ukE<gt> database interface module (DBI) to your
  612. templates.  See L<Template::Plugin::DBI> and L<DBI> for further details.
  613.  
  614.     [% USE DBI('dbi:driver:database', 'user', 'pass') %]
  615.  
  616.     [% FOREACH user = DBI.query( 'SELECT * FROM users' ) %]
  617.        [% user.id %] [% user.name %]
  618.     [% END %]
  619.  
  620. The DBI and relevant DBD modules are available from CPAN:
  621.  
  622.   http://www.cpan.org/modules/by-module/DBI/
  623.  
  624. =head2 Dumper
  625.  
  626. The Dumper plugin provides an interface to the Data::Dumper module.  See
  627. L<Template::Plugin::Dumper> and L<Data::Dumper> for futher details.
  628.  
  629.     [% USE dumper(indent=0, pad="<br>") %]
  630.     [% dumper.dump(myvar, yourvar) %]
  631.  
  632. =head2 File
  633.  
  634. The File plugin provides a general abstraction for files and can be
  635. used to fetch information about specific files within a filesystem.
  636. See L<Template::Plugin::File> for further details.
  637.  
  638.     [% USE File('/tmp/foo.html') %]
  639.     [% File.name %]     # foo.html
  640.     [% File.dir %]      # /tmp
  641.     [% File.mtime %]    # modification time
  642.  
  643. =head2 Filter
  644.  
  645. This module implements a base class plugin which can be subclassed
  646. to easily create your own modules that define and install new filters.
  647.  
  648.     package MyOrg::Template::Plugin::MyFilter;
  649.  
  650.     use Template::Plugin::Filter;
  651.     use base qw( Template::Plugin::Filter );
  652.  
  653.     sub filter {
  654.     my ($self, $text) = @_;
  655.  
  656.     # ...mungify $text...
  657.  
  658.     return $text;
  659.     }
  660.  
  661.     # now load it...
  662.     [% USE MyFilter %]
  663.  
  664.     # ...and use the returned object as a filter
  665.     [% FILTER $MyFilter %]
  666.       ...
  667.     [% END %]
  668.  
  669. See L<Template::Plugin::Filter> for further details.
  670.  
  671. =head2 Format
  672.  
  673. The Format plugin provides a simple way to format text according to a
  674. printf()-like format.   See L<Template::Plugin::Format> for further 
  675. details.
  676.  
  677.     [% USE bold = format('<b>%s</b>') %]
  678.     [% bold('Hello') %]
  679.  
  680. =head2 GD::Image, GD::Polygon, GD::Constants
  681.  
  682. These plugins provide access to the GD graphics library via Lincoln
  683. D. Stein's GD.pm interface.  These plugins allow PNG, JPEG and other
  684. graphical formats to be generated.
  685.  
  686.     [% FILTER null;
  687.         USE im = GD.Image(100,100);
  688.         # allocate some colors
  689.         black = im.colorAllocate(0,   0, 0);
  690.         red   = im.colorAllocate(255,0,  0);
  691.         blue  = im.colorAllocate(0,  0,  255);
  692.         # Draw a blue oval
  693.         im.arc(50,50,95,75,0,360,blue);
  694.         # And fill it with red
  695.         im.fill(50,50,red);
  696.         # Output image in PNG format
  697.         im.png | stdout(1);
  698.        END;
  699.     -%]
  700.  
  701. See L<Template::Plugin::GD::Image> for further details.
  702.  
  703. =head2 GD::Text, GD::Text::Align, GD::Text::Wrap
  704.  
  705. These plugins provide access to Martien Verbruggen's GD::Text,
  706. GD::Text::Align and GD::Text::Wrap modules. These plugins allow the
  707. layout, alignment and wrapping of text when drawing text in GD images.
  708.  
  709.     [% FILTER null;
  710.         USE gd  = GD.Image(200,400);
  711.         USE gdc = GD.Constants;
  712.         black = gd.colorAllocate(0,   0, 0);
  713.         green = gd.colorAllocate(0, 255, 0);
  714.         txt = "This is some long text. " | repeat(10);
  715.         USE wrapbox = GD.Text.Wrap(gd,
  716.          line_space  => 4,
  717.          color       => green,
  718.          text        => txt,
  719.         );
  720.         wrapbox.set_font(gdc.gdMediumBoldFont);
  721.         wrapbox.set(align => 'center', width => 160);
  722.         wrapbox.draw(20, 20);
  723.         gd.png | stdout(1);
  724.       END;
  725.     -%]
  726.  
  727. See L<Template::Plugin::GD::Text>, L<Template::Plugin::GD::Text::Align>
  728. and L<Template::Plugin::GD::Text::Wrap> for further details.
  729.  
  730. =head2 GD::Graph::lines, GD::Graph::bars, GD::Graph::points, GD::Graph::linespoin
  731. ts, GD::Graph::area, GD::Graph::mixed, GD::Graph::pie
  732.  
  733. These plugins provide access to Martien Verbruggen's GD::Graph module
  734. that allows graphs, plots and charts to be created. These plugins allow
  735. graphs, plots and charts to be generated in PNG, JPEG and other
  736. graphical formats.
  737.  
  738.     [% FILTER null;
  739.         data = [
  740.             ["1st","2nd","3rd","4th","5th","6th"],
  741.             [    4,    2,    3,    4,    3,  3.5]
  742.         ];
  743.         USE my_graph = GD.Graph.pie(250, 200);
  744.         my_graph.set(
  745.                 title => 'A Pie Chart',
  746.                 label => 'Label',
  747.                 axislabelclr => 'black',
  748.                 pie_height => 36,
  749.                 transparent => 0,
  750.         );
  751.         my_graph.plot(data).png | stdout(1);
  752.       END;
  753.     -%]
  754.  
  755. See
  756. L<Template::Plugin::GD::Graph::lines>,
  757. L<Template::Plugin::GD::Graph::bars>,
  758. L<Template::Plugin::GD::Graph::points>,
  759. L<Template::Plugin::GD::Graph::linespoints>,
  760. L<Template::Plugin::GD::Graph::area>,
  761. L<Template::Plugin::GD::Graph::mixed>,
  762. L<Template::Plugin::GD::Graph::pie>, and
  763. L<GD::Graph>,
  764. for more details.
  765.  
  766. =head2 GD::Graph::bars3d, GD::Graph::lines3d, GD::Graph::pie3d
  767.  
  768. These plugins provide access to Jeremy Wadsack's GD::Graph3d
  769. module.  This allows 3D bar charts and 3D lines plots to
  770. be generated.
  771.  
  772.     [% FILTER null;
  773.         data = [
  774.             ["1st","2nd","3rd","4th","5th","6th","7th", "8th", "9th"],
  775.             [    1,    2,    5,    6,    3,  1.5,    1,     3,     4],
  776.         ];
  777.         USE my_graph = GD.Graph.bars3d();
  778.         my_graph.set(
  779.             x_label         => 'X Label',
  780.             y_label         => 'Y label',
  781.             title           => 'A 3d Bar Chart',
  782.             y_max_value     => 8,
  783.             y_tick_number   => 8,
  784.             y_label_skip    => 2,
  785.             # shadows
  786.             bar_spacing     => 8,
  787.             shadow_depth    => 4,
  788.             shadowclr       => 'dred',
  789.             transparent     => 0,
  790.         my_graph.plot(data).png | stdout(1);
  791.       END;
  792.     -%]
  793.  
  794. See
  795. L<Template::Plugin::GD::Graph::lines3d>,
  796. L<Template::Plugin::GD::Graph::bars3d>, and
  797. L<Template::Plugin::GD::Graph::pie3d>
  798. for more details.
  799.  
  800. =head2 HTML
  801.  
  802. The HTML plugin is very new and very basic, implementing a few useful
  803. methods for generating HTML.  It is likely to be extended in the future
  804. or integrated with a larger project to generate HTML elements in a generic
  805. way (as discussed recently on the mod_perl mailing list).
  806.  
  807.     [% USE HTML %]
  808.     [% HTML.escape("if (a < b && c > d) ..." %]
  809.     [% HTML.attributes(border => 1, cellpadding => 2) %]
  810.     [% HTML.element(table => { border => 1, cellpadding => 2 }) %]
  811.  
  812. See L<Template::Plugin::HTML> for further details.
  813.  
  814. =head2 Iterator
  815.  
  816. The Iterator plugin provides a way to create a Template::Iterator
  817. object to iterate over a data set.  An iterator is created
  818. automatically by the FOREACH directive and is aliased to the 'loop'
  819. variable.  This plugin allows an iterator to be explicitly created
  820. with a given name, or the default plugin name, 'iterator'.  See
  821. L<Template::Plugin::Iterator> for further details.
  822.  
  823.     [% USE iterator(list, args) %]
  824.  
  825.     [% FOREACH item = iterator %]
  826.        [% '<ul>' IF iterator.first %]
  827.        <li>[% item %]
  828.        [% '</ul>' IF iterator.last %]
  829.     [% END %]
  830.  
  831. =head2 Pod
  832.  
  833. This plugin provides an interface to the L<Pod::POM|Pod::POM> module
  834. which parses POD documents into an internal object model which can
  835. then be traversed and presented through the Template Toolkit.
  836.  
  837.     [% USE Pod(podfile) %]
  838.  
  839.     [% FOREACH head1 = Pod.head1;
  840.      FOREACH head2 = head1/head2;
  841.        ...
  842.          END;
  843.        END
  844.     %]
  845.  
  846. =head2 String
  847.  
  848. The String plugin implements an object-oriented interface for 
  849. manipulating strings.  See L<Template::Plugin::String> for further 
  850. details.
  851.  
  852.     [% USE String 'Hello' %]
  853.     [% String.append(' World') %]
  854.  
  855.     [% msg = String.new('Another string') %]
  856.     [% msg.replace('string', 'text') %]
  857.  
  858.     The string "[% msg %]" is [% msg.length %] characters long.
  859.  
  860. =head2 Table
  861.  
  862. The Table plugin allows you to format a list of data items into a 
  863. virtual table by specifying a fixed number of rows or columns, with 
  864. an optional overlap.  See L<Template::Plugin::Table> for further 
  865. details.
  866.  
  867.     [% USE table(list, rows=10, overlap=1) %]
  868.  
  869.     [% FOREACH item = table.col(3) %]
  870.        [% item %]
  871.     [% END %]
  872.  
  873. =head2 URL
  874.  
  875. The URL plugin provides a simple way of contructing URLs from a base
  876. part and a variable set of parameters.  See L<Template::Plugin::URL>
  877. for further details.
  878.  
  879.     [% USE mycgi = url('/cgi-bin/bar.pl', debug=1) %]
  880.  
  881.     [% mycgi %]
  882.        # ==> /cgi/bin/bar.pl?debug=1
  883.  
  884.     [% mycgi(mode='submit') %]
  885.        # ==> /cgi/bin/bar.pl?mode=submit&debug=1
  886.  
  887. =head2 Wrap
  888.  
  889. The Wrap plugin uses the Text::Wrap module by David Muir Sharnoff 
  890. E<lt>muir@idiom.comE<gt> (with help from Tim Pierce and many many others)
  891. to provide simple paragraph formatting.  See L<Template::Plugin::Wrap>
  892. and L<Text::Wrap> for further details.
  893.  
  894.     [% USE wrap %]
  895.     [% wrap(mytext, 40, '* ', '  ') %]    # use wrap sub
  896.     [% mytext FILTER wrap(40) -%]    # or wrap FILTER
  897.  
  898. The Text::Wrap module is available from CPAN:
  899.  
  900.     http://www.cpan.org/modules/by-module/Text/
  901.  
  902. =head2 XML::DOM
  903.  
  904. The XML::DOM plugin gives access to the XML Document Object Module via
  905. Clark Cooper E<lt>cooper@sch.ge.comE<gt> and Enno Derksen's 
  906. E<lt>enno@att.comE<gt> XML::DOM module.  See L<Template::Plugin::XML::DOM> 
  907. and L<XML::DOM> for further details.
  908.  
  909.     [% USE dom = XML.DOM %]
  910.     [% doc = dom.parse(filename) %]
  911.  
  912.     [% FOREACH node = doc.getElementsByTagName('CODEBASE') %]
  913.        * [% node.getAttribute('href') %]
  914.     [% END %]
  915.  
  916. The plugin requires the XML::DOM module, available from CPAN:
  917.  
  918.     http://www.cpan.org/modules/by-module/XML/
  919.  
  920. =head2 XML::RSS
  921.  
  922. The XML::RSS plugin is a simple interface to Jonathan Eisenzopf's
  923. E<lt>eisen@pobox.comE<gt> XML::RSS module.  A RSS (Rich Site Summary)
  924. file is typically used to store short news 'headlines' describing
  925. different links within a site.  This plugin allows you to parse RSS
  926. files and format the contents accordingly using templates.  
  927. See L<Template::Plugin::XML::RSS> and L<XML::RSS> for further details.
  928.  
  929.     [% USE news = XML.RSS(filename) %]
  930.    
  931.     [% FOREACH item = news.items %]
  932.        <a href="[% item.link %]">[% item.title %]</a>
  933.     [% END %]
  934.  
  935. The XML::RSS module is available from CPAN:
  936.  
  937.     http://www.cpan.org/modules/by-module/XML/
  938.  
  939. =head2 XML::Simple
  940.  
  941. This plugin implements an interface to the L<XML::Simple|XML::Simple>
  942. module.
  943.  
  944.     [% USE xml = XML.Simple(xml_file_or_text) %]
  945.  
  946.     [% xml.head.title %]
  947.  
  948. See L<Template::Plugin::XML::Simple> for further details.
  949.  
  950. =head2 XML::Style
  951.  
  952. This plugin defines a filter for performing simple stylesheet based 
  953. transformations of XML text.  
  954.  
  955.     [% USE xmlstyle 
  956.            table = { 
  957.                attributes = { 
  958.                    border      = 0
  959.                    cellpadding = 4
  960.                    cellspacing = 1
  961.                }
  962.            }
  963.     %]
  964.  
  965.     [% FILTER xmlstyle %]
  966.     <table>
  967.     <tr>
  968.       <td>Foo</td> <td>Bar</td> <td>Baz</td>
  969.     </tr>
  970.     </table>
  971.     [% END %]
  972.  
  973. See L<Template::Plugin::XML::Style> for further details.
  974.  
  975. =head2 XML::XPath
  976.  
  977. The XML::XPath plugin provides an interface to Matt Sergeant's
  978. E<lt>matt@sergeant.orgE<gt> XML::XPath module.  See 
  979. L<Template::Plugin::XML::XPath> and L<XML::XPath> for further details.
  980.  
  981.     [% USE xpath = XML.XPath(xmlfile) %]
  982.     [% FOREACH page = xpath.findnodes('/html/body/page') %]
  983.        [% page.getAttribute('title') %]
  984.     [% END %]
  985.  
  986. The plugin requires the XML::XPath module, available from CPAN:
  987.  
  988.     http://www.cpan.org/modules/by-module/XML/
  989.  
  990.  
  991.  
  992.  
  993. =head1 BUGS / ISSUES
  994.  
  995. =over 4
  996.  
  997. =item *
  998.  
  999. It might be worthwhile being able to distinguish between absolute
  1000. module names and those which should be applied relative to PLUGIN_BASE
  1001. directories.  For example, use 'MyNamespace::MyModule' to denote
  1002. absolute module names (e.g. LOAD_PERL), and 'MyNamespace.MyModule' to
  1003. denote relative to PLUGIN_BASE.
  1004.  
  1005. =back
  1006.  
  1007. =head1 AUTHOR
  1008.  
  1009. Andy Wardley E<lt>abw@andywardley.comE<gt>
  1010.  
  1011. L<http://www.andywardley.com/|http://www.andywardley.com/>
  1012.  
  1013.  
  1014.  
  1015.  
  1016. =head1 VERSION
  1017.  
  1018. 2.70, distributed as part of the
  1019. Template Toolkit version 2.13, released on 30 January 2004.
  1020.  
  1021. =head1 COPYRIGHT
  1022.  
  1023.   Copyright (C) 1996-2004 Andy Wardley.  All Rights Reserved.
  1024.   Copyright (C) 1998-2002 Canon Research Centre Europe Ltd.
  1025.  
  1026. This module is free software; you can redistribute it and/or
  1027. modify it under the same terms as Perl itself.
  1028.  
  1029. =head1 SEE ALSO
  1030.  
  1031. L<Template|Template>, L<Template::Plugin|Template::Plugin>, L<Template::Context|Template::Context>
  1032.  
  1033. =cut
  1034.  
  1035. # Local Variables:
  1036. # mode: perl
  1037. # perl-indent-level: 4
  1038. # indent-tabs-mode: nil
  1039. # End:
  1040. #
  1041. # vim: expandtab shiftwidth=4:
  1042.