home *** CD-ROM | disk | FTP | other *** search
/ PC Online 1997 October / PCO1097.ISO / FilesBBS / OS2 / TCOS2200.ARJ / TCOS2200.ZIP / _TCINST.BTM (.txt) next >
Encoding:
4DOS Compressed Batch-To-Memory File  |  1997-07-30  |  15.2 KB  |  668 lines
  1. @*echo off
  2. *setlocal
  3. *unalias *
  4. setdos /g.,
  5. set product=Take Command
  6. on errormsg goto on_error
  7. on break goto on_break
  8. goto start
  9.  
  10. text > nul
  11.  
  12.                 _TCINST.BTM -- Take Command Self-Install
  13.  
  14.          Copyright 1997, JP Software Inc., All Rights Reserved.
  15.           Author:  Tom Rawson   Last Revision:  July 21, 1997
  16.  
  17. This file is used to install a downloaded copy of Take Command/16, Take
  18. Command/32, or Take Command for OS/2.  It performs basic installation
  19. functions once, then renames itself so it will not be run automatically
  20. a second time.
  21.  
  22. DO NOT MODIFY THIS FILE UNLESS INSTRUCTED TO DO SO BY OUR SUPPORT STAFF.
  23. We cannot provide support for the installation process if you have
  24. modified the installation batch file!
  25.  
  26. The primary functions provided by this file are:
  27.  
  28.    * Check that required files appear to have been extracted OK,
  29.      and perform other similar tests for proper version, operating
  30.      system, etc.
  31.  
  32.    * Locate the previous copy of the product, if any.
  33.  
  34.    * If there was a previous copy:
  35.       - Copy over the old .INI and TCSTART files.
  36.       - Update the old .INI file for the new path.
  37.       - Allow branding of the new version if appropriate.
  38.  
  39.    * For Take Command/16:
  40.       - Copy CTL3D as required
  41.       - Use DDE to set up a Take Command group.
  42.  
  43.    * For Take Command/32:
  44.       - If running in Windows NT 3.5, copy CTL3D as required
  45.       - If running in Win95 or NT 4.0+, create a shortcut for Take Command,
  46.         and add registry extensions.
  47.  
  48.    * For Take Command for OS/2:
  49.       - Call a REXX script to update CONFIG.SYS (updates OS2_SHELL, COMSPEC,
  50.         BOOKSHELF, DPATH, and LIBPATH).
  51.       - Call a REXX script to create a desktop object for Take Command for
  52.         OS/2.
  53. endtext
  54.  
  55.  
  56. :start
  57. iff %_dos eq WIN then
  58.    iff %_winver ge 3.20 then
  59.       cls
  60.       text
  61.  
  62. Take Command/16 is designed to run under Windows 3.1, 3.11, and Windows
  63. for Workgroups.  We do not recommend installing it under Windows 95 or
  64. Windows NT.  For a native 32-bit Windows implementation of our GUI
  65. command line tools use Take Command/32, rather than Take Command/16.
  66.  
  67.       endtext
  68.       goto done
  69.    endiff
  70.    if %_4ver ge 1.0 goto verok
  71. endiff
  72. if %_dos eq WIN95 .and. %_4ver ge 1.0 goto verok
  73. if %_dos eq WIN32 .and. %_4ver ge 1.0 goto verok
  74. if %_dos eq PM .and. %_4ver ge 1.0 goto verok
  75. cls
  76. text
  77.  
  78. This automated installation batch file is for use under Take Command 2.0
  79. or above.  It will not work for other products, or earlier versions.
  80.  
  81. endtext
  82. goto done
  83.  
  84.  
  85. :verok
  86. echo.
  87. echo Setting up ...
  88.  
  89.  
  90. setdos /c%=^ 
  91. setdos /p%=& 
  92. setdos /e%= 
  93.  
  94. option //execwait=Yes
  95.  
  96. alias fatalerr `(echo %& %+ goto fatalerr)`
  97. alias wait `echo. %+ pause Press any key to continue ...`
  98. alias yesno `echo. %+ inkey /k"yn" %2& (Y/N)? %%%1`
  99. alias retry `(beep %+ iff "%2&" ne "" then %+ echo. %+ echo %2& %+ endiff %+ goto %1)`
  100. alias addslash `if "%@right[1,%[%1]]" ne "\" set %1=%[%1]\`
  101. alias insthelp `pushd %+ .\insthelp.exe %& %+ set result=%? %+ popd`
  102. alias callrexx `pushd %+ call %& %+ set result=%? %+ popd`
  103. alias instinf `pushd %+ %instinf %& %+ popd`
  104. alias sep `echo. %+ echo %@repeat[%1,72] %+ echo.`
  105. alias clear `cls %+ echo. %+ echo.`
  106.  
  107. set cd=%_cwds
  108. set instinf=rem
  109. switch %_dos
  110.    case WIN
  111.       set product=Take Command/16
  112.       set base=TCMD
  113.       set cd=%@upper[%cd]
  114.       set opsys=Windows
  115.    case WIN95
  116.       set product=Take Command/32
  117.       set base=TCMD32
  118.       set instinf=rundll.exe
  119.       if "%windir" ne ""  .and. exist %windir\rundll.exe set instinf=%windir\rundll.exe
  120.       set instinf=%instinf setupx.dll,InstallHinfSection DefaultInstall 132
  121.       set opsys=Windows 95
  122.    case WIN32
  123.       set product=Take Command/32
  124.       set base=TCMD32
  125.       if %_dosver ge 4.00 set instinf=%SystemRoot\System32\rundll32.exe setupapi,InstallHinfSection DefaultInstall 132
  126.       set opsys=Windows NT
  127.    case PM
  128.       set product=Take Command for OS/2
  129.       set base=TCMDOS2
  130.       set opsys=OS/2
  131. endswitch
  132.  
  133. switch %base
  134.    case TCMD
  135.       set reqfiles=TCMD.EXE TC16DLL.DLL TCMD.HLP
  136.       set exefile=TCMD.EXE
  137.       set batext=BTM BAT
  138.       set oldver=1.02
  139.       set verlist=1.0 2.0
  140.    case TCMD32
  141.       set reqfiles=TCMD32.EXE TC32DLL.DLL TCMD32.HLP TCMD32.CNT SHRALIAS.EXE
  142.       set exefile=TCMD32.EXE
  143.       set batext=BTM CMD BAT
  144.       set oldver=1.02
  145.       set verlist=1.0 2.0
  146.    case TCMDOS2
  147.       set reqfiles=TCMDOS2.EXE JPOS2DLL.DLL KEYSTACK.EXE TCMDOS2.INF TCMDOS2H.MSG JPOS2INS.CMD
  148.       set exefile=TCMDOS2.EXE
  149.       set batext=BTM CMD
  150.       set oldver=1.0
  151.       set verlist=1.0 2.0
  152. endswitch
  153.  
  154.  
  155. cls
  156. echo.
  157. echo.
  158. echo Welcome to Take Command!
  159. echo.
  160. echo This installation procedure is run automatically the first time you
  161. echo start a new downloaded or trial copy of Take Command.  It is written
  162. echo entirely in the Take Command batch language.
  163. echo.
  164. echo If you are new to Take Command, this procedure will install Take Command
  165. echo on your system.  No system files will be modified without your
  166. echo permission.
  167. echo.
  168. echo If you already have a previous version of Take Command installed, this
  169. echo procedure will copy the settings (in the .INI and TCSTART files) and
  170. echo registration information (if available) from the previous version, and
  171. echo -- after requesting your permission -- will update the appropriate
  172. echo configuration files.
  173. echo.
  174. echo If you have already installed this new version of Take Command, or prefer
  175. echo to perform the installation manually as described in the %base.TXT file,
  176. echo you can exit now, and this installation program will not be run again.
  177. echo.
  178. inkey /k"yn" Proceed with installation (Y/N)? %%yn
  179. if "%yn" ne "Y" goto exit_noretry
  180.  
  181. cdd %@path[%@full[%0]] || (echo Cannot switch to the product directory! %+ goto fatalerr)
  182.  
  183. iff not exist %exefile then
  184.    cls
  185.    echo.
  186.    echo The Take Command automated installation batch file is not in the
  187.    echo directory where the product files are stored.  Please put all
  188.    echo the new Take Command files in the same directory and try again.
  189.    goto done
  190. endiff
  191.  
  192.  
  193. for %f in (%reqfiles) if not exist %f (set errname=%f %+ goto missing_file)
  194. goto filesok
  195.  
  196. :missing_file
  197. sep =
  198. echo The %errname file is missing.  This file is required to install
  199. echo %product.  Please check that all downloaded files were
  200. echo placed in the same directory.
  201. goto nonfatalerr
  202.  
  203.  
  204. :filesok
  205.  
  206. clear
  207. echo This procedure installs %product version %_4ver.
  208. yesno pver Are you currently using an earlier version of%=n%product on your system
  209.  
  210. if "%pver" ne "Y" goto noprev
  211.  
  212. :getpdir
  213. sep -
  214. echo Please enter the directory where your previous
  215. input version of %product is installed:  %%prevdir
  216. addslash prevdir
  217.  
  218. if not isdir %prevdir retry getpdir That is not a valid directory
  219. iff not exist %[prevdir]%exefile then
  220.    echo This directory does not appear to contain a previous version of
  221.    echo %product.  Please try again.
  222.    retry getpdir
  223. endiff
  224.  
  225. set prevtime=%@filetime[%[prevdir]%exefile]
  226. set prevver=%@left[2,%prevtime].%@instr[3,1,%prevtime]
  227. unset prevtime
  228. if "%@left[1,%prevver]" eq "0" set prevver=%@right[3,%prevver]
  229. iff %@index[%verlist,%prevver] ne -1 then
  230.    set newupg=%@if[%@eval[%prevver - %@left[%oldver,3]] ge 0.5,Y,N]
  231.    set upgdist=%@eval[%@left[%_4ver,3] - %prevver]
  232. else
  233.    sep -
  234.    echo The installation software cannot identify your previous version of Take
  235.    echo Command.  Installation can proceed, but a few prompts may be incorrect.
  236.    echo You can choose to proceed with the installation, re-enter the
  237.    echo installation directory, or stop and perform the installation manually,
  238.    echo using the instructions in %base.TXT
  239.    echo.
  240.    inkey /k"ydn" Enter Y to proceed, D to change the installation directory, or N to stop: %%yn
  241.    if "%yn" eq "D" goto getpdir
  242.    if "%yn" ne "Y" goto exit_noretry
  243.    set newupg=N
  244.    set upgdist=9.0
  245. endiff
  246. unset prevver
  247.  
  248. clear
  249. echo Your current %base.INI, TCSTART, and TCEXIT files (if any) will now be
  250. echo copied from the previous Take Command directory.  If these files already
  251. echo exist in the new Take Command directory you will be prompted for whether
  252. echo to replace the file in the new directory with the file from the old
  253. echo directory.
  254. echo.
  255. yesno yn Copy the %base.INI, TCSTART, and TCEXIT files
  256. iff "%yn" eq "Y" then
  257.  
  258.    :: Copy the files
  259.    if exist %[prevdir]%[base].ini copy /r %[prevdir]%[base].ini .\
  260.    for %f in (TCSTART TCEXIT) for %e in (%batext) if exist %[prevdir]%f.%e copy /r %[prevdir]%f.%e .\
  261.  
  262.    :: Update paths in INI file
  263.    iff exist %base.INI then
  264.       sep -
  265.       echo Any TCStartPath directive in the new copy of %base.INI will now be
  266.       echo updated to point to your new Take Command directory.  The old .INI file
  267.       echo will be saved as %base.JPS.  If you do not allow this update, you must
  268.       echo perform it manually, or %product may not work properly.
  269.       echo.
  270.       yesno yn Update %base.INI
  271.       set jptemp=%@unique[.]
  272.       iff "%yn" eq "Y" then
  273.          iff %base eq TCMDOS2 then
  274.             callrexx jpos2ins.cmd "TCMD" "%cd" "UpdateINI" "TCMDOS2.INI" "%jptemp"
  275.          else
  276.             copy %base.INI %jptemp > nul
  277.             set oldtcpath=%@iniread[%jptemp,TakeCommand,TCStartPath]
  278.             if "%oldtcpath" ne "" set result=%@iniwrite[%jptemp,TakeCommand,TCStartPath,%_cwd]
  279.          endiff
  280.          iff %result eq 0 then
  281.             copy %base.INI %base.JPS > nul
  282.             del /q %base.INI > nul
  283.             copy %jptemp %base.INI > nul
  284.          else
  285.             sep -
  286.             echo Paths in %base.INI could not be updated.  Be sure to manually update
  287.             echo any settings in %base.INI which point to the Take Command directory.
  288.             echo If you do not, %product may not work properly.
  289.          endiff
  290.          wait
  291.       endiff
  292.       del /q %jptemp > nul
  293.    endiff
  294.  
  295. else
  296.    sep -
  297.    echo You chose not to copy existing startup files from your previous Take
  298.    echo Command directory.  You may want to copy these files manually at a
  299.    echo later time, and update them for the new version.
  300.    wait
  301. endiff
  302.  
  303.  
  304. clear
  305. echo The next part of the installation process varies depending on whether
  306. echo you own a purchased or "registered" version of %product, as
  307. echo opposed to a trial or "shareware" version.
  308. echo.
  309. yesno yn Are you upgrading from a previously purchased%=ncopy of %product
  310. if "%yn" ne "Y" goto trialver
  311.  
  312.  
  313. iff %newupg eq Y then
  314.  
  315.    :: Previous version is 2.0 or later
  316.    iff %upgdist gt 0.1 then
  317.       :: Major update, order is probably required
  318.       sep -
  319.       echo The installation software has determined that you are installing a
  320.       echo major update to Take Command (as opposed to a minor or maintenance
  321.       echo update).
  322.       echo.
  323.       echo Normally such updates must be purchased; please contact JP Software
  324.       echo or your dealer for details.  If you order an upgrade you can use the
  325.       echo trial version while you wait for your upgrade to arrive.
  326.       echo.
  327.       echo If you believe you are eligible for a free registered copy of this
  328.       echo version even though it is a major update (for example, because you
  329.       echo purchased a special offer which included the next version), you can try
  330.       echo to "brand" Take Command with your name and serial number manually; for
  331.       echo instructions see the README.TXT file.  If branding fails with the
  332.       echo message "Contact JP Software or your dealer for an upgrade" then you
  333.       echo must purchase the upgrade.
  334.    else
  335.       :: Minor update
  336.       sep -
  337.       echo The installation software has determined that you are installing a
  338.       echo minor or maintenance update to Take Command.  The "branding" (name
  339.       echo and serial number) information should already be stored on your
  340.       echo system, and will be transferred automatically to the new version.
  341.       echo.
  342.       echo If the information does not transfer properly, or you need to
  343.       echo reinstall your branding information for any other reason, see the
  344.       echo manual branding instructions in the README.TXT file.
  345.       echo.
  346.    endiff
  347.  
  348. else
  349.  
  350.    :: Updating from 1.0x
  351.    sep -
  352.    echo This portion of the installation process provides information on "branding"
  353.    echo the new version of %product with your name and serial number.
  354.    echo.
  355.    echo This section is informational only; you cannot actually brand Take
  356.    echo Command now because it is in use (to run this installation batch file),
  357.    echo and %opsys does not allow running programs to be modified.  For
  358.    echo manual branding instructions see the README.TXT file.
  359.    echo.
  360.    echo You will only be eligible to brand this upgrade if you originally
  361.    echo purchased Take Command 1.0x on diskette, and you are now upgrading to
  362.    echo version 2.0.  If you originally obtained Take Command on our CD Suite,
  363.    echo in most cases you must purchase the version 2.0 upgrade (once you order
  364.    echo the upgrade you can continue to use this trial version until your order
  365.    echo arrives).  For more information see PRODUCTS.TXT and UPGFORM.TXT.
  366.    echo.
  367.    echo Branding will also require the brand program and brand information
  368.    echo (name, serial number, and validation code) from your previous version of
  369.    echo Take Command.  If you are eligible for the upgrade at no charge but have
  370.    echo lost your brand information, contact JP Software to obtain a replacement
  371.    echo (there is a small charge for this service).
  372.  
  373. endiff
  374.  
  375. wait
  376. goto doconfig
  377.  
  378.  
  379. :noprev
  380. :trialver
  381. sep -
  382. echo You may use this new trial version of %product for up to 21
  383. echo days while evaluating it.  After that time you must purchase Take Command
  384. echo if you continue to use it.  See our license agreement in the file
  385. echo LICENSE.TXT for complete details.
  386. wait
  387.  
  388.  
  389. :doconfig
  390.  
  391. if %base ne TCMDOS2 goto configdone
  392.  
  393. set csname=%_boot:\CONFIG.SYS
  394. set csbak=%_boot:\CONFIG.JPS
  395. set csmod=N
  396. clear
  397. echo The installation process updates paths in CONFIG.SYS so that Take Command
  398. echo for OS/2 can locate its files properly.  You have three choices:
  399. echo.
  400. echo    - Update the system CONFIG.SYS file.  This is the recommended method
  401. echo      and will fully install Take Command for OS/2 on your system.  Your
  402. echo      previous CONFIG.SYS file will be saved as CONFIG.JPS.
  403. echo.
  404. echo    - Make a copy of CONFIG.SYS in the Take Command for OS/2 directory
  405. echo      and update that copy, instead of the "real" CONFIG.SYS file.  This
  406. echo      allows you to review the changes before implementing them.  If
  407. echo      there is already a copy of CONFIG.SYS in the Take Command for OS/2
  408. echo      directory it will be renamed CONFIG.JPS.
  409. echo.
  410. echo    - Skip the CONFIG.SYS update.  In this case you will have to update
  411. echo      CONFIG.SYS manually (see the TCMDOS2.TXT file for details).
  412. echo.
  413. echo Enter:  Y to update %csname
  414. echo         C to update a copy of CONFIG.SYS in the Take Command directory
  415. echo         N to skip the CONFIG.SYS changes
  416. echo.
  417. inkey /k"YNC" Your choice:  %%csopt
  418.  
  419. switch %csopt
  420.  
  421.    case Y
  422.       set jptemp=%@unique[.]
  423.       callrexx jpos2ins.cmd "TCMD" "%cd" "UpdatePaths" "%csname" "%jptemp"
  424.       iff %result eq 0 then
  425.          copy %csname %csbak > nul
  426.          copy %jptemp %csname > nul
  427.          set csmod=Y
  428.          sep -
  429.          echo CONFIG.SYS has been updated.
  430.       else
  431.          sep -
  432.          echo CONFIG.SYS could not be updated due to the above error.  You must update
  433.          echo it manually (see the TCMDOS2.TXT file for details).
  434.       endiff
  435.       del /q %jptemp > nul
  436.  
  437.    case C
  438.       echo.
  439.       if exist .\config.sys (move .\CONFIG.SYS .\CONFIG.JPS > nul)
  440.       callrexx jpos2ins.cmd "TCMD" "%cd" "UpdatePaths" "%csname" "%[cd]CONFIG.SYS"
  441.       iff %result eq 0 then
  442.          sep -
  443.          echo The copy of CONFIG.SYS has been updated.  You can review this file, then
  444.          echo make changes to the real CONFIG.SYS file manually when you are ready.
  445.       else
  446.          sep -
  447.          echo The copy of CONFIG.SYS could not be updated due to the above error.  You
  448.          echo must update CONFIG.SYS manually (see the TCMDOS2.TXT file for details).
  449.       endiff
  450.  
  451.    case N
  452.       sep -
  453.       echo CONFIG.SYS will not be updated.  You can update it manually when you are
  454.       echo ready (see the TCMDOS2.TXT file for details).
  455.  
  456. endswitch
  457. wait
  458.  
  459.  
  460. :configdone
  461.  
  462.  
  463. switch %base
  464.  
  465.    case TCMD
  466.       clear
  467.       text
  468. The installation software can create a JP Software program group for
  469. Take Command/16, accessible from Program Manager.  The group will
  470. include items to start Take Command itself, and the Take Command help.
  471.  
  472. If you choose not to create these items now, you can create them
  473. manually at any time.  For instructions see the TCMD.TXT file, in the
  474. chapter on installing Take Command/16.
  475.  
  476. The group creation process may not work properly if Program Manager is
  477. not your Windows shell.
  478.       endtext
  479.       yesno yn Create a program group and items for Take Command/16
  480.       iff "%yn" == "Y" then
  481.          on errormsg
  482.          echo.
  483.          echo Working ...
  484.          ddeexec progman, progman, [CreateGroup(JP Software)]
  485.          (ddeexec progman, progman, [ReplaceItem(Take Command Prompt)]) >& nul
  486.          ddeexec progman, progman, [AddItem(%[cd]%exefile,Take Command Prompt,,,,,%_cwd,,)]
  487.          (ddeexec progman, progman, [ReplaceItem(Take Command Help)]) >& nul
  488.          ddeexec progman, progman, [AddItem(WINHELP %[cd]TCMD.HLP,Take Command Help,,,,,%_cwd,,)]
  489.          on errormsg goto on_error
  490.          activate "%_wintitle"
  491.          echo.
  492.          echo The program group and items have been created.
  493.          wait
  494.       endiff
  495.  
  496.       sep -
  497.       text
  498. Take Command/16 includes a feature called "Caveman" which allows you
  499. to run DOS applications within the Take Command window.  In order to
  500. use Caveman, you must add a line to the Windows SYSTEM.INI file to
  501. load the Caveman driver, CAVEMAN.386.
  502.  
  503. Due to the structure of SYSTEM.INI, the installation software cannot
  504. perform this step for you reliably.  If you want to use Caveman, see the
  505. Take Command/16 installation instructions in TCMD.TXT, which explain how
  506. to add the line for CAVEMAN.386 manually.
  507.       endtext
  508.       wait
  509.  
  510.    case TCMD32
  511.       clear
  512.       :: Registry stuff only works in Win95 or NT 4.0
  513.       iff (%_dos eq WIN95 .or. (%_dos eq WIN32 .and. %_dosver ge 4.00)) then
  514.          iff exist jpsoft.inf then
  515.             clear
  516.             text
  517. The installation software can create a JP Software program group for
  518. Take Command/32, accessible through the Start menu.  The group will
  519. include shortcuts to start Take Command/32 itself, and the Take
  520. Command/32 help.  The same process creates a desktop shortcut for Take
  521. Command/32 (easily deleted if you prefer to use only the Start menu).
  522.  
  523. The JP Software group and related desktop shortcuts will also be made
  524. removable using Windows' Uninstall facility (available from the Control
  525. Panel's Add / Remove Programs item).
  526.  
  527. If you choose not to create these items now, you can create shortcuts
  528. manually as described in the TCMD32.TXT file, in the chapter on
  529. installing Take Command/32.
  530.             endtext
  531.             yesno yn Create a program group and desktop shortcuts%=nfor Take Command/32
  532.             iff "%yn" == "Y" then
  533.                instinf %[cd]jpsoft.inf
  534.                echo.
  535.                echo The program group and shortcuts have been created.
  536.                wait
  537.             endiff
  538.          endiff
  539.  
  540.          iff exist jptcmd32.inf then
  541.             clear
  542.             text
  543. The installation software can install optional registry extensions for
  544. Take Command/32.  The registry extensions customize a few Windows
  545. functions to take advantage of features provided by Take Command/32.
  546. Specifically, they:
  547.  
  548.    - Create a new "Take Command/32 Prompt" in the context menu of drives
  549.      and directories, to launch Take Command in that drive or directory.
  550.  
  551.    - Extend Windows' definition of a "batch file" to include BTM files,
  552.      including the ability to double-click on a BTM file to execute it.
  553.  
  554.    - Provide an additional "open" option in the context menu of batch
  555.      files (.BAT, .CMD, and .BTM), to run the file with Take Command/32.
  556.  
  557. These registry extensions can be removed using Windows' Uninstall facility
  558. (available from the Control Panel under Add / Remove Programs).
  559.  
  560. If you choose not to install the registry extensions now, you can do so
  561. later as described in the TCMD32.TXT file, in the Take Command/32
  562. installation chapter.
  563.             endtext
  564.             yesno yn Install Take Command/32 registry extensions
  565.             iff "%yn" == "Y" then
  566.                instinf %[cd]jptcmd32.inf
  567.                echo.
  568.                echo The registry extensions have been installed.
  569.                wait
  570.             endiff
  571.          endiff
  572.       endiff
  573.  
  574.    case TCMDOS2
  575.       clear
  576.       text
  577. If you wish, the installation software can create an OS/2 desktop folder
  578. for Take Command for OS/2, including objects to start Take Command
  579. itself, and the Take Command help.  You can also create these objects
  580. manually as described in the TCMDOS2.TXT file, in the chapter on
  581. installing Take Command for OS/2.
  582.       endtext
  583.       yesno yn Create an OS/2 desktop folder for Take Command
  584.       iff "%yn" == "Y" then
  585.          callrexx jpos2ins.cmd "TCMD" "%cd" "CreateFolder"
  586.          wait
  587.       endiff
  588.  
  589. endswitch
  590.  
  591.  
  592. clear
  593. switch %base
  594.  
  595.    case TCMD .or. TCMD32
  596.       echo %product installation is complete.  To start %product, use
  597.       echo the shortcut or group created during the installation process.  If you
  598.       echo did not allow the installation software to create a shortcut you can
  599.       echo do so manually; instructions are in the %base.TXT file, in the chapter
  600.       echo on %product installation.
  601.  
  602.    case TCMDOS2
  603.       iff %csmod eq Y then
  604.          echo Take Command for OS/2 installation is complete.  Please reboot before
  605.          echo using Take Command, so that the changes made to paths in CONFIG.SYS can
  606.          echo take effect.
  607.       else
  608.          echo Take Command for OS/2 installation is complete.  You chose not to update
  609.          echo the system CONFIG.SYS file during the installation process.  When you
  610.          echo are ready, update CONFIG.SYS as described in the TCMDOS2.TXT file, then
  611.          echo reboot.
  612.       endiff
  613.  
  614. endswitch
  615.  
  616. goto exit_noretry
  617.  
  618.  
  619.  
  620. :on_error
  621. :nonfatalerr
  622. on errormsg
  623. on break
  624. echo.
  625. echo.
  626. echo *** The installation stopped due to the above error.  The installation
  627. echo     program will restart the next time you start Take Command.
  628. echo.
  629. goto done
  630.  
  631. :on_break
  632. on errormsg
  633. on break
  634. echo.
  635. echo.
  636. echo *** Installation interrupted.  The installation program will restart
  637. echo     the next time you start Take Command.
  638. echo.
  639. goto done
  640.  
  641. :fatalerr
  642. on errormsg
  643. on break
  644. echo.
  645. echo.
  646. echo *** Installation stopped due to the above error.
  647. echo.
  648. echo You will have to complete the installation manually.  For
  649. echo instructions see the chapter on %product installation
  650. echo in the %base.TXT file.
  651. echo.
  652.  
  653. :exit_noretry
  654. on errormsg
  655. on break
  656. set bname=%@full[%0]
  657. move %bname %@path[%bname]\%@name[%bname].btx >& nul
  658.  
  659. :done
  660. on errormsg
  661. on break
  662. echo.
  663. pause Press any key to exit to the Take Command prompt ...
  664. cls
  665. endlocal
  666. *if %@index["%prompt",$e] ne -1 *prompt
  667.  
  668.