PC Pro 1999 July/DPPCPRO0799.ISO/Ents/Files/model.dxr/00056_textScrollScript.ls

Text File | 1999-04-21 | 1.7 KB | 57 lines

property textSprite, myScrollDelay, minSafeArea, maxSafeArea, topLimit, bottomLimit, activeLeft, activeRight

on new me
  return me
end

on init me, whichTextSprite, scrollDelay, safeArea, tLimit, bLimit
  set textSprite to whichTextSprite
  set myScrollDelay to scrollDelay
  set myOffset to safeArea / 2.0
  set minSafeArea to 241 - myOffset
  set maxSafeArea to 240 + myOffset
  set topLimit to tLimit
  set bottomLimit to bLimit
  set activeLeft to the left of sprite textSprite
  set activeRight to the right of sprite textSprite
  append(the actorList, me)
end

on stepFrame me
  if the mouseV < 401 then
    if (the mouseH > activeLeft) and (the mouseH < activeRight) then
      if the mouseV > maxSafeArea then
        set myDirection to (the mouseV - (maxSafeArea - 10)) / myScrollDelay
        scrollUp(me, myDirection)
      else
        if the mouseV < minSafeArea then
          set myDirection to (the mouseV - (minSafeArea + 10)) / myScrollDelay
          scrollDown(me, myDirection)
        end if
      end if
    end if
  end if
end

on scrollUp me, myDirection
  set newPos to the locV of sprite textSprite - myDirection
  if newPos < topLimit then
    set the cursor of sprite textSprite to [7, 8]
    set the locV of sprite textSprite to topLimit
  else
    set the cursor of sprite textSprite to [3, 4]
    set the locV of sprite textSprite to newPos
  end if
end

on scrollDown me, myDirection
  set newPos to the locV of sprite textSprite - myDirection
  if newPos > bottomLimit then
    set the cursor of sprite textSprite to [5, 6]
    set the locV of sprite textSprite to bottomLimit
  else
    set the cursor of sprite textSprite to [1, 2]
    set the locV of sprite textSprite to newPos
  end if
end