home *** CD-ROM | disk | FTP | other *** search
/ PC Welt 2005 March / PCWELT_3_2005.ISO / pcwsoft / framework-2.2.exe / scrolledlistbox.itk < prev    next >
Encoding:
Text File  |  2003-09-01  |  25.9 KB  |  733 lines
  1. #
  2. # Scrolledlistbox
  3. # ----------------------------------------------------------------------
  4. # Implements a scrolled listbox with additional options to manage
  5. # horizontal and vertical scrollbars.  This includes options to control
  6. # which scrollbars are displayed and the method, i.e. statically,
  7. # dynamically, or none at all.  
  8. #
  9. # ----------------------------------------------------------------------
  10. #  AUTHOR: Mark L. Ulferts             EMAIL: mulferts@austin.dsccc.com
  11. #
  12. #  @(#) $Id: scrolledlistbox.itk,v 1.9 2002/03/16 16:25:44 mgbacke Exp $
  13. # ----------------------------------------------------------------------
  14. #            Copyright (c) 1995 DSC Technologies Corporation
  15. # ======================================================================
  16. # Permission to use, copy, modify, distribute and license this software 
  17. # and its documentation for any purpose, and without fee or written 
  18. # agreement with DSC, is hereby granted, provided that the above copyright 
  19. # notice appears in all copies and that both the copyright notice and 
  20. # warranty disclaimer below appear in supporting documentation, and that 
  21. # the names of DSC Technologies Corporation or DSC Communications 
  22. # Corporation not be used in advertising or publicity pertaining to the 
  23. # software without specific, written prior permission.
  24. # 
  25. # DSC DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING 
  26. # ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, AND NON-
  27. # INFRINGEMENT. THIS SOFTWARE IS PROVIDED ON AN "AS IS" BASIS, AND THE
  28. # AUTHORS AND DISTRIBUTORS HAVE NO OBLIGATION TO PROVIDE MAINTENANCE, 
  29. # SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS. IN NO EVENT SHALL 
  30. # DSC BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR 
  31. # ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
  32. # WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTUOUS ACTION,
  33. # ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS 
  34. # SOFTWARE.
  35. # ======================================================================
  36.  
  37. #
  38. # Usual options.
  39. #
  40. itk::usual Scrolledlistbox {
  41.     keep -activebackground -activerelief -background -borderwidth -cursor \
  42.      -elementborderwidth -foreground -highlightcolor -highlightthickness \
  43.      -jump -labelfont -selectbackground -selectborderwidth \
  44.      -selectforeground -textbackground -textfont -troughcolor 
  45. }
  46.  
  47. # ------------------------------------------------------------------
  48. #                          SCROLLEDLISTBOX
  49. # ------------------------------------------------------------------
  50. itcl::class iwidgets::Scrolledlistbox {
  51.     inherit iwidgets::Scrolledwidget
  52.  
  53.     constructor {args} {}
  54.     destructor {}
  55.  
  56.     itk_option define -dblclickcommand dblClickCommand Command {}
  57.     itk_option define -selectioncommand selectionCommand Command {}
  58.     itk_option define -width width Width 0
  59.     itk_option define -height height Height 0
  60.     itk_option define -visibleitems visibleItems VisibleItems 20x10
  61.     itk_option define -state state State normal
  62.  
  63.     public method curselection {} 
  64.     public method activate {index} 
  65.     public method bbox {index} 
  66.     public method clear {} 
  67.     public method see {index} 
  68.     public method index {index} 
  69.     public method delete {first {last {}}} 
  70.     public method get {first {last {}}} 
  71.     public method getcurselection {} 
  72.     public method insert {index args} 
  73.     public method nearest {y} 
  74.     public method scan {option args} 
  75.     public method selection {option first {last {}}} 
  76.     public method size {} 
  77.     public method selecteditemcount {} 
  78.     public method justify {direction} 
  79.     public method sort {{mode ascending}} 
  80.     public method xview {args} 
  81.     public method yview {args} 
  82.     public method itemconfigure {args}
  83.  
  84.     protected method _makeSelection {} 
  85.     protected method _dblclick {} 
  86.     protected method _fixIndex {index}
  87.  
  88.     #
  89.     # List the event sequences that invoke single and double selection.
  90.     # Should these change in the underlying Tk listbox, then they must
  91.     # change here too.
  92.     #
  93.     common doubleSelectSeq { \
  94.     <Double-1> 
  95.     }
  96.  
  97.     common singleSelectSeq { \
  98.         <Control-Key-backslash> \
  99.     <Control-Key-slash> \
  100.     <Key-Escape> \
  101.     <Shift-Key-Select> \
  102.     <Control-Shift-Key-space> \
  103.     <Key-Select> \
  104.     <Key-space> \
  105.     <Control-Shift-Key-End> \
  106.     <Control-Key-End> \
  107.     <Control-Shift-Key-Home> \
  108.     <Control-Key-Home> \
  109.     <Key-Down> \
  110.     <Key-Up> \
  111.     <Shift-Key-Down> \
  112.     <Shift-Key-Up> \
  113.     <Control-Button-1> \
  114.     <Shift-Button-1> \
  115.     <ButtonRelease-1> \
  116.     }
  117. }
  118.  
  119. #
  120. # Provide a lowercased access method for the Scrolledlistbox class.
  121. # 
  122. proc ::iwidgets::scrolledlistbox {pathName args} {
  123.     uplevel ::iwidgets::Scrolledlistbox $pathName $args
  124. }
  125.  
  126. #
  127. # Use option database to override default resources of base classes.
  128. #
  129. option add *Scrolledlistbox.labelPos n widgetDefault
  130.  
  131. # ------------------------------------------------------------------
  132. #                        CONSTRUCTOR
  133. # ------------------------------------------------------------------
  134. itcl::body iwidgets::Scrolledlistbox::constructor {args} {
  135.     #
  136.     # Our -width and -height options are slightly different than
  137.     # those implemented by our base class, so we're going to
  138.     # remove them and redefine our own.
  139.     #
  140.     itk_option remove iwidgets::Scrolledwidget::width
  141.     itk_option remove iwidgets::Scrolledwidget::height
  142.  
  143.     # 
  144.     # Create the listbox.
  145.     #
  146.     itk_component add listbox {
  147.     listbox $itk_interior.listbox \
  148.         -width 1 -height 1 \
  149.             -xscrollcommand \
  150.         [itcl::code $this _scrollWidget $itk_interior.horizsb] \
  151.         -yscrollcommand \
  152.         [itcl::code $this _scrollWidget $itk_interior.vertsb]
  153.     } {
  154.     usual
  155.  
  156.     keep -borderwidth -exportselection -relief -selectmode
  157.     keep -listvariable
  158.     
  159.     rename -font -textfont textFont Font
  160.     rename -background -textbackground textBackground Background
  161.     rename -highlightbackground -background background Background
  162.     }
  163.     grid $itk_component(listbox) -row 0 -column 0 -sticky nsew
  164.     grid rowconfigure $_interior 0 -weight 1
  165.     grid columnconfigure $_interior 0 -weight 1
  166.     
  167.     # 
  168.     # Configure the command on the vertical scroll bar in the base class.
  169.     #
  170.     $itk_component(vertsb) configure \
  171.     -command [itcl::code $itk_component(listbox) yview]
  172.  
  173.     #
  174.     # Configure the command on the horizontal scroll bar in the base class.
  175.     #
  176.     $itk_component(horizsb) configure \
  177.         -command [itcl::code $itk_component(listbox) xview]
  178.     
  179.     # 
  180.     # Create a set of bindings for monitoring the selection and install
  181.     # them on the listbox component.
  182.     #
  183.     foreach seq $singleSelectSeq {
  184.         bind SLBSelect$this $seq [itcl::code $this _makeSelection]
  185.     }
  186.  
  187.     foreach seq $doubleSelectSeq {
  188.         bind SLBSelect$this $seq [itcl::code $this _dblclick]
  189.     }
  190.  
  191.     bindtags $itk_component(listbox) \
  192.             [linsert [bindtags $itk_component(listbox)] end SLBSelect$this]
  193.  
  194.     #
  195.     # Also create a set of bindings for disabling the scrolledlistbox.
  196.     # Since the command for it is "break", we can drop the $this since
  197.     # they don't need to be unique to the object level.
  198.     #
  199.     if {[bind SLBDisabled] == {}} {
  200.         foreach seq $singleSelectSeq {
  201.             bind SLBDisabled $seq break
  202.         }
  203.  
  204.         bind SLBDisabled <Button-1> break
  205.  
  206.         foreach seq $doubleSelectSeq {
  207.             bind SLBDisabled $seq break
  208.         }
  209.     }
  210.  
  211.     #
  212.     # Initialize the widget based on the command line options.
  213.     #
  214.     eval itk_initialize $args
  215. }
  216.  
  217. # ------------------------------------------------------------------
  218. #                           DESTURCTOR
  219. # ------------------------------------------------------------------
  220. itcl::body iwidgets::Scrolledlistbox::destructor {} {
  221. }
  222.  
  223. # ------------------------------------------------------------------
  224. #                             OPTIONS
  225. # ------------------------------------------------------------------
  226.  
  227. # ------------------------------------------------------------------
  228. # OPTION: -dblclickcommand
  229. #
  230. # Specify a command to be executed upon double click of a listbox 
  231. # item.  Also, create a couple of bindings used for specific
  232. # selection modes
  233. # ------------------------------------------------------------------
  234. itcl::configbody iwidgets::Scrolledlistbox::dblclickcommand {}
  235.  
  236. # ------------------------------------------------------------------
  237. # OPTION: -selectioncommand
  238. #
  239. # Specifies a command to be executed upon selection of a listbox 
  240. # item.  The command will be called upon each selection regardless 
  241. # of selection mode..
  242. # ------------------------------------------------------------------
  243. itcl::configbody iwidgets::Scrolledlistbox::selectioncommand {}
  244.  
  245. # ------------------------------------------------------------------
  246. # OPTION: -width
  247. #
  248. # Specifies the width of the scrolled list box as an entire unit.
  249. # The value may be specified in any of the forms acceptable to 
  250. # Tk_GetPixels.  Any additional space needed to display the other
  251. # components such as margins and scrollbars force the listbox
  252. # to be compressed.  A value of zero along with the same value for 
  253. # the height causes the value given for the visibleitems option 
  254. # to be applied which administers geometry constraints in a different
  255. # manner.
  256. # ------------------------------------------------------------------
  257. itcl::configbody iwidgets::Scrolledlistbox::width {
  258.     if {$itk_option(-width) != 0} {
  259.         set shell [lindex [grid info $itk_component(listbox)] 1]
  260.  
  261.         #
  262.         # Due to a bug in the tk4.2 grid, we have to check the 
  263.         # propagation before setting it.  Setting it to the same
  264.         # value it already is will cause it to toggle.
  265.         #
  266.         if {[grid propagate $shell]} {
  267.             grid propagate $shell no
  268.         }
  269.     
  270.         $itk_component(listbox) configure -width 1
  271.         $shell configure \
  272.                 -width [winfo pixels $shell $itk_option(-width)] 
  273.     } else {
  274.         configure -visibleitems $itk_option(-visibleitems)
  275.     }
  276. }
  277.  
  278. # ------------------------------------------------------------------
  279. # OPTION: -height
  280. #
  281. # Specifies the height of the scrolled list box as an entire unit.
  282. # The value may be specified in any of the forms acceptable to 
  283. # Tk_GetPixels.  Any additional space needed to display the other
  284. # components such as margins and scrollbars force the listbox
  285. # to be compressed.  A value of zero along with the same value for 
  286. # the width causes the value given for the visibleitems option 
  287. # to be applied which administers geometry constraints in a different
  288. # manner.
  289. # ------------------------------------------------------------------
  290. itcl::configbody iwidgets::Scrolledlistbox::height {
  291.     if {$itk_option(-height) != 0} {
  292.         set shell [lindex [grid info $itk_component(listbox)] 1]
  293.  
  294.         #
  295.         # Due to a bug in the tk4.2 grid, we have to check the 
  296.         # propagation before setting it.  Setting it to the same
  297.         # value it already is will cause it to toggle.
  298.         #
  299.         if {[grid propagate $shell]} {
  300.             grid propagate $shell no
  301.         }
  302.     
  303.         $itk_component(listbox) configure -height 1
  304.         $shell configure \
  305.                 -height [winfo pixels $shell $itk_option(-height)] 
  306.     } else {
  307.         configure -visibleitems $itk_option(-visibleitems)
  308.     }
  309. }
  310.  
  311. # ------------------------------------------------------------------
  312. # OPTION: -visibleitems
  313. #
  314. # Specified the widthxheight in characters and lines for the listbox.
  315. # This option is only administered if the width and height options
  316. # are both set to zero, otherwise they take precedence.  With the
  317. # visibleitems option engaged, geometry constraints are maintained
  318. # only on the listbox.  The size of the other components such as 
  319. # labels, margins, and scrollbars, are additive and independent, 
  320. # effecting the overall size of the scrolled list box.  In contrast,
  321. # should the width and height options have non zero values, they
  322. # are applied to the scrolled list box as a whole.  The listbox 
  323. # is compressed or expanded to maintain the geometry constraints.
  324. # ------------------------------------------------------------------
  325. itcl::configbody iwidgets::Scrolledlistbox::visibleitems {
  326.     if {[regexp {^[0-9]+x[0-9]+$} $itk_option(-visibleitems)]} {
  327.         if {($itk_option(-width) == 0) && \
  328.                 ($itk_option(-height) == 0)} {
  329.             set chars [lindex [split $itk_option(-visibleitems) x] 0]
  330.             set lines [lindex [split $itk_option(-visibleitems) x] 1]
  331.         
  332.             set shell [lindex [grid info $itk_component(listbox)] 1]
  333.  
  334.             #
  335.             # Due to a bug in the tk4.2 grid, we have to check the 
  336.             # propagation before setting it.  Setting it to the same
  337.             # value it already is will cause it to toggle.
  338.             #
  339.             if {! [grid propagate $shell]} {
  340.                 grid propagate $shell yes
  341.             }
  342.         
  343.             $itk_component(listbox) configure -width $chars -height $lines
  344.         }
  345.     
  346.     } else {
  347.         error "bad visibleitems option\
  348.                 \"$itk_option(-visibleitems)\": should be\
  349.         widthxheight"
  350.     }
  351. }
  352.  
  353. # ------------------------------------------------------------------
  354. # OPTION: -state
  355. #
  356. # Specifies the state of the scrolledlistbox which may be either
  357. # disabled or normal.  In a disabled state, the scrolledlistbox 
  358. # does not accept user selection.  The default is normal.
  359. # ------------------------------------------------------------------
  360. itcl::configbody iwidgets::Scrolledlistbox::state {
  361.     set tags [bindtags $itk_component(listbox)]
  362.  
  363.     #
  364.     # If the state is normal, then we need to remove the disabled 
  365.     # bindings if they exist.  If the state is disabled, then we need
  366.     # to install the disabled bindings if they haven't been already.
  367.     #
  368.     switch -- $itk_option(-state) {
  369.         normal {
  370.                 $itk_component(listbox) configure \
  371.                     -foreground $itk_option(-foreground)
  372.                 $itk_component(listbox) configure \
  373.                     -selectforeground $itk_option(-selectforeground)
  374.             if {[set index [lsearch $tags SLBDisabled]] != -1} {
  375.                 bindtags $itk_component(listbox) \
  376.                         [lreplace $tags $index $index]
  377.             }
  378.         }
  379.  
  380.         disabled {
  381.                 $itk_component(listbox) configure \
  382.                     -foreground $itk_option(-disabledforeground)
  383.                 $itk_component(listbox) configure \
  384.                     -selectforeground $itk_option(-disabledforeground)
  385.             if {[set index [lsearch $tags SLBDisabled]] == -1} {
  386.                 bindtags $itk_component(listbox) \
  387.                         [linsert $tags 1 SLBDisabled]
  388.             }
  389.         }
  390.         default {
  391.             error "bad state value \"$itk_option(-state)\":\
  392.                     must be normal or disabled"
  393.         }
  394.     }
  395. }
  396.  
  397. # ------------------------------------------------------------------
  398. #                            METHODS
  399. # ------------------------------------------------------------------
  400.  
  401. # ------------------------------------------------------------------
  402. # METHOD: curselection 
  403. #
  404. # Returns a list containing the indices of all the elements in the 
  405. # listbox that are currently selected.
  406. # ------------------------------------------------------------------
  407. itcl::body iwidgets::Scrolledlistbox::curselection {} {
  408.     return [$itk_component(listbox) curselection]
  409. }
  410.  
  411. # ------------------------------------------------------------------
  412. # METHOD: activate index
  413. #
  414. # Sets the active element to the one indicated by index.
  415. # ------------------------------------------------------------------
  416. itcl::body iwidgets::Scrolledlistbox::activate {index} {
  417.     return [$itk_component(listbox) activate [_fixIndex $index]]
  418. }
  419.  
  420. # ------------------------------------------------------------------
  421. # METHOD: bbox index
  422. #
  423. # Returns four element list describing the bounding box for the list
  424. # item at index
  425. # ------------------------------------------------------------------
  426. itcl::body iwidgets::Scrolledlistbox::bbox {index} {
  427.     return [$itk_component(listbox) bbox [_fixIndex $index]]
  428. }
  429.  
  430. # ------------------------------------------------------------------
  431. # METHOD clear 
  432. #
  433. # Clear the listbox area of all items.
  434. # ------------------------------------------------------------------
  435. itcl::body iwidgets::Scrolledlistbox::clear {} {
  436.     delete 0 end
  437. }
  438.  
  439. # ------------------------------------------------------------------
  440. # METHOD: see index
  441. #
  442. # Adjusts the view such that the element given by index is visible.
  443. # ------------------------------------------------------------------
  444. itcl::body iwidgets::Scrolledlistbox::see {index} {
  445.     $itk_component(listbox) see [_fixIndex $index]
  446. }
  447.  
  448. # ------------------------------------------------------------------
  449. # METHOD: index index
  450. #
  451. # Returns the decimal string giving the integer index corresponding 
  452. # to index.  The index value may be a integer number, active,
  453. # anchor, end, @x,y, or a pattern.
  454. # ------------------------------------------------------------------
  455. itcl::body iwidgets::Scrolledlistbox::index {index} {
  456.     if {[regexp {(^[0-9]+$)|(^active$)|(^anchor$)|(^end$)|(^@-?[0-9]+,-?[0-9]+$)} $index]} {
  457.     return [$itk_component(listbox) index $index]
  458.     
  459.     } else {
  460.         set indexValue [lsearch -glob [get 0 end] $index]
  461.         if {$indexValue == -1} {
  462.             error "bad Scrolledlistbox index \"$index\": must be active,\
  463.                     anchor, end, @x,y, number, or a pattern"
  464.         }
  465.         return $indexValue
  466.     }
  467. }
  468.  
  469. # ------------------------------------------------------------------
  470. # METHOD: _fixIndex index
  471. #
  472. # Similar to the regular "index" method, but it only converts
  473. # the index to a numerical value if it is a string pattern.  If
  474. # the index is in the proper form to be used with the listbox,
  475. # it is left alone.  This fixes problems associated with converting
  476. # an index such as "end" to a numerical value.
  477. # ------------------------------------------------------------------
  478. itcl::body iwidgets::Scrolledlistbox::_fixIndex {index} {
  479.     if {[regexp {(^[0-9]+$)|(^active$)|(^anchor$)|(^end$)|(^@[0-9]+,[0-9]+$)} \
  480.             $index]} {
  481.         return $index
  482.  
  483.     } else {
  484.         set indexValue [lsearch -glob [get 0 end] $index]
  485.  
  486.         if {$indexValue == -1} {
  487.             error "bad Scrolledlistbox index \"$index\": must be active,\
  488.                     anchor, end, @x,y, number, or a pattern"
  489.         }
  490.         return $indexValue
  491.     }
  492. }
  493.  
  494. # ------------------------------------------------------------------
  495. # METHOD: delete first ?last?
  496. #
  497. # Delete one or more elements from list box based on the first and 
  498. # last index values.  Indexes may be a number, active, anchor, end,
  499. # @x,y, or a pattern.
  500. # ------------------------------------------------------------------
  501. itcl::body iwidgets::Scrolledlistbox::delete {first {last {}}} {
  502.     set first [_fixIndex $first]
  503.     
  504.     if {$last != {}} {
  505.         set last [_fixIndex $last]
  506.     } else {
  507.         set last $first
  508.     }
  509.     
  510.     eval $itk_component(listbox) delete $first $last
  511. }
  512.  
  513. # ------------------------------------------------------------------
  514. # METHOD: get first ?last?
  515. #
  516. # Returns the elements of the listbox indicated by the indexes. 
  517. # Indexes may be a number, active, anchor, end, @x,y, ora pattern.
  518. # ------------------------------------------------------------------
  519. itcl::body iwidgets::Scrolledlistbox::get {first {last {}}} {
  520.     set first [_fixIndex $first]
  521.     
  522.     if {$last != {}} {
  523.         set last [_fixIndex $last]
  524.     }
  525.     
  526.     if {$last == {}} {
  527.         return [$itk_component(listbox) get $first]
  528.     } else {
  529.         return [$itk_component(listbox) get $first $last]
  530.     }
  531. }
  532.  
  533. # ------------------------------------------------------------------
  534. # METHOD: getcurselection 
  535. #
  536. # Returns the contents of the listbox element indicated by the current 
  537. # selection indexes.  Short cut version of get and curselection 
  538. # command combination.
  539. # ------------------------------------------------------------------
  540. itcl::body iwidgets::Scrolledlistbox::getcurselection {} {
  541.     set rlist {}
  542.  
  543.     if {[selecteditemcount] > 0} {
  544.         set cursels [$itk_component(listbox) curselection]
  545.     
  546.         switch $itk_option(-selectmode) {
  547.             single -
  548.             browse {
  549.                 set rlist [$itk_component(listbox) get $cursels]
  550.             }
  551.  
  552.             multiple -
  553.             extended {
  554.                 foreach sel $cursels {
  555.                     lappend rlist [$itk_component(listbox) get $sel]
  556.                 }
  557.             }
  558.         }
  559.     }
  560.     
  561.     return $rlist
  562. }
  563.  
  564. # ------------------------------------------------------------------
  565. # METHOD: insert index string ?string ...?
  566. #
  567. # Insert zero or more elements in the list just before the element 
  568. # given by index.
  569. # ------------------------------------------------------------------
  570. itcl::body iwidgets::Scrolledlistbox::insert {index args} {
  571.     set index [_fixIndex $index]
  572.  
  573.     eval $itk_component(listbox) insert $index $args
  574. }
  575.  
  576. # ------------------------------------------------------------------
  577. # METHOD: nearest y
  578. #
  579. # Given a y-coordinate within the listbox, this command returns the 
  580. # index of the visible listbox element nearest to that y-coordinate.
  581. # ------------------------------------------------------------------
  582. itcl::body iwidgets::Scrolledlistbox::nearest {y} {
  583.     $itk_component(listbox) nearest $y
  584. }
  585.  
  586. # ------------------------------------------------------------------
  587. # METHOD: scan option args 
  588. #
  589. # Implements scanning on listboxes.
  590. # ------------------------------------------------------------------
  591. itcl::body iwidgets::Scrolledlistbox::scan {option args} {
  592.     eval $itk_component(listbox) scan $option $args
  593. }
  594.  
  595. # ------------------------------------------------------------------
  596. # METHOD: selection option first ?last?
  597. #
  598. # Adjusts the selection within the listbox.  The index value may be 
  599. # a integer number, active, anchor, end, @x,y, or a pattern.
  600. # ------------------------------------------------------------------
  601. itcl::body iwidgets::Scrolledlistbox::selection {option first {last {}}} {
  602.     set first [_fixIndex $first]
  603.     
  604.     if {$last != {}} {
  605.         set last [_fixIndex $last]
  606.         $itk_component(listbox) selection $option $first $last
  607.     } else {
  608.         $itk_component(listbox) selection $option $first 
  609.     }
  610. }
  611.  
  612. # ------------------------------------------------------------------
  613. # METHOD: size 
  614. #
  615. # Returns a decimal string indicating the total number of elements 
  616. # in the listbox.
  617. # ------------------------------------------------------------------
  618. itcl::body iwidgets::Scrolledlistbox::size {} {
  619.     return [$itk_component(listbox) size]
  620. }
  621.  
  622. # ------------------------------------------------------------------
  623. # METHOD: selecteditemcount 
  624. #
  625. # Returns a decimal string indicating the total number of selected 
  626. # elements in the listbox.
  627. # ------------------------------------------------------------------
  628. itcl::body iwidgets::Scrolledlistbox::selecteditemcount {} {
  629.     return [llength [$itk_component(listbox) curselection]]
  630. }
  631.  
  632. # ------------------------------------------------------------------
  633. # METHOD: justify direction
  634. #
  635. # Justifies the list scrolled region in one of four directions: top,
  636. # bottom, left, or right.
  637. # ------------------------------------------------------------------
  638. itcl::body iwidgets::Scrolledlistbox::justify {direction} {
  639.     switch $direction {
  640.         left { 
  641.             $itk_component(listbox) xview moveto 0
  642.         }
  643.         right {
  644.             $itk_component(listbox) xview moveto 1
  645.         }
  646.         top {
  647.             $itk_component(listbox) yview moveto 0
  648.         }
  649.         bottom {
  650.             $itk_component(listbox) yview moveto 1
  651.         }
  652.         default {
  653.             error "bad justify argument \"$direction\": should\
  654.                 be left, right, top, or bottom"
  655.         }
  656.     }
  657. }
  658.  
  659. # ------------------------------------------------------------------
  660. # METHOD: sort mode
  661. #
  662. # Sort the current list. This can take any sort switch from
  663. # the lsort command: ascii, integer, real, command, 
  664. # increasing/ascending, decreasing/descending, etc.
  665. #     
  666. # ------------------------------------------------------------------
  667. itcl::body iwidgets::Scrolledlistbox::sort {{mode ascending}} {
  668.  
  669.     set vals [$itk_component(listbox) get 0 end]
  670.     if {[llength $vals] == 0} {return}
  671.  
  672.     switch $mode {
  673.         ascending   {set mode increasing}
  674.         descending  {set mode decreasing}
  675.     }
  676.  
  677.     $itk_component(listbox) delete 0 end
  678.     if {[catch {eval $itk_component(listbox) insert end \
  679.             [lsort -${mode} $vals]} errorstring]} {
  680.         error "bad sort argument \"$mode\": must be a valid argument to the\
  681.                 Tcl lsort command"
  682.     }
  683.  
  684.     return
  685. }
  686.  
  687. # ------------------------------------------------------------------
  688. # METHOD: xview args
  689. #
  690. # Change or query the vertical position of the text in the list box.
  691. # ------------------------------------------------------------------
  692. itcl::body iwidgets::Scrolledlistbox::xview {args} {
  693.     return [eval $itk_component(listbox) xview $args]
  694. }
  695.  
  696. # ------------------------------------------------------------------
  697. # METHOD: yview args
  698. #
  699. # Change or query the horizontal position of the text in the list box.
  700. # ------------------------------------------------------------------
  701. itcl::body iwidgets::Scrolledlistbox::yview {args} {
  702.     return [eval $itk_component(listbox) yview $args]
  703. }
  704.  
  705. # ------------------------------------------------------------------
  706. # METHOD: itemconfigure args
  707. #
  708. # This is a wrapper method around the new tk8.3 itemconfigure command
  709. # for the listbox.
  710. # ------------------------------------------------------------------
  711. itcl::body iwidgets::Scrolledlistbox::itemconfigure {args} {
  712.     return [eval $itk_component(listbox) itemconfigure $args]
  713. }
  714.  
  715. # ------------------------------------------------------------------
  716. # PROTECTED METHOD: _makeSelection 
  717. #
  718. # Evaluate the selection command.
  719. # ------------------------------------------------------------------
  720. itcl::body iwidgets::Scrolledlistbox::_makeSelection {} {
  721.     uplevel #0 $itk_option(-selectioncommand)
  722. }
  723.  
  724. # ------------------------------------------------------------------
  725. # PROTECTED METHOD: _dblclick 
  726. #
  727. # Evaluate the double click command option if not empty.
  728. # ------------------------------------------------------------------
  729. itcl::body iwidgets::Scrolledlistbox::_dblclick {} {
  730.     uplevel #0 $itk_option(-dblclickcommand)
  731. }   
  732.  
  733.