home *** CD-ROM | disk | FTP | other *** search
/ InfoMagic Source Code 1993 July / THE_SOURCE_CODE_CD_ROM.iso / gnu / emacs-19.16 / lisp / sendmail.el < prev    next >
Encoding:
Text File  |  1993-07-01  |  28.9 KB  |  840 lines
  1. ;;; sendmail.el --- mail sending commands for Emacs.
  2.  
  3. ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
  4.  
  5. ;; Maintainer: FSF
  6. ;; Keywords: mail
  7.  
  8. ;; This file is part of GNU Emacs.
  9.  
  10. ;; GNU Emacs is free software; you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation; either version 2, or (at your option)
  13. ;; any later version.
  14.  
  15. ;; GNU Emacs is distributed in the hope that it will be useful,
  16. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18. ;; GNU General Public License for more details.
  19.  
  20. ;; You should have received a copy of the GNU General Public License
  21. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23.  
  24. ;;; Commentary:
  25.  
  26. ;; This mode provides mail-sending facilities from within Emacs.  It is
  27. ;; documented in the Emacs user's manual.
  28.  
  29. ;;; Code:
  30.  
  31. ;;;###autoload
  32. (defvar mail-self-blind nil "\
  33. Non-nil means insert BCC to self in messages to be sent.
  34. This is done when the message is initialized,
  35. so you can remove or alter the BCC field to override the default.")
  36.  
  37. ;;;###autoload
  38. (defvar mail-interactive nil "\
  39. Non-nil means when sending a message wait for and display errors.
  40. nil means let mailer mail back a message to report errors.")
  41.  
  42. ;;;###autoload
  43. (defvar mail-yank-ignored-headers "^via:\\|^mail-from:\\|^origin:\\|^status:\\|^remailed\\|^received:\\|^message-id:\\|^summary-line:\\|^to:\\|^subject:\\|^in-reply-to:\\|^return-path:" "\
  44. Delete these headers from old message when it's inserted in a reply.")
  45.  
  46. ;; Useful to set in site-init.el
  47. ;;;###autoload
  48. (defvar send-mail-function 'sendmail-send-it "\
  49. Function to call to send the current buffer as mail.
  50. The headers are be delimited by a line which is `mail-header-separator'.")
  51.  
  52. ;;;###autoload
  53. (defvar mail-header-separator "--text follows this line--" "\
  54. *Line used to separate headers from text in messages being composed.")
  55.  
  56. ;;;###autoload
  57. (defvar mail-archive-file-name nil "\
  58. *Name of file to write all outgoing messages in, or nil for none.
  59. Do not use an rmail file here!  Instead, use its inbox file.")
  60.  
  61. (defvar mail-default-reply-to nil
  62.   "*Address to insert as default Reply-to field of outgoing messages.")
  63.  
  64. (defvar mail-alias-file nil
  65.   "*If non-nil, the name of a file to use instead of `/usr/lib/aliases'.
  66. This file defines aliases to be expanded by the mailer; this is a different
  67. feature from that of defining aliases in `.mailrc' to be expanded in Emacs.
  68. This variable has no effect unless your system uses sendmail as its mailer.")
  69.  
  70. (defvar mail-aliases t
  71.   "Alist of mail address aliases,
  72. or t meaning should be initialized from `~/.mailrc'.
  73. The alias definitions in `~/.mailrc' have this form:
  74.     alias ALIAS MEANING")
  75.  
  76. (defvar mail-yank-prefix nil
  77.   "*Prefix insert on lines of yanked message being replied to.
  78. nil means use indentation.")
  79. (defvar mail-indentation-spaces 3
  80.   "*Number of spaces to insert at the beginning of each cited line.
  81. Used by `mail-yank-original' via `mail-yank-cite'.")
  82. (defvar mail-yank-hooks '(mail-indent-citation)
  83.   "Obsolete hook for modifying a citation just inserted in the mail buffer.
  84. Each hook function can find the citation between (point) and (mark t).
  85. And each hook function should leave point and mark around the citation
  86. text as modified.
  87.  
  88. This is a normal hook, misnamed for historical reasons.
  89. It is semi-obsolete and mail agents should no longer use it.")
  90.  
  91. (defvar mail-citation-hook nil
  92.   "*Hook for modifying a citation just inserted in the mail buffer.
  93. Each hook function can find the citation between (point) and (mark t).
  94. And each hook function should leave point and mark around the citation
  95. text as modified.
  96.  
  97. If this hook is entirely empty (nil), a default action is taken
  98. instead of no action.")
  99.  
  100. (defvar mail-abbrevs-loaded nil)
  101. (defvar mail-mode-map nil)
  102.  
  103. (autoload 'build-mail-aliases "mailalias"
  104.   "Read mail aliases from `~/.mailrc' and set `mail-aliases'."
  105.   nil)
  106.  
  107. (autoload 'expand-mail-aliases "mailalias"
  108.   "Expand all mail aliases in suitable header fields found between BEG and END.
  109. Suitable header fields are `To', `Cc' and `Bcc' and their `Resent-' variants.
  110. Optional second arg EXCLUDE may be a regular expression defining text to be
  111. removed from alias expansions."
  112.   nil)
  113.  
  114. ;;;###autoload
  115. (defvar mail-signature nil
  116.   "*Text inserted at end of mail buffer when a message is initialized.
  117. If t, it means to insert the contents of the file `~/.signature'.")
  118.  
  119. (defvar mail-reply-buffer nil)
  120. (defvar mail-send-actions nil
  121.   "A list of actions to be performed upon successful sending of a message.")
  122.  
  123. (defvar mail-default-headers nil
  124.   "*A string containing header lines, to be inserted in outgoing messages.
  125. It is inserted before you edit the message,
  126. so you can edit or delete these lines.")
  127.  
  128. (defvar mail-mode-syntax-table nil
  129.   "Syntax table used while in mail mode.")
  130.  
  131. (if (null mail-mode-syntax-table)
  132.     (progn
  133.      (setq mail-mode-syntax-table (copy-syntax-table text-mode-syntax-table))
  134.      (modify-syntax-entry ?% ". " mail-mode-syntax-table)))
  135.  
  136. (defun mail-setup (to subject in-reply-to cc replybuffer actions)
  137.   (if (eq mail-aliases t)
  138.       (progn
  139.     (setq mail-aliases nil)
  140.     (if (file-exists-p "~/.mailrc")
  141.         (build-mail-aliases))))
  142.   (setq mail-send-actions actions)
  143.   (setq mail-reply-buffer replybuffer)
  144.   (goto-char (point-min))
  145.   (insert "To: ")
  146.   (save-excursion
  147.     (if to
  148.     ;; Here removed code to extract names from within <...>
  149.     ;; on the assumption that mail-strip-quoted-names
  150.     ;; has been called and has done so.
  151.     (let ((fill-prefix "\t")
  152.           (address-start (point)))
  153.       (insert to "\n")
  154.       (fill-region-as-paragraph address-start (point-max)))
  155.       (newline))
  156.     (if cc
  157.     (let ((fill-prefix "\t")
  158.           (address-start (progn (insert "CC: ") (point))))
  159.       (insert cc "\n")
  160.       (fill-region-as-paragraph address-start (point-max))))
  161.     (if in-reply-to
  162.     (insert "In-reply-to: " in-reply-to "\n"))
  163.     (insert "Subject: " (or subject "") "\n")
  164.     (if mail-default-headers
  165.     (insert mail-default-headers))
  166.     (if mail-default-reply-to
  167.     (insert "Reply-to: " mail-default-reply-to "\n"))
  168.     (if mail-self-blind
  169.     (insert "BCC: " (user-login-name) "\n"))
  170.     (if mail-archive-file-name
  171.     (insert "FCC: " mail-archive-file-name "\n"))
  172.     (insert mail-header-separator "\n")
  173.     ;; Insert the signature.  But remember the beginning of the message.
  174.     (if to (setq to (point)))
  175.     (cond ((eq mail-signature t)
  176.        (if (file-exists-p "~/.signature")
  177.            (insert-file-contents "~/.signature")))
  178.       (mail-signature
  179.        (insert mail-signature)))
  180.     (goto-char (point-max))
  181.     (or (bolp) (newline)))
  182.   (if to (goto-char to))
  183.   (or to subject in-reply-to
  184.       (set-buffer-modified-p nil))
  185.   (run-hooks 'mail-setup-hook))
  186.  
  187. ;;;###autoload
  188. (defun mail-mode ()
  189.   "Major mode for editing mail to be sent.
  190. Like Text Mode but with these additional commands:
  191. C-c C-s  mail-send (send the message)    C-c C-c  mail-send-and-exit
  192. C-c C-f  move to a header field (and create it if there isn't):
  193.      C-c C-f C-t  move to To:    C-c C-f C-s  move to Subj:
  194.      C-c C-f C-b  move to BCC:    C-c C-f C-c  move to CC:
  195. C-c C-t  move to message text.
  196. C-c C-y  mail-yank-original (insert current message, in Rmail).
  197. C-c C-q  mail-fill-yanked-message (fill what was yanked).
  198. C-c C-v  mail-sent-via (add a sent-via field for each To or CC)."
  199.   (interactive)
  200.   (kill-all-local-variables)
  201.   (make-local-variable 'mail-reply-buffer)
  202.   (setq mail-reply-buffer nil)
  203.   (make-local-variable 'mail-send-actions)
  204.   (set-syntax-table mail-mode-syntax-table)
  205.   (use-local-map mail-mode-map)
  206.   (setq local-abbrev-table text-mode-abbrev-table)
  207.   (setq major-mode 'mail-mode)
  208.   (setq mode-name "Mail")
  209.   (setq buffer-offer-save t)
  210.   (make-local-variable 'paragraph-separate)
  211.   (make-local-variable 'paragraph-start)
  212.   (setq paragraph-start (concat "^" mail-header-separator
  213.                 "$\\|^[ \t]*[-_][-_][-_]+$\\|"
  214.                 paragraph-start))
  215.   (setq paragraph-separate (concat "^" mail-header-separator
  216.                    "$\\|^[ \t]*[-_][-_][-_]+$\\|"
  217.                    paragraph-separate))
  218.   (run-hooks 'text-mode-hook 'mail-mode-hook))
  219.  
  220. ;;; Set up keymap.
  221.  
  222. (if mail-mode-map
  223.     nil
  224.   (setq mail-mode-map (nconc (make-sparse-keymap) text-mode-map))
  225.   (define-key mail-mode-map "\C-c?" 'describe-mode)
  226.   (define-key mail-mode-map "\C-c\C-f\C-t" 'mail-to)
  227.   (define-key mail-mode-map "\C-c\C-f\C-b" 'mail-bcc)
  228.   (define-key mail-mode-map "\C-c\C-f\C-f" 'mail-fcc)
  229.   (define-key mail-mode-map "\C-c\C-f\C-c" 'mail-cc)
  230.   (define-key mail-mode-map "\C-c\C-f\C-s" 'mail-subject)
  231.   (define-key mail-mode-map "\C-c\C-t" 'mail-text)
  232.   (define-key mail-mode-map "\C-c\C-y" 'mail-yank-original)
  233.   (define-key mail-mode-map "\C-c\C-q" 'mail-fill-yanked-message)
  234.   (define-key mail-mode-map "\C-c\C-w" 'mail-signature)
  235.   (define-key mail-mode-map "\C-c\C-v" 'mail-sent-via)
  236.   (define-key mail-mode-map "\C-c\C-c" 'mail-send-and-exit)
  237.   (define-key mail-mode-map "\C-c\C-s" 'mail-send))
  238.  
  239. (define-key mail-mode-map [menu-bar mail]
  240.   (cons "Mail" (make-sparse-keymap "Mail")))
  241.  
  242. (define-key mail-mode-map [menu-bar mail fill]
  243.   '("Fill Citation" . mail-fill-yanked-message))
  244.  
  245. (define-key mail-mode-map [menu-bar mail yank]
  246.   '("Cite Original" . mail-yank-original))
  247.  
  248. (define-key mail-mode-map [menu-bar mail signature]
  249.   '("Insert Signature" . mail-signature))
  250.  
  251. (define-key mail-mode-map [menu-bar mail send-stay]
  252.   '("Send, Keep Editing" . mail-send))
  253.  
  254. (define-key mail-mode-map [menu-bar mail send]
  255.   '("Send Message" . mail-send-and-exit))
  256.  
  257. (define-key mail-mode-map [menu-bar headers]
  258.   (cons "Headers" (make-sparse-keymap "Headers")))
  259.  
  260. (define-key mail-mode-map [menu-bar headers sent-via]
  261.   '("Sent Via" . mail-sent-via))
  262.  
  263. (define-key mail-mode-map [menu-bar headers text]
  264.   '("Text" . mail-text))
  265.  
  266. (define-key mail-mode-map [menu-bar headers bcc]
  267.   '("Bcc" . mail-bcc))
  268.  
  269. (define-key mail-mode-map [menu-bar headers fcc]
  270.   '("Fcc" . mail-fcc))
  271.  
  272. (define-key mail-mode-map [menu-bar headers cc]
  273.   '("Cc" . mail-cc))
  274.  
  275. (define-key mail-mode-map [menu-bar headers subject]
  276.   '("Subject" . mail-subject))
  277.  
  278. (define-key mail-mode-map [menu-bar headers to]
  279.   '("To" . mail-to))
  280.  
  281. (defun mail-send-and-exit (arg)
  282.   "Send message like `mail-send', then, if no errors, exit from mail buffer.
  283. Prefix arg means don't delete this window."
  284.   (interactive "P")
  285.   (mail-send)
  286.   (let ((newbuf (other-buffer (current-buffer))))
  287.     (bury-buffer (current-buffer))
  288.     (if (and (not arg)
  289.          (not (one-window-p))
  290.          (save-excursion
  291.            (set-buffer (window-buffer (next-window (selected-window) 'not)))
  292.            (eq major-mode 'rmail-mode)))
  293.     (delete-window)
  294.       (switch-to-buffer newbuf))))
  295.  
  296. (defun mail-send ()
  297.   "Send the message in the current buffer.
  298. If `mail-interactive' is non-nil, wait for success indication
  299. or error messages, and inform user.
  300. Otherwise any failure is reported in a message back to
  301. the user from the mailer."
  302.   (interactive)
  303.   (if (if buffer-file-name
  304.       (y-or-n-p "Send buffer contents as mail message? ")
  305.     (or (buffer-modified-p)
  306.         (y-or-n-p "Message already sent; resend? ")))
  307.       (progn
  308.     (message "Sending...")
  309.     (run-hooks 'mail-send-hook)
  310.     (funcall send-mail-function)
  311.     ;; Now perform actions on successful sending.
  312.     (while mail-send-actions
  313.       (condition-case nil
  314.           (apply (car (car mail-send-actions))
  315.              (cdr (car mail-send-actions)))
  316.         (error))
  317.       (setq mail-send-actions (cdr mail-send-actions)))
  318.     (message "Sending...done")
  319.     ;; If buffer has no file, mark it as unmodified and delete autosave.
  320.     (if (not buffer-file-name)
  321.         (progn
  322.           (set-buffer-modified-p nil)
  323.           (delete-auto-save-file-if-necessary t))))))
  324.  
  325. (defun sendmail-send-it ()
  326.   (let ((errbuf (if mail-interactive
  327.             (generate-new-buffer " sendmail errors")
  328.           0))
  329.     (tembuf (generate-new-buffer " sendmail temp"))
  330.     (case-fold-search nil)
  331.     delimline
  332.     (mailbuf (current-buffer)))
  333.     (unwind-protect
  334.     (save-excursion
  335.       (set-buffer tembuf)
  336.       (erase-buffer)
  337.       (insert-buffer-substring mailbuf)
  338.       (goto-char (point-max))
  339.       ;; require one newline at the end.
  340.       (or (= (preceding-char) ?\n)
  341.           (insert ?\n))
  342.       ;; Change header-delimiter to be what sendmail expects.
  343.       (goto-char (point-min))
  344.       (re-search-forward
  345.         (concat "^" (regexp-quote mail-header-separator) "\n"))
  346.       (replace-match "\n")
  347.       (backward-char 1)
  348.       (setq delimline (point-marker))
  349.       (if mail-aliases
  350.           (expand-mail-aliases (point-min) delimline))
  351.       (goto-char (point-min))
  352.       ;; ignore any blank lines in the header
  353.       (while (and (re-search-forward "\n\n\n*" delimline t)
  354.               (< (point) delimline))
  355.         (replace-match "\n"))
  356.       (let ((case-fold-search t))
  357.         (goto-char (point-min))
  358.         (if (re-search-forward "^Sender:" delimline t)
  359.         (error "Sender may not be specified."))
  360.         ;; Find and handle any FCC fields.
  361.         (goto-char (point-min))
  362.         (if (re-search-forward "^FCC:" delimline t)
  363.         (mail-do-fcc delimline))
  364.         ;; If the From is different than current user, insert Sender.
  365.         (goto-char (point-min))
  366.         (and (re-search-forward "^From:"  delimline t)
  367.          (progn
  368.            (require 'mail-utils)
  369.            (not (string-equal
  370.              (mail-strip-quoted-names
  371.               (save-restriction
  372.                 (narrow-to-region (point-min) delimline)
  373.                 (mail-fetch-field "From")))
  374.              (user-login-name))))
  375.          (progn
  376.            (forward-line 1)
  377.            (insert "Sender: " (user-login-name) "\n")))
  378.         ;; "S:" is an abbreviation for "Subject:".
  379.         (goto-char (point-min))
  380.         (if (re-search-forward "^S:" delimline t)
  381.         (replace-match "Subject:"))
  382.         ;; Don't send out a blank subject line
  383.         (goto-char (point-min))
  384.         (if (re-search-forward "^Subject:[ \t]*\n" delimline t)
  385.         (replace-match ""))
  386.         (if mail-interactive
  387.         (save-excursion
  388.           (set-buffer errbuf)
  389.           (erase-buffer))))
  390.       (apply 'call-process-region
  391.          (append (list (point-min) (point-max)
  392.                    (if (boundp 'sendmail-program)
  393.                    sendmail-program
  394.                  "/usr/lib/sendmail")
  395.                    nil errbuf nil
  396.                    "-oi" "-t")
  397.              ;; Always specify who from,
  398.              ;; since some systems have broken sendmails.
  399.              (list "-f" (user-login-name))
  400. ;;;             ;; Don't say "from root" if running under su.
  401. ;;;             (and (equal (user-real-login-name) "root")
  402. ;;;                  (list "-f" (user-login-name)))
  403.              (and mail-alias-file
  404.                   (list (concat "-oA" mail-alias-file)))
  405.              ;; These mean "report errors by mail"
  406.              ;; and "deliver in background".
  407.              (if (null mail-interactive) '("-oem" "-odb"))))
  408.       (if mail-interactive
  409.           (save-excursion
  410.         (set-buffer errbuf)
  411.         (goto-char (point-min))
  412.         (while (re-search-forward "\n\n* *" nil t)
  413.           (replace-match "; "))
  414.         (if (not (zerop (buffer-size)))
  415.             (error "Sending...failed to %s"
  416.                (buffer-substring (point-min) (point-max)))))))
  417.       (kill-buffer tembuf)
  418.       (if (bufferp errbuf)
  419.       (kill-buffer errbuf)))))
  420.  
  421. (defun mail-do-fcc (header-end)
  422.   (let (fcc-list
  423.     (rmailbuf (current-buffer))
  424.     (time (current-time))
  425.     timezone
  426.     (tembuf (generate-new-buffer " rmail output"))
  427.     (case-fold-search t))
  428.     (save-excursion
  429.       (goto-char (point-min))
  430.       (while (re-search-forward "^FCC:[ \t]*" header-end t)
  431.     (setq fcc-list (cons (buffer-substring (point)
  432.                            (progn
  433.                          (end-of-line)
  434.                          (skip-chars-backward " \t")
  435.                          (point)))
  436.                  fcc-list))
  437.     (delete-region (match-beginning 0)
  438.                (progn (forward-line 1) (point))))
  439.       (let* ((foo (current-time-zone time))
  440.          (offset (if (car foo) (/ (car foo) 60) 0))
  441.          (abs (abs offset)))
  442.     (setq timezone (format "%s%02d%02d"
  443.                    (if (< offset 0) "-" "+")
  444.                    (/ abs 60)
  445.                    (% abs 60))))
  446.       (set-buffer tembuf)
  447.       (erase-buffer)
  448.       ;; This initial newline is written out if the fcc file already exists.
  449.       (insert "\nFrom " (user-login-name) " "
  450.           (current-time-string time) "\n")
  451.       ;; Insert the time zone before the year.
  452.       (forward-char -1)
  453.       (forward-word -1)
  454.       (insert timezone " ")
  455.       (goto-char (point-max))
  456.       (insert-buffer-substring rmailbuf)
  457.       ;; Make sure messages are separated.
  458.       (goto-char (point-max))
  459.       (insert ?\n)
  460.       (goto-char 2)
  461.       ;; ``Quote'' "^From " as ">From "
  462.       ;;  (note that this isn't really quoting, as there is no requirement
  463.       ;;   that "^[>]+From " be quoted in the same transparent way.)
  464.       (let ((case-fold-search nil))
  465.     (while (search-forward "\nFrom " nil t)
  466.       (forward-char -5)
  467.       (insert ?>)))
  468.       (while fcc-list
  469.     (let ((buffer (get-file-buffer (car fcc-list))))
  470.       (if buffer
  471.           ;; File is present in a buffer => append to that buffer.
  472.           (let ((curbuf (current-buffer))
  473.             (beg (point-min)) (end (point-max))
  474.             (beg2 (save-excursion (goto-char (point-min))
  475.                       (forward-line 2) (point))))
  476.         (save-excursion
  477.           (set-buffer buffer)
  478.           ;; Keep the end of the accessible portion at the same place
  479.           ;; unless it is the end of the buffer.
  480.           (let ((max (if (/= (1+ (buffer-size)) (point-max))
  481.                  (point-max))))
  482.             (unwind-protect
  483.             ;; Code below lifted from rmailout.el
  484.             ;; function rmail-output-to-rmail-file:
  485.             (let ((buffer-read-only nil)
  486.                   (msg (and (boundp 'rmail-current-message)
  487.                     rmail-current-message)))
  488.               ;; If MSG is non-nil, buffer is in RMAIL mode.
  489.               (if msg
  490.                   (progn
  491.                 (rmail-maybe-set-message-counters)
  492.                 (widen)
  493.                 (narrow-to-region (point-max) (point-max))
  494.                 (insert "\C-l\n0, unseen,,\n*** EOOH ***\n"
  495.                     "From: " (user-login-name) "\n"
  496.                     "Date: " (current-time-string) "\n")
  497.                 (insert-buffer-substring curbuf beg2 end)
  498.                 (insert "\n\C-_")
  499.                 (goto-char (point-min))
  500.                 (widen)
  501.                 (search-backward "\n\^_")
  502.                 (narrow-to-region (point) (point-max))
  503.                 (rmail-count-new-messages t)
  504.                 (rmail-show-message msg)
  505.                 (setq max nil))
  506.                 ;; Output file not in rmail mode
  507.                 ;; => just insert at the end.
  508.                 (narrow-to-region (point-min) (1+ (buffer-size)))
  509.                 (goto-char (point-max))
  510.                 (insert-buffer-substring curbuf beg end)))
  511.               (if max (narrow-to-region (point-min) max))))))
  512.         ;; Else append to the file directly.
  513.         (write-region
  514.          ;; Include a blank line before if file already exists.
  515.  
  516.          (if (file-exists-p (car fcc-list)) (point-min) (1+ (point-min)))
  517.          (point-max) (car fcc-list) t)))
  518.     (setq fcc-list (cdr fcc-list))))
  519.     (kill-buffer tembuf)))
  520.  
  521. (defun mail-sent-via ()
  522.   "Make a Sent-via header line from each To or CC header line."
  523.   (interactive)
  524.   (save-excursion
  525.     (goto-char (point-min))
  526.     ;; find the header-separator
  527.     (search-forward (concat "\n" mail-header-separator "\n"))
  528.     (forward-line -1)
  529.     ;; put a marker at the end of the header
  530.     (let ((end (point-marker))
  531.       (case-fold-search t)
  532.       to-line)
  533.       (goto-char (point-min))
  534.       ;; search for the To: lines and make Sent-via: lines from them
  535.       ;; search for the next To: line
  536.       (while (re-search-forward "^\\(to\\|cc\\):" end t)
  537.     ;; Grab this line plus all its continuations, sans the `to:'.
  538.     (let ((to-line
  539.            (buffer-substring (point)
  540.                  (progn
  541.                    (if (re-search-forward "^[^ \t\n]" end t)
  542.                        (backward-char 1)
  543.                      (goto-char end))
  544.                    (point)))))
  545.       ;; Insert a copy, with altered header field name.
  546.       (insert-before-markers "Sent-via:" to-line))))))
  547.  
  548. (defun mail-to ()
  549.   "Move point to end of To-field."
  550.   (interactive)
  551.   (expand-abbrev)
  552.   (mail-position-on-field "To"))
  553.  
  554. (defun mail-subject ()
  555.   "Move point to end of Subject-field."
  556.   (interactive)
  557.   (expand-abbrev)
  558.   (mail-position-on-field "Subject"))
  559.  
  560. (defun mail-cc ()
  561.   "Move point to end of CC-field.  Create a CC field if none."
  562.   (interactive)
  563.   (expand-abbrev)
  564.   (or (mail-position-on-field "cc" t)
  565.       (progn (mail-position-on-field "to")
  566.          (insert "\nCC: "))))
  567.  
  568. (defun mail-bcc ()
  569.   "Move point to end of BCC-field.  Create a BCC field if none."
  570.   (interactive)
  571.   (expand-abbrev)
  572.   (or (mail-position-on-field "bcc" t)
  573.       (progn (mail-position-on-field "to")
  574.          (insert "\nBCC: "))))
  575.  
  576. (defun mail-fcc ()
  577.   "Add a new FCC field, with file name completion."
  578.   (interactive)
  579.   (expand-abbrev)
  580.   (or (mail-position-on-field "fcc" t)    ;Put new field after exiting FCC.
  581.       (mail-position-on-field "to"))
  582.   (insert "\nFCC: " (read-file-name "Folder carbon copy: ")))
  583.  
  584. (defun mail-position-on-field (field &optional soft)
  585.   (let (end
  586.     (case-fold-search t))
  587.     (goto-char (point-min))
  588.     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "\n"))
  589.     (setq end (match-beginning 0))
  590.     (goto-char (point-min))
  591.     (if (re-search-forward (concat "^" (regexp-quote field) ":") end t)
  592.     (progn
  593.       (re-search-forward "^[^ \t]" nil 'move)
  594.       (beginning-of-line)
  595.       (skip-chars-backward "\n")
  596.       t)
  597.       (or soft
  598.       (progn (goto-char end)
  599.          (insert field ": \n")
  600.          (skip-chars-backward "\n")))
  601.       nil)))
  602.  
  603. (defun mail-text ()
  604.   "Move point to beginning of text field."
  605.   (interactive)
  606.   (goto-char (point-min))
  607.   (search-forward (concat "\n" mail-header-separator "\n")))
  608.  
  609. (defun mail-signature (atpoint)
  610.   "Sign letter with contents of `mail-signature-file'."
  611.   (interactive "P")
  612.   (save-excursion
  613.     (or atpoint
  614.     (goto-char (point-max)))
  615.     (skip-chars-backward " \t\n")
  616.     (end-of-line)
  617.     (or atpoint
  618.     (delete-region (point) (point-max)))
  619.     (insert "\n\n")
  620.     (insert-file-contents (expand-file-name "~/.signature"))))
  621.  
  622. (defun mail-fill-yanked-message (&optional justifyp)
  623.   "Fill the paragraphs of a message yanked into this one.
  624. Numeric argument means justify as well."
  625.   (interactive "P")
  626.   (save-excursion
  627.     (goto-char (point-min))
  628.     (search-forward (concat "\n" mail-header-separator "\n") nil t)
  629.     (fill-individual-paragraphs (point)
  630.                 (point-max)
  631.                 justifyp
  632.                 t)))
  633.  
  634. (defun mail-indent-citation ()
  635.   "Modify text just inserted from a message to be cited.
  636. The inserted text should be the region.
  637. When this function returns, the region is again around the modified text.
  638.  
  639. Normally, indent each nonblank line `mail-indentation-spaces' spaces.
  640. However, if `mail-yank-prefix' is non-nil, insert that prefix on each line."
  641.   (let ((start (point)))
  642.     (mail-yank-clear-headers start (mark t))
  643.     (if (null mail-yank-prefix)
  644.     (indent-rigidly start (mark t) mail-indentation-spaces)
  645.       (save-excursion
  646.     (goto-char start)
  647.     (while (< (point) (mark t))
  648.       (insert mail-yank-prefix)
  649.       (forward-line 1))))))
  650.  
  651. (defun mail-yank-original (arg)
  652.   "Insert the message being replied to, if any (in rmail).
  653. Puts point before the text and mark after.
  654. Normally, indents each nonblank line ARG spaces (default 3).
  655. However, if `mail-yank-prefix' is non-nil, insert that prefix on each line.
  656.  
  657. Just \\[universal-argument] as argument means don't indent, insert no prefix,
  658. and don't delete any header fields."
  659.   (interactive "P")
  660.   (if mail-reply-buffer
  661.       (let ((start (point)))
  662.     (delete-windows-on mail-reply-buffer)
  663.     (insert-buffer mail-reply-buffer)
  664.     (if (consp arg)
  665.         nil
  666.       (goto-char start)
  667.       (let ((mail-indentation-spaces (if arg (prefix-numeric-value arg)
  668.                        mail-indentation-spaces)))
  669.         (if mail-citation-hook
  670.         (run-hooks 'mail-citation-hook)
  671.           (run-hooks 'mail-yank-hooks))))
  672.     ;; This is like exchange-point-and-mark, but doesn't activate the mark.
  673.     ;; It is cleaner to avoid activation, even though the command
  674.     ;; loop would deactivate the mark because we inserted text.
  675.     (goto-char (prog1 (mark t)
  676.              (set-marker (mark-marker) (point) (current-buffer))))
  677.     (if (not (eolp)) (insert ?\n)))))
  678.  
  679. (defun mail-yank-clear-headers (start end)
  680.   (save-excursion
  681.     (goto-char start)
  682.     (if (search-forward "\n\n" end t)
  683.     (save-restriction
  684.       (narrow-to-region start (point))
  685.       (goto-char start)
  686.       (while (let ((case-fold-search t))
  687.            (re-search-forward mail-yank-ignored-headers nil t))
  688.         (beginning-of-line)
  689.         (delete-region (point)
  690.                (progn (re-search-forward "\n[^ \t]")
  691.                   (forward-char -1)
  692.                   (point))))))))
  693.  
  694. ;; Put these last, to reduce chance of lossage from quitting in middle of loading the file.
  695.  
  696. ;;;###autoload
  697. (defun mail (&optional noerase to subject in-reply-to cc replybuffer actions)
  698.   "Edit a message to be sent.  Prefix arg means resume editing (don't erase).
  699. When this function returns, the buffer `*mail*' is selected.
  700. The value is t if the message was newly initialized; otherwise, nil.
  701.  
  702. By default, the signature file `~/.signature' is inserted at the end;
  703. see the variable `mail-signature'.
  704.  
  705. \\<mail-mode-map>
  706. While editing message, type \\[mail-send-and-exit] to send the message and exit.
  707.  
  708. Various special commands starting with C-c are available in sendmail mode
  709. to move to message header fields:
  710. \\{mail-mode-map}
  711.  
  712. If `mail-self-blind' is non-nil, a BCC to yourself is inserted
  713. when the message is initialized.
  714.  
  715. If `mail-default-reply-to' is non-nil, it should be an address (a string);
  716. a Reply-to: field with that address is inserted.
  717.  
  718. If `mail-archive-file-name' is non-nil, an FCC field with that file name
  719. is inserted.
  720.  
  721. If `mail-setup-hook' is bound, its value is called with no arguments
  722. after the message is initialized.  It can add more default fields.
  723.  
  724. When calling from a program, the second through fifth arguments
  725.  TO, SUBJECT, IN-REPLY-TO and CC specify if non-nil
  726.  the initial contents of those header fields.
  727.  These arguments should not have final newlines.
  728. The sixth argument REPLYBUFFER is a buffer whose contents
  729.  should be yanked if the user types C-c C-y.
  730. The seventh argument ACTIONS is a list of actions to take
  731.  if/when the message is sent.  Each action looks like (FUNCTION . ARGS);
  732.  when the message is sent, we apply FUNCTION to ARGS.
  733.  This is how Rmail arranges to mark messages `answered'."
  734.   (interactive "P")
  735. ;;; This is commented out because I found it was confusing in practice.
  736. ;;; It is easy enough to rename *mail* by hand with rename-buffer
  737. ;;; if you want to have multiple mail buffers.
  738. ;;; And then you can control which messages to save. --rms.
  739. ;;;  (let ((index 1)
  740. ;;;    buffer)
  741. ;;;    ;; If requested, look for a mail buffer that is modified and go to it.
  742. ;;;    (if noerase
  743. ;;;    (progn
  744. ;;;      (while (and (setq buffer
  745. ;;;                (get-buffer (if (= 1 index) "*mail*"
  746. ;;;                      (format "*mail*<%d>" index))))
  747. ;;;              (not (buffer-modified-p buffer)))
  748. ;;;        (setq index (1+ index)))
  749. ;;;      (if buffer (switch-to-buffer buffer)
  750. ;;;        ;; If none exists, start a new message.
  751. ;;;        ;; This will never re-use an existing unmodified mail buffer
  752. ;;;        ;; (since index is not 1 anymore).  Perhaps it should.
  753. ;;;        (setq noerase nil))))
  754. ;;;    ;; Unless we found a modified message and are happy, start a new message.
  755. ;;;    (if (not noerase)
  756. ;;;    (progn
  757. ;;;      ;; Look for existing unmodified mail buffer.
  758. ;;;      (while (and (setq buffer
  759. ;;;                (get-buffer (if (= 1 index) "*mail*"
  760. ;;;                      (format "*mail*<%d>" index))))
  761. ;;;              (buffer-modified-p buffer))
  762. ;;;        (setq index (1+ index)))
  763. ;;;      ;; If none, make a new one.
  764. ;;;      (or buffer
  765. ;;;          (setq buffer (generate-new-buffer "*mail*")))
  766. ;;;      ;; Go there and initialize it.
  767. ;;;      (switch-to-buffer buffer)
  768. ;;;      (erase-buffer)
  769. ;;;          (setq default-directory (expand-file-name "~/"))
  770. ;;;          (auto-save-mode auto-save-default)
  771. ;;;          (mail-mode)
  772. ;;;          (mail-setup to subject in-reply-to cc replybuffer actions)
  773. ;;;      (if (and buffer-auto-save-file-name
  774. ;;;           (file-exists-p buffer-auto-save-file-name))
  775. ;;;          (message "Auto save file for draft message exists; consider M-x mail-recover"))
  776. ;;;          t))
  777.   (switch-to-buffer "*mail*")
  778.   (setq default-directory (expand-file-name "~/"))
  779.   (auto-save-mode auto-save-default)
  780.   (mail-mode)
  781.   (let (initialized)
  782.     (and (not noerase)
  783.      (or (not (buffer-modified-p))
  784.          (y-or-n-p "Unsent message being composed; erase it? "))
  785.      (progn (erase-buffer)
  786.         (mail-setup to subject in-reply-to cc replybuffer actions)
  787.         (setq initialized t)))
  788.     (if (and buffer-auto-save-file-name
  789.          (file-exists-p buffer-auto-save-file-name))
  790.     (message "Auto save file for draft message exists; consider M-x mail-recover"))
  791.     initialized))
  792.  
  793. (defun mail-recover ()
  794.   "Reread contents of current buffer from its last auto-save file."
  795.   (interactive)
  796.   (let ((file-name (make-auto-save-file-name)))
  797.     (cond ((save-window-excursion
  798.          (if (not (eq system-type 'vax-vms))
  799.          (with-output-to-temp-buffer "*Directory*"
  800.            (buffer-disable-undo standard-output)
  801.            (call-process "ls" nil standard-output nil "-l" file-name)))
  802.          (yes-or-no-p (format "Recover auto save file %s? " file-name)))
  803.        (let ((buffer-read-only nil))
  804.          (erase-buffer)
  805.          (insert-file-contents file-name nil)))
  806.       (t (error "mail-recover cancelled.")))))
  807.  
  808. ;;;###autoload
  809. (defun mail-other-window (&optional noerase to subject in-reply-to cc replybuffer sendactions)
  810.   "Like `mail' command, but display mail buffer in another window."
  811.   (interactive "P")
  812.   (let ((pop-up-windows t))
  813.     (pop-to-buffer "*mail*"))
  814.   (mail noerase to subject in-reply-to cc replybuffer sendactions))
  815.  
  816. ;;;###autoload
  817. (defun mail-other-frame (&optional noerase to subject in-reply-to cc replybuffer sendactions)
  818.   "Like `mail' command, but display mail buffer in another frame."
  819.   (interactive "P")
  820.   (let ((pop-up-frames t))
  821.     (pop-to-buffer "*mail*"))
  822.   (mail noerase to subject in-reply-to cc replybuffer sendactions))
  823.  
  824.  
  825. ;;;###autoload
  826. (define-key ctl-x-map "m" 'mail)
  827.  
  828. ;;;###autoload
  829. (define-key ctl-x-4-map "m" 'mail-other-window)
  830.  
  831. ;;;###autoload
  832. (define-key ctl-x-5-map "m" 'mail-other-frame)
  833.  
  834.  
  835. ;;; Do not add anything but external entries on this page.
  836.  
  837. (provide 'sendmail)
  838.  
  839. ;;; sendmail.el ends here
  840.