Aminet 18/aminetcdnumber181997.iso/Aminet/comm/thor/SortEvents.lha/SortEvents.thor

Text File | 1997-02-20 | 7KB | 254 lines

/* SortEvents © 1996-97 Roy E Brown

   $VER: SortEvents.thor 2.0 (20.2.97)

   SortEvents V2.0 can only be executed from within Thor.

   SortEvents V2.0 will sort all active Thor Events into the
   following order:

   Email
   Newsgroup
   Other (Join, Resign, Retract etc.)
   Upload
   Download

   The Event list is read and displayed to the user. If 'Sort Events' is
   selected then the Events are sorted and the new order is re-displayed.

   SortEvents will create 'ENV:THOR/SortEvents' when first used. This is
   used to indicate that Events have been sorted at least once during the
   current session.

   SortEvents works by writing new Events in the order given above. It will
   leave 'DEL' type Events in the Event lister when viewed from within Thor.
   Once all Events have been successfully dealt with, these will disappear.

*/

Options Results

Vers="SortEvents V2.0 ©1996-97 Roy E Brown"
lf='0a'x
SE=0

/* Is Thor active? */
If ~Show('P','THOR.01') Then
  Do
    Say "Thor needs to be available for this script"
    Exit
  End

/* Check for BBSREAD */
If ~Show('P','BBSREAD') Then
  Do
    Address command
    "run >nil: `GetEnv THOR/THORPath`bin/LoadBBSRead"
    "WaitForPort BBSREAD"
  End

/* Get the current System name */
Address THOR.01
CURRENTSYSTEM Current
SystemName=CURRENT.BBSNAME

/* Define Events waiting to be sent */
EDF_ACTIVE= '00000000'x   /* Event is active  */
EDF_ERROR = '00000008'x   /* Error with Event */

EVE_ENTERMSG    = 0       /* Enter message     */
EVE_REPLYMSG    = 1       /* Reply message     */
EVE_JOINCONF    = 2       /* Join conference   */
EVE_RESIGNCONF  = 3       /* Resign conference */
EVE_DOWNLOAD    = 4       /* Download File     */
EVE_UPLOAD      = 5       /* Upload File       */
EVE_CONFLIST    = 6       /* Get conflist      */
EVE_RETRACTMSG  = 13      /* Retract Message   */

Address BBSREAD

GETBBSDATA '"'SystemName'"' stem BBSDATA
If RC~=0 Then Call Error

If BBSDATA.NUMEVENTS=0 Then
  Do
    Address THOR.01
    REQUESTNOTIFY TEXT '"'vers'\n\n    There are no Events to sort!" BT "OOPS!"'
    Exit
  End

If BBSDATA.NUMEVENTS~>1 Then
  Do
    Address THOR.01
    REQUESTNOTIFY TEXT '"'vers'\n\n    How can I sort just 1 Event?" BT "OOPS!"'
    Exit
  End

/* Have we sorted Events once already? */
If Exists("Env:THOR/SortEvents") Then
  Do
    Address THOR.01
    'REQUESTNOTIFY TEXT "'vers'\n\nYou have already sorted Thor Events\n  once during the current session.\n  Do you wish to sort them again?\n" BT  "_Sort Again|_Cancel"'
    If result=0 Then Exit
  End

Call ReadEvents

Exit

/* Get the Event details and make a list */
ReadEvents:
OldList=''
Address BBSREAD
GETBBSDATA '"'SystemName'"' stem BBSDATA
If RC~=0 Then Call Error
  Do num=BBSDATA.FIRSTEVENT To BBSDATA.LASTEVENT
    Drop Eventtag. Eventdata.
    READBREVENT '"'SystemName'"' EVENTNR num TAGSSTEM eventtag DATASTEM eventdata
    If EVENTDATA.FLAGS=EDF_ACTIVE Then
    Do
      If EVENTTAG.LOCALFILE~="EVENTTAG.LOCALFILE" Then Suffix="File(s) Attached"
      Else Suffix=''
      If EVENTDATA.EVENTTYPE=EVE_JOINCONF Then
        Do
          OldList=OldList"Join Conference\n"
          Iterate num
        End
      If EVENTDATA.EVENTTYPE=EVE_RETRACTMSG Then
        Do
          OldList=OldList"Retract Message\n"
          Iterate num
        End
      If EVENTDATA.EVENTTYPE=EVE_UPLOAD Then
        Do
          OldList=OldList"Upload File\n"
          Iterate num
        End
      If EVENTDATA.EVENTTYPE=EVE_DOWNLOAD Then
        Do
          OldList=OldList"Download File\n"
          Iterate num
        End
      If EVENTDATA.EVENTTYPE=EVE_RESIGNCONF Then
        Do
          OldList=OldList"Resign Conference\n"
          Iterate num
        End
      If EVENTDATA.EVENTTYPE=EVE_CONFLIST Then
        Do
          OldList=OldList"Get Conference List\n"
          Iterate num
        End
      If EVENTTAG.CONFERENCE='EMail' Then
        Do
          OldList=OldList"EMail Event "Suffix"\n"
          Iterate num
        End
    Else
      Do
        OldList=OldList"Newsgroup Event "Suffix"\n"
        Iterate num
      End
  End
