home *** CD-ROM | disk | FTP | other *** search
/ PC Professionell 2004 December / PCpro_2004_12.ISO / files / webserver / tsw / TSW_3.4.0.exe / Apache2 / perl / Date.pm < prev    next >
Encoding:
Perl POD Document  |  2004-01-30  |  10.6 KB  |  362 lines
  1. #============================================================= -*-Perl-*-
  2. #
  3. # Template::Plugin::Date
  4. #
  5. # DESCRIPTION
  6. #
  7. #   Plugin to generate formatted date strings.
  8. #
  9. # AUTHORS
  10. #   Thierry-Michel Barral  <kktos@electron-libre.com>
  11. #   Andy Wardley           <abw@cre.canon.co.uk>
  12. #
  13. # COPYRIGHT
  14. #   Copyright (C) 2000 Thierry-Michel Barral, Andy Wardley.
  15. #
  16. #   This module is free software; you can redistribute it and/or
  17. #   modify it under the same terms as Perl itself.
  18. #
  19. #----------------------------------------------------------------------------
  20. #
  21. # $Id: Date.pm,v 2.71 2004/01/13 16:20:38 abw Exp $
  22. #
  23. #============================================================================
  24.  
  25. package Template::Plugin::Date;
  26.  
  27. use strict;
  28. use vars qw( $VERSION $FORMAT @LOCALE_SUFFIX );
  29. use base qw( Template::Plugin );
  30. use Template::Plugin;
  31.  
  32. use POSIX ();
  33.  
  34. $VERSION = sprintf("%d.%02d", q$Revision: 2.71 $ =~ /(\d+)\.(\d+)/);
  35. $FORMAT  = '%H:%M:%S %d-%b-%Y';    # default strftime() format
  36. @LOCALE_SUFFIX = qw( .ISO8859-1 .ISO_8859-15 .US-ASCII .UTF-8 );
  37.  
  38. #------------------------------------------------------------------------
  39. # new(\%options)
  40. #------------------------------------------------------------------------
  41.  
  42. sub new {
  43.     my ($class, $context, $params) = @_;
  44.     bless {
  45.     $params ? %$params : ()
  46.     }, $class;
  47. }
  48.  
  49.  
  50. #------------------------------------------------------------------------
  51. # now()
  52. # 
  53. # Call time() to return the current system time in seconds since the epoch.
  54. #------------------------------------------------------------------------
  55.  
  56. sub now {
  57.     return time();
  58. }
  59.  
  60.  
  61. #------------------------------------------------------------------------
  62. # format()                           
  63. # format($time)
  64. # format($time, $format)
  65. # format($time, $format, $locale)
  66. # format($time, $format, $locale, $gmt_flag)
  67. # format(\%named_params);
  68. # 
  69. # Returns a formatted time/date string for the specified time, $time, 
  70. # (or the current system time if unspecified) using the $format, $locale,
  71. # and $gmt values specified as arguments or internal values set defined
  72. # at construction time).  Specifying a Perl-true value for $gmt will
  73. # override the local time zone and force the output to be for GMT.
  74. # Any or all of the arguments may be specified as named parameters which 
  75. # get passed as a hash array reference as the final argument.
  76. # ------------------------------------------------------------------------
  77.  
  78. sub format {
  79.     my $self   = shift;
  80.     my $params = ref($_[$#_]) eq 'HASH' ? pop(@_) : { };
  81.     my $time   = shift(@_) || $params->{ time } || $self->{ time } 
  82.                || $self->now();
  83.     my $format = @_ ? shift(@_) 
  84.             : ($params->{ format } || $self->{ format } || $FORMAT);
  85.     my $locale = @_ ? shift(@_)
  86.             : ($params->{ locale } || $self->{ locale });
  87.     my $gmt = @_ ? shift(@_)
  88.             : ($params->{ gmt } || $self->{ gmt });
  89.     my (@date, $datestr);
  90.  
  91.     if ($time =~ /^\d+$/) {
  92.         # $time is now in seconds since epoch
  93.         if ($gmt) {
  94.             @date = (gmtime($time))[0..6];
  95.         }
  96.         else {
  97.             @date = (localtime($time))[0..6];
  98.         }
  99.     }
  100.     else {
  101.         # if $time is numeric, then we assume it's seconds since the epoch
  102.         # otherwise, we try to parse it as a 'H:M:S D:M:Y' string
  103.         @date = (split(/(?:\/| |:|-)/, $time))[2,1,0,3..5];
  104.         return (undef, Template::Exception->new('date',
  105.                "bad time/date string:  expects 'h:m:s d:m:y'  got: '$time'"))
  106.             unless @date >= 6 && defined $date[5];
  107.         $date[4] -= 1;     # correct month number 1-12 to range 0-11
  108.         $date[5] -= 1900;  # convert absolute year to years since 1900
  109.         $time = &POSIX::mktime(@date);
  110.     }
  111.     
  112.     if ($locale) {
  113.     # format the date in a specific locale, saving and subsequently
  114.         # restoring the current locale.
  115.         my $old_locale = &POSIX::setlocale(&POSIX::LC_ALL);
  116.  
  117.         # some systems expect locales to have a particular suffix
  118.         for my $suffix ('', @LOCALE_SUFFIX) {
  119.             my $try_locale = $locale.$suffix;
  120.         my $setlocale = &POSIX::setlocale(&POSIX::LC_ALL, $try_locale);
  121.             if (defined $setlocale && $try_locale eq $setlocale) {
  122.                 $locale = $try_locale;
  123.                 last;
  124.             }
  125.         }
  126.         $datestr = &POSIX::strftime($format, @date);
  127.         &POSIX::setlocale(&POSIX::LC_ALL, $old_locale);
  128.     }
  129.     else {
  130.         $datestr = &POSIX::strftime($format, @date);
  131.     }
  132.  
  133.     return $datestr;
  134. }
  135.  
  136. sub calc {
  137.     my $self = shift;
  138.     eval { require "Date/Calc.pm" };
  139.     $self->throw("failed to load Date::Calc: $@") if $@;
  140.     return Template::Plugin::Date::Calc->new('no context');
  141. }
  142.  
  143. sub manip {
  144.     my $self = shift;
  145.     eval { require "Date/Manip.pm" };
  146.     $self->throw("failed to load Date::Manip: $@") if $@;
  147.     return Template::Plugin::Date::Manip->new('no context');
  148. }
  149.  
  150.  
  151. sub throw {
  152.     my $self = shift;
  153.     die (Template::Exception->new('date', join(', ', @_)));
  154. }
  155.  
  156.  
  157. package Template::Plugin::Date::Calc;
  158. use base qw( Template::Plugin );
  159. use vars qw( $AUTOLOAD );
  160. *throw = \&Template::Plugin::Date::throw;
  161.  
  162. sub AUTOLOAD {
  163.     my $self = shift;
  164.     my $method = $AUTOLOAD;
  165.  
  166.     $method =~ s/.*:://;
  167.     return if $method eq 'DESTROY';
  168.  
  169.     my $sub = \&{"Date::Calc::$method"};
  170.     $self->throw("no such Date::Calc method: $method")
  171.     unless $sub;
  172.  
  173.     &$sub(@_);
  174. }
  175.  
  176. package Template::Plugin::Date::Manip;
  177. use base qw( Template::Plugin );
  178. use vars qw( $AUTOLOAD );
  179. *throw = \&Template::Plugin::Date::throw;
  180.  
  181. sub AUTOLOAD {
  182.     my $self = shift;
  183.     my $method = $AUTOLOAD;
  184.     
  185.     $method =~ s/.*:://;
  186.     return if $method eq 'DESTROY';
  187.     
  188.     my $sub = \&{"Date::Manip::$method"};
  189.     $self->throw("no such Date::Manip method: $method")
  190.         unless $sub;
  191.     
  192.     &$sub(@_);
  193. }
  194.     
  195.     
  196. 1;
  197.  
  198. __END__
  199.  
  200.  
  201. #------------------------------------------------------------------------
  202. # IMPORTANT NOTE
  203. #   This documentation is generated automatically from source
  204. #   templates.  Any changes you make here may be lost.
  205. # 
  206. #   The 'docsrc' documentation source bundle is available for download
  207. #   from http://www.template-toolkit.org/docs.html and contains all
  208. #   the source templates, XML files, scripts, etc., from which the
  209. #   documentation for the Template Toolkit is built.
  210. #------------------------------------------------------------------------
  211.  
  212. =head1 NAME
  213.  
  214. Template::Plugin::Date - Plugin to generate formatted date strings
  215.  
  216. =head1 SYNOPSIS
  217.  
  218.     [% USE date %]
  219.  
  220.     # use current time and default format
  221.     [% date.format %]
  222.  
  223.     # specify time as seconds since epoch or 'h:m:s d-m-y' string
  224.     [% date.format(960973980) %]
  225.     [% date.format('4:20:36 21/12/2000') %]
  226.  
  227.     # specify format
  228.     [% date.format(mytime, '%H:%M:%S') %]
  229.  
  230.     # specify locale
  231.     [% date.format(date.now, '%a %d %b %y', 'en_GB') %]
  232.  
  233.     # named parameters 
  234.     [% date.format(mytime, format = '%H:%M:%S') %]
  235.     [% date.format(locale = 'en_GB') %]
  236.     [% date.format(time   = date.now, 
  237.            format = '%H:%M:%S', 
  238.                    locale = 'en_GB) %]
  239.    
  240.     # specify default format to plugin
  241.     [% USE date(format = '%H:%M:%S', locale = 'de_DE') %]
  242.  
  243.     [% date.format %]
  244.     ...
  245.  
  246. =head1 DESCRIPTION
  247.  
  248. The Date plugin provides an easy way to generate formatted time and date
  249. strings by delegating to the POSIX strftime() routine.  
  250.  
  251. The plugin can be loaded via the familiar USE directive.
  252.  
  253.     [% USE date %]
  254.  
  255. This creates a plugin object with the default name of 'date'.  An alternate
  256. name can be specified as such:
  257.  
  258.     [% USE myname = date %]
  259.  
  260. The plugin provides the format() method which accepts a time value, a
  261. format string and a locale name.  All of these parameters are optional
  262. with the current system time, default format ('%H:%M:%S %d-%b-%Y') and
  263. current locale being used respectively, if undefined.  Default values
  264. for the time, format and/or locale may be specified as named parameters 
  265. in the USE directive.
  266.  
  267.     [% USE date(format = '%a %d-%b-%Y', locale = 'fr_FR') %]
  268.  
  269. When called without any parameters, the format() method returns a string
  270. representing the current system time, formatted by strftime() according 
  271. to the default format and for the default locale (which may not be the
  272. current one, if locale is set in the USE directive).
  273.  
  274.     [% date.format %]
  275.  
  276. The plugin allows a time/date to be specified as seconds since the epoch,
  277. as is returned by time().
  278.  
  279.     File last modified: [% date.format(filemod_time) %]
  280.  
  281. The time/date can also be specified as a string of the form 'h:m:s d/m/y'.
  282. Any of the characters : / - or space may be used to delimit fields.
  283.  
  284.     [% USE day = date(format => '%A', locale => 'en_GB') %]
  285.     [% day.format('4:20:00 9-13-2000') %]  
  286.  
  287. Output:
  288.  
  289.     Tuesday
  290.  
  291. A format string can also be passed to the format() method, and a locale
  292. specification may follow that.
  293.  
  294.     [% date.format(filemod, '%d-%b-%Y') %]
  295.     [% date.format(filemod, '%d-%b-%Y', 'en_GB') %]
  296.  
  297. A fourth parameter allows you to force output in GMT, in the case of 
  298. seconds-since-the-epoch input:
  299.  
  300.     [% date.format(filemod, '%d-%b-%Y', 'en_GB', 1) %]
  301.  
  302. Note that in this case, if the local time is not GMT, then also specifying
  303. '%Z' (time zone) in the format parameter will lead to an extremely 
  304. misleading result.
  305.  
  306. Any or all of these parameters may be named.  Positional parameters
  307. should always be in the order ($time, $format, $locale).
  308.  
  309.     [% date.format(format => '%H:%M:%S') %]
  310.     [% date.format(time => filemod, format => '%H:%M:%S') %]
  311.     [% date.format(mytime, format => '%H:%M:%S') %]
  312.     [% date.format(mytime, format => '%H:%M:%S', locale => 'fr_FR') %]
  313.     [% date.format(mytime, format => '%H:%M:%S', gmt => 1) %]
  314.     ...etc...
  315.  
  316. The now() method returns the current system time in seconds since the 
  317. epoch.  
  318.  
  319.     [% date.format(date.now, '%A') %]
  320.  
  321. The calc() method can be used to create an interface to the Date::Calc
  322. module (if installed on your system).
  323.  
  324.     [% calc = date.calc %]
  325.     [% calc.Monday_of_Week(22, 2001).join('/') %]
  326.  
  327. The manip() method can be used to create an interface to the Date::Manip
  328. module (if installed on your system).
  329.  
  330.     [% manip = date.manip %]
  331.     [% manip.UnixDate("Noon Yesterday","%Y %b %d %H:%M") %]
  332.  
  333. =head1 AUTHORS
  334.  
  335. Thierry-Michel Barral E<lt>kktos@electron-libre.comE<gt> wrote the original
  336. plugin.
  337.  
  338. Andy Wardley E<lt>abw@cre.canon.co.ukE<gt> provided some minor
  339. fixups/enhancements, a test script and documentation.
  340.  
  341. Mark D. Mills E<lt>mark@hostile.orgE<gt> cloned Date::Manip from the
  342. cute Date::Calc sub-plugin.
  343.  
  344. =head1 VERSION
  345.  
  346. 2.71, distributed as part of the
  347. Template Toolkit version 2.13, released on 30 January 2004.
  348.  
  349.  
  350.  
  351. =head1 COPYRIGHT
  352.  
  353. Copyright (C) 2000 Thierry-Michel Barral, Andy Wardley.
  354.  
  355. This module is free software; you can redistribute it and/or
  356. modify it under the same terms as Perl itself.
  357.  
  358. =head1 SEE ALSO
  359.  
  360. L<Template::Plugin|Template::Plugin>, L<POSIX|POSIX>
  361.  
  362.