PC Pro 1999 January/dppcpro0199a.iso/January/Fp98/SDK/Wizards/Vb/Botgen.bas

BASIC Source File | 1997-09-18 | 10.8 KB | 449 lines

Attribute VB_Name = "BOTGEN"
' -------------------------------------------------------------------
' File: BOTGEN.BAS
' Copyright (c) 1995 Vermeer Technologies, Inc.  All rights reserved.
' -------------------------------------------------------------------

Option Explicit

' definitions for Vermeer Bots
Const VBOTL_OPEN = "<!--VERMEER BOT="
Const VBOTL_INDENT = "    "
Const VBOTL_CLOSE = "-->"

Const DATEBOT_EDIT = "EDITED"
Const DATEBOT_REGEN = "REGENERATED"

Sub BotAddParameter(s As String, bvar As String, bval As String)

    Dim nl As String
    Dim q As String

    nl = Chr$(13) & Chr$(10)
    q = Chr$(34) ' double quote

    s = s & VBOTL_INDENT & bvar & "=" & q & bval & q & nl

End Sub

Function BotCheckImageVal(ImgFile As String) As Integer

    ' tell us if ImgFile could reasonably be expected
    ' to hold the name of an image file (GIF or JPEG)

    Dim tmp As String
    Dim dloc As Integer
    Dim slen As Integer

    If ImgFile = "" Then
        BotCheckImageVal = False
        Exit Function
    End If

    tmp = LCase$(ImgFile)
    slen = Len(tmp)

    If InStr(tmp, ".gif") = (slen - 3) Then
        BotCheckImageVal = True
        Exit Function
    End If
    If InStr(tmp, ".GIF") = (slen - 3) Then
        BotCheckImageVal = True
        Exit Function
    End If

    If InStr(tmp, ".jpg") = (slen - 3) Then
        BotCheckImageVal = True
        Exit Function
    End If
    If InStr(tmp, ".JPG") = (slen - 3) Then
        BotCheckImageVal = True
        Exit Function
    End If

    If InStr(tmp, ".jpe") = (slen - 3) Then
        BotCheckImageVal = True
        Exit Function
    End If
    If InStr(tmp, ".JPE") = (slen - 3) Then
        BotCheckImageVal = True
        Exit Function
    End If

    If InStr(tmp, ".jpeg") = (slen - 4) Then
        BotCheckImageVal = True
        Exit Function
    End If
    If InStr(tmp, ".JPEG") = (slen - 4) Then
        BotCheckImageVal = True
        Exit Function
    End If

    BotCheckImageVal = False

End Function

Function BotCheckIncludeVal(IncFile As String) As Integer

    ' tell us if IncFile could reasonably be expected
    ' to hold the name of an include file (.htm or .html)

    Dim tmp As String
    Dim dloc As Integer
    Dim slen As Integer

    If IncFile = "" Then
        BotCheckIncludeVal = False
        Exit Function
    End If

    tmp = LCase$(IncFile)
    slen = Len(tmp)

    If InStr(tmp, ".htm") = (slen - 3) Then
        BotCheckIncludeVal = True
        Exit Function
    End If
    If InStr(tmp, ".HTM") = (slen - 3) Then
        BotCheckIncludeVal = True
        Exit Function
    End If

    If InStr(tmp, ".html") = (slen - 4) Then
        BotCheckIncludeVal = True
        Exit Function
    End If
    If InStr(tmp, ".HTML") = (slen - 4) Then
        BotCheckIncludeVal = True
        Exit Function
    End If

    BotCheckIncludeVal = False

End Function

Sub BotClose(s As String)

    s = s & VBOTL_CLOSE  ' no terminating newline

End Sub

Function BotMakeBoolVal(truth As Integer) As String

    If truth Then
        BotMakeBoolVal = "True"
    Else
        BotMakeBoolVal = "False"
    End If

End Function