End

If SE=0 Then
  Do
    SortString="    This is the current order of\n         Active Thor Events:\n"
    Buttons="_Sort Events|_Cancel"
  End
Else
  Do
    SortString="    Events have been sorted into\n        the following order:\n"
    Buttons="_Thank You"
  End

  Address THOR.01
  'REQUESTNOTIFY TEXT "'vers'\n\n'SortString'\n'OldList'\n" BT "'Buttons'"'
  If result=0 Then Exit
  If result=1 Then Call Sort
Return

/* Sort Events */
Sort:
  Address BBSREAD
  Do num=BBSDATA.FIRSTEVENT To BBSDATA.LASTEVENT
    Drop Eventtag. Eventdata.
    READBREVENT '"'SystemName'"' EVENTNR num TAGSSTEM eventtag DATASTEM eventdata
    If RC~=0 Then Call Error
    If EVENTDATA.FLAGS=EDF_ACTIVE Then
      Do
        If EVENTDATA.EVENTTYPE=EVE_DOWNLOAD|EVENTDATA.EVENTTYPE=EVE_UPLOAD Then
        Iterate num
        If EVENTTAG.CONFERENCE="EMail" Then
            Iterate num
        If EVENTDATA.EVENTTYPE=EVE_ENTERMSG|EVENTDATA.EVENTTYPE=EVE_REPLYMSG Then
          Do
            WRITEBREVENT '"'SystemName'"' Event EVENTDATA.EVENTTYPE STEM eventtag
            If RC~=0 Then Call Error
            UPDATEBREVENT BBSNAME '"'SystemName'"' EVENTNR num SETDELETED
            If RC~=0 Then Call Error
            Iterate num
          End
        Else Iterate num
      End
  End
  Do num=BBSDATA.FIRSTEVENT To BBSDATA.LASTEVENT
    Drop Eventtag. Eventdata.
    READBREVENT '"'SystemName'"' EVENTNR num TAGSSTEM eventtag DATASTEM eventdata
    If EVENTDATA.FLAGS=EDF_ACTIVE Then
      Do
        If EVENTTAG.CONFERENCE="EMail" Then Iterate num
        If EVENTDATA.EVENTTYPE=EVE_ENTERMSG|EVENTDATA.EVENTTYPE=EVE_REPLYMSG Then iterate num
        If EVENTDATA.EVENTTYPE=EVE_DOWNLOAD|EVENTDATA.EVENTTYPE=EVE_UPLOAD Then Iterate num
          Do
            WRITEBREVENT '"'SystemName'"' Event EVENTDATA.EVENTTYPE STEM eventtag
            If RC~=0 Then Call Error
            UPDATEBREVENT BBSNAME '"'SystemName'"' EVENTNR num SETDELETED
            Iterate num
          End
      End
  End
  Do num=BBSDATA.FIRSTEVENT To BBSDATA.LASTEVENT
    Drop Eventtag. Eventdata.
    READBREVENT '"'SystemName'"' EVENTNR num TAGSSTEM eventtag DATASTEM eventdata
    If EVENTDATA.FLAGS=EDF_ACTIVE Then
      Do
        If EVENTDATA.EVENTTYPE=EVE_UPLOAD then
          Do
            WRITEBREVENT '"'SystemName'"' Event EVENTDATA.EVENTTYPE STEM eventtag
            If RC~=0 Then Call Error
            UPDATEBREVENT BBSNAME '"'SystemName'"' EVENTNR num SETDELETED
            If RC~=0 Then Call Error
          End
      End
  End
  Do num=BBSDATA.FIRSTEVENT To BBSDATA.LASTEVENT
    Drop Eventtag. Eventdata.
    READBREVENT '"'SystemName'"' EVENTNR num TAGSSTEM eventtag DATASTEM eventdata
    If EVENTDATA.FLAGS=EDF_ACTIVE Then
      Do
        If EVENTDATA.EVENTTYPE=EVE_DOWNLOAD then
          Do
            WRITEBREVENT '"'SystemName'"' Event EVENTDATA.EVENTTYPE STEM eventtag
            If RC~=0 Then Call Error
            UPDATEBREVENT BBSNAME '"'SystemName'"' EVENTNR num SETDELETED
            If RC~=0 Then Call Error
          End
      End
  End
  Address Command
  'SetEnv THOR/SortEvents 'vers''
  SE=1
  Call ReadEvents
Return

/* BBSREAD ERRORS */
Error:
Do
  Address THOR.01
  'REQUESTNOTIFY TEXT "'vers'\n\n'BBSREAD.LASTERROR'" BT "_Exit"'
  Exit
End
Return