InfoMagic Source Code 1993 July/THE_SOURCE_CODE_CD_ROM.iso/gnu/gccdist/kitdist.com

Text File | 1992-04-30 | 2.0 KB | 63 lines

$!
$! This command file creates a VMSINSTAL-able distribution of GCC.  The
$! kit is written to the device pointed to by the logical name "dist".
$! The version should be a 3 digit number, two major, and one minor.
$! (VMSINSTAL restriction).
$!
$! This procedure assumes that the files are layed out in the directory
$! tree structure with subdirectories bison, gcc-src, and gcc.
$!
$if f$search("bison.dir").eqs."" then goto nope
$if f$search("gcc-src.dir").eqs."" then goto nope
$if f$search("gcc.dir").eqs."" then goto nope
$if f$search("[.gcc]include.dir").eqs."" then goto nope
$ define dist $diska:[eric]
$vers:=014
$!
$!
$   ROOT = -
    F$PARSE (f$environment("DEFAULT"),,,"DEVICE","NO_CONCEAL") -
    + F$PARSE (f$environment("DEFAULT"),,,"DIRECTORY","NO_CONCEAL") -
    - "][" - "]" + ".]"
$assign 'root' dumping/tran=conc
$backup dumping:[gcc-src...]*.*; gcc-src.sav/save/block=8192/noverify/nolog
$!
$root = root - ".]" + ".gcc.]"
$assign 'root' dumping1/tran=conc
$backup dumping1:[include...]*.*; gcc-include.sav/save/block=8192/noverify/nolog
$deassign dumping1
$!
$backup_flag := /block=8192
$!
$if f$getdvi("dist","devclass").ne.2 then goto noinit
$! initialize the dist
$init dist gcc
$ mount /foreign dist:
$backup_flag := /verify/label=""GCC""
$noinit:
$backup/interchange 'backup_flag' -
    dumping:[000000]aaaread.me;, -
    dumping:[000000]kitinstal.com; -
    dist:gcc'vers'.a/save
$backup/interchange 'backup_flag' /excl=*.dir  -
    dumping:[gcc]*.*;,dumping:[000000]gcc-src.sav;, -
    dumping:[000000]gcc-include.sav; dist:gcc'vers'.b/save
$backup/interchange 'backup_flag'   dumping:[bison]*.*; dist:gcc'vers'.c/save
$if f$getdvi("dist","devclass").eq.2 then dismount dist:
$deassign dist
$deassign dumping
$!
$! Now clean up a little
$!
$delete gcc-src.sav;/nolog
$delete gcc-include.sav;/nolog
$exit
$!
$!
$nope:
$type sys$input
    You have not run this command procedure from the proper directory.
You must have bison, gcc-src, and gcc subdirectories, and a [.gcc]include
subsubdirectory.
$exit 4