home *** CD-ROM | disk | FTP | other *** search
/ PC Welt 2006 November (DVD) / PCWELT_11_2006.ISO / casper / filesystem.squashfs / usr / lib / perl / 5.8.8 / IO / Socket / INET.pm next >
Encoding:
Perl POD Document  |  2006-07-07  |  6.3 KB  |  279 lines
  1. # IO::Socket::INET.pm
  2. #
  3. # Copyright (c) 1997-8 Graham Barr <gbarr@pobox.com>. All rights reserved.
  4. # This program is free software; you can redistribute it and/or
  5. # modify it under the same terms as Perl itself.
  6.  
  7. package IO::Socket::INET;
  8.  
  9. use strict;
  10. our(@ISA, $VERSION);
  11. use IO::Socket;
  12. use Socket;
  13. use Carp;
  14. use Exporter;
  15. use Errno;
  16.  
  17. @ISA = qw(IO::Socket);
  18. $VERSION = "1.29";
  19.  
  20. my $EINVAL = exists(&Errno::EINVAL) ? Errno::EINVAL() : 1;
  21.  
  22. IO::Socket::INET->register_domain( AF_INET );
  23.  
  24. my %socket_type = ( tcp  => SOCK_STREAM,
  25.             udp  => SOCK_DGRAM,
  26.             icmp => SOCK_RAW
  27.           );
  28.  
  29. sub new {
  30.     my $class = shift;
  31.     unshift(@_, "PeerAddr") if @_ == 1;
  32.     return $class->SUPER::new(@_);
  33. }
  34.  
  35. sub _sock_info {
  36.   my($addr,$port,$proto) = @_;
  37.   my $origport = $port;
  38.   my @proto = ();
  39.   my @serv = ();
  40.  
  41.   $port = $1
  42.     if(defined $addr && $addr =~ s,:([\w\(\)/]+)$,,);
  43.  
  44.   if(defined $proto  && $proto =~ /\D/) {
  45.     if(@proto = getprotobyname($proto)) {
  46.       $proto = $proto[2] || undef;
  47.     }
  48.     else {
  49.       $@ = "Bad protocol '$proto'";
  50.       return;
  51.     }
  52.   }
  53.  
  54.   if(defined $port) {
  55.     my $defport = ($port =~ s,\((\d+)\)$,,) ? $1 : undef;
  56.     my $pnum = ($port =~ m,^(\d+)$,)[0];
  57.  
  58.     @serv = getservbyname($port, $proto[0] || "")
  59.     if ($port =~ m,\D,);
  60.  
  61.     $port = $serv[2] || $defport || $pnum;
  62.     unless (defined $port) {
  63.     $@ = "Bad service '$origport'";
  64.     return;
  65.     }
  66.  
  67.     $proto = (getprotobyname($serv[3]))[2] || undef
  68.     if @serv && !$proto;
  69.   }
  70.  
  71.  return ($addr || undef,
  72.      $port || undef,
  73.      $proto || undef
  74.     );
  75. }
  76.  
  77. sub _error {
  78.     my $sock = shift;
  79.     my $err = shift;
  80.     {
  81.       local($!);
  82.       my $title = ref($sock).": ";
  83.       $@ = join("", $_[0] =~ /^$title/ ? "" : $title, @_);
  84.       close($sock)
  85.     if(defined fileno($sock));
  86.     }
  87.     $! = $err;
  88.     return undef;
  89. }
  90.  
  91. sub _get_addr {
  92.     my($sock,$addr_str, $multi) = @_;
  93.     my @addr;
  94.     if ($multi && $addr_str !~ /^\d+(?:\.\d+){3}$/) {
  95.     (undef, undef, undef, undef, @addr) = gethostbyname($addr_str);
  96.     } else {
  97.     my $h = inet_aton($addr_str);
  98.     push(@addr, $h) if defined $h;
  99.     }
  100.     @addr;
  101. }
  102.  
  103. sub configure {
  104.     my($sock,$arg) = @_;
  105.     my($lport,$rport,$laddr,$raddr,$proto,$type);
  106.  
  107.     $arg->{LocalAddr} = $arg->{LocalHost}
  108.     if exists $arg->{LocalHost} && !exists $arg->{LocalAddr};
  109.  
  110.     ($laddr,$lport,$proto) = _sock_info($arg->{LocalAddr},
  111.                     $arg->{LocalPort},
  112.                     $arg->{Proto})
  113.             or return _error($sock, $!, $@);
  114.  
  115.     $laddr = defined $laddr ? inet_aton($laddr)
  116.                 : INADDR_ANY;
  117.  
  118.     return _error($sock, $EINVAL, "Bad hostname '",$arg->{LocalAddr},"'")
  119.     unless(defined $laddr);
  120.  
  121.     $arg->{PeerAddr} = $arg->{PeerHost}
  122.     if exists $arg->{PeerHost} && !exists $arg->{PeerAddr};
  123.  
  124.     unless(exists $arg->{Listen}) {
  125.     ($raddr,$rport,$proto) = _sock_info($arg->{PeerAddr},
  126.                         $arg->{PeerPort},
  127.                         $proto)
  128.             or return _error($sock, $!, $@);
  129.     }
  130.  
  131.     $proto ||= (getprotobyname('tcp'))[2];
  132.  
  133.     my $pname = (getprotobynumber($proto))[0];
  134.     $type = $arg->{Type} || $socket_type{lc $pname};
  135.  
  136.     my @raddr = ();
  137.  
  138.     if(defined $raddr) {
  139.     @raddr = $sock->_get_addr($raddr, $arg->{MultiHomed});
  140.     return _error($sock, $EINVAL, "Bad hostname '",$arg->{PeerAddr},"'")
  141.         unless @raddr;
  142.     }
  143.  
  144.     while(1) {
  145.  
  146.     $sock->socket(AF_INET, $type, $proto) or
  147.         return _error($sock, $!, "$!");
  148.  
  149.         if (defined $arg->{Blocking}) {
  150.         defined $sock->blocking($arg->{Blocking})
  151.         or return _error($sock, $!, "$!");
  152.     }
  153.  
  154.     if ($arg->{Reuse} || $arg->{ReuseAddr}) {
  155.         $sock->sockopt(SO_REUSEADDR,1) or
  156.             return _error($sock, $!, "$!");
  157.     }
  158.  
  159.     if ($arg->{ReusePort}) {
  160.         $sock->sockopt(SO_REUSEPORT,1) or
  161.             return _error($sock, $!, "$!");
  162.     }
  163.  
  164.     if ($arg->{Broadcast}) {
  165.         $sock->sockopt(SO_BROADCAST,1) or
  166.             return _error($sock, $!, "$!");
  167.     }
  168.  
  169.     if($lport || ($laddr ne INADDR_ANY) || exists $arg->{Listen}) {
  170.         $sock->bind($lport || 0, $laddr) or
  171.             return _error($sock, $!, "$!");
  172.     }
  173.  
  174.     if(exists $arg->{Listen}) {
  175.         $sock->listen($arg->{Listen} || 5) or
  176.         return _error($sock, $!, "$!");
  177.         last;
  178.     }
  179.  
  180.      # don't try to connect unless we're given a PeerAddr
  181.      last unless exists($arg->{PeerAddr});
  182.  
  183.         $raddr = shift @raddr;
  184.  
  185.     return _error($sock, $EINVAL, 'Cannot determine remote port')
  186.         unless($rport || $type == SOCK_DGRAM || $type == SOCK_RAW);
  187.  
  188.     last
  189.         unless($type == SOCK_STREAM || defined $raddr);
  190.  
  191.     return _error($sock, $EINVAL, "Bad hostname '",$arg->{PeerAddr},"'")
  192.         unless defined $raddr;
  193.  
  194. #        my $timeout = ${*$sock}{'io_socket_timeout'};
  195. #        my $before = time() if $timeout;
  196.  
  197.     undef $@;
  198.         if ($sock->connect(pack_sockaddr_in($rport, $raddr))) {
  199. #            ${*$sock}{'io_socket_timeout'} = $timeout;
  200.             return $sock;
  201.         }
  202.  
  203.     return _error($sock, $!, $@ || "Timeout")
  204.         unless @raddr;
  205.  
  206. #    if ($timeout) {
  207. #        my $new_timeout = $timeout - (time() - $before);
  208. #        return _error($sock,
  209. #                         (exists(&Errno::ETIMEDOUT) ? Errno::ETIMEDOUT() : $EINVAL),
  210. #                         "Timeout") if $new_timeout <= 0;
  211. #        ${*$sock}{'io_socket_timeout'} = $new_timeout;
  212. #        }
  213.  
  214.     }
  215.  
  216.     $sock;
  217. }
  218.  
  219. sub connect {
  220.     @_ == 2 || @_ == 3 or
  221.        croak 'usage: $sock->connect(NAME) or $sock->connect(PORT, ADDR)';
  222.     my $sock = shift;
  223.     return $sock->SUPER::connect(@_ == 1 ? shift : pack_sockaddr_in(@_));
  224. }
  225.  
  226. sub bind {
  227.     @_ == 2 || @_ == 3 or
  228.        croak 'usage: $sock->bind(NAME) or $sock->bind(PORT, ADDR)';
  229.     my $sock = shift;
  230.     return $sock->SUPER::bind(@_ == 1 ? shift : pack_sockaddr_in(@_))
  231. }
  232.  
  233. sub sockaddr {
  234.     @_ == 1 or croak 'usage: $sock->sockaddr()';
  235.     my($sock) = @_;
  236.     my $name = $sock->sockname;
  237.     $name ? (sockaddr_in($name))[1] : undef;
  238. }
  239.  
  240. sub sockport {
  241.     @_ == 1 or croak 'usage: $sock->sockport()';
  242.     my($sock) = @_;
  243.     my $name = $sock->sockname;
  244.     $name ? (sockaddr_in($name))[0] : undef;
  245. }
  246.  
  247. sub sockhost {
  248.     @_ == 1 or croak 'usage: $sock->sockhost()';
  249.     my($sock) = @_;
  250.     my $addr = $sock->sockaddr;
  251.     $addr ? inet_ntoa($addr) : undef;
  252. }
  253.  
  254. sub peeraddr {
  255.     @_ == 1 or croak 'usage: $sock->peeraddr()';
  256.     my($sock) = @_;
  257.     my $name = $sock->peername;
  258.     $name ? (sockaddr_in($name))[1] : undef;
  259. }
  260.  
  261. sub peerport {
  262.     @_ == 1 or croak 'usage: $sock->peerport()';
  263.     my($sock) = @_;
  264.     my $name = $sock->peername;
  265.     $name ? (sockaddr_in($name))[0] : undef;
  266. }
  267.  
  268. sub peerhost {
  269.     @_ == 1 or croak 'usage: $sock->peerhost()';
  270.     my($sock) = @_;
  271.     my $addr = $sock->peeraddr;
  272.     $addr ? inet_ntoa($addr) : undef;
  273. }
  274.  
  275. 1;
  276.  
  277. __END__
  278.  
  279.