home *** CD-ROM | disk | FTP | other *** search
/ PCNET 2006 August - Disc 1 / PCNET_CD_2006_08_1.iso / linux / puppy-barebones-2.01r2.iso / pup_201.sfs / usr / sbin / sockspy.tcl < prev    next >
Encoding:
Text File  |  2004-07-19  |  38.1 KB  |  1,175 lines
  1. #!/bin/sh
  2. # restart using wish    -*- mode: tcl; tab-width: 8; -*- \
  3. exec wish $0 ${1+"$@"}
  4.  
  5. # sockspy: copyright tom poindexter 1998
  6. # sockspy: copyright Keith Vetter 2002
  7. #        tpoindex@nyx.net
  8. # version 1.0 - december 10, 1998
  9. # version 2.0 - January, 2002 by Keith Vetter
  10. # KPV Nov 01, 2002 - added proxy mode
  11. # KPV Dec 21, 2002 - added extract window
  12. # version 2.5 - February, 2003 by Don Libes
  13. # DL Jan/Feb, 2003 - added date support, state save/restore, cmdline display
  14. # 
  15. # spy on conversation between a tcp client and server
  16. #
  17. # usage: sockspy clientPort serverHost serverPort
  18. #  -or-     sockspy -proxy proxyPort
  19. #       clientPort - port to which clients connect
  20. #       serverHost - machine where real server runs
  21. #       serverPort - port on which real server listens
  22. #
  23. #  e.g. to snoop on http connections to a web server:
  24. #    sockspy 8080 www.some.com 80
  25. #  then client web browser should use a url like:
  26. #     http://localhost:8080/index.html
  27. #     (or set your browser's proxy to use 8080 on the sockspy machine)
  28.  
  29. catch {package require uri}            ;# Error handled below
  30.  
  31. array set state {
  32.     version 2.5
  33.     extract 0
  34.     bbar 1
  35.     ascii 1
  36.     autoscroll 1
  37.     autowrap 1
  38.     capture 1
  39.     msg ""
  40.     fixed {}
  41.     fixedbold {}
  42.     fontSize 9
  43.     playback ""
  44.     gui 0
  45.     listen ""
  46.     title "not connected"
  47.     proxy 0
  48.     fname ""
  49.     time 1
  50.     timeFormat ""
  51.     timeFormatDefault "%H:%M:%S "
  52. }
  53.  
  54. # variables to save across runs
  55. set saveList {
  56.     state(extract)
  57.     state(bbar)
  58.     state(ascii)
  59.     state(autoscroll)
  60.     state(autowrap)
  61.     state(proxy)
  62.     state(fname)
  63.     state(time)
  64.     state(timeFormat)
  65.     state(fontSize)
  66.     extract(client)
  67.     extract(server)
  68.     extract(meta2)
  69.     SP(proxyPort)
  70.     SP(clntPort)
  71.     SP(servPort)
  72.     SP(servHost)
  73. }
  74.  
  75. array set colors {client green server cyan meta red meta2 yellow}
  76. array set SP {proxyPort 8080 clntPort 8080 servHost "" servPort 80}
  77.  
  78. set extract(client) {^(GET |POST |HEAD )}
  79. set extract(server) {^(HTTP/|Location: |Content-)}
  80. set extract(meta2) {.}
  81. #set extract(meta) {.}
  82.  
  83. ##+##########################################################################
  84. # 
  85. # createMain -- Creates the display
  86. # 
  87. proc createMain {} {
  88.     global state colors tcl_platform
  89.     
  90.     wm withdraw .
  91.  
  92.     set state(fixed) [font create -family courier -size $state(fontSize)]
  93.     set state(fixedbold) [font create -family courier -size $state(fontSize) \
  94.           -weight bold]
  95.  
  96.     wm title . "SockSpy -- $state(title)"
  97.     wm resizable .  1 1
  98.     wm protocol . WM_DELETE_WINDOW Shutdown    ;# So we shut down cleanly
  99.  
  100.     #
  101.     # Set up the menus
  102.     #
  103.     menu .m -tearoff 0
  104.     . configure -menu .m
  105.     .m add cascade -menu .m.file -label "File" -underline 0
  106.     .m add cascade -menu .m.view -label "View" -underline 0
  107.     .m add cascade -menu .m.help -label "Help" -underline 0
  108.     
  109.     menu .m.file
  110.     .m.file add command -label "Save ..." -underline 0 -command saveOutput
  111.     .m.file add command -label "Reconnect ..." -underline 0 -command GetSetup
  112.     .m.file add separator
  113.     .m.file add command -label "Exit" -underline 1 -command Shutdown
  114.     
  115.     menu .m.view
  116.     .m.view add command -label " Clear" -underline 1 -command clearOutput
  117.     .m.view add separator
  118.     .m.view add checkbutton -label " ButtonBar" -variable state(bbar) \
  119.         -underline 1 -command ButtonBar
  120.     .m.view add checkbutton -label " Extract Window" -variable state(extract) \
  121.         -underline 1 -command ToggleExtract
  122.     .m.view add separator
  123.     .m.view add command -label " + Font" -command [list doFont 1]
  124.     .m.view add command -label " - Font" -command [list doFont -1]
  125.     .m.view add separator
  126.     .m.view add radiobutton -label " Hex" -underline 1 \
  127.         -variable state(ascii) -value 0 -command redraw
  128.     .m.view add radiobutton -label " ASCII" -underline 1 \
  129.         -variable state(ascii) -value 1 -command redraw
  130.     .m.view add separator
  131.     .m.view add checkbutton -label " Autoscroll" -underline 5 \
  132.         -variable state(autoscroll)
  133.     .m.view add checkbutton -label " Autowrap" -underline 5 \
  134.         -variable state(autowrap) -command ToggleWrap
  135.     .m.view add checkbutton -label " Capture" -underline 5 \
  136.         -variable state(capture) -command ToggleCapture
  137.     .m.view add separator
  138.     .m.view add checkbutton -label " Time" \
  139.     -variable state(time) -command redraw
  140.     .m.view add command -label " Time Format ..." -command timestampWindow
  141.  
  142.     menu .m.help -tearoff 0
  143.     .m.help add command -label Help -underline 1 -command Help
  144.     .m.help add separator
  145.     .m.help add command -label About -command About
  146.     #
  147.     # Title and status window
  148.     #
  149.     frame .bbar
  150.     frame .cmd -relief sunken -bd 2
  151.     radiobutton .cmd.hex -text Hex -variable state(ascii) \
  152.         -value 0 -command redraw
  153.     radiobutton .cmd.ascii -text ASCII -variable state(ascii) \
  154.         -value 1 -command redraw
  155.     checkbutton .cmd.autos -text Autoscroll -variable state(autoscroll)
  156.     checkbutton .cmd.autow -text Autowrap -variable state(autowrap) \
  157.      -command ToggleWrap
  158.     checkbutton .cmd.capture -text Capture -variable state(capture) \
  159.      -command ToggleCapture
  160.     checkbutton .cmd.time -text Time -variable state(time) \
  161.      -command redraw
  162.     button .cmd.clear -text Clear -command clearOutput
  163.     #button .cmd.incr -text "+ Font" -command [list doFont 1]
  164.     #button .cmd.decr -text "- Font" -command [list doFont -1]
  165.     button .cmd.save -text Save -command saveOutput
  166.     button .cmd.kill -text Exit -command Shutdown
  167.     pack .cmd -side top -fill x -pady 5 -in .bbar
  168.     pack .cmd.kill .cmd.save .cmd.clear .cmd.autow .cmd.autos .cmd.capture \
  169.     .cmd.time \
  170.     -side right -padx 3 -pady 3
  171.     #label .title -relief ridge -textvariable state(title)
  172.     #.title config -font "[.title cget -font] bold"
  173.     label .stat -textvariable state(msg) -relief ridge -anchor w
  174.  
  175.     #
  176.     # Now for the output area of the display
  177.     #
  178.     scrollbar .yscroll -orient vertical -command {.out yview}
  179.     scrollbar .xscroll -orient horizontal -command {.out xview}
  180.     text .out -width 80 -height 50 -font $state(fixed) -bg white -setgrid 1 \
  181.         -yscrollcommand ".yscroll set" -xscrollcommand ".xscroll set"
  182.     foreach t [array names colors] {
  183.     .out tag configure $t -background $colors($t) -borderwidth 2 \
  184.         -relief raised -lmargin1 5 -lmargin2 5
  185.     .out tag configure time_$t -background $colors($t) -borderwidth 2 \
  186.         -relief raised -lmargin1 5 -lmargin2 5 -font $state(fixedbold)
  187.     }
  188.     .out tag configure client2 -font $state(fixedbold)
  189.     .out tag raise sel                ;# Selection is most prominent
  190.  
  191.     grid .bbar -       -row 0 -sticky ew
  192.     grid .out .yscroll -row 1 -sticky news
  193.     grid .xscroll      -row 2 -sticky ew
  194.     grid .stat -       -row 3 -sticky ew
  195.     grid rowconfigure     . 1 -weight 1
  196.     grid columnconfigure . 0 -weight 1
  197.  
  198.     bind .out <Control-l> clearOutput
  199.     bind all <Alt-c> {console show}
  200.     focus .out
  201.     wm geometry . +10+10
  202. }
  203. ##+##########################################################################
  204. # 
  205. # createExtract -- Creates the extract toplevel window.
  206. # 
  207. proc createExtract {} {
  208.     global state colors
  209.     
  210.     if {[winfo exists .extract]} {
  211.     wm deiconify .extract
  212.     return
  213.     }
  214.     set top ".extract"
  215.     toplevel $top
  216.     wm title $top "SockSpy Extract"
  217.     wm protocol $top WM_DELETE_WINDOW [list ToggleExtract -1]
  218.     if {[regexp {(\+[0-9]+)(\+[0-9]+)$} [wm geom .] => wx wy]} {
  219.     wm geom $top "+[expr {$wx+35+[winfo width .]}]+[expr {$wy+15}]"
  220.     }
  221.  
  222.     frame $top.top -bd 2 -relief ridge
  223.     label $top.top.c  -text "Client Filter" -anchor e
  224.     entry $top.top.ce -textvariable extract(client) -bg $colors(client)
  225.     label $top.top.s  -text "Server Filter" -anchor e
  226.     entry $top.top.se -textvariable extract(server) -bg $colors(server)
  227.     label $top.top.m  -text "Metadata Filter" -anchor e
  228.     entry $top.top.me -textvariable extract(meta2) -bg $colors(meta2)
  229.     
  230.     text $top.out -width 80 -height 20 -font $state(fixed) -bg beige \
  231.     -setgrid 1 -wrap none -yscrollcommand [list $top.yscroll set] \
  232.     -xscrollcommand [list $top.xscroll set]
  233.     foreach t [array names colors] {
  234.     $top.out tag configure $t -background $colors($t) -borderwidth 2 \
  235.         -relief raised -lmargin1 5 -lmargin2 5
  236.     $top.out tag configure time_$t -background $colors($t) -borderwidth 2 \
  237.         -relief raised -lmargin1 5 -lmargin2 5 -font $state(fixedbold)
  238.     }
  239.     $top.out tag raise sel            ;# Selection is most prominent
  240.  
  241.     scrollbar $top.yscroll -orient vertical -command [list $top.out yview]
  242.     scrollbar $top.xscroll -orient horizontal -command [list $top.out xview]
  243.     grid $top.top - -row 0     -sticky ew -ipady 10
  244.     grid $top.out $top.yscroll -sticky news
  245.     grid $top.xscroll           -sticky ew
  246.  
  247.     grid rowconfigure     $top 1 -weight 1
  248.     grid columnconfigure $top 0 -weight 1
  249.  
  250.     grid $top.top.c $top.top.ce -row 0 -sticky ew
  251.     grid $top.top.s $top.top.se           -sticky ew
  252.     grid $top.top.m $top.top.me           -sticky ew
  253.     grid columnconfigure $top.top 1 -weight 1
  254.     grid columnconfigure $top.top 2 -minsize 10
  255. }
  256. ##+##########################################################################
  257. # 
  258. # doFont -- Changes the size of the font used for the display text
  259. # 
  260. proc doFont {delta} {
  261.     global state
  262.  
  263.     incr state(fontSize) $delta
  264.     font configure $state(fixed) -size $state(fontSize)
  265.     font configure $state(fixedbold) -size $state(fontSize)
  266. }
  267. ##+##########################################################################
  268. # 
  269. # clearOutput -- Erases the content of the output window
  270. # 
  271. proc clearOutput {} {
  272.     global state
  273.     if {$state(gui)} {
  274.     .out delete 0.0 end
  275.     catch {.extract.out delete 0.0 end}
  276.     }
  277.     set state(playback) ""
  278. }
  279. ##+##########################################################################
  280. # 
  281. # redraw -- Redraws the contents of the output window.
  282. #
  283. # It does this by replaying the input stream.
  284. # 
  285. proc redraw {} {
  286.     global state 
  287.  
  288.     set save_as $state(autoscroll)        ;# Disable autoscrolling
  289.     set state(autoscroll) 0
  290.  
  291.     set p $state(playback)            ;# Save what gets displayed
  292.     clearOutput                    ;# Erase current screen
  293.     foreach {who data time} $p {        ;# Replay the input stream
  294.     insertData $who $data $time 1
  295.     }
  296.     set state(autoscroll) $save_as
  297. }
  298. ##+##########################################################################
  299. # 
  300. # saveOutput -- Saves the content of the output window. 
  301. # 
  302. # It uses the playback stream as its data source.
  303. # 
  304. proc saveOutput {} {
  305.     global state but
  306.  
  307.     set but -1
  308.     set but [tk_dialog .what "SockSpy Save" "Save which window?" \
  309.         questhead 2 server client both cancel]
  310.  
  311.     if {$but == -1 || $but == 3} {
  312.     return
  313.     }
  314.     set file [tk_getSaveFile -parent . -initialfile $state(fname)]
  315.     if {$file == ""} return
  316.  
  317.     set state(fname) $file
  318.     if {[catch {open $file w} fd]} {
  319.     tk_messageBox -message "file $file cannot be opened" -icon error \
  320.         -type ok
  321.     return
  322.     }
  323.     fconfigure $fd -translation binary
  324.     foreach {who data time} $state(playback) {
  325.     if {$who == "meta" || $who == "meta2"} continue
  326.     if {$but == 2 || ($but == 0 && $who == "server") || \
  327.         ($but == 1 && $who == "client")} {
  328.         if {$state(time)} {
  329.         puts $fd [timestamp $time]
  330.         }
  331.         puts $fd $data
  332.     }
  333.     }
  334.     close $fd
  335.     bell
  336. }
  337. ##+##########################################################################
  338. # 
  339. # printable -- Replaces all unprintable characters into dots.
  340. # 
  341. proc printable {s {spaces 0}} {
  342.     regsub -all {[^\x09\x20-\x7e]} $s "." n
  343.     if {$spaces} {
  344.     regsub -all { } $n "_" n
  345.     }
  346.     return $n;
  347. }
  348. ##+##########################################################################
  349. # 
  350. # insertData -- Inserts data into the output window. WHO tells us if it is
  351. # from the client, server or meta.
  352. # 
  353. proc insertData {who data {time {}} {force 0}} {
  354.     global state
  355.     array set prefix {meta = meta2 = client > server <}
  356.  
  357.     if {$time == ""} {                ;# If not set, then set to now
  358.     set time [clock seconds]
  359.     }
  360.     set timestamp [timestamp $time]
  361.  
  362.     DoExtract $who $data $timestamp        ;# Display any extracted data
  363.     if {! $force && ! $state(capture)} return    ;# No display w/o capture on
  364.     lappend state(playback) $who $data $time    ;# Save for redraw and saving
  365.     
  366.     if {$state(ascii) || [regexp {^meta2?$} $who] } {
  367.     regsub -all \r $data "" data
  368.     foreach line [split $data \n] {
  369.         set line [printable $line]
  370.         set tag $who
  371.         if {$tag == "client" && [regexp -nocase {^get |^post } $line]} {
  372.         lappend tag client2
  373.         }
  374.         if {$state(gui)} {
  375.         .out insert end "$timestamp" time_$tag "$line\n" $tag
  376.         } else {
  377.         puts "$timestamp$prefix($who)$line"
  378.         }
  379.     }
  380.     } else {                    ;# Hex output
  381.     while {[string length $data]} {
  382.         set line [string range $data 0 15]
  383.         set data [string range $data [string length $line] end]
  384.         binary scan $line H* hex
  385.         regsub -all {([0-9a-f][0-9a-f])} $hex {\1 } hex
  386.         set line [format "%-48.48s    %-16.16s\n" $hex [printable $line 1]] 
  387.         if {$state(gui)} {
  388.         .out insert end "$timestamp" time_$who "$line" $who
  389.         } else {
  390.         puts "$timestamp$prefix(who)$line"
  391.         }
  392.     }
  393.     }
  394.     if {$state(autoscroll) && $state(gui)} {
  395.     .out see end
  396.     }
  397. }
  398. ##+##########################################################################
  399. #
  400. # timestampInit -- Initialize timestamp support
  401. #
  402. proc timestampInit {} {
  403.     global state
  404.  
  405.     set state(timeFormat) $state(timeFormatDefault)
  406. }
  407. ##+##########################################################################
  408. #
  409. # timestamp -- Produce printable timestamps
  410. #
  411. # Note that it is the user's responsibility to make sure the
  412. # user-supplied format ends with a delimiter or separator such as a
  413. # space or colon. The timestamp code itself checks whether or not it
  414. # should do anything to simplify the many different places in the code
  415. # from which can be called.
  416.  
  417. proc timestamp {time} {
  418.     global state
  419.     
  420.     if {! $state(time)} { return "" }
  421.     return [clock format $time -format $state(timeFormat)]
  422. }
  423. ##+###########################################################################
  424. #
  425. # timestampWindow -- Dialog for the user to configure the timestamp format.
  426. #
  427. proc timestampWindow {} {
  428.     global state
  429.  
  430.     set state(oldTimeFormat) $state(timeFormat)
  431.  
  432.     set w .tf2
  433.     destroy .tf
  434.     toplevel .tf
  435.     wm title .tf "SockSpy Time Format"
  436.  
  437.     set txt "Edit the format used for timestamps. "
  438.     append txt "See Tcl's clock command documentation for a complete "
  439.     append txt "description of acceptable formats."
  440.     
  441.     frame .tf.top -bd 2 -relief raised -padx 5
  442.     
  443.     message .tf.t -aspect 500 -text $txt
  444.     label .tf.l -text "Format: "
  445.     entry .tf.e -textvariable state(timeFormat)
  446.     button .tf.default -text Default -width 10 -command {tfButton default}
  447.     button .tf.ok -text OK -width 10 -command {tfButton ok}
  448.     button .tf.cancel -text Cancel -width 10 -command {tfButton cancel}
  449.     
  450.     grid .tf.top -row 0 -column 0 -columnspan 4 -sticky ew -padx 10 -pady 10
  451.     grid columnconfigure .tf 0 -weight 1
  452.     grid x .tf.default .tf.ok .tf.cancel -padx 5 -sticky ew
  453.     grid rowconfigure .tf 2 -minsize 8
  454.  
  455.     grid .tf.t - -in .tf.top -row 0
  456.     grid .tf.l .tf.e -in .tf.top -row 1 -pady 10 -sticky ew
  457.     grid columnconfigure .tf.top 1 -weight 1
  458.     grid columnconfigure .tf.top 2 -minsize 10
  459.  
  460.     focus .tf.e
  461.     .tf.e icursor end
  462.     .tf.e select range 0 end
  463. }
  464. ##+##########################################################################
  465. # 
  466. # tfButton -- handles button clicks on the timestamp dialog
  467. # 
  468. proc tfButton {who} {
  469.     if {$who == "defaut"} {
  470.     set ::state(timeFormat) $::state(timeFormatDefault)
  471.     } elseif {$who == "ok"} {
  472.     destroy .tf
  473.     redraw
  474.     } elseif {$who == "cancel"} {
  475.     set ::state(timeFormat) $::state(oldTimeFormat)
  476.     destroy .tf
  477.     }
  478. }
  479. ##+##########################################################################
  480. # 
  481. # INFO
  482. # 
  483. # Puts up an informational message both in the output window and
  484. # in the status window.
  485. # 
  486. proc INFO {msg {who meta} {time {}} {display 0}} {
  487.     global state
  488.     set state(msg) $msg
  489.     insertData $who $msg $time $display
  490. }
  491. proc ERROR {emsg} {
  492.     if {$::state(gui)} {
  493.     tk_messageBox -title "SockSpy Error" -message $emsg -icon error
  494.     } else {
  495.     puts $emsg
  496.     }
  497. }
  498. ##+##########################################################################
  499. # 
  500. # sockReadable -- Called when there is data available on the fromSocket
  501. # 
  502. proc sockReadable {fromSock toSock who} {
  503.     global state
  504.     set data [read $fromSock]
  505.     if {[string length $data] == 0} {
  506.     close $fromSock
  507.     catch { close $toSock }
  508.     insertData meta "----- closed connection -----"
  509.     INFO "waiting for new connection..." 
  510.     return
  511.     }
  512.     if {$toSock == ""} {            ;# Not connected yet
  513.     ProxyConnect $fromSock $data        ;# Do proxy forwarding
  514.     } else {
  515.     catch { puts -nonewline $toSock $data } ;# Forward if we have a socket
  516.     }
  517.     insertData $who $data
  518.     update
  519. }
  520. ##+##########################################################################
  521. # 
  522. # ProxyConnect
  523. # 
  524. # Called from a new socket connection when we have to determing who
  525. # to forward to.
  526. # 
  527. proc ProxyConnect {fromSock data} {
  528.     set line1 [lindex [split $data \r] 0]
  529.     set bad [regexp -nocase {(http:[^ ]+)} $line1 => uri]
  530.     if {$bad == 0} {
  531.     INFO "ERROR: cannot extract URI from '$line1'"
  532.     close $fromSock
  533.     insertData meta "----- closed connection -----"
  534.     insertData meta "waiting for new connection..." 
  535.     }
  536.     set state(uri) $uri                ;# For debugging
  537.     array set URI [::uri::split $uri]
  538.     if {$URI(port) == ""} { set URI(port) 80 }
  539.     set bad [catch {set sockServ [socket $URI(host) $URI(port)]} reason]
  540.     if {$bad} {
  541.     set msg "cannot connect to $URI(host):$URI(port) => $reason"
  542.     INFO $msg
  543.     close $fromSock
  544.     ERROR $msg
  545.     insertData meta "----- closed connection -----"
  546.     insertData meta "waiting for new connection..." 
  547.     return
  548.     }
  549.     INFO "fowarding to $URI(host):$URI(port)" meta2
  550.     fileevent $fromSock readable \
  551.     [list sockReadable $fromSock $sockServ client]
  552.     fconfigure $sockServ -blocking 0 -buffering none -translation binary
  553.     fileevent $sockServ readable \
  554.     [list sockReadable $sockServ $fromSock server]
  555.     puts -nonewline $sockServ $data
  556. }
  557. ##+##########################################################################
  558. # 
  559. # clntConnect -- Called when we get a new client connection
  560. # 
  561. proc clntConnect {sockClnt ip port} {
  562.     global state SP
  563.  
  564.     set state(sockClnt) $sockClnt
  565.     set state(meta) ""
  566.     
  567.     INFO "connect from [fconfigure $sockClnt -sockname] $port" meta2
  568.     if {$state(proxy) || $SP(servHost) == {} || $SP(servHost) == "none"} {
  569.     set sockServ ""
  570.     } else {
  571.     set n [catch {set sockServ [socket $SP(servHost) $SP(servPort)]} reason]
  572.     if {$n} {
  573.         INFO "cannot connect: $reason"
  574.         close $sockClnt
  575.         ERROR "cannot connect to $SP(servHost) $SP(servPort): $reason"
  576.         insertData meta "----- closed connection -----"
  577.         insertData meta "waiting for new connection..." 
  578.         
  579.     }
  580.     INFO "connecting to $SP(servHost):$SP(servPort)" meta2
  581.     }
  582.  
  583.     ;# Configure connection to the client
  584.     fconfigure $sockClnt -blocking 0 -buffering none -translation binary
  585.     fileevent $sockClnt readable \
  586.         [list sockReadable $sockClnt $sockServ client]
  587.  
  588.     ;# Configure connection to the server
  589.     if {[string length $sockServ]} {
  590.     fconfigure $sockServ -blocking 0 -buffering none -translation binary
  591.     fileevent $sockServ readable \
  592.         [list sockReadable $sockServ $sockClnt server]
  593.     }
  594. }
  595. ##+##########################################################################
  596. # 
  597. # DoListen
  598. # 
  599. # Opens the socket server to listen for connections. It first closes it if
  600. # it is already open.
  601. # 
  602. proc DoListen {} {
  603.     global state SP
  604.  
  605.     set rval 1
  606.     catch {close $state(sockClnt)}        ;# Only the last open connection
  607.     
  608.     ;# Close old listener if it exists
  609.     if {$state(listen) != ""} {
  610.     set n [catch {close $state(listen)} emsg]
  611.     if {$n} { INFO "socket close error: $emsg"}
  612.     set state(listen) ""
  613.     update                    ;# Need else socket below fails
  614.     }
  615.  
  616.     # Listen on clntPort or proxyPort for incoming connections
  617.     set port $SP(clntPort)
  618.     if {$state(proxy)} {set port $SP(proxyPort)}
  619.     set n [catch {set state(listen) [socket -server clntConnect $port]} emsg]
  620.     
  621.     if {$n} {
  622.     INFO "socket open error: $emsg"
  623.     set state(title) "not connected"
  624.     set rval 0
  625.     } else {
  626.     if {$state(proxy)} {
  627.         set state(title) "proxy localhost:$SP(proxyPort)"
  628.     } else {
  629.         set state(title) "localhost:$SP(clntPort) <--> "
  630.         append state(title) "$SP(servHost):$SP(servPort)"
  631.     }
  632.     INFO $state(title)
  633.     INFO "waiting for new connection..."
  634.     }
  635.     wm title . "SockSpy -- $state(title)"
  636.     return $rval
  637. }
  638. ##+##########################################################################
  639. # 
  640. # GetSetup -- Prompts the user for client port, server host and server port
  641. # 
  642. proc GetSetup {} {
  643.     global state SP ok
  644.     array set save [array get SP]
  645.     set ok 0                    ;# Assume cancelling
  646.  
  647.     ;# Put in some default values
  648.     if {![string length $SP(proxyPort)]} {set SP(proxyPort) 8080}
  649.     if {![string length $SP(clntPort)]}     {set SP(clntPort) 8080}
  650.     if {![string length $SP(servPort)]}     {set SP(servPort) 80}
  651.     
  652.     if {! $state(gui)} {
  653.     catch {close $state(listen)}
  654.  
  655.     set d "no" ; if {$state(proxy)} { set d yes }
  656.     set p [Prompt "Proxy mode" $d]
  657.     if {[regexp -nocase {^y$|^yes$} $p]} {
  658.         set state(proxy) 1
  659.         set SP(proxyPort) [Prompt "proxy port" $SP(proxyPort)]
  660.     } else {
  661.         set state(proxy) 0
  662.         set SP(clntPort) [Prompt "Client port" $SP(clntPort)]
  663.         set SP(servHost) [Prompt "Server host" $SP(servHost)]
  664.         set SP(servPort) [Prompt "Server port" $SP(servPort)]
  665.     }
  666.     DoListen
  667.     return
  668.     } 
  669.  
  670.     destroy .dlg
  671.     toplevel .dlg
  672.     wm title .dlg "SockSpy Setup"
  673.     wm geom .dlg +176+176
  674.     #wm transient .dlg .
  675.     
  676.     label .dlg.top -bd 2 -relief raised
  677.     set msg    "You can configure SockSpy to either forward data\n"
  678.     append msg "a fixed server and port or to use the HTTP Proxy\n"
  679.     append msg "protocol to dynamically determine the server and\n"
  680.     append msg "port to forward data to."
  681.  
  682.     frame .dlg.fforward
  683.     frame .dlg.fproxy
  684.     frame .dlg.fcmdline
  685.  
  686.     label .dlg.msg -text $msg -justify left
  687.     radiobutton .dlg.forward -text "Use fixed server forwarding" \
  688.     -variable state(proxy)    -value 0 -anchor w -command GetSetup2
  689.     label .dlg.fl1 -text "Client Port:" -anchor e
  690.     entry .dlg.fe1 -textvariable SP(clntPort)
  691.  
  692.     label .dlg.fl2 -text "Server Host:" -anchor e
  693.     entry .dlg.fe2 -textvariable SP(servHost)
  694.     label .dlg.fl3 -text "Server Port:" -anchor e
  695.     entry .dlg.fe3 -textvariable SP(servPort)
  696.     
  697.     radiobutton .dlg.proxy -text "Use HTTP Proxying" \
  698.     -variable state(proxy)    -value 1 -anchor w -command GetSetup2
  699.     label .dlg.pl1 -text "Proxy Port:" -anchor e
  700.     entry .dlg.pe1 -textvariable SP(proxyPort)
  701.  
  702.     label .dlg.cllabel -text "Command Line Equivalent"
  703.     entry .dlg.clvar -textvariable SP(cmdLine) \
  704.     -borderwidth 2 -relief sunken
  705.     # -state readonly doesn't seem to work, sigh
  706.  
  707.     button .dlg.ok -text OK -width 10 -command ValidForm
  708.     button .dlg.cancel -text Cancel -width 10 -command [list destroy .dlg]
  709.     
  710.     grid .dlg.top -row 0 -column 0 -columnspan 3 -sticky ew -padx 10 -pady 10
  711.     grid columnconfigure .dlg 0 -weight 1
  712.     grid x .dlg.ok .dlg.cancel -padx 10
  713.     grid configure .dlg.ok -padx 0
  714.     grid rowconfigure .dlg 2 -minsize 8
  715.     
  716.     pack .dlg.msg -in .dlg.top -side top -fill x -padx 10 -pady 5
  717.     pack .dlg.fforward .dlg.fproxy .dlg.fcmdline -in .dlg.top \
  718.     -side top -fill x -padx 10 -pady 10
  719.     
  720.     grid .dlg.cllabel -in .dlg.fcmdline -row 0 -column 0 -sticky w 
  721.     grid .dlg.clvar -in .dlg.fcmdline -row 1 -column 0 -sticky ew
  722.     grid columnconfigure .dlg.fcmdline 0 -weight 1
  723.     # no need for row/col configure
  724.  
  725.     grid .dlg.proxy - - -in .dlg.fproxy -sticky w
  726.     grid x .dlg.pl1 .dlg.pe1 -in .dlg.fproxy -sticky ew
  727.     grid columnconfigure .dlg.fproxy 0 -minsize .2i
  728.     grid columnconfigure .dlg.fproxy 2 -weight 1
  729.     grid columnconfigure .dlg.fproxy 3 -minsize 10
  730.     grid rowconfigure .dlg.fproxy 2 -minsize 10
  731.  
  732.     grid .dlg.forward - - -in .dlg.fforward -sticky w
  733.     grid x .dlg.fl1 .dlg.fe1 -in .dlg.fforward -sticky ew
  734.     grid x .dlg.fl2 .dlg.fe2 -in .dlg.fforward -sticky ew
  735.     grid x .dlg.fl3 .dlg.fe3 -in .dlg.fforward -sticky ew
  736.     grid columnconfigure .dlg.fforward 0 -minsize .2i
  737.     grid columnconfigure .dlg.fforward 2 -weight 1
  738.     grid columnconfigure .dlg.fforward 3 -minsize 10
  739.     grid rowconfigure .dlg.fforward 4 -minsize 10
  740.     raise .dlg
  741.  
  742.     bind .dlg.forward <Return>    [bind all <Key-Tab>]
  743.     bind .dlg.proxy <Return>  [bind all <Key-Tab>]
  744.     bind .dlg.fe1 <Return> [bind all <Key-Tab>]
  745.     bind .dlg.fe2 <Return> [bind all <Key-Tab>]
  746.     bind .dlg.fe3 <Return> [list .dlg.ok invoke]
  747.     bind .dlg.pe1 <Return> [list .dlg.ok invoke]
  748.  
  749.     GetSetup2
  750.     .dlg.pe1 icursor end
  751.     .dlg.fe2 icursor end
  752.  
  753.     # trace all variables involved in the Setup window 
  754.     trace variable state(proxy) w cmdlineUpdate
  755.     trace variable SP w cmdlineUpdate
  756.     cmdlineUpdate SP servHost w
  757.  
  758.     if {$state(proxy)} { focus -force .dlg.pe1 } { focus -force .dlg.fe2 }
  759.  
  760.     raise .dlg
  761.     tkwait window .dlg
  762.     wm deiconify .  
  763.  
  764.     if {$ok} {
  765.     DoListen
  766.     } else {
  767.     array set SP [array get save]
  768.     }
  769. }
  770. ##+##########################################################################
  771. # 
  772. # GetSetup2 -- toggles between forwarding and proxying modes in the dialog
  773. # 
  774. proc GetSetup2 {} {
  775.     global state
  776.     array set s {1 normal 0 disabled}
  777.     if {! $state(proxy)} { array set s {0 normal 1 disabled} }
  778.     
  779.     .dlg.pl1 config -state $s(1)
  780.     .dlg.pe1 config -state $s(1)
  781.     foreach w {1 2 3} {
  782.     .dlg.fl$w config -state $s(0)
  783.     .dlg.fe$w config -state $s(0)
  784.     }
  785. }
  786. ##+##########################################################################
  787. # 
  788. # ValidForm -- if setup dialog has valid entries then kill the dialog
  789. # 
  790. proc ValidForm {} {
  791.     global state SP ok
  792.     set ok 0
  793.     if {$state(proxy)} {
  794.     if {$SP(proxyPort) != ""} {set ok 1}
  795.     } elseif {$SP(clntPort) !="" && $SP(servHost) !="" && $SP(servPort) !=""} {
  796.     set ok 1
  797.     }
  798.     if {$ok} {destroy .dlg}
  799.     return $ok
  800. }
  801. ##+#########################################################################
  802. #
  803. # cmdlineUpdate
  804. #
  805. # cmdlineUpdate watches the connection variables and updates the command-line
  806. # equivalent.
  807. #
  808. proc cmdlineUpdate {X elt X} {
  809.     global SP
  810.  
  811.     # Check that port values are integers and that server host is not empty.
  812.     if {$::state(proxy)} {
  813.     set SP(cmdLine) "sockspy -proxy $SP(proxyPort)"
  814.     if {! [string is integer -strict $SP(proxyPort)]} {
  815.         set SP(cmdLine) "none (invalid proxy port above)"
  816.     }
  817.     return
  818.     }
  819.     
  820.     if {$SP(servHost) == ""} {
  821.     set SP(cmdLine) "none (invalid server host above)"
  822.     return
  823.     }
  824.     foreach elt {clntPort servPort} lbl {"client port" "server port"} {
  825.     if {! [string is integer -strict $SP($elt)]} {
  826.         set SP(cmdLine) "none (invalid $lbl above)"
  827.         return
  828.     }
  829.     }
  830.     set SP(cmdLine) "sockspy $SP(clntPort) $SP(servHost) $SP(servPort)"
  831. }
  832. ##+##########################################################################
  833. # 
  834. # Prompt -- Non-gui way to get input from the user.
  835. # 
  836. proc Prompt {prompt {default ""}} {
  837.     if {$default != ""} {
  838.     puts -nonewline "$prompt ($default): "
  839.     } else {
  840.     puts -nonewline "$prompt: "
  841.     }
  842.     flush stdout
  843.     set n [gets stdin line]
  844.  
  845.     if {$n == 0 && $default != ""} {
  846.     set line $default
  847.     }
  848.     return $line
  849. }
  850. ##+##########################################################################
  851. # 
  852. # Shutdown -- Closes the listen port before exiting
  853. # 
  854. proc Shutdown {} {
  855.     global state
  856.  
  857.     catch {close $state(listen)}
  858.     stateSaveReal                ;# save all state info NOW!
  859.     exit
  860. }
  861. ##+##########################################################################
  862. # 
  863. # ButtonBar -- Toggles the visibility of the button bar
  864. # 
  865. proc ButtonBar {} {
  866.     global state
  867.  
  868.     if {$state(bbar)} {                ;# Need to add button bar
  869.     pack .cmd -side top -fill x -pady 5 -in .bbar
  870.     } else {
  871.     pack forget .cmd
  872.     .bbar config -height 1            ;# Need this to give remove gap
  873.     }
  874. }
  875. ##+##########################################################################
  876. # 
  877. # ToggleExtract -- Toggles the visibility of the extract window
  878. # 
  879. proc ToggleExtract {{how 0}} {
  880.     global state
  881.  
  882.     if {$how == -1} {                ;# Hard kill
  883.     destroy .extract
  884.     set state(extract) 0
  885.     return
  886.     }
  887.     if {$state(extract)} {
  888.     createExtract
  889.     } else {
  890.     catch {wm withdraw .extract}
  891.     }
  892. }
  893. ##+##########################################################################
  894. # 
  895. # ToggleWrap -- turns on or off wrap in the text window
  896. # 
  897. proc ToggleWrap {} {
  898.     global state
  899.     array set x {0 none 1 char}
  900.     .out configure -wrap $x($state(autowrap))
  901. }
  902. ##+##########################################################################
  903. # 
  904. # ToggleCapture -- puts up a help message
  905. # 
  906. proc ToggleCapture {} {
  907.     global state
  908.     if {$state(capture)} {
  909.     INFO "Data capture display enabled" meta
  910.     .out config -bg white
  911.     } else {
  912.     INFO "Data capture display disabled" meta 1
  913.     .out config -bg grey88
  914.     }
  915. }
  916. ##+##########################################################################
  917. # 
  918. # Help -- a simple help system
  919. # 
  920. proc Help {} {
  921.     destroy .help
  922.     toplevel .help
  923.     wm title .help "SockSpy Help"
  924.     wm geom .help "+[expr {[winfo x .] + 50}]+[expr {[winfo y .] + 50}]"
  925.  
  926.     text .help.t -relief raised -wrap word -width 70 -height 25 \
  927.     -padx 10 -pady 10 -cursor {} -yscrollcommand {.help.sb set}
  928.     scrollbar .help.sb -orient vertical -command {.help.t yview}
  929.     button .help.dismiss -text Dismiss -command {destroy .help}
  930.     pack .help.dismiss -side bottom -pady 10
  931.     pack .help.sb -side right -fill y
  932.     pack .help.t -side top -expand 1 -fill both
  933.  
  934.     set bold "[font actual [.help.t cget -font]] -weight bold"
  935.     set fixed "[font actual [.help.t cget -font]] -family courier"
  936.     .help.t tag config title -justify center -foregr red -font "Times 20 bold"
  937.     .help.t tag configure title2 -justify center -font "Times 12 bold"
  938.     .help.t tag configure header -font $bold
  939.     .help.t tag configure n -lmargin1 15 -lmargin2 15
  940.     .help.t tag configure fixed -font $fixed -lmargin1 25 -lmargin2 55
  941.  
  942.     .help.t insert end "SockSpy\n" title
  943.     .help.t insert end "Authors: Tom Poindexter and Keith Vetter\n\n" title2
  944.  
  945.     set m "SockSpy lets you watch the conversation of a tcp client and server. "
  946.     append m "SockSpy acts much like a gateway: it waits for a tcp connection, "
  947.     append m "then connects to the real server. Data from the client is passed "
  948.     append m "on to the server, and data from the server is passed onto the "
  949.     append m "client.\n\n"
  950.  
  951.     append m "Along the way, the data streams are also displayed in text "
  952.     append m "widget with data sent from the client displayed in green, data "
  953.     append m "from the server in blue and connection metadata in red. The data "
  954.     append m "can be displayed as printable ASCII or both hex and "
  955.     append m "printables.\n\n"
  956.     .help.t insert end "What is SockSpy?\n" header $m n
  957.  
  958.     set m "Why might you want to use SockSpy? Debugging tcp client/server "
  959.     append m "programs, examining protocols and diagnosing network problems "
  960.     append m "are top candidates. Perhaps you just want to figure out how "
  961.     append m "something works. I've used it to bypass firewalls, to rediscover "
  962.     append m "my lost smtp password, to access a news server on a remote "
  963.     append m "network, etc.\n\nIt's not a replacement for heavy-duty tools "
  964.     append m "such as 'tcpdump' and other passive packet sniffers. On the "
  965.     append m "other hand, SockSpy doesn't require any special privileges to "
  966.     append m "run (unless of course, you try to listen on a Unix reserved tcp "
  967.     append m "port less than 1024.)\n\n"
  968.     .help.t insert end "Why Use SockSpy?\n" header $m n
  969.  
  970.     set m "Just double click on SockSpy to start it. You will be prompted for "
  971.     append m "various connection parameters described below.\n\n"
  972.     append m "Alternatively, you can specify the connection parameters on the "
  973.     append m "command line. This is also how you can run SockSpy in text mode "
  974.     append m "without a GUI.\n\n"
  975.     append m "To start SockSpy from the command line:\n"
  976.     .help.t insert end "How to Use SockSpy\n" header $m n
  977.     
  978.     set m "$ sockspy <listen-port> <server-host> <server-port>\n  or\n"
  979.     append m "$ sockspy -proxy <proxy-port>\n\n"
  980.     .help.t insert end $m fixed
  981.  
  982.     set m "To start SockSpy in text mode without a GUI:\n"
  983.     .help.t insert end $m n
  984.     set m "$ tclsh sockspy <listen-port> <server-host> <server-port>\n    or\n"
  985.     append m "$ tclsh sockspy -proxy <proxy-port>\n\n"
  986.     .help.t insert end $m fixed
  987.  
  988.     set m    "<listen-port>: the tcp port on which to listen. Clients should "
  989.     append m "connect to this port.\n"
  990.     append m "<server-host>:  the host where the real server runs.\n"
  991.     append m "<server-port>:  the tcp port on which the real server listens.\n"
  992.     append m "<proxy-port>:  the tcp port on which to listen in proxy-mode.\n\n"
  993.     .help.t insert end $m n
  994.  
  995.     set m "In proxy mode SockSpy works like a simple HTTP proxy server. "
  996.     append m "Instead of forwarding to a fixed server and port, it follows the "
  997.     append m "HTTP proxy protocol and reads the server information from the "
  998.     append m "first line of HTTP request.\n\n"
  999.     append m "You can turn on proxy mode by selecting it in the SockSpy Setup "
  1000.     append m "dialog, or by specifying -proxy on the command line.\n\n"
  1001.     .help.t insert end "Proxy Mode\n" header $m n
  1002.  
  1003.     set m "The extract window lets you extract specific parts of the "
  1004.     append m "data stream. As data arrives from the client, server, or as "
  1005.     append m "metadata, it gets matched against the appropriate regular "
  1006.     append m "expression filter. If it matches, the data gets displayed "
  1007.     append m "in the extract window. (Malformed regular expression are "
  1008.     append m "silently ignored.)\n\n"
  1009.     .help.t insert end "Extract Window\n" header $m n
  1010.  
  1011.     set m "To spy on HTTP connections to a server, type:\n"
  1012.     .help.t insert end "Example\n" header $m n
  1013.     .help.t insert end "  sockspy 8080 www.some.com 80\n" fixed
  1014.     .help.t insert end "and point your browser to\n" n
  1015.     .help.t insert end "  http://localhost:8080/index.html\n\n" fixed
  1016.     .help.t insert end "Alternatively, you could configure your browser to " n
  1017.     .help.t insert end "use localhost and port 8000 as its proxy, and then " n
  1018.     .help.t insert end "type:\n" n
  1019.     .help.t insert end "  sockspy -proxy 8000\n" fixed
  1020.     .help.t insert end "and user your browser normally.\n" n
  1021.     
  1022.     .help.t config -state disabled
  1023. }
  1024. ##+##########################################################################
  1025. # 
  1026. # About -- simple about box
  1027. # 
  1028. proc About {} {
  1029.     set m "SockSpy  version $::state(version)\n"
  1030.     append m "by Tom Poindexter and Keith Vetter\n"
  1031.     append m "Copyright 1998-[clock format [clock seconds] -format %Y]\n\n"
  1032.     append m "A program to eavesdrop on a tcp client server conversation."
  1033.     tk_messageBox -icon info -title "About SockSpy" -message $m -parent .
  1034. }
  1035. ##+##########################################################################
  1036. # 
  1037. # DoExtract -- Displays any data matching the RE in the extract window
  1038. # 
  1039. proc DoExtract {who data timestamp} {
  1040.     global state extract
  1041.  
  1042.     if {! $state(gui)} return
  1043.     if {! [info exists extract($who)]} return
  1044.     if {! [winfo exists .extract]} return
  1045.     
  1046.     regsub -all \r $data "" data
  1047.     foreach line [split $data \n] {
  1048.     if {$extract($who) == ""} continue
  1049.     catch {
  1050.         if {[regexp -nocase $extract($who) $line]} {
  1051.         .extract.out insert end "$timestamp" time_$who
  1052.         .extract.out insert end "$line\n" $who
  1053.         }
  1054.     }
  1055.     }
  1056.     if {$state(autoscroll)} {
  1057.     .extract.out see end
  1058.     }
  1059. }
  1060. ##+##########################################################################
  1061. # 
  1062. # stateRestore - Initialize save/restore package and do restore.
  1063. # 
  1064. proc stateRestore {} {
  1065.     global env state SP extract
  1066.  
  1067.     switch $::tcl_platform(platform) "macintosh" {
  1068.     set stateFile [file join $env(PREF_FOLDER) "SockSpy Preferences"]
  1069.     } "windows" {
  1070.     set stateFile [file join $env(HOME) "sockspy.cfg"]
  1071.     } "unix" {
  1072.     if {[info exists env(DOTDIR)]} {
  1073.         set stateFile [file join $env(DOTDIR) .sockspy]
  1074.     } else {
  1075.         set stateFile [file join $env(HOME) .sockspy]
  1076.     }
  1077.     }
  1078.     
  1079.     # complain only if it exists and we fail to read it successsfully
  1080.     if {[file exists $stateFile]} {
  1081.     uplevel #0 source $stateFile
  1082.     }
  1083.     
  1084.     set state(stateFile) $stateFile
  1085.     
  1086.     foreach v $::saveList {
  1087.     trace variable $v w stateSave
  1088.     }
  1089. }
  1090. ##+#########################################################################
  1091. #
  1092. # stateSave and stateSaveReal - Save program state.
  1093. #
  1094. # Two procs are used to do this.  stateSave is called to schedule the save.
  1095. # stateSaveReal is called to actually do the save.
  1096. #
  1097. # stateSave schedules the save a short time in the future to avoid interfering
  1098. # with the UI.    This is especially a problem with the "extract" variables which
  1099. # aren't edited from a modal dialogue and thus have no associated "OK" button
  1100. # to tell us when to save them.     (The alternative would be to save them after
  1101. # every keystroke - yuk.)
  1102. #
  1103. proc stateSave {a b c} {
  1104.     catch {after cancel $::state(saveId)}
  1105.     set ::state(saveId) [after 5000 stateSaveReal]
  1106. }
  1107.  
  1108. proc stateSaveReal {} {
  1109.     global state SP extract
  1110.  
  1111.     # silently ignore open failure
  1112.     if {[catch {open $state(stateFile) w} sf]} return
  1113.  
  1114.     set now [clock format [clock seconds] -format %c]
  1115.     puts $sf "# SockSpy Initialization File"
  1116.     puts $sf "# Written by SockSpy $state(version) on $now."
  1117.     puts $sf "#"
  1118.     puts $sf "# Warning: If you edit this file while SockSpy is running, "
  1119.     puts $sf "# edits will be lost! Also, only edit the lines already here. "
  1120.     puts $sf "# If you add procs or more variables, they will not be saved."
  1121.     
  1122.     puts $sf ""
  1123.     foreach v $::saveList {
  1124.     puts $sf "set $v \"[string map {[ \\[ \\ \\\\} [set $v]]\""
  1125.     }
  1126.     close $sf
  1127. }
  1128.  
  1129. ################################################################
  1130. ################################################################
  1131. ################################################################
  1132.  
  1133. set state(gui) [info exists tk_version]
  1134. if {[catch {package present uri}]} {
  1135.     ERROR "ERROR: SockSpy requires the uri package from tcllib."
  1136.     exit 1
  1137. }
  1138.     
  1139. timestampInit
  1140. stateRestore
  1141.  
  1142. if {$state(gui)} createMain
  1143.  
  1144. if {[lindex $argv 0] == "-local"} {
  1145.     set argv [list 8080 localhost 80]
  1146.     set argc 3
  1147. }
  1148.  
  1149. if {[lindex $argv 0] == "-proxy"} {
  1150.     set state(proxy) 1
  1151.     if {$argc == 2} {
  1152.     set SP(proxyPort) [lindex $argv 1]
  1153.     DoListen
  1154.     } else {
  1155.     GetSetup
  1156.     }
  1157. } else {
  1158.     if {$argc >= 1} { set SP(clntPort) [lindex $argv 0] }
  1159.     if {$argc >= 2} { set SP(servHost) [lindex $argv 1] }
  1160.     if {$argc >= 3} { set SP(servPort) [lindex $argv 2] }
  1161.     if {$argc >= 3} {
  1162.     DoListen
  1163.     } else {
  1164.     GetSetup
  1165.     }
  1166. }
  1167.  
  1168. if {$state(extract)} createExtract
  1169.  
  1170. if {! $state(gui)} {
  1171.     vwait forever                ;# tclsh needs this
  1172. } else {
  1173.     wm deiconify .
  1174. }
  1175.