PC Pro 1999 July/DPPCPRO0799.ISO/Ents/Files/startUp.dxr/00002_masterScript.ls

Text File | 1999-04-21 | 4.4 KB | 170 lines

property myMovieName, currentMovieName, currentVideo, currentReturnMovieName, thePlatform, thePath, PD, HDPath
global gSoundObj

on new me, whichPlatform, whichPD, whichPath
  set thePlatform to whichPlatform
  set PD to whichPD
  set thePath to whichPath
  set HDPath to getHDPath(me)
  return me
end

on getHDPath me
  set the itemDelimiter to PD
  set myHDPath to item 1 of getOSDirectory() & PD
  set the itemDelimiter to ","
  return myHDPath
end

on openNetPage me, whichURL
  set myBrowser to browserName()
  if not browserExists(me, myBrowser) then
    set myMessage to "Your default internet browser is not located in the place specified in your system directory, would you like to locate your browser?"
    if userComplies(me, "Find Browser", myMessage) then
      set myFileIO to new(xtra("FileIO"))
      setFilterMask(myFileIO, "Executable (*.exe), *.exe")
      set myBrowser to displayOpen(myFileIO)
      if myBrowser <> EMPTY then
        browserName(myBrowser)
        browserName(#enabled, 1)
        gotoNetPage(whichURL)
      end if
    end if
  else
    browserName(#enabled, 1)
    gotoNetPage(whichURL)
  end if
end

on browserExists me, myBrowser
  if thePlatform = #win then
    set total to the length of myBrowser
    if chars(myBrowser, total - 3, total) = ".EXE" then
      return 1
    end if
  else
    if thePlatform = #mac then
      if myBrowser <> EMPTY then
        return 1
      end if
    end if
  end if
  return 0
end

on userComplies me, myTitle, myMessage
  set myMuiObj to new(xtra("Mui"))
  set alertInitList to [#buttons: #OkCancel, #title: myTitle, #message: myMessage, #icon: #caution, #movable: 1]
  set buttonResult to alert(myMuiObj, alertInitList)
  if buttonResult = 1 then
    return 1
  else
    return 0
  end if
end

on CopyFile me, whichFile, hasVersion
  if hasVersion then
    set whichFile to formatFileName(me, whichFile)
  end if
  set myMessage to "This will copy the file" && QUOTE & whichFile & QUOTE && "to the root of your HardDrive. Click OK to continue..."
  alert(string(myMessage))
  register(xtra("ProgressCopy"), "yswii8fsygx2")
  set myProgress to new(xtra("ProgressCopy"), 1, 0, 0)
  set mySrc to thePath & "Download" & PD & whichFile
  set myDest to HDPath & whichFile
  if CopyFile(myProgress, mySrc, myDest, 0, 1, 1) <> 0 then
    case error(myProgress) of
      3:
        alert(string(QUOTE & whichFile & QUOTE && "has already been copied..."))
      34:
        alert(string(QUOTE & whichFile & QUOTE && "will not be copied..."))
      5:
        alert(string(QUOTE & whichFile & QUOTE && "can't be found..."))
      13, 15:
        alert(string("Not enough free space to copy" && QUOTE & whichFile & QUOTE & "..."))
      otherwise:
        alert(string("Error copying" && QUOTE & whichFile & QUOTE & "..."))
    end case
  end if
  set myProgress to VOID
end

on formatFileName me, whichFile
  if thePlatform = #mac then
    set myName to chars(whichFile, 1, the length of whichFile - 4)
    set myExt to chars(whichFile, the length of whichFile - 3, the length of whichFile)
    return myName & "mac" & myExt
  end if
  return whichFile
end

on autoUnloadMovie me
  if not voidp(myMovieName) then
    unloadMovie(myMovieName)
  end if
  set myMovieName to the movieName
end

on autoLoad me, start, stop
  cursor(4)
  preloadMember(member start, stop)
  cursor(-1)
end

on autoPuppet me, start, stop
  cursor(-1)
  repeat with i = start to stop
    puppetSprite(i, 1)
  end repeat
end

on autoNotPuppet me, start, stop
  repeat with i = start to stop
    puppetSprite(i, 0)
  end repeat
end

on playSound me, whichChannel, whichSound
  puppetSound(whichChannel, 0)
  puppetSound(whichChannel, member whichSound)
end

on playVideo me, whichVid, whichReturn
  set currentVideo to whichVid
  if not voidp(whichReturn) then
    set currentReturnMovieName to whichReturn
  else
    set currentReturnMovieName to the movieName
  end if
  autoGoMovie(me, "Movie5", 1, 1)
end

on autoGoMovie me, whichMovie, blankMeFirst, fadeSoundOut
  cursor(4)
  set currentMovieName to whichMovie
  if fadeSoundOut then
    playSoundTrack(gSoundObj, 0, 1, 255)
  end if
  if (the colorDepth < 16) and blankMeFirst then
    autoNotPuppet(me, 1, 48)
    go("exitBlank")
  else
    autoNotPuppet(me, 1, 41)
    go(1, whichMovie)
  end if
end

on autoCustomwait me, seconds
  set time to seconds * 60
  set timerStart to the timer
  repeat while (the timer - timerStart) < time
    cursor(4)
  end repeat
  cursor(-1)
end

on getMovieName me
  return currentMovieName
end