Function BotMakeDateVal(reqdate As Variant) As String

    ' NOTE: create the date parameter using
    ' DateSerial and TimeSerial functions, or
    ' DateValue and TimeValue functions,
    ' and then add them together:
    '
    ' reqdate = DateSerial(10,17,88) + TimeSerial(9,35,0)
    ' reqdate = DateValue("10/17/88") + TimeValue("09:35:00")
    '

    Dim dstr As String
    Dim tstr As String

    If VarType(reqdate) <> 7 Then
        ' ERROR
        MsgBox "ERROR: BotMakeDateVal given non-date parameter."
        BotMakeDateVal = ""
        Exit Function
    End If

    ' TODO: deal with time zone conversion
    BotMakeDateVal = Format$(reqdate, "dd mmm yyyy hh:mm:ss")

End Function

Function BotMakeIntVal(i As Integer)

    BotMakeIntVal = CStr(i)

End Function

Function BotMakeStrVal(s As String) As String

    BotMakeStrVal = HTMLString(s)

End Function

Sub BotOpen(s As String, botname As String)

    Dim nl As String

    nl = Chr$(13) & Chr$(10)

    s = VBOTL_OPEN & botname & nl

End Sub

Sub BotReOpen(s As String)

    Dim slen As Integer

    slen = Len(VBOTL_CLOSE)

    If Right$(s, slen) = VBOTL_CLOSE Then
        s = Left$(s, Len(s) - slen)
    End If

End Sub

Sub CreateDateBot(s As String, dtype As String, sformat As String)

    ' create Bot inside passed string

    ' use DATEBOT_EDIT or DATEBOT_REGEN constants for dtype param

    Dim tmp As String

    Select Case dtype
        Case DATEBOT_EDIT
            ' ok
        Case DATEBOT_REGEN
            'ok
        Case Else
            ' error
            MsgBox "ERROR: CreateDateBot given bad date type parameter."
            Exit Sub
    End Select

    BotOpen s, "TimeStamp"  ' XXX - new name

    tmp = BotMakeStrVal(dtype)
    BotAddParameter s, "S-TYPE", tmp

    If sformat <> "" Then
        tmp = BotMakeStrVal(sformat)
        BotAddParameter s, "S-FORMAT", tmp
    End If

    BotClose s

End Sub

Sub CreateIncludeBot(s As String, IncFile As String)

    ' create Bot inside passed string

    Dim tmp As String

    If IncFile = "" Then
        MsgBox "ERROR: CreateIncludeBot given empty include file."
        Exit Sub
    End If

    If Not BotCheckIncludeVal(IncFile) Then
        MsgBox "ERROR: CreateIncludeBot given bad HTML file name."
        Exit Sub
    End If

    BotOpen s, "Include"

    tmp = BotMakeStrVal(IncFile)
    BotAddParameter s, "U-INCLUDE", IncFile

    BotClose s

End Sub

Sub CreateMacroBot(s As String, varname As String)

    ' create Bot inside passed string

    Dim tmp As String

    If varname = "" Then
        MsgBox "ERROR: CreateMacroBot given empty name."
        Exit Sub
    End If

    BotOpen s, "Substitution"  ' xxx - new name

    tmp = BotMakeStrVal(varname)
    BotAddParameter s, "S-VARIABLE", varname

    BotClose s

End Sub

Sub CreatePlaceholderBot(s As String, AuthorText As String, UserText As String)

    ' create Bot inside passed string

    Dim tmp As String

    If AuthorText = "" Then
        MsgBox "ERROR: CreatePlaceholderBot given empty AuthorText parameter."
        Exit Sub
    End If

    BotOpen s, "PurpleText"

    tmp = BotMakeStrVal(AuthorText)
    BotAddParameter s, "PREVIEW", tmp

    If UserText <> "" Then
        tmp = BotMakeStrVal(UserText)
        BotAddParameter s, "S-VIEWABLE", tmp
    End If

    BotClose s

End Sub

Sub CreateSearchBot(s As String, indexname As String, textsource As String)

    ' create Bot inside passed string

    Dim tmp As String

    BotOpen s, "Search"     ' xxx - new name

    If indexname <> "" Then
        tmp = BotMakeStrVal(indexname)
        BotAddParameter s, "S-INDEX", tmp
    Else
        BotAddParameter s, "S-INDEX", "All"
    End If

    If textsource <> "" Then
        tmp = BotMakeStrVal(textsource)
        BotAddParameter s, "S-DSN", tmp
    End If

    BotClose s

End Sub

