home *** CD-ROM | disk | FTP | other *** search
/ Mac Easy 2010 May / Mac Life Ubuntu.iso / casper / filesystem.squashfs / usr / lib / perl5 / Glib / MakeHelper.pm < prev    next >
Encoding:
Perl POD Document  |  2008-11-04  |  16.7 KB  |  582 lines
  1. #
  2. # $Header: /cvsroot/gtk2-perl/gtk2-perl-xs/Glib/MakeHelper.pm,v 1.44 2008/03/30 17:21:39 kaffeetisch Exp $
  3. #
  4.  
  5. package Glib::MakeHelper;
  6.  
  7. our $VERSION = '0.03';
  8.  
  9. =head1 NAME
  10.  
  11. Glib::MakeHelper - Makefile.PL utilities for Glib-based extensions
  12.  
  13. =head1 SYNOPSIS
  14.  
  15.  eval "use Glib::MakeHelper; 1"
  16.      or complain_that_glib_is_too_old_and_die();
  17.  
  18.  %xspod_files = Glib::MakeHelper->do_pod_files (@xs_files);
  19.  
  20.  package MY;
  21.  sub postamble {
  22.      return Glib::MakeHelper->postamble_clean ()
  23.           . Glib::MakeHelper->postamble_docs (@main::xs_files)
  24.           . Glib::MakeHelper->postamble_rpms (
  25.                  MYLIB     => $build_reqs{MyLib},
  26.             );
  27.  }
  28.  
  29. =head1 DESCRIPTION
  30.  
  31. The Makefile.PL for your typical Glib-based module is huge and hairy, thanks to
  32. all the crazy hoops you have to jump through to get things right.  This module
  33. wraps up some of the more intense and error-prone bits to reduce the amount of
  34. copied code and potential for errors.
  35.  
  36. =cut
  37.  
  38. use strict;
  39. use warnings;
  40. use Carp;
  41. use Cwd;
  42.  
  43. our @gend_pods = ();
  44.  
  45. =head1 METHODS
  46.  
  47. =over
  48.  
  49. =item HASH = Glib::MakeHelper->do_pod_files (@xs_files)
  50.  
  51. Scan the I<@xs_files> and return a hash describing the pod files that will
  52. be created.  This is in the format wanted by WriteMakefile(). If @ARGV contains
  53. the string C<disable-apidoc> an empty list will be returned and thus no apidoc
  54. pod will be generated speeding up the build process.
  55.  
  56. =cut
  57.  
  58. sub do_pod_files
  59. {
  60.     return () if (grep /disable[-_]apidoc/i, @ARGV);
  61.     print STDERR "Including generated API documentation...\n";
  62.  
  63.     shift; # package name
  64.  
  65.     # try to get it from pwd first, then fall back to installed
  66.     # this is so Glib will get associated copy, and everyone else
  67.     # should use the installed glib copy
  68.     eval { require 'ParseXSDoc.pm'; 1; } or require Glib::ParseXSDoc;
  69.     $@ = undef;
  70.     import Glib::ParseXSDoc;
  71.  
  72.     my %pod_files = ();
  73.  
  74.     open PARSE, '>build/doc.pl';
  75.     select PARSE;
  76.     my $pods = xsdocparse (@_);
  77.     select STDOUT;
  78.     @gend_pods = ();
  79.     foreach (@$pods)
  80.     {
  81.         my $pod = $_;
  82.         my $path = '$(INST_LIB)';
  83.         $pod = File::Spec->catfile ($path, split (/::/, $_)) . ".pod";
  84.         push @gend_pods, $pod;
  85.         $pod_files{$pod} = '$(INST_MAN3DIR)/'.$_.'.$(MAN3EXT)';
  86.     }
  87.     $pod_files{'$(INST_LIB)/$(FULLEXT)/index.pod'} = '$(INST_MAN3DIR)/$(NAME)::index.$(MAN3EXT)';
  88.  
  89.     return %pod_files;
  90. }
  91.  
  92. =item LIST = Glib::MakeHelper->select_files_by_version ($stem, $major, $minor)
  93.  
  94. Returns a list of all files that match "$stem-\d+\.\d+" and for which the first
  95. number is bigger than I<$major> and the second number is bigger than I<$minor>.
  96. If I<$minor> is odd, it will be incremented by one so that the version number of
  97. an upcoming stable release can be used during development as well.
  98.  
  99. =cut
  100.  
  101. sub select_files_by_version {
  102.     my ($class, $stem, $major, $minor) = @_;
  103.  
  104.     # make minors even, so that we don't have to deal with stable/unstable
  105.     # file naming changes.
  106.     $minor++ if ($minor % 2);
  107.  
  108.     my @files = ();
  109.     foreach (glob $stem . '-*.*') {
  110.         if (/$stem-(\d+)\.(\d+)/) {
  111.             push @files, $_
  112.                 if  $1 <= $major
  113.                 and $2 <= $minor;
  114.         }
  115.     }
  116.  
  117.     return @files;
  118. }
  119.  
  120. =item LIST = Glib::MakeHelper->read_source_list_file ($filename)
  121.  
  122. Reads I<$filename>, removes all comments (starting with "#") and leading and
  123. trailing whitespace, and returns a list of all lines that survived the treatment.
  124.  
  125. =cut
  126.  
  127. sub read_source_list_file {
  128.     my ($class, $filename) = @_;
  129.     my @list = ();
  130.     open IN, $filename or die "can't read $filename: $!\n";
  131.     while (<IN>) {
  132.         s/#.*$//;        # eat comments
  133.         s/^\s*//;        # trim leading space
  134.         s/\s*$//;        # trim trailing space
  135.         push @list, $_ if $_;    # keep non-blanks
  136.     }
  137.     close IN;
  138.     return @list;
  139. }
  140.  
  141. =item string = Glib::MakeHelper->get_configure_requires_yaml (%module_to_version)
  142.  
  143. Generates YAML code that lists every module found in I<%module_to_version>
  144. under the C<configure_requires> key.  This can be used with
  145. I<ExtUtils::MakeMaker>'s C<EXTRA_META> parameter to specify which modules are
  146. needed at I<Makefile.PL> time.
  147.  
  148. =cut
  149.  
  150. sub get_configure_requires_yaml {
  151.   shift; # package name
  152.   my %prereqs = @_;
  153.  
  154.   my $yaml = "configure_requires:\n";
  155.   while (my ($module, $version) = each %prereqs) {
  156.     $yaml .= "   $module: $version\n";
  157.   }
  158.  
  159.   return $yaml;
  160. }
  161.  
  162. =item string = Glib::MakeHelper->postamble_clean (@files)
  163.  
  164. Create and return the text of a realclean rule that cleans up after much 
  165. of the autogeneration performed by Glib-based modules.  Everything in @files
  166. will be deleted, too (it may be empty).
  167.  
  168. The reasoning behind using this instead of just having you use the 'clean'
  169. or 'realclean' keys is that this avoids you having to remember to put Glib's
  170. stuff in your Makefile.PL's WriteMakefile arguments.
  171.  
  172. =cut
  173.  
  174. sub postamble_clean
  175. {
  176.     shift; # package name
  177. "
  178. realclean ::
  179.     -\$(RM_RF) build perl-\$(DISTNAME).spec ".join(" ", @_)."
  180. ";
  181. }
  182.  
  183. =item string = Glib::MakeHelper->postamble_docs (@xs_files)
  184.  
  185. NOTE: this is The Old Way.  see L<postamble_docs_full> for The New Way.
  186.  
  187. Create and return the text of Makefile rules to build documentation from
  188. the XS files with Glib::ParseXSDoc and Glib::GenPod.
  189.  
  190. Use this in your MY::postamble to enable autogeneration of POD.
  191.  
  192. This updates dependencies with the list of pod names generated by an earlier
  193. run of C<do_pod_files>.
  194.  
  195. There is a special Makefile variable POD_DEPENDS that should be set to the
  196. list of files that need to be created before the doc.pl step is run, include
  197. files.
  198.  
  199. There is also a variable BLIB_DONE which should be used as a dependency
  200. anywhere a rule needs to be sure that a loadable and working module resides in
  201. the blib directory before running.
  202.  
  203. =cut
  204.  
  205. sub postamble_docs
  206. {
  207.     my ($class, @xs_files) = @_;
  208.     return Glib::MakeHelper->postamble_docs_full (XS_FILES => \@xs_files);
  209. }
  210.  
  211. =item string = Glib::MakeHelper->postamble_docs_full (...)
  212.  
  213. Create and return the text of Makefile rules to build documentation from
  214. the XS files with Glib::ParseXSDoc and Glib::GenPod.
  215.  
  216. Use this in your MY::postamble to enable autogeneration of POD.
  217.  
  218. This updates dependencies with the list of pod names generated by an earlier
  219. run of C<do_pod_files>.
  220.  
  221. There is a special Makefile variable POD_DEPENDS that should be set to the
  222. list of files that need to be created before the doc.pl step is run, include
  223. files.
  224.  
  225. There is also a variable BLIB_DONE which should be used as a dependancy
  226. anywhere a rule needs to be sure that a loadable and working module resides in
  227. the blib directory before running.
  228.  
  229. The parameters are a list of key=>value pairs.  You must specify at minimum
  230. either DEPENDS or XS_FILES.
  231.  
  232. =over
  233.  
  234. =item DEPENDS => ExtUtils::Depends object
  235.  
  236. Most gtk2-perl modules use ExtUtils::Depends to find headers, typemaps,
  237. and other data from parent modules and to install this data for child
  238. modules.  We can find from this object the list of XS files to scan for
  239. documentation, doctype mappings for parent modules, and other goodies.
  240.  
  241. =item XS_FILES => \@xs_file_names
  242.  
  243. A list of xs files to scan for documentation.  Ignored if DEPENDS is
  244. used.
  245.  
  246. =item DOCTYPES => \@doctypes_file_names
  247.  
  248. List of filenames to pass to C<Glib::GenPod::add_types>.  May be omitted.
  249.  
  250. =item COPYRIGHT => string
  251.  
  252. POD text to be inserted in the 'COPYRIGHT' section of each generated page.
  253. May be omitted.
  254.  
  255. =item COPYRIGHT_FROM => file name
  256.  
  257. The name of a file containing the POD to be inserted in the 'COPYRIGHT'
  258. section of each generated page.  May be omitted.
  259.  
  260. =item NAME => extension name
  261.  
  262. The name of the extension, used to set the main mod for Glib::GenPod (used in the
  263. generated see-also listings).  May be omitted in favor of the name held
  264. inside the ExtUtils::Depends object.  If DEPENDS is also specified, NAME wins.
  265.  
  266. =back
  267.  
  268. =cut
  269.  
  270. sub postamble_docs_full {
  271.     my $class = shift; # package name
  272.     my %params = @_;
  273.  
  274.     croak "Usage: $class\->postamble_docs_full (...)\n"
  275.         . "  where ... is a list of key/value pairs including at the\n"
  276.         . "  very least one of DEPENDS=>\$extutils_depends_object or\n"
  277.         . "  XS_FILES=>\@xs_files\n"
  278.         . "    "
  279.         unless $params{DEPENDS} or $params{XS_FILES};
  280.  
  281.     my @xs_files = ();
  282.     my @doctypes = ();
  283.     my $add_types = '';
  284.     my $copyright = '';
  285.     my $name = '';
  286.  
  287.     if ($params{DOCTYPES}) {
  288.         @doctypes = ('ARRAY' eq ref $params{DOCTYPES})
  289.                   ? @{$params{DOCTYPES}}
  290.                   : ($params{DOCTYPES});
  291.     }
  292.  
  293.     if (UNIVERSAL::isa ($params{DEPENDS}, 'ExtUtils::Depends')) {
  294.         my $dep = $params{DEPENDS};
  295.  
  296.         # fetch list of XS files from depends object.
  297.         # HACK ALERT: the older versions of ExtUtils::Depends
  298.         # (<0.2) use a different key layout and don't store enough
  299.         # metadata about the dependencies, so we require >=0.2;
  300.         # however, the older versions don't support import version
  301.         # checking (in fact they don't support version-checking at
  302.         # all), so the "use" test in a Makefile.PL can't tell if
  303.         # it has loaded a new enough version!
  304.         # the rewrite at version 0.200 added the get_dep() method,
  305.         # which we use, so let's check for that.
  306.         unless (defined &ExtUtils::Depends::get_deps) {
  307.             use ExtUtils::MakeMaker;
  308.             warn "ExtUtils::Depends is too old, need at "
  309.                . "least version 0.2";
  310.             # this is so that CPAN builds will do the upgrade
  311.             # properly.
  312.             WriteMakefile(
  313.                 PREREQ_FATAL => 1,
  314.                 PREREQ_PM => { 'ExtUtils::Depends' => 0.2, },
  315.             );
  316.             exit 1; # not reached.
  317.         }
  318.         # continue with the excessive validation...
  319.         croak "value of DEPENDS key must be an ExtUtils::Depends object"
  320.             unless UNIVERSAL::isa $dep, 'ExtUtils::Depends';
  321.         croak "corrupt or invalid ExtUtils::Depends instance -- "
  322.             . "the xs key is "
  323.             .(exists ($dep->{xs}) ? "missing" : "broken")."!"
  324.             unless exists $dep->{xs}
  325.                and 'ARRAY' eq ref $dep->{xs};
  326.  
  327.         # finally, *this* is what we wanted.
  328.         @xs_files = @{$dep->{xs}};
  329.  
  330.         # fetch doctypes files from the depends' dependencies.
  331.         my %deps = $dep->get_deps;
  332.         foreach my $d (keys %deps) {
  333.             my $f = File::Spec->catfile ($deps{$d}{instpath},
  334.                                          'doctypes');
  335.             #warn "looking for $f\n";
  336.             push @doctypes, $f
  337.                 if -f $f;
  338.         }
  339.  
  340.         # the depends object conveniently knows the main module name.
  341.         $name = $dep->{name};
  342.     } else {
  343.         @xs_files = @{ $params{XS_FILES} };
  344.     }
  345.  
  346.     if ($params{COPYRIGHT}) {
  347.         $copyright = $params{COPYRIGHT};
  348.     } elsif ($params{COPYRIGHT_FROM}) {
  349.         open IN, $params{COPYRIGHT_FROM} or
  350.             croak "can't open $params{COPYRIGHT_FROM} for reading: $!\n";
  351.         local $/ = undef;
  352.         $copyright = <IN>;
  353.         close IN;
  354.     }
  355.  
  356.     if ($copyright) {
  357.         # this text has to be escaped for both make and the shell.
  358.         $copyright =~ s/\n/\\n/gm; # collapse to one line.
  359.         $copyright = "Glib::GenPod::set_copyright(qq{$copyright});";
  360.     }
  361.  
  362.     # the module name specified explicitly overrides the one in a
  363.     # depends object.
  364.     $name = $params{NAME} if $params{NAME};
  365.     # now sanitize
  366.     if ($name) {
  367.         # this is supposed to be a module name; names don't have
  368.         # things in them that need escaping, so let's leave it alone.
  369.         # that way, if there's a quoting error, the user will figure
  370.         # it out real quick.
  371.         $name = "Glib::GenPod::set_main_mod(qq($name));";
  372.     }
  373.  
  374.     #warn "".scalar(@doctypes)." doctype files\n";
  375.     #warn "".scalar(@xs_files)." xs files\n";
  376.  
  377.     if (@doctypes) {
  378.         $add_types = 'add_types ('
  379.                    . join(', ', map {'qq(' . quotemeta ($_) . ')'} @doctypes)
  380.                    . '); '
  381.     }
  382.  
  383.     my $docgen_code = ''
  384.         . $add_types
  385.         . ' '
  386.         . $copyright
  387.         . ' '
  388.         . $name
  389.         . ' $(POD_SET) '
  390.         . 'xsdoc2pod(q(build/doc.pl), q($(INST_LIB)), q(build/podindex));';
  391.  
  392.     #warn "docgen_code: $docgen_code\n";
  393.  
  394.     # BLIB_DONE should be set to something we can depend on that will
  395.     # ensure that we are safe to link against an up to date module out
  396.     # of blib. basically what we need to wait on is the static/dynamic
  397.     # lib file to be created. the following trick is intended to handle
  398.     # both of those cases without causing the other to happen.
  399.  
  400.     return <<"__EOM__";
  401.  
  402. BLIB_DONE=build/blib_done_\$(LINKTYPE)
  403.  
  404. build/blib_done_dynamic :: \$(INST_DYNAMIC)
  405.     \$(NOECHO) \$(TOUCH) \$@
  406.  
  407. build/blib_done_static :: \$(INST_STATIC)
  408.     \$(NOECHO) \$(TOUCH) \$@
  409.  
  410. build/blib_done_ :: build/blib_done_dynamic
  411.     \$(NOECHO) \$(TOUCH) \$@
  412.  
  413. # documentation stuff
  414. \$(INST_LIB)/Glib/GenPod.pm \$(INST_LIB)/Glib/ParseXSDoc.pm: pm_to_blib
  415.  
  416. build/doc.pl :: Makefile @xs_files
  417.     \$(NOECHO) \$(ECHO) Parsing XS files...
  418.     \$(NOECHO) $^X -I \$(INST_LIB) -I \$(INST_ARCHLIB) -MGlib::ParseXSDoc \\
  419.         -e "xsdocparse (qw(@xs_files))" > \$@
  420.  
  421. # passing all of these files through the single podindex file, which is 
  422. # created at the same time, prevents problems with -j4 where xsdoc2pod would 
  423. # have multiple instances
  424. @gend_pods :: build/podindex
  425.  
  426. build/podindex :: \$(BLIB_DONE) Makefile build/doc.pl \$(POD_DEPENDS)
  427.     \$(NOECHO) \$(ECHO) Generating POD...
  428.     \$(NOECHO) $^X -I \$(INST_LIB) -I \$(INST_ARCHLIB) -MGlib::GenPod -M\$(NAME) \\
  429.         -e "$docgen_code"
  430.  
  431. \$(INST_LIB)/\$(FULLEXT)/:
  432.     $^X -MExtUtils::Command -e mkpath \$@
  433.  
  434. \$(INST_LIB)/\$(FULLEXT)/index.pod :: \$(INST_LIB)/\$(FULLEXT)/ build/podindex
  435.     \$(NOECHO) \$(ECHO) Creating POD index...
  436.     \$(NOECHO) $^X -e "print qq(\\n=head1 NAME\\n\\n\$(NAME) \\\\- API Reference Pod Index\\n\\n=head1 PAGES\\n\\n=over\\n\\n)" \\
  437.         > \$(INST_LIB)/\$(FULLEXT)/index.pod
  438.     \$(NOECHO) $^X -nae "print qq(=item L<\$\$F[1]>\\n\\n);" < build/podindex >> \$(INST_LIB)/\$(FULLEXT)/index.pod
  439.     \$(NOECHO) $^X -e "print qq(=back\\n\\n);" >> \$(INST_LIB)/\$(FULLEXT)/index.pod
  440. __EOM__
  441. }
  442.  
  443. =item string = Glib::MakeHelper->postamble_rpms (HASH)
  444.  
  445. Create and return the text of Makefile rules to manage building RPMs.
  446. You'd put this in your Makefile.PL's MY::postamble.
  447.  
  448. I<HASH> is a set of search and replace keys for the spec file.  All 
  449. occurences of @I<key>@ in the spec file template perl-$(DISTNAME).spec.in
  450. will be replaced with I<value>.  'VERSION' and 'SOURCE' are supplied for
  451. you.  For example:
  452.  
  453.  Glib::MakeHelper->postamble_rpms (
  454.         MYLIB     => 2.0.0, # we can work with anything from this up
  455.         MYLIB_RUN => 2.3.1, # we are actually compiled against this one
  456.         PERL_GLIB => 1.01,  # you must have this version of Glib
  457.  );
  458.  
  459. will replace @MYLIB@, @MYLIB_RUN@, and @PERL_GLIB@ in spec file.  See
  460. the build setups for Glib and Gtk2 for examples.
  461.  
  462. Note: This function just returns an empty string on Win32.
  463.  
  464. =cut
  465.  
  466. sub postamble_rpms
  467. {
  468.     shift; # package name
  469.  
  470.     return '' unless $ENV{GPERL_BUILD_RPMS};
  471.     
  472.     my @dirs = qw{$(RPMS_DIR) $(RPMS_DIR)/BUILD $(RPMS_DIR)/RPMS 
  473.               $(RPMS_DIR)/SOURCES $(RPMS_DIR)/SPECS $(RPMS_DIR)/SRPMS};
  474.     my $cwd = getcwd();
  475.     
  476.     chomp (my $date = `date +"%a %b %d %Y"`);
  477.  
  478.     my %subs = (
  479.         'VERSION' => '$(VERSION)',
  480.         'SOURCE'  => '$(DISTNAME)-$(VERSION).tar.gz',
  481.         'DATE'    => $date,
  482.         @_,
  483.     );
  484.     
  485.     my $substitute = '$(PERL) -npe \''.join('; ', map {
  486.             "s/\\\@$_\\\@/$subs{$_}/g";
  487.         } keys %subs).'\'';
  488.  
  489. "
  490.  
  491. RPMS_DIR=\$(HOME)/rpms
  492.  
  493. \$(RPMS_DIR)/:
  494.     -mkdir @dirs
  495.  
  496. SUBSTITUTE=$substitute
  497.  
  498. perl-\$(DISTNAME).spec :: perl-\$(DISTNAME).spec.in \$(VERSION_FROM) Makefile
  499.     \$(SUBSTITUTE) \$< > \$@
  500.  
  501. dist-rpms :: Makefile dist perl-\$(DISTNAME).spec \$(RPMS_DIR)/
  502.     cp \$(DISTNAME)-\$(VERSION).tar.gz \$(RPMS_DIR)/SOURCES/
  503.     rpmbuild -ba --define \"_topdir \$(RPMS_DIR)\" perl-\$(DISTNAME).spec
  504.  
  505. dist-srpms :: Makefile dist perl-\$(DISTNAME).spec \$(RPMS_DIR)/
  506.     cp \$(DISTNAME)-\$(VERSION).tar.gz \$(RPMS_DIR)/SOURCES/
  507.     rpmbuild -bs --nodeps --define \"_topdir \$(RPMS_DIR)\" perl-\$(DISTNAME).spec
  508. ";
  509. }
  510.  
  511. package MY;
  512.  
  513. =back
  514.  
  515. =head1 NOTICE
  516.  
  517. The MakeMaker distributed with perl 5.8.x generates makefiles with a bug that
  518. causes object files to be created in the wrong directory.  There is an override
  519. inserted by this module under the name MY::const_cccmd to fix this issue.
  520.  
  521. =cut
  522.  
  523. sub const_cccmd {
  524.     my $inherited = shift->SUPER::const_cccmd (@_);
  525.     return '' unless $inherited;
  526.     require Config;
  527.     # a more sophisticated match may be necessary, but this works for me.
  528.     if ($Config::Config{cc} eq "cl") {
  529.         $inherited .= ' /Fo$@';
  530.     } else {
  531.         $inherited .= ' -o $@';
  532.     }
  533.     $inherited;
  534. }
  535.  
  536. #
  537. # And, some black magick to help make learn to shut the hell up.
  538. #
  539.  
  540. sub quiet_rule {
  541.     my $cmds = shift;
  542.     my @lines = split /\n/, $cmds;
  543.     foreach (@lines) {
  544.         if (/NOECHO/) {
  545.             # already quiet
  546.         } elsif (/XSUBPP/) {
  547.             s/^\t/\t\$(NOECHO) \$(ECHO) [ XS \$< ]\n\t\$(NOECHO) /;
  548.         } elsif (/CCCMD/) {
  549.             s/^\t/\t\$(NOECHO) \$(ECHO) [ CC \$< ]\n\t\$(NOECHO) /;
  550.         } elsif (/\bLD\b/) {
  551.             s/^\t/\t\$(NOECHO) \$(ECHO) [ LD \$@ ]\n\t\$(NOECHO) /;
  552.         } elsif (/[_\b]AR\b/) {
  553.             s/^\t/\t\$(NOECHO) \$(ECHO) [ AR \$@ ]\n\t\$(NOECHO) /;
  554.         }
  555.     }
  556.     return join "\n", @lines;
  557. }
  558.  
  559. sub c_o { return quiet_rule (shift->SUPER::c_o (@_)); }
  560. sub xs_o { return quiet_rule (shift->SUPER::xs_o (@_)); }
  561. sub xs_c { return quiet_rule (shift->SUPER::xs_c (@_)); }
  562. sub dynamic_lib { return quiet_rule (shift->SUPER::dynamic_lib (@_)); }
  563. sub static_lib { return quiet_rule (shift->SUPER::static_lib (@_)); }
  564.  
  565. 1;
  566.  
  567. =head1 AUTHOR
  568.  
  569. Ross McFarland E<lt>rwmcfa1 at neces dot comE<gt>
  570.  
  571. hacked up and documented by muppet.
  572.  
  573. =head1 COPYRIGHT AND LICENSE
  574.  
  575. Copyright 2003-2004 by the gtk2-perl team
  576.  
  577. This library is free software; you can redistribute it and/or modify
  578. it under the terms of the Lesser General Public License (LGPL).  For 
  579. more information, see http://www.fsf.org/licenses/lgpl.txt
  580.  
  581. =cut
  582.