home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Source Code 1993 July / THE_SOURCE_CODE_CD_ROM.iso / gnu / emacs-19.16 / lisp / sort.el < prev    next >
Encoding:
Text File  |  1993-06-08  |  17.1 KB  |  472 lines
  1. ;;; sort.el --- commands to sort text in an Emacs buffer.
  2.  
  3. ;; Copyright (C) 1986, 1987 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Howie Kaye
  6. ;; Maintainer: FSF
  7. ;; Keywords: unix
  8.  
  9. ;; This file is part of GNU Emacs.
  10.  
  11. ;; GNU Emacs is free software; you can redistribute it and/or modify
  12. ;; it under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation; either version 2, or (at your option)
  14. ;; any later version.
  15.  
  16. ;; GNU Emacs is distributed in the hope that it will be useful,
  17. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19. ;; GNU General Public License for more details.
  20.  
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24.  
  25. ;;; Commentary:
  26.  
  27. ;;; This package provides the sorting facilities documented in the Emacs
  28. ;;; user's manual.
  29.  
  30. ;;; Code:
  31.  
  32. (defvar sort-fold-case nil
  33.   "*Non-nil if the buffer sort functions should ignore case.")
  34.  
  35. (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  36.   "General text sorting routine to divide buffer into records and sort them.
  37. Arguments are REVERSE NEXTRECFUN ENDRECFUN &optional STARTKEYFUN ENDKEYFUN.
  38.  
  39. We divide the accessible portion of the buffer into disjoint pieces
  40. called sort records.  A portion of each sort record (perhaps all of
  41. it) is designated as the sort key.  The records are rearranged in the
  42. buffer in order by their sort keys.  The records may or may not be
  43. contiguous.
  44.  
  45. Usually the records are rearranged in order of ascending sort key.
  46. If REVERSE is non-nil, they are rearranged in order of descending sort key.
  47.  
  48. The next four arguments are functions to be called to move point
  49. across a sort record.  They will be called many times from within sort-subr.
  50.  
  51. NEXTRECFUN is called with point at the end of the previous record.
  52. It moves point to the start of the next record.
  53. It should move point to the end of the buffer if there are no more records.
  54. The first record is assumed to start at the position of point when sort-subr
  55. is called.
  56.  
  57. ENDRECFUN is called with point within the record.
  58. It should move point to the end of the record.
  59.  
  60. STARTKEYFUN moves from the start of the record to the start of the key.
  61. It may return either a non-nil value to be used as the key, or
  62. else the key is the substring between the values of point after
  63. STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  64. starts at the beginning of the record.
  65.  
  66. ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  67. ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  68. same as ENDRECFUN."
  69.   ;; Heuristically try to avoid messages if sorting a small amt of text.
  70.   (let ((messages (> (- (point-max) (point-min)) 50000)))
  71.     (save-excursion
  72.       (if messages (message "Finding sort keys..."))
  73.       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  74.                        startkeyfun endkeyfun))
  75.          (old (reverse sort-lists))
  76.          (case-fold-search sort-fold-case))
  77.     (if (null sort-lists)
  78.         ()
  79.       (or reverse (setq sort-lists (nreverse sort-lists)))
  80.       (if messages (message "Sorting records..."))
  81.       (setq sort-lists
  82.         (if (fboundp 'sortcar)
  83.             (sortcar sort-lists
  84.                  (cond ((numberp (car (car sort-lists)))
  85.                     ;; This handles both ints and floats.
  86.                     '<)
  87.                    ((consp (car (car sort-lists)))
  88.                     (function
  89.                      (lambda (a b)
  90.                        (> 0 (compare-buffer-substrings 
  91.                          nil (car a) (cdr a)
  92.                          nil (car b) (cdr b))))))
  93.                    (t
  94.                     'string<)))
  95.           (sort sort-lists
  96.             (cond ((numberp (car (car sort-lists)))
  97.                    (function
  98.                 (lambda (a b)
  99.                   (< (car a) (car b)))))
  100.                   ((consp (car (car sort-lists)))
  101.                    (function
  102.                 (lambda (a b)
  103.                   (> 0 (compare-buffer-substrings 
  104.                     nil (car (car a)) (cdr (car a))
  105.                     nil (car (car b)) (cdr (car b)))))))
  106.                   (t
  107.                    (function
  108.                 (lambda (a b)
  109.                   (string< (car a) (car b)))))))))
  110.       (if reverse (setq sort-lists (nreverse sort-lists)))
  111.       (if messages (message "Reordering buffer..."))
  112.       (sort-reorder-buffer sort-lists old)))
  113.       (if messages (message "Reordering buffer... Done"))))
  114.   nil)
  115.  
  116. ;; Parse buffer into records using the arguments as Lisp expressions;
  117. ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
  118. ;; where KEY is the sort key (a number or string),
  119. ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
  120.  
  121. ;; The records appear in the list lastmost first!
  122.  
  123. (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
  124.   (let ((sort-lists ())
  125.     (start-rec nil)
  126.     done key)
  127.     ;; Loop over sort records.
  128.     ;(goto-char (point-min)) -- it is the caller's responsibility to
  129.     ;arrange this if necessary
  130.     (while (not (eobp))
  131.       (setq start-rec (point))        ;save record start
  132.       (setq done nil)
  133.       ;; Get key value, or move to start of key.
  134.       (setq key (catch 'key
  135.           (or (and startkeyfun (funcall startkeyfun))
  136.               ;; If key was not returned as value,
  137.               ;; move to end of key and get key from the buffer.
  138.               (let ((start (point)))
  139.             (funcall (or endkeyfun
  140.                      (prog1 endrecfun (setq done t))))
  141.             (cons start (point))))))
  142.       ;; Move to end of this record (start of next one, or end of buffer).
  143.       (cond ((prog1 done (setq done nil)))
  144.         (endrecfun (funcall endrecfun))
  145.         (nextrecfun (funcall nextrecfun) (setq done t)))
  146.       (if key (setq sort-lists (cons
  147.                  ;; consing optimization in case in which key
  148.                  ;; is same as record.
  149.                  (if (and (consp key)
  150.                       (equal (car key) start-rec)
  151.                       (equal (cdr key) (point)))
  152.                      (cons key key)
  153.                    (cons key (cons start-rec (point))))
  154.                  sort-lists)))
  155.       (and (not done) nextrecfun (funcall nextrecfun)))
  156.     sort-lists))
  157.  
  158. (defun sort-reorder-buffer (sort-lists old)
  159.   (let ((inhibit-quit t)
  160.     (last (point-min))
  161.     (min (point-min)) (max (point-max)))
  162.     ;; Make sure insertions done for reordering
  163.     ;; do not go after any markers at the end of the sorted region,
  164.     ;; by inserting a space to separate them.
  165.     (goto-char (point-max))
  166.     (insert-before-markers " ")
  167.     (narrow-to-region min (1- (point-max)))
  168.     (while sort-lists
  169.       (goto-char (point-max))
  170.       (insert-buffer-substring (current-buffer)
  171.                    last
  172.                    (nth 1 (car old)))
  173.       (goto-char (point-max))
  174.       (insert-buffer-substring (current-buffer)
  175.                    (nth 1 (car sort-lists))
  176.                    (cdr (cdr (car sort-lists))))
  177.       (setq last (cdr (cdr (car old)))
  178.         sort-lists (cdr sort-lists)
  179.         old (cdr old)))
  180.     (goto-char (point-max))
  181.     (insert-buffer-substring (current-buffer)
  182.                  last
  183.                  max)
  184.     ;; Delete the original copy of the text.
  185.     (delete-region min max)
  186.     ;; Get rid of the separator " ".
  187.     (goto-char (point-max))
  188.     (narrow-to-region min (1+ (point)))
  189.     (delete-region (point) (1+ (point)))))
  190.  
  191. ;;;###autoload
  192. (defun sort-lines (reverse beg end) 
  193.   "Sort lines in region alphabetically; argument means descending order.
  194. Called from a program, there are three arguments:
  195. REVERSE (non-nil means reverse order), BEG and END (region to sort)."
  196.   (interactive "P\nr")
  197.   (save-excursion
  198.     (save-restriction
  199.       (narrow-to-region beg end)
  200.       (goto-char (point-min))
  201.       (sort-subr reverse 'forward-line 'end-of-line))))
  202.  
  203. ;;;###autoload
  204. (defun sort-paragraphs (reverse beg end)
  205.   "Sort paragraphs in region alphabetically; argument means descending order.
  206. Called from a program, there are three arguments:
  207. REVERSE (non-nil means reverse order), BEG and END (region to sort)."
  208.   (interactive "P\nr")
  209.   (save-excursion
  210.     (save-restriction
  211.       (narrow-to-region beg end)
  212.       (goto-char (point-min))
  213.       (sort-subr reverse
  214.          (function (lambda () (skip-chars-forward "\n \t\f")))
  215.          'forward-paragraph))))
  216.  
  217. ;;;###autoload
  218. (defun sort-pages (reverse beg end)
  219.   "Sort pages in region alphabetically; argument means descending order.
  220. Called from a program, there are three arguments:
  221. REVERSE (non-nil means reverse order), BEG and END (region to sort)."
  222.   (interactive "P\nr")
  223.   (save-excursion
  224.     (save-restriction
  225.       (narrow-to-region beg end)
  226.       (goto-char (point-min))
  227.       (sort-subr reverse
  228.          (function (lambda () (skip-chars-forward "\n")))
  229.          'forward-page))))
  230.  
  231. (defvar sort-fields-syntax-table nil)
  232. (if sort-fields-syntax-table nil
  233.   (let ((table (make-syntax-table))
  234.     (i 0))
  235.     (while (< i 256)
  236.       (modify-syntax-entry i "w" table)
  237.       (setq i (1+ i)))
  238.     (modify-syntax-entry ?\  " " table)
  239.     (modify-syntax-entry ?\t " " table)
  240.     (modify-syntax-entry ?\n " " table)
  241.     (modify-syntax-entry ?\. "_" table)    ; for floating pt. numbers. -wsr
  242.     (setq sort-fields-syntax-table table)))
  243.  
  244. ;;;###autoload
  245. (defun sort-numeric-fields (field beg end)
  246.   "Sort lines in region numerically by the ARGth field of each line.
  247. Fields are separated by whitespace and numbered from 1 up.
  248. Specified field must contain a number in each line of the region.
  249. With a negative arg, sorts by the ARGth field counted from the right.
  250. Called from a program, there are three arguments:
  251. FIELD, BEG and END.  BEG and END specify region to sort.
  252. If you want to sort floating-point numbers, try `sort-float-fields'."
  253.   (interactive "p\nr")
  254.   (sort-fields-1 field beg end
  255.          (function (lambda ()
  256.                  (sort-skip-fields (1- field))
  257.                  (string-to-number
  258.                   (buffer-substring
  259.                     (point)
  260.                 (save-excursion
  261.                   ;; This is just wrong! Even without floats...
  262.                   ;; (skip-chars-forward "[0-9]")
  263.                   (forward-sexp 1)
  264.                   (point))))))
  265.          nil))
  266.  
  267. ;;;###autoload
  268. (defun sort-float-fields (field beg end)
  269.   "Sort lines in region numerically by the ARGth field of each line.
  270. Fields are separated by whitespace and numbered from 1 up.  Specified field
  271. must contain a floating point number in each line of the region.  With a
  272. negative arg, sorts by the ARGth field counted from the right.  Called from a
  273. program, there are three arguments: FIELD, BEG and END.  BEG and END specify
  274. region to sort."
  275.   (interactive "p\nr")
  276.   (sort-fields-1 field beg end
  277.          (function (lambda ()
  278.                  (sort-skip-fields (1- field))
  279.                  (string-to-number
  280.                   (buffer-substring
  281.                    (point)
  282.                    (save-excursion
  283.                  (re-search-forward
  284.                   "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
  285.                  (point))))))
  286.          nil))
  287.  
  288. ;;;###autoload
  289. (defun sort-fields (field beg end)
  290.   "Sort lines in region lexicographically by the ARGth field of each line.
  291. Fields are separated by whitespace and numbered from 1 up.
  292. With a negative arg, sorts by the ARGth field counted from the right.
  293. Called from a program, there are three arguments:
  294. FIELD, BEG and END.  BEG and END specify region to sort."
  295.   (interactive "p\nr")
  296.   (sort-fields-1 field beg end
  297.          (function (lambda ()
  298.                  (sort-skip-fields (1- field))
  299.                  nil))
  300.          (function (lambda () (skip-chars-forward "^ \t\n")))))
  301.  
  302. (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
  303.   (let ((tbl (syntax-table)))
  304.     (if (zerop field) (setq field 1))
  305.     (unwind-protect
  306.     (save-excursion
  307.       (save-restriction
  308.         (narrow-to-region beg end)
  309.         (goto-char (point-min))
  310.         (set-syntax-table sort-fields-syntax-table)
  311.         (sort-subr nil
  312.                'forward-line 'end-of-line
  313.                startkeyfun endkeyfun)))
  314.       (set-syntax-table tbl))))
  315.  
  316. (defun sort-skip-fields (n)
  317.   (let ((bol (point))
  318.     (eol (save-excursion (end-of-line 1) (point))))
  319.     (if (> n 0) (forward-word n)
  320.       (end-of-line)
  321.       (forward-word (1+ n)))
  322.     (if (or (and (>= (point) eol) (> n 0))
  323.         ;; this is marginally wrong; if the first line of the sort
  324.         ;; at bob has the wrong number of fields the error won't be
  325.         ;; reported until the next short line.
  326.         (and (< (point) bol) (< n 0)))
  327.     (error "Line has too few fields: %s"
  328.            (buffer-substring bol eol)))
  329.     (skip-chars-forward " \t")))
  330.  
  331.  
  332. ;;;###autoload
  333. (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
  334.   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
  335. RECORD-REGEXP specifies the textual units which should be sorted.
  336.   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
  337. KEY specifies the part of each record (ie each match for RECORD-REGEXP)
  338.   is to be used for sorting.
  339.   If it is \"\\digit\" then the digit'th \"\\(...\\)\" match field from
  340.   RECORD-REGEXP is used.
  341.   If it is \"\\&\" then the whole record is used.
  342.   Otherwise, it is a regular-expression for which to search within the record.
  343. If a match for KEY is not found within a record then that record is ignored.
  344.  
  345. With a negative prefix arg sorts in reverse order.
  346.  
  347. For example: to sort lines in the region by the first word on each line
  348.  starting with the letter \"f\",
  349.  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\=\\<f\\w*\\>\""
  350.   ;; using negative prefix arg to mean "reverse" is now inconsistent with
  351.   ;; other sort-.*fields functions but then again this was before, since it
  352.   ;; didn't use the magnitude of the arg to specify anything.
  353.   (interactive "P\nsRegexp specifying records to sort: 
  354. sRegexp specifying key within record: \nr")
  355.   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
  356.      (setq key-regexp 0))
  357.     ((string-match "\\`\\\\[1-9]\\'" key-regexp)
  358.      (setq key-regexp (- (aref key-regexp 1) ?0))))
  359.   (save-excursion
  360.     (save-restriction
  361.       (narrow-to-region beg end)
  362.       (goto-char (point-min))
  363.       (let (sort-regexp-record-end) ;isn't dynamic scoping wonderful?
  364.     (re-search-forward record-regexp)
  365.     (setq sort-regexp-record-end (point))
  366.     (goto-char (match-beginning 0))
  367.     (sort-subr reverse
  368.            (function (lambda ()
  369.                    (and (re-search-forward record-regexp nil 'move)
  370.                     (setq sort-regexp-record-end (match-end 0))
  371.                     (goto-char (match-beginning 0)))))
  372.            (function (lambda ()
  373.                    (goto-char sort-regexp-record-end)))
  374.            (function (lambda ()
  375.                    (let ((n 0))
  376.                  (cond ((numberp key-regexp)
  377.                     (setq n key-regexp))
  378.                        ((re-search-forward
  379.                       key-regexp sort-regexp-record-end t)
  380.                     (setq n 0))
  381.                        (t (throw 'key nil)))
  382.                  (condition-case ()
  383.                      (if (fboundp 'buffer-substring-lessp)
  384.                      (cons (match-beginning n)
  385.                            (match-end n))
  386.                      (buffer-substring (match-beginning n)
  387.                                (match-end n)))
  388.                    ;; if there was no such register
  389.                    (error (throw 'key nil)))))))))))
  390.  
  391.  
  392. (defvar sort-columns-subprocess t)
  393.  
  394. ;;;###autoload
  395. (defun sort-columns (reverse &optional beg end)
  396.   "Sort lines in region alphabetically by a certain range of columns.
  397. For the purpose of this command, the region includes
  398. the entire line that point is in and the entire line the mark is in.
  399. The column positions of point and mark bound the range of columns to sort on.
  400. A prefix argument means sort into reverse order.
  401.  
  402. Note that `sort-columns' rejects text that contains tabs,
  403. because tabs could be split across the specified columns
  404. and it doesn't know how to handle that.  Also, when possible,
  405. it uses the `sort' utility program, which doesn't understand tabs.
  406. Use \\[untabify] to convert tabs to spaces before sorting."
  407.   (interactive "P\nr")
  408.   (save-excursion
  409.     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
  410.       (goto-char (min beg end))
  411.       (setq col-beg1 (current-column))
  412.       (beginning-of-line)
  413.       (setq beg1 (point))
  414.       (goto-char (max beg end))
  415.       (setq col-end1 (current-column))
  416.       (forward-line)
  417.       (setq end1 (point))
  418.       (setq col-start (min col-beg1 col-end1))
  419.       (setq col-end (max col-beg1 col-end1))
  420.       (if (search-backward "\t" beg1 t)
  421.       (error "sort-columns does not work with tabs.  Use M-x untabify."))
  422.       (if (not (eq system-type 'vax-vms))
  423.       ;; Use the sort utility if we can; it is 4 times as fast.
  424.       (call-process-region beg1 end1 "sort" t t nil
  425.                    (if reverse "-rt\n" "-t\n")
  426.                    (concat "+0." col-start)
  427.                    (concat "-0." col-end))
  428.     ;; On VMS, use Emacs's own facilities.
  429.     (save-excursion
  430.       (save-restriction
  431.         (narrow-to-region beg1 end1)
  432.         (goto-char beg1)
  433.         (sort-subr reverse 'forward-line 'end-of-line
  434.                (function (lambda () (move-to-column col-start) nil))
  435.                (function (lambda () (move-to-column col-end) nil)))))))))
  436.  
  437. ;;;###autoload
  438. (defun reverse-region (beg end)
  439.   "Reverse the order of lines in a region.
  440. From a program takes two point or marker arguments, BEG and END."
  441.   (interactive "r")
  442.   (if (> beg end)
  443.       (let (mid) (setq mid end end beg beg mid)))
  444.   (save-excursion
  445.     ;; put beg at the start of a line and end and the end of one --
  446.     ;; the largest possible region which fits this criteria
  447.     (goto-char beg)
  448.     (or (bolp) (forward-line 1))
  449.     (setq beg (point))
  450.     (goto-char end)
  451.     ;; the test for bolp is for those times when end is on an empty line;
  452.     ;; it is probably not the case that the line should be included in the
  453.     ;; reversal; it isn't difficult to add it afterward.
  454.     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
  455.     (setq end (point-marker))
  456.     ;; the real work.  this thing cranks through memory on large regions.
  457.     (let (ll (do t))
  458.       (while do
  459.     (goto-char beg)
  460.     (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
  461.                ll))
  462.     (setq do (/= (point) end))
  463.     (delete-region beg (if do (1+ (point)) (point))))
  464.       (while (cdr ll)
  465.     (insert (car ll) "\n")
  466.     (setq ll (cdr ll)))
  467.       (insert (car ll)))))
  468.  
  469. (provide 'sort)
  470.  
  471. ;;; sort.el ends here
  472.