PC Pro 1996 February/PCPRO_FEB96.ISO/3rdparty/tools/toolcrft/demo/popctrls.clw

Text File | 1995-10-23 | 4.7 KB | 135 lines

                MEMBER('DEMO.CLW')

PopupControls   PROCEDURE

Q1              QUEUE,PRE()
F1                STRING(20)
                END

Text1           STRING(500)


Screen WINDOW('Control Types Supported by Power Popup'),AT(,,291,228),FONT('MS Sans Serif',8,,FONT:bold), |
         CENTER,STATUS,SYSTEM,GRAY,DOUBLE,MDI
       BUTTON('Button 1'),AT(216,178,61,23),USE(?Button1)
       STRING('Right Click in here for'),AT(83,178,115,12),USE(?String1),CENTER
       STRING('Region Control 1 Covers the Whole Screen'),AT(0,209,292,12),FONT('MS Sans Serif',8,0FF0000H,FONT:bold), |
           USE(?String3),CENTER
       COMBO(@s20),AT(159,81,126,18),USE(?DropCombo),DROP(5),FROM(Q1)
       CUSTOM('Custom 1'),AT(193,106,90,58),USE(?Custom1),CLASS('GRAPH.VBX','Graph')
       STRING('Right Click on Blank Area of the Screen to Demonstrate'),AT(0,218,292,10),FONT('MS Sans Serif',8,0FF0000H,FONT:bold), |
           USE(?String4),CENTER
       LIST,AT(159,60,126,18),USE(?DropList),DROP(5),FROM(Q1)
       LIST,AT(14,5,116,57),USE(?List),FROM(Q1)
       COMBO(@s20),AT(15,68,114,49),USE(?Combo1),FROM(Q1)
       TEXT,AT(158,5,125,52),USE(Text1)
       GROUP('Group 1'),AT(10,122,54,41),USE(?Group1),BOXED
         CHECK('Check 1'),AT(17,135,,),USE(?Check1)
         CHECK('Check 2'),AT(17,148,,),USE(?Check2)
         REGION,AT(10,127,51,34),USE(?Region3)
       END
       ENTRY(@s20),AT(81,133,,),USE(?Entry1)
       SPIN(@s20),AT(81,151,,),USE(?Spin1)
       OPTION('Option 1'),AT(10,167,54,39),USE(?Option1),BOXED
         RADIO('Radio 1'),AT(16,181,,),USE(?Option1:Radio1)
         RADIO('Radio 2'),AT(16,191,,),USE(?Option1:Radio2)
       END
       STRING('Region Control 2'),AT(83,189,115,12),USE(?String2),CENTER
       REGION,AT(12,174,50,29),USE(?Region4)
       BOX,AT(81,170,120,36),USE(?Box1)
       REGION,AT(81,171,120,35),USE(?Region2),CURSOR(CURSOR:Cross)
       REGION,AT(-2,-2,295,230),USE(?Region1)
     END


 CODE


 LOOP Q# = 1 to 50
   F1 = 'Test#' & Q#
   ADD(Q1)
 END

 OPEN(Screen)

 Accept
   CASE EVENT()
   OF EVENT:OpenWindow
     CreatePopup(?List,'List &Insert|[Ins Sub1|Ins Sub2|[Ins Sub2-1|Ins Sub2-2|Ins Sub2-3]|Ins Sub3]|List &Change|List &Delete|[Del Sub1|Del Sub2|Del Sub3|-|DelSub4%CHK]|-|List &Other%CHK')
     SetPopupChecked(?List,16,TRUE)
     CreatePopup(?DropList,'DropList &Insert|DropList &Change|DropList &Delete|-|Re-Create this Menu')
     CreatePopup(?Combo1,'Combo &Insert|Combo &Delete')
     CreatePopup(?DropCombo,'DropCombo &Insert|DropCombo &Delete')
     CreatePopup(?Button1,'Button&1|Button&2|-|Buttom&3%chk|Button&4%chk')
     SetPopupChecked(?Button1,4,TRUE)
     CreatePopup(?Text1,'Text&1|Text&2|Text&3')
     CreatePopup(?Spin1,'Spin&1|Spin&2|Spin&3')
     CreatePopup(?Entry1,'Entry&1|Entry&2|Entry&3')
     CreatePopup(?Region3,'Check&1|Check&2|Check&3')
     AliasPopup(?Region3,?Check1)
     AliasPopup(?Region3,?Check2)
     CreatePopup(?Region4,'Radio&1|Radio&2|Radio&3')
     AliasPopup(?Region4,?Option1:Radio1)
     AliasPopup(?Region4,?Option1:Radio2)
     CreatePopup(?Custom1,'Custom&1|Custom&2|Custom&3')
     CreatePopup(?Region1,'Region1 &Insert|Region1 &Change|Region1 &Delete|-|Region1 &Sub Menu|[Reg Sub&1|Reg Sub&2|Reg Sub&3]')
     DisablePopup(?Region1,2,3)
     DisablePopup(?Region1,7)
     CreatePopup(?Region2,'Region2 &Insert|Region2 &Change|Region2 &Delete')
     SetPopupText(?Spin1,2,'Spin Text Was &Changed at Runtime - Try Selecting this Option')

   OF EVENT:CloseWIndow
     FreePopups
   END

   CASE FIELD()
   OF ?Spin1
     CASE EVENT()
     OF POPUP:EVENT:Accepted
       IF POPUP:Choice = 2
         IF NOT Changed#
           Changed# = 1
           SetPopupText(?Spin1,2,'Spin&2')
         ELSE
           Changed# = 0
           SetPopupText(?Spin1,2,'Spin Text Was &Changed at Runtime - Try Selecting this Option')
         END
       END
     END

   OF ?DropList
     CASE EVENT()
     OF POPUP:EVENT:Accepted
       EXECUTE POPUP:Choice
         Ret# = MESSAGE('DropList Insert')
         Ret# = MESSAGE('DropList Change')
         Ret# = MESSAGE('DropList Delete')
         NOP# = 0
         CreatePopup(?DropList,'New DropList &Insert|New DropList &Change|New DropList &Delete')
       END
     END

   OF ?Region1
     CASE EVENT()
     OF POPUP:EVENT:Accepted
       EXECUTE POPUP:Choice
         Ret# = MESSAGE('Region1 Insert')
         Ret# = MESSAGE('Region1 Change')
         UnhidePopup(?Region1,2)
       END
     END

   OF ?Region3
     CASE EVENT()
     OF POPUP:EVENT:Accepted
       EXECUTE POPUP:Choice
         Ret# = MESSAGE('Check Option 1')
         Ret# = MESSAGE('Check Option 2')
         Ret# = MESSAGE('Check Option 3')
       END
     END
   END
 END
 CLOSE(Screen)