home *** CD-ROM | disk | FTP | other *** search
/ TestDrive Super Store 3.0 / TESTDRIVE_3.ISO / realizer / utility / custom.rlz next >
Encoding:
Text File  |  1992-09-30  |  2.9 KB  |  95 lines

  1. '***********************************************************************
  2. '    Custom.rlz                      
  3. '
  4. '    Realizer.ini customization program
  5. '
  6. '    Copyright ⌐ 1991-1992 Computer Associates International, Inc.
  7. '    All rights reserved.
  8. '
  9. '***********************************************************************
  10.  
  11. LOCAL CustProfGetS, CustProfGetI, CustProfSet, startup, editfont, flags, font
  12. LOCAL MyProfGetS, MyProfSet
  13.  
  14. EXTERNAL "kernel" PROC CustProfSet(POINTER, POINTER, POINTER, POINTER) ALIAS "WritePrivateProfileString"                          
  15. EXTERNAL "kernel" FUNC CustProfGetS(POINTER, POINTER, POINTER, POINTER, INTEGER, POINTER) AS INTEGER ALIAS "GetPrivateProfileString"                    
  16. EXTERNAL "kernel" FUNC CustProfGetI(POINTER, POINTER, INTEGER, POINTER) AS WORD ALIAS "GetPrivateProfileInt"    
  17.  
  18. FUNC MyProfGetS(profstr)
  19.     LOCAL length, buf
  20.     buf = String$(255, " ")
  21.     length = CustProfGetS("Realizer", profstr, "?", buf, 255, "Realizer.ini")        
  22.     buf = Left$(buf, length)
  23.     RETURN buf
  24. END FUNC
  25.  
  26. PROC MyProfSet(profstr, valstr)
  27.     WHILE valstr <> "" AND Left$(valstr, 1) = " "
  28.         valstr = Mid$(valstr, 2)
  29.     END WHILE
  30.     IF valstr = "" THEN
  31.         CustProfSet("Realizer", profstr, "?", "Realizer.ini")
  32.     ELSE    
  33.         CustProfSet("Realizer", profstr, valstr, "Realizer.ini")  
  34.     END IF   
  35. END PROC   
  36.  
  37. FormNew(FormQUnique; "Set Realizer Initialization Values", _Title)
  38. FormControl(_Size; _Center, _Center, 60 pct, 40 pct)
  39. FormSetObject(10, _CaptionLeft, "Startup command:", 3 pct, 10 pct)
  40. FormSetObject(20, _TextBox, "", 37 pct, 8 pct, 60 pct, _Default)
  41. FormSetObject(30, _CaptionCenter, "Program Editor Font:", 3 pct, 40 pct)
  42. FormSetObject(40, _TextBox, "", 40 pct, 38 pct, 32 pct, _Default)
  43. FormSetObject(50, _Button, "New Font...", 75 pct, 38 pct, 22 pct, FormQObject(40)[_FQO_Height])
  44. FormSetObject(1, _DefButton, "OK", _Left, _Bottom)
  45. FormSetObject(2, _Button, "Cancel", _Right, _Bottom)
  46.  
  47. startup = MyProfGetS("Startup")
  48. IF startup <> "?" THEN          
  49.     FormModifyObject(20, _Normal, startup)              
  50. END IF
  51. editfont = MyProfGetS("EditFont")
  52. IF editfont <> "?" THEN
  53.     FormModifyObject(40, _Normal, editfont)
  54. END IF
  55.  
  56. LOOP  
  57.     SELECT CASE FormWait
  58.         CASE 1    'OK  
  59.             MyProfSet("Startup", FormQStr(20))        
  60.             MyProfSet("EditFont", FormQStr(40))
  61.             EXIT LOOP    
  62.         CASE 2    'Cancel  
  63.             EXIT LOOP
  64.         CASE 50    'Font button
  65.             font = StdFont
  66.             IF font[1] <> "" THEN
  67.                 editfont = font[1] + "-" + font[2]
  68.                 flags = StrToNum(font[3])
  69.                 IF flags THEN
  70.                 editfont = editfont + "/"
  71.                 IF flags mod 2 THEN
  72.                     editfont = editfont + "b"
  73.                 END IF
  74.                 flags = flags \ 2
  75.                 IF flags mod 2 THEN
  76.                     editfont = editfont + "i"
  77.                 END IF
  78.                 flags = flags \ 2
  79.                 IF flags mod 2 THEN
  80.                     editfont = editfont + "u"
  81.                 END IF
  82.                 flags = flags \ 2
  83.                 IF flags mod 2 THEN
  84.                     editfont = editfont + "s"
  85.                 END IF
  86.             END IF
  87.             FormModifyObject(40, _Normal, editfont)
  88.         END IF
  89.     END SELECT  
  90. END LOOP  
  91.  
  92. FormControl(_Close)
  93. EXIT PROGRAM
  94.  
  95.