home *** CD-ROM | disk | FTP | other *** search
/ CD Actual 3 / CD ACTUAL 3.iso / linux / incoming / jstools-.6v3 / jstools- / jstools-tk3.6v3.0 / lib / jedit_cmds.tcl < prev    next >
Encoding:
Text File  |  1995-03-14  |  22.0 KB  |  745 lines
  1. # jedit_cmds.tcl - most user-visible commands for jedit
  2. #   (preference commands are in jedit_prefs.tcl)
  3. # 
  4. # Copyright 1992-1994 by Jay Sekora.  All rights reserved, except 
  5. # that this file may be freely redistributed in whole or in part 
  6. # for non-profit, noncommercial use.
  7.  
  8. ######################################################################
  9. #
  10. # NOTE: these mostly take the arguments "t args", where t is the text
  11. # widget they apply to.  That way they can be used in a j:tkb:mkmap
  12. # table (where %W %K %A will be appended to the command before 
  13. # execution) as well as with just %W in bindings.  In a few cases
  14. # where t would be ignored, they just take "args".
  15. #
  16. ######################################################################
  17.  
  18. ######################################################################
  19. # view the help file
  20. ######################################################################
  21.  
  22. proc jedit:cmd:help { t args } {
  23.   exec jdoc jedit &
  24. }
  25.  
  26. ######################################################################
  27. # make the about box
  28. ######################################################################
  29.  
  30. proc jedit:cmd:about { t args } {
  31.   global VERSION
  32.   set about_editor [format {
  33.     j:rt:hl "jedit"
  34.     j:rt:cr
  35.     j:rt:rm "by Jay Sekora, "
  36.     j:rt:tt "js@bu.edu"
  37.     j:rt:par
  38.     j:rt:rm "A customisable text editor for X Windows."
  39.     j:rt:cr
  40.     j:rt:rm "Version %s."
  41.     j:rt:par
  42.     j:rt:rm "Copyright \251 1992-1994 by Jay Sekora.  "
  43.     j:rt:rm "All rights reserved, except that this file may be freely "
  44.     j:rt:rm "redistributed in whole or in part for non\255profit, "
  45.     j:rt:rm "noncommercial use."
  46.     j:rt:par
  47.     j:rt:rm "If you find bugs or have suggestions for improvement, "
  48.     j:rt:rm "please let me know.  "
  49.     j:rt:rm "Feel free to use bits of this code in your own "
  50.     j:rt:tt "wish"
  51.     j:rt:rm " scripts."
  52.   } $VERSION]
  53.   j:about .about $about_editor
  54.   j:about:button .about {About jedit} $about_editor
  55.   j:about:button .about {About the Author} [j:about_jay]
  56.   j:about:button .about {About Tk and Tcl} [j:about_tktcl]
  57.   
  58.   tkwait window .about
  59. }
  60.  
  61. ######################################################################
  62. # open a new editor window
  63. ######################################################################
  64.  
  65. proc jedit:cmd:new_window { args } {
  66.   jedit:jedit
  67. }
  68.  
  69. ######################################################################
  70. # prompt user for mode
  71. ######################################################################
  72.  
  73. proc jedit:cmd:ask_mode { t args } {
  74.   global MODE
  75.   
  76.   set window [jedit:text_to_top $t]
  77.   set prompt_result [j:prompt -text "Editing Mode:"]
  78.   if {$prompt_result != {}} then {
  79.     jedit:set_mode $t $prompt_result
  80.     jedit:apply_mode $window
  81.   }
  82. }
  83.  
  84. ######################################################################
  85. # close a window
  86. ######################################################################
  87.  
  88. proc jedit:cmd:close { t args } {
  89.   global JEDIT_WINDOW_COUNT
  90.   
  91.   if {$JEDIT_WINDOW_COUNT == 1} {
  92.     jedit:cmd:quit $t
  93.   } else {
  94.     set mode [jedit:get_mode $t]
  95.     if {[info procs mode:$mode:pre_close_hook] != {}} {
  96.       mode:$mode:pre_close_hook $t
  97.     }
  98.     
  99.     if {[info procs mode:$mode:close] == {}} {
  100.       if [j:confirm -text "Are you sure you want to close this window?"] {
  101.         incr JEDIT_WINDOW_COUNT -1    ;# one fewer window
  102.         destroy [jedit:text_to_top $t]
  103.       }
  104.     } else {
  105.       mode:$mode:close $t
  106.     }
  107.   }
  108. }
  109.  
  110. ######################################################################
  111. # quit the editor
  112. ######################################################################
  113.  
  114. proc jedit:cmd:quit { t args } {
  115.   set mode [jedit:get_mode $t]
  116.   
  117.   if {[info procs mode:$mode:pre_quit_hook] != {}} {
  118.     mode:$mode:pre_quit_hook $t
  119.   }
  120.   
  121.   if {[info procs mode:$mode:quit] == {}} {
  122.     if [j:confirm -text "Are you sure you want to quit?"] {
  123.       exit 0
  124.     }
  125.   } else {
  126.     mode:$mode:quit $t
  127.   }
  128. }
  129.  
  130. ######################################################################
  131. # read in a file
  132. ######################################################################
  133.  
  134. proc jedit:cmd:load { t args } {
  135.   jedit:cmd:save_checkpoint $t    ;# save undo information
  136.  
  137.   set filename [j:fs -prompt "Load:"]
  138.   if {"x$filename" != "x"} then {
  139.     jedit:set_filename $t $filename
  140.     
  141.     # if new filename should have a different mode, set it:
  142.     set old_mode [jedit:get_mode $t]
  143.     set new_mode [jedit:guess_mode $filename]
  144.     if {[string compare $old_mode $new_mode] != 0} {
  145.       jedit:set_mode $t $new_mode
  146.       jedit:apply_mode $t
  147.     }
  148.     
  149.     jedit:read $filename $t
  150.   }
  151. }
  152.   
  153. ######################################################################
  154. # write out a file, using window's filename if defined
  155. ######################################################################
  156.  
  157. proc jedit:cmd:save { t args } {
  158.   set filename [jedit:get_filename $t]
  159.   if {"x$filename" != "x"} then {
  160.     jedit:write $filename $t
  161.   } else {
  162.     set filename [j:fs -prompt "Save as:"]
  163.     if {"x$filename" != "x"} then {
  164.       jedit:set_filename $t $filename
  165.       jedit:set_label [jedit:text_to_top $t]
  166.       jedit:write $filename $t
  167.     }
  168.   }
  169. }
  170.  
  171. ######################################################################
  172. # write out a file, prompting for a filename
  173. ######################################################################
  174.  
  175. proc jedit:cmd:saveas { t args } {
  176.   set filename [j:fs -prompt "Save as:"]
  177.   if {"x$filename" != "x" && \
  178.      ( ! [file exists $filename] || \
  179.       [j:confirm -text \
  180.       "File \"$filename\" exists; replace it?"] )} then {
  181.     jedit:set_filename $t $filename
  182.     jedit:set_label [jedit:text_to_top $t]
  183.     jedit:write $filename $t
  184.   }
  185. }
  186.  
  187. ######################################################################
  188. # print the file using lpr
  189. ######################################################################
  190.  
  191. proc jedit:cmd:print { t args } {
  192.   global J_PREFS
  193.   if [j:confirm -priority 24 \
  194.     -text "Print using `lpr' to printer `$J_PREFS(printer)'?"] {
  195.     exec lpr -P$J_PREFS(printer) << [$t get 1.0 end]
  196.   }
  197. }
  198.  
  199. ######################################################################
  200. # print rich-text as postscript using lpr
  201. ######################################################################
  202.  
  203. proc jedit:cmd:print_postscript { t args } {
  204.   global J_PREFS
  205.   if [j:confirm -priority 24 \
  206.     -text "Print as PostScript using `lpr' to printer `$J_PREFS(printer)'?"] {
  207.     exec lpr -P$J_PREFS(printer) << [j:tc:ps:convert_text $t]
  208.   }
  209. }
  210.  
  211. ######################################################################
  212. # read in a file and insert it at the insert mark
  213. ######################################################################
  214.  
  215. proc jedit:cmd:insfile { t args } {
  216.   jedit:cmd:save_checkpoint $t            ;# save undo information
  217.   set prompt_result [j:fs -prompt "Insert:"]
  218.   if {$prompt_result != {}} then {
  219.     j:text:insert_string $t [exec cat $prompt_result]
  220.     j:text:insert_string $t "\n"
  221.   }
  222. }
  223.  
  224. ######################################################################
  225. # delete the selection and copy it to CUTBUFFER
  226. ######################################################################
  227.  
  228. proc jedit:cmd:cut { t args } {
  229.   global CUTBUFFER
  230.  
  231.   jedit:cmd:save_checkpoint $t            ;# save undo information
  232.  
  233.   set CUTBUFFER [$t get sel.first sel.last]
  234.   j:text:delete $t sel.first sel.last
  235. }
  236.  
  237. ######################################################################
  238. # copy the selection into CUTBUFFER
  239. ######################################################################
  240.  
  241. proc jedit:cmd:copy { t args } {
  242.   global CUTBUFFER
  243.  
  244.   set CUTBUFFER [$t get sel.first sel.last]
  245. }
  246.  
  247. ######################################################################
  248. # insert CUTBUFFER
  249. ######################################################################
  250.  
  251. proc jedit:cmd:paste { t args } {
  252.   global CUTBUFFER
  253.   
  254.   set mode [jedit:get_mode $t]
  255.   
  256.   jedit:cmd:save_checkpoint $t            ;# save undo information
  257.  
  258.   if {[info procs mode:$mode:pre_paste_hook] != {}} {
  259.     mode:$mode:pre_paste_hook $t
  260.   }
  261.  
  262.   j:text:insert_string $t $CUTBUFFER
  263.  
  264.   if {[info procs mode:$mode:post_paste_hook] != {}} {
  265.     mode:$mode:post_paste_hook $t
  266.   }
  267. }
  268.  
  269. ######################################################################
  270. # copy the selection into a text panel (as a note)
  271. ######################################################################
  272.  
  273. proc jedit:cmd:note { t args } {
  274.   j:more -title Note -text [$t get sel.first sel.last]
  275. }
  276.  
  277. ######################################################################
  278. # mark the entire text as selected
  279. ######################################################################
  280.  
  281. proc jedit:cmd:select_all { t args } {
  282.   $t tag add sel 1.0 end
  283. }
  284.  
  285. ######################################################################
  286. # prompt for a Unix command to run on the selection
  287. ######################################################################
  288.  
  289. proc jedit:cmd:run_pipe { t args } {
  290.   global UNIX_PIPE; append UNIX_PIPE {}
  291.  
  292.   set prompt_result [j:prompt -text "Unix Filter:" -default $UNIX_PIPE]
  293.   if {$prompt_result != {}} then {
  294.     set UNIX_PIPE $prompt_result
  295.     jedit:pipe $t $UNIX_PIPE        ;# handles checkpointing
  296.   }
  297. }
  298.  
  299. ######################################################################
  300. # prompt for a Unix command to insert
  301. ######################################################################
  302.  
  303. proc jedit:cmd:run_command { t args } {
  304.   global UNIX_COMMAND; append UNIX_COMMAND {}
  305.  
  306.   set prompt_result [j:prompt -text "Unix Command:" -default $UNIX_COMMAND]
  307.   if {$prompt_result != {}} then {
  308.     set UNIX_COMMAND $prompt_result
  309.     catch { eval exec $UNIX_COMMAND } result
  310.     if {$result != {}} {
  311.       append result "\n"
  312.       jedit:cmd:save_checkpoint $t            ;# save undo information
  313.       j:text:insert_string $t $result
  314.     }
  315.   }
  316. }
  317.  
  318. ######################################################################
  319. # expand dynamic abbreviation before insert
  320. ######################################################################
  321.  
  322. proc jedit:cmd:dabbrev { t args } {
  323.   # THIS COULD BE SIMPLIFIED: do i need both match... and abbrev... vars?
  324.   # PROBLEM: this depends on the Text widget's notion of words.
  325.   # it would be nice to be able to expand, say, $tk_l to $tk_library.
  326.  
  327.   global ABBREV ABBREV_POS MATCH MATCH_POS
  328.  
  329.   $t mark set abbrevend insert
  330.   $t mark set abbrevstart insert
  331.   while {[$t compare abbrevstart != 1.0] &&
  332.          [string match {[a-zA-Z0-9']} [$t get {abbrevstart - 1 char}]]} {
  333.     $t mark set abbrevstart {abbrevstart -1char}
  334.   }
  335.  
  336.   set ABBREV_POS [$t index abbrevstart]    ;# for dabbrev_again
  337.  
  338.   set ABBREV [$t get abbrevstart insert]
  339.  
  340.   set context [$t get 0.0 abbrevstart]
  341.  
  342.   while {1} {
  343.     set matchpos [string last $ABBREV $context]
  344.   
  345.     if {$matchpos == -1} {return 0}    ;# not found
  346.  
  347.     $t mark set matchstart [$t index "0.0 +$matchpos chars"]
  348.     if {[$t compare matchstart == {matchstart wordstart}]} {
  349.       $t mark set matchend [$t index {matchstart wordend}]
  350.       break                ;# sort of an `until'
  351.     }
  352.     set context [$t get 0.0 matchstart]
  353.   }
  354.  
  355.   set MATCH [$t get matchstart matchend]
  356.  
  357.   set MATCH_POS [$t index matchstart]
  358.  
  359.   j:text:replace $t abbrevstart abbrevend $MATCH
  360.   return 1
  361. }
  362.  
  363. # ######################################################################
  364. # # dabbrev_again - search earlier in the text for abbrevs
  365. # #   CURRENTLY NOT USED
  366. # ######################################################################
  367. # 
  368. # proc dabbrev_again { t args } {
  369. #   # THIS COULD BE SIMPLIFIED: do i need both match... and abbrev... vars?
  370. #   # PROBLEM: this depends on the Text widget's notion of words.
  371. #   # it would be nice to be able to expand, say, $tk_l to $tk_library.
  372. # 
  373. #   global ABBREV ABBREV_POS MATCH MATCH_POS
  374. # 
  375. #   set context [$t get 0.0 $MATCH_POS]
  376. # 
  377. #   while {1} {
  378. #     set matchpos [string last $ABBREV $context]
  379. #   
  380. #     if {$matchpos == -1} {
  381. #       return [sabbrev]            ;# try the static table
  382. #     }
  383. #     $t mark set matchstart [$t index "0.0 +$matchpos chars"]
  384. #     if {[$t compare matchstart == {matchstart wordstart}]} {
  385. #       $t mark set matchend [$t index {matchstart wordend}]
  386. #       break                ;# sort of an `until'
  387. #     }
  388. #     set context [$t get 0.0 matchstart]
  389. #   }
  390. # 
  391. #   set MATCH [$t get matchstart matchend]
  392. # 
  393. #   set MATCH_POS [$t index matchstart]
  394. # 
  395. #   j:text:replace $t $ABBREV_POS abbrevend "$MATCH "
  396. # }
  397.  
  398. ######################################################################
  399. # look up and expand static abbrev before insert
  400. ######################################################################
  401.  
  402. proc jedit:cmd:sabbrev { t args } {
  403.   $t mark set abbrevend insert
  404.   # following don't really need to be global (shared with dabbrev):
  405.   global ABBREV ABBREV_POS ABBREVS
  406.  
  407.   $t mark set abbrevend insert
  408.   $t mark set abbrevstart insert
  409.   while {[$t compare abbrevstart != 1.0] &&
  410.          [string match {[a-zA-Z0-9_']} [$t get {abbrevstart - 1 char}]]} {
  411.     $t mark set abbrevstart {abbrevstart -1char}
  412.   }
  413.  
  414.   # avoid expanding things like \def, .PP, file.c, etc.:
  415.   set prefix [$t get {abbrevstart -2chars} {abbrevstart}]
  416.   if {[string length $prefix] > 0} {
  417.     if {[string match {?[@$%&+=\:~.]} $prefix]} {
  418.       return 0
  419.     }
  420.     # don't expand "l" in "ls -l", but do expand "this---l"
  421.     if {[string match "\[ \t\n\]-" $prefix]} {    ;# don't expand "ls -l"
  422.       return 0
  423.     }
  424.     # don't expand "s" in "house(s)", but do expand "so (s) of"
  425.     if {[string match "\[a-zA-Z](" $prefix]} {    ;# don't expand "house(s)"
  426.       return 0
  427.     }
  428.   }
  429.  
  430.   set ABBREV_POS [$t index abbrevstart]    ;# for dabbrev_again
  431.  
  432.   # first try regular version:
  433.   set ABBREV [$t get abbrevstart insert]
  434.   if {[info exists ABBREVS($ABBREV)]} {
  435.     j:text:replace $t $ABBREV_POS abbrevend $ABBREVS($ABBREV)
  436.     return 1
  437.   }
  438.   # else try capitalised version
  439.   if {[string match {[A-Z][a-z]*} $ABBREV]} {
  440.     set lcabbrev [jedit:uncapitalise $ABBREV]
  441.     if {[info exists ABBREVS($lcabbrev)]} {
  442.       j:text:replace $t $ABBREV_POS abbrevend \
  443.         [jedit:capitalise $ABBREVS($lcabbrev)]
  444.       return 1
  445.     }
  446.   }
  447.   return 0
  448. }
  449.  
  450. ######################################################################
  451. # edit your abbrevs file
  452. ######################################################################
  453.  
  454. proc jedit:cmd:edit_abbrevs { args } {
  455.   global HOME
  456.   if {! [file isdirectory "$HOME/.tk"]} then {
  457.     exec mkdir "$HOME/.tk"
  458.     # above should have error-checking
  459.   }
  460.   exec jabbrevs "$HOME/.tk/abbrevs.tcl" &    ;# doesn't currently use arg
  461. }
  462.  
  463. ######################################################################
  464. # read abbrevs file
  465. ######################################################################
  466.  
  467. proc jedit:cmd:read_abbrevs { args } {
  468.   j:source_config abbrevs.tcl
  469. }
  470.  
  471. ######################################################################
  472. # toggle static abbrevs
  473. ######################################################################
  474.  
  475. proc jedit:cmd:toggle_sabbrev { t args } {
  476.   global JEDIT_MODEPREFS
  477.   
  478.   set mode [jedit:get_mode $t]
  479.   
  480.   set JEDIT_MODEPREFS($mode,sabbrev) \
  481.     [expr {! $JEDIT_MODEPREFS($mode,sabbrev)}]
  482. }
  483.  
  484. ######################################################################
  485. # toggle dynamic abbrevs
  486. ######################################################################
  487.  
  488. proc jedit:cmd:toggle_dabbrev { t args } {
  489.   global JEDIT_MODEPREFS
  490.   
  491.   set mode [jedit:get_mode $t]
  492.   
  493.   set JEDIT_MODEPREFS($mode,dabbrev) \
  494.     [expr {! $JEDIT_MODEPREFS($mode,dabbrev)}]
  495. }
  496.  
  497. ######################################################################
  498. # go to a particular line
  499. ######## NEED TO CHECK THAT AN INDEX WAS TYPED!
  500. ######################################################################
  501.  
  502. proc jedit:cmd:go_to_line { t args } {
  503.   set prompt_result [j:prompt -text "Go to line number:"]
  504.   if {$prompt_result != {}} then {
  505.     jedit:go_to_line $t $prompt_result
  506.   }
  507. }
  508.  
  509. ######################################################################
  510. # display which line the cursor is on
  511. ######################################################################
  512.  
  513. proc jedit:cmd:current_line { t args } {
  514.   set insertindex [split [$t index insert] {.}]
  515.   set line [lindex $insertindex 0]
  516.   set column [lindex $insertindex 1]
  517.   j:alert -title "Notice" \
  518.     -text "The insertion point is at line $line, column $column."
  519. }
  520.  
  521. ######################################################################
  522. # insert X selection
  523. ######################################################################
  524.  
  525. proc jedit:cmd:xpaste { t args } {
  526.   set mode [jedit:get_mode $t]
  527.   
  528.   jedit:cmd:save_checkpoint $t            ;# save undo information
  529.   
  530.   if {[info procs mode:$mode:pre_xpaste_hook] != {}} {
  531.     mode:$mode:pre_xpaste_hook $t
  532.   }
  533.  
  534.   j:text:insert_string $t [j:selection_if_any]
  535.  
  536.   if {[info procs mode:$mode:post_xpaste_hook] != {}} {
  537.     mode:$mode:post_xpaste_hook $t
  538.   }
  539. }
  540.  
  541. ######################################################################
  542. # front end for j:find to match jedit:cmd argument convention
  543. ######################################################################
  544.  
  545. proc jedit:cmd:find { t args } {
  546.   jedit:cmd:save_checkpoint $t
  547.   j:find $t
  548. }
  549.  
  550. ######################################################################
  551. # find same string again (same kind of search)
  552. ######################################################################
  553.  
  554. proc jedit:cmd:find_again { t args } {
  555.   jedit:cmd:save_checkpoint $t
  556.   j:find:again $t
  557. }
  558.  
  559. ######################################################################
  560. # hacks for more-specific kinds of finds (for vi/emacs bindings)
  561. ### BOGUS!  jedit should not need to know about the internals of j:find!
  562. ######################################################################
  563.  
  564. proc jedit:cmd:find_forward { t args } {
  565.   global j_find
  566.   set j_find(backwards) 0
  567.   j:find $t
  568. }
  569.  
  570. proc jedit:cmd:find_backward { t args } {
  571.   global j_find
  572.   set j_find(backwards) 1
  573.   j:find $t
  574. }
  575.  
  576. ######################################################################
  577. # save all windows and quit
  578. ######################################################################
  579.  
  580. # we need to make sure there's a filename before calling save, because
  581. # a cancel in the saveas file selector box will cancel the save, but
  582. # not the quit!
  583.  
  584. proc jedit:cmd:done { t args } {
  585.   set mode [jedit:get_mode $t]
  586.   
  587.   if {[info procs mode:$mode:done] == {}} {
  588.     set filename [jedit:get_filename $t]
  589.     if {"x$filename" == "x"} then {
  590.       set filename [j:fs -prompt "Save as:"]
  591.       if {"x$filename" == "x"} {            ;# user clicked cancel
  592.         return
  593.       } else {
  594.         jedit:set_filename $t $filename
  595.       }
  596.     }
  597.  
  598.     jedit:cmd:save $t
  599.     jedit:cmd:close $t
  600.   } else {
  601.     mode:$mode:done $t
  602.   }
  603. }
  604.  
  605. ######################################################################
  606. # panel to let user insert any iso-8859 character
  607. ######################################################################
  608.  
  609. proc jedit:cmd:char_panel { t args } {
  610.   set tl [j:new_toplevel .high_bit]
  611.   wm title $tl "Characters"
  612.   
  613.   message $tl.m -aspect 350 \
  614.     -text "Click on a character to insert it."
  615.   text $tl.t -width 16 -height 12 -wrap none \
  616.     -cursor top_left_arrow \
  617.     -font -*-courier-bold-r-normal-*-*-140-* \
  618.     -borderwidth 2 -relief groove
  619.   
  620.   # using j:buttonbar for visual consistency:  
  621.   j:buttonbar $tl.b -buttons {
  622.     {ok Done {}}
  623.   }
  624.   $tl.b.ok configure -command "destroy $tl"
  625.   
  626.   for {set i 32} {$i < 112} {incr i 16} {
  627.     for {set j 0} {$j < 16} {incr j} {
  628.       $tl.t insert end [format %c [expr {$i + $j}]]
  629.     }
  630.     $tl.t insert end "\n"
  631.   }
  632.   for {set j 112} {$j < 127} {incr j} {
  633.     $tl.t insert end [format %c $j]
  634.   }
  635.   $tl.t insert end " \n "
  636.   for {set i 160} {$i < 256} {incr i 16} {
  637.     for {set j 0} {$j < 16} {incr j} {
  638.       $tl.t insert end [format %c [expr {$i + $j}]]
  639.     }
  640.     $tl.t insert end "\n"
  641.   }
  642.   $tl.t configure -state disabled
  643.   
  644.   pack $tl.m -fill x
  645.   pack $tl.t -padx 10
  646.   pack $tl.b -anchor e
  647.   
  648.   bind $tl.t <ButtonRelease-1> "
  649.     j:text:insert_string $t \[%W get @%x,%y\]
  650.   "
  651.   foreach event {
  652.     <ButtonRelease-3> <B3-Motion> <Button-3> <ButtonRelease-2>
  653.     <ButtonRelease-1><B2-Motion> <Button-2> <Shift-B1-Motion>
  654.     <Shift-Button-1> <B1-Motion> <Triple-Button-1> <Double-Button-1>
  655.     <Button-1>
  656.     } {
  657.     bind $tl.t $event {;}
  658.   }
  659. }
  660.  
  661. ######################################################################
  662. # insert a hyphen
  663. ######################################################################
  664.  
  665. proc jedit:cmd:hyphen { t args } {
  666.   j:text:insert_string $t "\xad"
  667. }
  668.  
  669. ######################################################################
  670. # insert a copyright symbol
  671. ######################################################################
  672.  
  673. proc jedit:cmd:copyright { t args } {
  674.   j:text:insert_string $t "\xa9"
  675. }
  676.  
  677. ######################################################################
  678. # rich-text cut
  679. ######################################################################
  680.  
  681. proc jedit:cmd:rich_cut { t } {
  682.   jedit:cmd:rich_copy $t            ;# (saves checkpoint)
  683.   $t delete sel.first sel.last
  684. }
  685.  
  686. ######################################################################
  687. # rich-text copy
  688. ######################################################################
  689.  
  690. proc jedit:cmd:rich_copy { t } {
  691.   global RICHBUFFER
  692.   
  693.   jedit:cmd:save_checkpoint $t            ;# save undo information
  694.   
  695.   set RICHBUFFER {}
  696.   set curstring {}
  697.   set curtags [$t tag names sel.first]
  698.   
  699.   $t mark set richptr sel.first
  700.   
  701.   while {[$t compare richptr < sel.last]} {
  702.     set tags [$t tag names richptr]
  703.     set char [$t get richptr]
  704.     if {"x$tags" != "x$curtags"} {    ;# new "range" of text
  705.       lappend RICHBUFFER [list $curstring $curtags]
  706.       set curstring $char
  707.       set curtags $tags
  708.     } else {
  709.       append curstring $char
  710.     }
  711.     $t mark set richptr {richptr+1c}
  712.   }
  713.   lappend RICHBUFFER [list $curstring $curtags]
  714.   return
  715. }
  716.  
  717. ######################################################################
  718. # rich-text paste
  719. #   partly lifted from insertWithTags in mkStyles.tcl demo
  720. ######################################################################
  721.  
  722. proc jedit:cmd:rich_paste { t } {
  723.   global RICHBUFFER
  724.   
  725.   jedit:cmd:save_checkpoint $t            ;# save undo information
  726.   
  727.   lappend RICHBUFFER {}            ;# make sure it's defined
  728.   
  729.   foreach pair $RICHBUFFER {
  730.     set text [lindex $pair 0]
  731.     set tags [lindex $pair 1]
  732.     
  733.     set start [$t index insert]
  734.     $t insert insert $text
  735.     foreach tag [$t tag names $start] {
  736.       $t tag remove $tag $start insert    ;# clear tags inherited from left
  737.     }
  738.     foreach tag $tags {    
  739.       $t tag add $tag $start insert    ;# add new tags
  740.     }
  741.   }
  742.   $t tag remove sel 1.0 end        ;# clear selection (guaranteed in text)
  743.   return
  744. }
  745.