Sub CreateTimedImageBot(s As String, ImgFile As String, ElseImgFile As String, AltText As String, ElseAltText As String, StartDate As Variant, EndDate As Variant)

    ' create Bot inside passed string

    ' NOTE: create the date parameters using
    ' DateSerial and TimeSerial functions, or
    ' DateValue and TimeValue functions,
    ' and then add them together:
    '
    ' reqdate = DateSerial(10,17,88) + TimeSerial(9,35,0)
    ' reqdate = DateValue("10/17/88") + TimeValue("09:35:00")
    '

    Dim tmp As String

    If Not BotCheckImageVal(ImgFile) Then
        MsgBox "ERROR: CreateTimedImageBot given bad image file."
        Exit Sub
    End If
    If ElseImgFile <> "" Then
        If Not BotCheckImageVal(ElseImgFile) Then
            MsgBox "ERROR: CreateTimedImageBot given bad else-image file."
            Exit Sub
        End If
    End If
    If VarType(StartDate) <> 7 Or VarType(EndDate) <> 7 Then
        MsgBox "ERROR: CreateTimedImageBot given non-date parameter(s)."
        Exit Sub
    End If
    If DateDiff("s", StartDate, EndDate) < 0 Then
        MsgBox "ERROR: CreateTimedImageBot given start date greater than end date."
        Exit Sub
    End If

    BotOpen s, "ScheduledImage"  ' xxx - new name

    tmp = BotMakeStrVal(ImgFile)
    BotAddParameter s, "U-SRC", tmp

    If ElseImgFile <> "" Then
        tmp = BotMakeStrVal(ElseImgFile)
        BotAddParameter s, "U-ELSE-SRC", tmp
    End If

    If AltText <> "" Then
        tmp = BotMakeStrVal(AltText)
        BotAddParameter s, "S-ALT", tmp
    End If

    If ElseAltText <> "" Then
        ' don't provide ElseAltText unless ElseImgFile has been provided
        If ElseImgFile <> "" Then
            tmp = BotMakeStrVal(ElseAltText)
            BotAddParameter s, "S-ELSE-ALT", tmp
        End If
    End If

    tmp = BotMakeDateVal(StartDate)
    BotAddParameter s, "D-START-DATE", tmp

    tmp = BotMakeDateVal(EndDate)
    BotAddParameter s, "D-END-DATE", tmp

    BotClose s

End Sub

Sub CreateTimedIncludeBot(s As String, IncFile As String, ElseIncFile As String, StartDate As Variant, EndDate As Variant)

    ' create Bot inside passed string

    ' NOTE: create the date parameters using
    ' DateSerial and TimeSerial functions, or
    ' DateValue and TimeValue functions,
    ' and then add them together:
    '
    ' reqdate = DateSerial(10,17,88) + TimeSerial(9,35,0)
    ' reqdate = DateValue("10/17/88") + TimeValue("09:35:00")
    '

    Dim tmp As String

    If Not BotCheckIncludeVal(IncFile) Then
        MsgBox "ERROR: CreateTimedIncludeBot given bad include file."
        Exit Sub
    End If
    If ElseIncFile <> "" Then
        If Not BotCheckIncludeVal(ElseIncFile) Then
            MsgBox "ERROR: CreateTimedIncludeBot given bad else-include file."
            Exit Sub
        End If
    End If
    If VarType(StartDate) <> 7 Or VarType(EndDate) <> 7 Then
        MsgBox "ERROR: CreateTimedIncludeBot given non-date parameter(s)."
        Exit Sub
    End If
    If DateDiff("s", StartDate, EndDate) < 0 Then
        MsgBox "ERROR: CreateTimedIncludeBot given start date greater than end date."
        Exit Sub
    End If

    BotOpen s, "ScheduledInclude"  ' xxx - new name

    tmp = BotMakeStrVal(IncFile)
    BotAddParameter s, "U-INCLUDE", tmp

    If ElseIncFile <> "" Then
        tmp = BotMakeStrVal(ElseIncFile)
        BotAddParameter s, "U-ELSE-INCLUDE", tmp
    End If

    tmp = BotMakeDateVal(StartDate)
    BotAddParameter s, "D-START-DATE", tmp

    tmp = BotMakeDateVal(EndDate)
    BotAddParameter s, "D-END-DATE", tmp

    BotClose s

End Sub